configure.ac

   1
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [194],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT
  46
  47 # i18n stuff for the PolicyKit policy files
  48 IT_PROG_INTLTOOL([0.40.0])
  49
  50 GETTEXT_PACKAGE=systemd
  51 AC_SUBST(GETTEXT_PACKAGE)
  52
  53 AC_PROG_MKDIR_P
  54 AC_PROG_LN_S
  55 AC_PROG_SED
  56 AC_PROG_GREP
  57 AC_PROG_AWK
  58
  59 AC_PROG_CC
  60 AC_PROG_CC_C99
  61 AM_PROG_CC_C_O
  62 AC_PROG_GCC_TRADITIONAL
  63
  64 AC_PATH_PROG([M4], [m4])
  65 AC_PATH_PROG([XSLTPROC], [xsltproc])
  66
  67 AC_PATH_PROG([QUOTAON], [quotaon], [/sbin/quotaon])
  68 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/sbin/quotacheck])
  69
  70 AC_PATH_PROG([SETCAP], [setcap], [/sbin/setcap])
  71
  72 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  73 m4_ifdef([GTK_DOC_CHECK], [
  74 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])
  75 ], [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
  76
  77 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  78         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  79 ])
  80
  81 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  82 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  83 ], [AM_CONDITIONAL([HAVE_INTROSPECTION], [false])])
  84
  85 AC_PATH_TOOL(OBJCOPY, objcopy)
  86 AC_PATH_TOOL(STRINGS, strings)
  87 AC_PATH_TOOL(GPERF, gperf)
  88 if test -z "$GPERF" ; then
  89         AC_MSG_ERROR([*** gperf not found])
  90 fi
  91
  92 # we use python to build the man page index, and for systemd-python
  93 have_python=no
  94 have_python_devel=no
  95
  96 AC_ARG_WITH([python],
  97         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
  98
  99 AS_IF([test "x$with_python" != "xno"], [
 100         AM_PATH_PYTHON(,, [:])
 101         if test "$PYTHON" != : ; then
 102                 have_python=yes
 103                 AC_PATH_PROG([PYTHON_CONFIG], python-config)
 104
 105                 if test -n "$PYTHON_CONFIG" ; then
 106                         have_python_devel=yes
 107                         PYTHON_CFLAGS="`$PYTHON_CONFIG --cflags`"
 108                         PYTHON_LIBS="`$PYTHON_CONFIG --libs`"
 109                         AC_SUBST(PYTHON_CFLAGS)
 110                         AC_SUBST(PYTHON_LIBS)
 111                 fi
 112         fi
 113 ])
 114
 115 AM_CONDITIONAL([HAVE_PYTHON], [test "$have_python" = "yes"])
 116 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 117
 118 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 119         -pipe \
 120         -Wall \
 121         -Wextra \
 122         -Wno-inline \
 123         -Wundef \
 124         -Wformat=2 \
 125         -Wlogical-op \
 126         -Wsign-compare \
 127         -Wformat-security \
 128         -Wmissing-include-dirs \
 129         -Wformat-nonliteral \
 130         -Wold-style-definition \
 131         -Wpointer-arith \
 132         -Winit-self \
 133         -Wdeclaration-after-statement \
 134         -Wfloat-equal \
 135         -Wmissing-prototypes \
 136         -Wstrict-prototypes \
 137         -Wredundant-decls \
 138         -Wmissing-declarations \
 139         -Wmissing-noreturn \
 140         -Wshadow \
 141         -Wendif-labels \
 142         -Wcast-align \
 143         -Wstrict-aliasing=2 \
 144         -Wwrite-strings \
 145         -Wno-long-long \
 146         -Wno-overlength-strings \
 147         -Wno-unused-parameter \
 148         -Wno-missing-field-initializers \
 149         -Wno-unused-result \
 150         -Werror=overflow \
 151         -ffast-math \
 152         -fno-common \
 153         -fdiagnostics-show-option \
 154         -fno-strict-aliasing \
 155         -fvisibility=hidden \
 156         -ffunction-sections \
 157         -fdata-sections \
 158         -fstack-protector \
 159         --param=ssp-buffer-size=4])
 160 AC_SUBST([OUR_CFLAGS], $with_cflags)
 161
 162 CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 163         -Wp,-D_FORTIFY_SOURCE=2])
 164 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 165
 166 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 167         -Wl,--as-needed \
 168         -Wl,--gc-sections \
 169         -Wl,-z,relro \
 170         -Wl,-z,now])
 171 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 172
 173 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 174 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 175
 176 save_LIBS="$LIBS"
 177 LIBS=
 178 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 179 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 180 CAP_LIBS="$LIBS"
 181 LIBS="$save_LIBS"
 182 AC_SUBST(CAP_LIBS)
 183
 184 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 185 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 186 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 187 #include <unistd.h>
 188 #include <sys/mount.h>
 189 #include <fcntl.h>]])
 190
 191 # This makes sure pkg.m4 is available.
 192 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 193
 194 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 195 PKG_CHECK_MODULES(KMOD, [libkmod >= 5])
 196 PKG_CHECK_MODULES(BLKID,[blkid >= 2.20])
 197
 198 # ------------------------------------------------------------------------------
 199 have_ima=yes
 200 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 201                 [case "${enableval}" in
 202                         yes) have_ima=yes ;;
 203                         no) have_ima=no ;;
 204                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 205                 esac],
 206                 [have_ima=yes])
 207
 208 if test "x${have_ima}" != xno ; then
 209         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 210 fi
 211
 212 # ------------------------------------------------------------------------------
 213 have_selinux=no
 214 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 215 if test "x$enable_selinux" != "xno"; then
 216         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 217                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 218         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 219                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 220         fi
 221 fi
 222 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 223 if test "x${have_selinux}" != xno ; then
 224         sushell=/sbin/sushell
 225 else
 226         sushell=/bin/bash
 227 fi
 228 AC_SUBST(sushell)
 229
 230 # ------------------------------------------------------------------------------
 231 have_xz=no
 232 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 233 if test "x$enable_xz" != "xno"; then
 234         PKG_CHECK_MODULES(XZ, [ liblzma ],
 235                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 236         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 237                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 238         fi
 239 fi
 240 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 241
 242 # ------------------------------------------------------------------------------
 243 AC_ARG_ENABLE([tcpwrap],
 244         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 245                 [case "${enableval}" in
 246                         yes) have_tcpwrap=yes ;;
 247                         no) have_tcpwrap=no ;;
 248                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 249                 esac],
 250                 [have_tcpwrap=auto])
 251
 252 if test "x${have_tcpwrap}" != xno ; then
 253         ACX_LIBWRAP
 254         if test "x${LIBWRAP_LIBS}" = x ; then
 255                 if test "x$have_tcpwrap" = xyes ; then
 256                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 257                 fi
 258                 have_tcpwrap=no
 259         else
 260                 have_tcpwrap=yes
 261         fi
 262 else
 263         LIBWRAP_LIBS=
 264 fi
 265 AC_SUBST(LIBWRAP_LIBS)
 266
 267 # ------------------------------------------------------------------------------
 268 AC_ARG_ENABLE([pam],
 269         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 270                 [case "${enableval}" in
 271                         yes) have_pam=yes ;;
 272                         no) have_pam=no ;;
 273                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 274                 esac],
 275                 [have_pam=auto])
 276
 277 if test "x${have_pam}" != xno ; then
 278         AC_CHECK_HEADERS(
 279                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 280                 [have_pam=yes],
 281                 [if test "x$have_pam" = xyes ; then
 282                         AC_MSG_ERROR([*** PAM headers not found.])
 283                 fi])
 284
 285         AC_CHECK_LIB(
 286                 [pam],
 287                 [pam_syslog],
 288                 [have_pam=yes],
 289                 [if test "x$have_pam" = xyes ; then
 290                         AC_MSG_ERROR([*** libpam not found.])
 291                 fi])
 292
 293         if test "x$have_pam" = xyes ; then
 294                 PAM_LIBS="-lpam -lpam_misc"
 295                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 296         else
 297                 have_pam=no
 298         fi
 299 else
 300         PAM_LIBS=
 301 fi
 302 AC_SUBST(PAM_LIBS)
 303 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 304
 305 # ------------------------------------------------------------------------------
 306 AC_ARG_ENABLE([acl],
 307         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 308                 [case "${enableval}" in
 309                         yes) have_acl=yes ;;
 310                         no) have_acl=no ;;
 311                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 312                 esac],
 313                 [have_acl=auto])
 314
 315 if test "x${have_acl}" != xno ; then
 316         AC_CHECK_HEADERS(
 317                 [sys/acl.h acl/libacl.h],
 318                 [have_acl=yes],
 319                 [if test "x$have_acl" = xyes ; then
 320                         AC_MSG_ERROR([*** ACL headers not found.])
 321                 fi])
 322
 323         AC_CHECK_LIB(
 324                 [acl],
 325                 [acl_get_file],
 326                 [have_acl=yes],
 327                 [if test "x$have_acl" = xyes ; then
 328                         AC_MSG_ERROR([*** libacl not found.])
 329                 fi])
 330
 331         if test "x$have_acl" = xyes ; then
 332                 ACL_LIBS="-lacl"
 333                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 334         else
 335                 have_acl=no
 336         fi
 337 else
 338         ACL_LIBS=
 339 fi
 340 AC_SUBST(ACL_LIBS)
 341 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 342
 343 # ------------------------------------------------------------------------------
 344 AC_ARG_ENABLE([gcrypt],
 345         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 346                 [case "${enableval}" in
 347                         yes) have_gcrypt=yes ;;
 348                         no) have_gcrypt=no ;;
 349                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 350                 esac],
 351                 [have_gcrypt=auto])
 352
 353 if test "x${have_gcrypt}" != xno ; then
 354         AM_PATH_LIBGCRYPT(
 355                 [1.4.5],
 356                 [have_gcrypt=yes],
 357                 [if test "x$have_gcrypt" = xyes ; then
 358                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 359                 fi])
 360
 361         if test "x$have_gcrypt" = xyes ; then
 362                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 363                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 364                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 365         else
 366                 have_gcrypt=no
 367         fi
 368 else
 369         GCRYPT_LIBS=
 370         GCRYPT_CFLAGS=
 371 fi
 372 AC_SUBST(GCRYPT_LIBS)
 373 AC_SUBST(GCRYPT_CFLAGS)
 374 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 375
 376 # ------------------------------------------------------------------------------
 377 AC_ARG_ENABLE([audit],
 378         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 379                 [case "${enableval}" in
 380                         yes) have_audit=yes ;;
 381                         no) have_audit=no ;;
 382                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 383                 esac],
 384                 [have_audit=auto])
 385
 386 if test "x${have_audit}" != xno ; then
 387         AC_CHECK_HEADERS(
 388                 [libaudit.h],
 389                 [have_audit=yes],
 390                 [if test "x$have_audit" = xyes ; then
 391                         AC_MSG_ERROR([*** AUDIT headers not found.])
 392                 fi])
 393
 394         AC_CHECK_LIB(
 395                 [audit],
 396                 [audit_open],
 397                 [have_audit=yes],
 398                 [if test "x$have_audit" = xyes ; then
 399                         AC_MSG_ERROR([*** libaudit not found.])
 400                 fi])
 401
 402         if test "x$have_audit" = xyes ; then
 403                 AUDIT_LIBS="-laudit"
 404                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 405         else
 406                 have_audit=no
 407         fi
 408 else
 409         AUDIT_LIBS=
 410 fi
 411 AC_SUBST(AUDIT_LIBS)
 412
 413 # ------------------------------------------------------------------------------
 414 have_libcryptsetup=no
 415 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 416 if test "x$enable_libcryptsetup" != "xno"; then
 417         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
 418                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 419         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 420                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 421         fi
 422 fi
 423 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 424
 425 # ------------------------------------------------------------------------------
 426 have_qrencode=no
 427 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 428 if test "x$enable_qrencode" != "xno"; then
 429         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 430                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 431         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 432                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 433         fi
 434 fi
 435 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 436
 437 # ------------------------------------------------------------------------------
 438 have_microhttpd=no
 439 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 440 if test "x$enable_microhttpd" != "xno"; then
 441         PKG_CHECK_MODULES(MICROHTTPD, [ libmicrohttpd ],
 442                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 443         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 444                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 445         fi
 446 fi
 447 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 448
 449 # ------------------------------------------------------------------------------
 450 have_binfmt=no
 451 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 452 if test "x$enable_binfmt" != "xno"; then
 453         have_binfmt=yes
 454 fi
 455 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 456
 457 # ------------------------------------------------------------------------------
 458 have_vconsole=no
 459 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 460 if test "x$enable_vconsole" != "xno"; then
 461         have_vconsole=yes
 462 fi
 463 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 464
 465 # ------------------------------------------------------------------------------
 466 have_readahead=no
 467 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 468 if test "x$enable_readahead" != "xno"; then
 469         have_readahead=yes
 470 fi
 471 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 472
 473 # ------------------------------------------------------------------------------
 474 have_quotacheck=no
 475 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 476 if test "x$enable_quotacheck" != "xno"; then
 477         have_quotacheck=yes
 478 fi
 479 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 480
 481 # ------------------------------------------------------------------------------
 482 have_randomseed=no
 483 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 484 if test "x$enable_randomseed" != "xno"; then
 485         have_randomseed=yes
 486 fi
 487 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 488
 489 # ------------------------------------------------------------------------------
 490 have_logind=no
 491 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 492 if test "x$enable_logind" != "xno"; then
 493         have_logind=yes
 494 fi
 495 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 496 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 497
 498 # ------------------------------------------------------------------------------
 499 have_hostnamed=no
 500 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 501 if test "x$enable_hostnamed" != "xno"; then
 502         have_hostnamed=yes
 503 fi
 504 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 505
 506 # ------------------------------------------------------------------------------
 507 have_timedated=no
 508 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 509 if test "x$enable_timedated" != "xno"; then
 510         have_timedated=yes
 511 fi
 512 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 513
 514 # ------------------------------------------------------------------------------
 515 have_localed=no
 516 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 517 if test "x$enable_localed" != "xno"; then
 518         have_localed=yes
 519 fi
 520 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 521
 522 # ------------------------------------------------------------------------------
 523 have_coredump=no
 524 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 525 if test "x$enable_coredump" != "xno"; then
 526         have_coredump=yes
 527 fi
 528 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 529
 530 # ------------------------------------------------------------------------------
 531 AC_ARG_WITH(usb-ids-path,
 532         [AS_HELP_STRING([--with-usb-ids-path=DIR], [Path to usb.ids file])],
 533         [USB_DATABASE=${withval}],
 534         [if test -n "$usbids" ; then
 535                 USB_DATABASE="$usbids"
 536         else
 537                 PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
 538                 AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])
 539         fi])
 540 AC_MSG_CHECKING([for USB database location])
 541 AC_MSG_RESULT([$USB_DATABASE])
 542 AC_SUBST(USB_DATABASE)
 543
 544 AC_ARG_WITH(pci-ids-path,
 545         [AS_HELP_STRING([--with-pci-ids-path=DIR], [Path to pci.ids file])],
 546         [PCI_DATABASE=${withval}],
 547         [if test -n "$pciids" ; then
 548                 PCI_DATABASE="$pciids"
 549         else
 550                 PKG_CHECK_MODULES(LIBPCI, libpci >= 3)
 551                 AC_SUBST([PCI_DATABASE], [$($PKG_CONFIG --variable=idsdir libpci)/pci.ids])
 552         fi])
 553 AC_MSG_CHECKING([for PCI database location])
 554 AC_MSG_RESULT([$PCI_DATABASE])
 555 AC_SUBST(PCI_DATABASE)
 556
 557 # ------------------------------------------------------------------------------
 558 AC_ARG_WITH(firmware-path,
 559        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 560           [Firmware search path (default=ROOTPREFIX/lib/firmware/updates:ROOTPREFIX/lib/firmware)]),
 561        [], [with_firmware_path="$rootprefix/lib/firmware/updates:$rootprefix/lib/firmware"])
 562 OLD_IFS=$IFS
 563 IFS=:
 564 for i in $with_firmware_path; do
 565        if test "x${FIRMWARE_PATH}" = "x"; then
 566               FIRMWARE_PATH="\\\"${i}/\\\""
 567        else
 568               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 569        fi
 570 done
 571 IFS=$OLD_IFS
 572 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
 573
 574 # ------------------------------------------------------------------------------
 575 AC_ARG_ENABLE([gudev],
 576        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 577        [], [enable_gudev=yes])
 578 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0]) ])
 579 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 580
 581 # ------------------------------------------------------------------------------
 582 AC_ARG_ENABLE([keymap],
 583        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 584        [], [enable_keymap=yes])
 585 AS_IF([test "x$enable_keymap" = "xyes"], [
 586        AC_PATH_PROG([GPERF], [gperf])
 587        if test -z "$GPERF"; then
 588               AC_MSG_ERROR([gperf is needed])
 589        fi
 590
 591        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 592        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 593 ])
 594 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 595
 596 # ------------------------------------------------------------------------------
 597 have_manpages=no
 598 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 599 AS_IF([test "x$enable_manpages" != xno], [
 600         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 601                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 602         ])
 603         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 604 ])
 605 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 606
 607 # ------------------------------------------------------------------------------
 608
 609 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux, mandriva, mageia, angstrom or other]))
 610 if test "z$with_distro" = "z"; then
 611         if test "$cross_compiling" = yes; then
 612                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 613         else
 614                 with_distro=$($GREP '^ID=' /etc/os-release 2>/dev/null | $SED 's/ID=//');
 615         fi
 616         if test "z$with_distro" = "z"; then
 617                 with_distro=other
 618         fi
 619 fi
 620 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 621 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 622
 623 # Location of the init scripts as mandated by LSB
 624 SYSTEM_SYSVINIT_PATH=/etc/init.d
 625 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 626
 627 M4_DEFINES=
 628
 629 case $with_distro in
 630         fedora)
 631                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 632                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 633                 M4_DEFINES=-DTARGET_FEDORA=1
 634                 ;;
 635         opensuse|suse)
 636                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 637                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 638                 M4_DEFINES=-DTARGET_SUSE=1
 639                 ;;
 640         debian)
 641                 SYSTEM_SYSVRCND_PATH=/etc
 642                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 643                 M4_DEFINES=-DTARGET_DEBIAN=1
 644                 ;;
 645         ubuntu)
 646                 SYSTEM_SYSVRCND_PATH=/etc
 647                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 648                 M4_DEFINES=-DTARGET_UBUNTU=1
 649                 ;;
 650         arch)
 651                 SYSTEM_SYSVINIT_PATH=
 652                 SYSTEM_SYSVRCND_PATH=
 653                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 654                 M4_DEFINES=-DTARGET_ARCH=1
 655                 ;;
 656         gentoo)
 657                 SYSTEM_SYSVINIT_PATH=
 658                 SYSTEM_SYSVRCND_PATH=
 659                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 660                 M4_DEFINES=-DTARGET_GENTOO=1
 661                 ;;
 662         slackware)
 663                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 664                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 665                 M4_DEFINES=-DTARGET_SLACKWARE=1
 666                 ;;
 667         frugalware)
 668                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 669                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 670                 M4_DEFINES=-DTARGET_FRUGALWARE=1
 671                 ;;
 672         altlinux)
 673                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 674                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 675                 M4_DEFINES=-DTARGET_ALTLINUX=1
 676                 ;;
 677         mandriva)
 678                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 679                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 680                 M4_DEFINES=-DTARGET_MANDRIVA=1
 681                 ;;
 682         angstrom)
 683                 SYSTEM_SYSVRCND_PATH=/etc
 684                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 685                 M4_DEFINES=-DTARGET_ANGSTROM=1
 686                 ;;
 687         mageia)
 688                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 689                 AC_DEFINE(TARGET_MAGEIA, [], [Target is Mageia])
 690                 M4_DEFINES=-DTARGET_MAGEIA=1
 691                 ;;
 692         other)
 693                 ;;
 694         *)
 695                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 696                 ;;
 697 esac
 698
 699 AC_ARG_WITH([sysvinit-path],
 700         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 701                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 702         [SYSTEM_SYSVINIT_PATH="$withval"],
 703         [])
 704
 705 AC_ARG_WITH([sysvrcd-path],
 706         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 707                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 708         [SYSTEM_SYSVRCND_PATH="$withval"],
 709         [])
 710
 711 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 712 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 713 AC_SUBST(M4_DEFINES)
 714
 715 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 716         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 717         SYSTEM_SYSV_COMPAT="yes"
 718         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 719 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 720         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 721 else
 722         SYSTEM_SYSV_COMPAT="no"
 723 fi
 724
 725 AC_ARG_WITH([tty-gid],
 726         [AS_HELP_STRING([--with-tty-gid=GID],
 727                 [Specify the numeric GID of the 'tty' group])],
 728         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 729         [])
 730
 731 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 732 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 733 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 734 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 735 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 736 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 737 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 738 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 739 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 740 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 741 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 742 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 743 AM_CONDITIONAL(TARGET_MAGEIA, test x"$with_distro" = xmageia)
 744
 745 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 746
 747 AC_ARG_WITH([dbuspolicydir],
 748         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 749         [],
 750         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 751
 752 AC_ARG_WITH([dbussessionservicedir],
 753         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 754         [],
 755         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 756
 757 AC_ARG_WITH([dbussystemservicedir],
 758         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 759         [],
 760         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 761
 762 AC_ARG_WITH([dbusinterfacedir],
 763         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 764         [],
 765         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 766
 767 AC_ARG_WITH([rootprefix],
 768         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 769         [], [with_rootprefix=${ac_default_prefix}])
 770
 771 AC_ARG_WITH([rootlibdir],
 772         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 773         [],
 774         [with_rootlibdir=${libdir}])
 775
 776 AC_ARG_WITH([pamlibdir],
 777         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 778         [],
 779         [with_pamlibdir=${with_rootlibdir}/security])
 780
 781 AC_ARG_ENABLE([split-usr],
 782         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 783         [],
 784         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 785                 enable_split_usr=yes
 786         ], [
 787                 enable_split_usr=no
 788         ])])
 789
 790 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 791         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 792 ])
 793
 794 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 795 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 796 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 797 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 798 AC_SUBST([pamlibdir], [$with_pamlibdir])
 799 AC_SUBST([rootprefix], [$with_rootprefix])
 800 AC_SUBST([rootlibdir], [$with_rootlibdir])
 801
 802 AC_CONFIG_FILES([
 803         Makefile po/Makefile.in
 804         docs/libudev/Makefile
 805         docs/libudev/version.xml
 806         docs/gudev/Makefile
 807         docs/gudev/version.xml
 808 ])
 809
 810 AC_OUTPUT
 811 AC_MSG_RESULT([
 812         $PACKAGE_NAME $VERSION
 813
 814         Distribution:            ${with_distro}
 815         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 816         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 817         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 818         libcryptsetup:           ${have_libcryptsetup}
 819         tcpwrap:                 ${have_tcpwrap}
 820         PAM:                     ${have_pam}
 821         AUDIT:                   ${have_audit}
 822         IMA:                     ${have_ima}
 823         SELinux:                 ${have_selinux}
 824         XZ:                      ${have_xz}
 825         ACL:                     ${have_acl}
 826         GCRYPT:                  ${have_gcrypt}
 827         QRENCODE:                ${have_qrencode}
 828         MICROHTTPD:              ${have_microhttpd}
 829         binfmt:                  ${have_binfmt}
 830         vconsole:                ${have_vconsole}
 831         readahead:               ${have_readahead}
 832         quotacheck:              ${have_quotacheck}
 833         randomseed:              ${have_randomseed}
 834         logind:                  ${have_logind}
 835         hostnamed:               ${have_hostnamed}
 836         timedated:               ${have_timedated}
 837         localed:                 ${have_localed}
 838         coredump:                ${have_coredump}
 839         firmware path:           ${FIRMWARE_PATH}
 840         usb.ids:                 ${USB_DATABASE}
 841         pci.ids:                 ${PCI_DATABASE}
 842         gudev:                   ${enable_gudev}
 843         gintrospection:          ${enable_introspection}
 844         keymap:                  ${enable_keymap}
 845         Python:                  ${have_python}
 846         Python Headers:          ${have_python_devel}
 847
 848         prefix:                  ${prefix}
 849         rootprefix:              ${with_rootprefix}
 850         sysconf dir:             ${sysconfdir}
 851         datarootdir:             ${datarootdir}
 852         includedir:              ${includedir}
 853         include_prefix:          ${INCLUDE_PREFIX}
 854         lib dir:                 ${libdir}
 855         rootlib dir:             ${with_rootlibdir}
 856         PAM modules dir:         ${with_pamlibdir}
 857         D-Bus policy dir:        ${with_dbuspolicydir}
 858         D-Bus session dir:       ${with_dbussessionservicedir}
 859         D-Bus system dir:        ${with_dbussystemservicedir}
 860         D-Bus interfaces dir:    ${with_dbusinterfacedir}
 861         Split /usr:              ${enable_split_usr}
 862         man pages:               ${have_manpages}
 863         gtk-doc:                 ${enable_gtk_doc}
 864
 865         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 866         CPPLAGS:                 ${OUR_CPPFLAGS} ${CPPFLAGS}
 867         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 868 ])