configure.ac: Add a --without-python option.

Being able to be explicit about Python support (in addition to the
default of auto-detecting it) and acting upon the result, specifying
it as an option gains us more control about both dependencies and
the resulting build.

Furthermore, relying purely on auto-detection can lead to problems for
source-based distros. E. g. systemd being built before *both* 32-bit &
64-bit ABIs are installed will lead to build failures as systemd's
build system will pick up either 32-/64-bit Python, conclude both are
available and fail if that's not the case.

diff --git a/configure.ac b/configure.ac
index fe8137d81848951f97766d5232e54f04924deec4..1bb657d157ac744d5d41c898656a1a3208cba64b 100644 (file)
--- a/configure.ac
+++ b/configure.ac
@@ -92,19 +92,26 @@ fi
 # we use python to build the man page index, and for systemd-python
 have_python=no
 have_python_devel=no
-AM_PATH_PYTHON(,, [:])
-if test "$PYTHON" != : ; then
-        have_python=yes
-        AC_PATH_PROG([PYTHON_CONFIG], python-config)
-
-        if test -n "$PYTHON_CONFIG" ; then
-                have_python_devel=yes
-                PYTHON_CFLAGS="`$PYTHON_CONFIG --cflags`"
-                PYTHON_LIBS="`$PYTHON_CONFIG --libs`"
-                AC_SUBST(PYTHON_CFLAGS)
-                AC_SUBST(PYTHON_LIBS)
+
+AC_ARG_WITH([python],
+        [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
+
+AS_IF([test "x$with_python" != "xno"], [
+        AM_PATH_PYTHON(,, [:])
+        if test "$PYTHON" != : ; then
+                have_python=yes
+                AC_PATH_PROG([PYTHON_CONFIG], python-config)
+
+                if test -n "$PYTHON_CONFIG" ; then
+                        have_python_devel=yes
+                        PYTHON_CFLAGS="`$PYTHON_CONFIG --cflags`"
+                        PYTHON_LIBS="`$PYTHON_CONFIG --libs`"
+                        AC_SUBST(PYTHON_CFLAGS)
+                        AC_SUBST(PYTHON_LIBS)
+                fi
         fi
-fi
+])
+
 AM_CONDITIONAL([HAVE_PYTHON], [test "$have_python" = "yes"])
 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])