chiark - git - mdw - stgit/blob - contrib/stgit.el

   1 ;; stgit.el: An emacs mode for StGit
   2 ;;
   3 ;; Copyright (C) 2007 David Kågedal <davidk@lysator.liu.se>
   4 ;;
   5 ;; To install: put this file on the load-path and place the following
   6 ;; in your .emacs file:
   7 ;;
   8 ;;    (require 'stgit)
   9 ;;
  10 ;; To start: `M-x stgit'
  11
  12 (require 'git nil t)
  13
  14 (defun stgit (dir)
  15   "Manage StGit patches for the tree in DIR."
  16   (interactive "DDirectory: \n")
  17   (switch-to-stgit-buffer (git-get-top-dir dir))
  18   (stgit-reload))
  19
  20 (unless (fboundp 'git-get-top-dir)
  21   (defun git-get-top-dir (dir)
  22     "Retrieve the top-level directory of a git tree."
  23     (let ((cdup (with-output-to-string
  24                   (with-current-buffer standard-output
  25                     (cd dir)
  26                     (unless (eq 0 (call-process "git" nil t nil
  27                                                 "rev-parse" "--show-cdup"))
  28                       (error "Cannot find top-level git tree for %s" dir))))))
  29       (expand-file-name (concat (file-name-as-directory dir)
  30                                 (car (split-string cdup "\n")))))))
  31
  32 (defun stgit-refresh-git-status (&optional dir)
  33   "If it exists, refresh the `git-status' buffer belonging to
  34 directory DIR or `default-directory'"
  35   (when (and (fboundp 'git-find-status-buffer)
  36              (fboundp 'git-refresh-status))
  37     (let* ((top-dir (git-get-top-dir (or dir default-directory)))
  38            (git-status-buffer (and top-dir (git-find-status-buffer top-dir))))
  39       (when git-status-buffer
  40         (with-current-buffer git-status-buffer
  41           (git-refresh-status))))))
  42
  43 (defun switch-to-stgit-buffer (dir)
  44   "Switch to a (possibly new) buffer displaying StGit patches for DIR."
  45   (setq dir (file-name-as-directory dir))
  46   (let ((buffers (buffer-list)))
  47     (while (and buffers
  48                 (not (with-current-buffer (car buffers)
  49                        (and (eq major-mode 'stgit-mode)
  50                             (string= default-directory dir)))))
  51       (setq buffers (cdr buffers)))
  52     (switch-to-buffer (if buffers
  53                           (car buffers)
  54                         (create-stgit-buffer dir)))))
  55
  56 (defun create-stgit-buffer (dir)
  57   "Create a buffer for showing StGit patches.
  58 Argument DIR is the repository path."
  59   (let ((buf (create-file-buffer (concat dir "*stgit*")))
  60         (inhibit-read-only t))
  61     (with-current-buffer buf
  62       (setq default-directory dir)
  63       (stgit-mode)
  64       (setq buffer-read-only t))
  65     buf))
  66
  67 (defmacro stgit-capture-output (name &rest body)
  68   "Capture StGit output and show it in a window at the end."
  69   `(let ((output-buf (get-buffer-create ,(or name "*StGit output*")))
  70          (stgit-dir default-directory)
  71          (inhibit-read-only t))
  72      (with-current-buffer output-buf
  73        (erase-buffer)
  74        (setq default-directory stgit-dir)
  75        (setq buffer-read-only t))
  76      (let ((standard-output output-buf))
  77        ,@body)
  78      (with-current-buffer output-buf
  79        (set-buffer-modified-p nil)
  80        (setq buffer-read-only t)
  81        (if (< (point-min) (point-max))
  82            (display-buffer output-buf t)))))
  83 (put 'stgit-capture-output 'lisp-indent-function 1)
  84
  85 (defun stgit-make-run-args (args)
  86   "Return a copy of ARGS with its elements converted to strings."
  87   (mapcar (lambda (x)
  88             ;; don't use (format "%s" ...) to limit type errors
  89             (cond ((stringp x) x)
  90                   ((integerp x) (number-to-string x))
  91                   ((symbolp x) (symbol-name x))
  92                   (t
  93                    (error "Bad element in stgit-make-run-args args: %S" x))))
  94           args))
  95
  96 (defun stgit-run-silent (&rest args)
  97   (setq args (stgit-make-run-args args))
  98   (apply 'call-process "stg" nil standard-output nil args))
  99
 100 (defun stgit-run (&rest args)
 101   (setq args (stgit-make-run-args args))
 102   (let ((msgcmd (mapconcat #'identity args " ")))
 103     (message "Running stg %s..." msgcmd)
 104     (apply 'call-process "stg" nil standard-output nil args)
 105     (message "Running stg %s...done" msgcmd)))
 106
 107 (defun stgit-run-git (&rest args)
 108   (setq args (stgit-make-run-args args))
 109   (let ((msgcmd (mapconcat #'identity args " ")))
 110     (message "Running git %s..." msgcmd)
 111     (apply 'call-process "git" nil standard-output nil args)
 112     (message "Running git %s...done" msgcmd)))
 113
 114 (defun stgit-run-git-silent (&rest args)
 115   (setq args (stgit-make-run-args args))
 116   (apply 'call-process "git" nil standard-output nil args))
 117
 118 (defun stgit-reload ()
 119   "Update the contents of the StGit buffer."
 120   (interactive)
 121   (let ((inhibit-read-only t)
 122         (curline (line-number-at-pos))
 123         (curpatch (stgit-patch-at-point)))
 124     (erase-buffer)
 125     (insert "Branch: ")
 126     (stgit-run-silent "branch")
 127     (stgit-run-silent "series" "--description")
 128     (stgit-rescan)
 129     (if curpatch
 130         (stgit-goto-patch curpatch)
 131       (goto-line curline)))
 132   (stgit-refresh-git-status))
 133
 134 (defgroup stgit nil
 135   "A user interface for the StGit patch maintenance tool."
 136   :group 'tools)
 137
 138 (defface stgit-description-face
 139   '((((background dark)) (:foreground "tan"))
 140     (((background light)) (:foreground "dark red")))
 141   "The face used for StGit descriptions"
 142   :group 'stgit)
 143
 144 (defface stgit-top-patch-face
 145   '((((background dark)) (:weight bold :foreground "yellow"))
 146     (((background light)) (:weight bold :foreground "purple"))
 147     (t (:weight bold)))
 148   "The face used for the top patch names"
 149   :group 'stgit)
 150
 151 (defface stgit-applied-patch-face
 152   '((((background dark)) (:foreground "light yellow"))
 153     (((background light)) (:foreground "purple"))
 154     (t ()))
 155   "The face used for applied patch names"
 156   :group 'stgit)
 157
 158 (defface stgit-unapplied-patch-face
 159   '((((background dark)) (:foreground "gray80"))
 160     (((background light)) (:foreground "orchid"))
 161     (t ()))
 162   "The face used for unapplied patch names"
 163   :group 'stgit)
 164
 165 (defface stgit-modified-file-face
 166   '((((class color) (background light)) (:foreground "purple"))
 167     (((class color) (background dark)) (:foreground "salmon")))
 168   "StGit mode face used for modified file status"
 169   :group 'stgit)
 170
 171 (defface stgit-unmerged-file-face
 172   '((((class color) (background light)) (:foreground "red" :bold t))
 173     (((class color) (background dark)) (:foreground "red" :bold t)))
 174   "StGit mode face used for unmerged file status"
 175   :group 'stgit)
 176
 177 (defface stgit-unknown-file-face
 178   '((((class color) (background light)) (:foreground "goldenrod" :bold t))
 179     (((class color) (background dark)) (:foreground "goldenrod" :bold t)))
 180   "StGit mode face used for unknown file status"
 181   :group 'stgit)
 182
 183 (defface stgit-file-permission-face
 184   '((((class color) (background light)) (:foreground "green" :bold t))
 185     (((class color) (background dark)) (:foreground "green" :bold t)))
 186   "StGit mode face used for permission changes."
 187   :group 'stgit)
 188
 189 (defcustom stgit-expand-find-copies-harder
 190   nil
 191   "Try harder to find copied files when listing patches.
 192
 193 When not nil, runs git diff-tree with the --find-copies-harder
 194 flag, which reduces performance."
 195   :type 'boolean
 196   :group 'stgit)
 197
 198 (defconst stgit-file-status-code-strings
 199   (mapcar (lambda (arg)
 200             (cons (car arg)
 201                   (propertize (cadr arg) 'face (car (cddr arg)))))
 202           '((add         "Added"       stgit-modified-file-face)
 203             (copy        "Copied"      stgit-modified-file-face)
 204             (delete      "Deleted"     stgit-modified-file-face)
 205             (modify      "Modified"    stgit-modified-file-face)
 206             (rename      "Renamed"     stgit-modified-file-face)
 207             (mode-change "Mode change" stgit-modified-file-face)
 208             (unmerged    "Unmerged"    stgit-unmerged-file-face)
 209             (unknown     "Unknown"     stgit-unknown-file-face)))
 210   "Alist of code symbols to description strings")
 211
 212 (defun stgit-file-status-code-as-string (code)
 213   "Return stgit status code as string"
 214   (let ((str (assq (if (consp code) (car code) code)
 215                    stgit-file-status-code-strings)))
 216     (when str
 217       (format "%-11s  "
 218               (if (and str (consp code) (/= (cdr code) 100))
 219                   (format "%s %s" (cdr str)
 220                           (propertize (format "%d%%" (cdr code))
 221                                       'face 'stgit-description-face))
 222                 (cdr str))))))
 223
 224 (defun stgit-file-status-code (str &optional score)
 225   "Return stgit status code from git status string"
 226   (let ((code (assoc str '(("A" . add)
 227                            ("C" . copy)
 228                            ("D" . delete)
 229                            ("M" . modify)
 230                            ("R" . rename)
 231                            ("T" . mode-change)
 232                            ("U" . unmerged)
 233                            ("X" . unknown)))))
 234     (setq code (if code (cdr code) 'unknown))
 235     (when (stringp score)
 236       (if (> (length score) 0)
 237           (setq score (string-to-number score))
 238         (setq score nil)))
 239     (if score (cons code score) code)))
 240
 241 (defconst stgit-file-type-strings
 242   '((#o100 . "file")
 243     (#o120 . "symlink")
 244     (#o160 . "subproject"))
 245   "Alist of names of file types")
 246
 247 (defun stgit-file-type-string (type)
 248   "Return string describing file type TYPE (the high bits of file permission).
 249 Cf. `stgit-file-type-strings' and `stgit-file-type-change-string'."
 250   (let ((type-str (assoc type stgit-file-type-strings)))
 251     (or (and type-str (cdr type-str))
 252         (format "unknown type %o" type))))
 253
 254 (defun stgit-file-type-change-string (old-perm new-perm)
 255   "Return string describing file type change from OLD-PERM to NEW-PERM.
 256 Cf. `stgit-file-type-string'."
 257   (let ((old-type (lsh old-perm -9))
 258         (new-type (lsh new-perm -9)))
 259     (cond ((= old-type new-type) "")
 260           ((zerop new-type) "")
 261           ((zerop old-type)
 262            (if (= new-type #o100)
 263                ""
 264              (format "   (%s)" (stgit-file-type-string new-type))))
 265           (t (format "   (%s -> %s)"
 266                      (stgit-file-type-string old-type)
 267                      (stgit-file-type-string new-type))))))
 268
 269 (defun stgit-file-mode-change-string (old-perm new-perm)
 270   "Return string describing file mode change from OLD-PERM to NEW-PERM.
 271 Cf. `stgit-file-type-change-string'."
 272   (setq old-perm (logand old-perm #o777)
 273         new-perm (logand new-perm #o777))
 274   (if (or (= old-perm new-perm)
 275           (zerop old-perm)
 276           (zerop new-perm))
 277       ""
 278     (let* ((modified       (logxor old-perm new-perm))
 279            (not-x-modified (logand (logxor old-perm new-perm) #o666)))
 280       (cond ((zerop modified) "")
 281             ((and (zerop not-x-modified)
 282                   (or (and (eq #o111 (logand old-perm #o111))
 283                            (propertize "-x" 'face 'stgit-file-permission-face))
 284                       (and (eq #o111 (logand new-perm #o111))
 285                            (propertize "+x" 'face
 286                                        'stgit-file-permission-face)))))
 287             (t (concat (propertize (format "%o" old-perm)
 288                                    'face 'stgit-file-permission-face)
 289                        (propertize " -> "
 290                                    'face 'stgit-description-face)
 291                        (propertize (format "%o" new-perm)
 292                                    'face 'stgit-file-permission-face)))))))
 293
 294 (defun stgit-expand-patch (patchsym)
 295   "Expand (show modification of) the patch with name PATCHSYM (a
 296 symbol) at point.
 297 `stgit-expand-find-copies-harder' controls how hard to try to
 298 find copied files."
 299   (save-excursion
 300     (forward-line)
 301     (let* ((start (point))
 302            (result (with-output-to-string
 303                      (stgit-run-git "diff-tree" "-r" "-z"
 304                                     (if stgit-expand-find-copies-harder
 305                                         "--find-copies-harder"
 306                                       "-C")
 307                                     (stgit-id patchsym)))))
 308       (let (mstart)
 309         (while (string-match "\0:\\([0-7]+\\) \\([0-7]+\\) [0-9A-Fa-f]\\{40\\} [0-9A-Fa-f]\\{40\\} \\(\\([CR]\\)\\([0-9]*\\)\0\\([^\0]*\\)\0\\([^\0]*\\)\\|\\([ABD-QS-Z]\\)\0\\([^\0]*\\)\\)"
 310                              result mstart)
 311           (let ((copy-or-rename (match-string 4 result))
 312                 (old-perm       (read (format "#o%s" (match-string 1 result))))
 313                 (new-perm       (read (format "#o%s" (match-string 2 result))))
 314                 (line-start (point))
 315                 status
 316                 change
 317                 properties)
 318             (insert "    ")
 319             (if copy-or-rename
 320                 (let ((cr-score       (match-string 5 result))
 321                       (cr-from-file   (match-string 6 result))
 322                       (cr-to-file     (match-string 7 result)))
 323                   (setq status (stgit-file-status-code copy-or-rename
 324                                                        cr-score)
 325                         properties (list 'stgit-old-file cr-from-file
 326                                          'stgit-new-file cr-to-file)
 327                         change (concat
 328                                 cr-from-file
 329                                 (propertize " -> "
 330                                             'face 'stgit-description-face)
 331                                 cr-to-file)))
 332               (setq status (stgit-file-status-code (match-string 8 result))
 333                     properties (list 'stgit-file (match-string 9 result))
 334                     change (match-string 9 result)))
 335
 336             (let ((mode-change (stgit-file-mode-change-string old-perm
 337                                                               new-perm)))
 338               (insert (format "%-12s" (stgit-file-status-code-as-string
 339                                        status))
 340                       mode-change
 341                       (if (> (length mode-change) 0) " " "")
 342                       change
 343                       (propertize (stgit-file-type-change-string old-perm
 344                                                                  new-perm)
 345                                   'face 'stgit-description-face)
 346                       ?\n))
 347             (add-text-properties line-start (point) properties))
 348           (setq mstart (match-end 0))))
 349       (when (= start (point))
 350         (insert "    <no files>\n"))
 351       (put-text-property start (point) 'stgit-file-patchsym patchsym))))
 352
 353 (defun stgit-rescan ()
 354   "Rescan the status buffer."
 355   (save-excursion
 356     (let ((marked ()))
 357       (goto-char (point-min))
 358       (while (not (eobp))
 359         (cond ((looking-at "Branch: \\(.*\\)")
 360                (put-text-property (match-beginning 1) (match-end 1)
 361                                   'face 'bold))
 362               ((looking-at "\\([>+-]\\)\\( \\)\\([^ ]+\\) *[|#] \\(.*\\)")
 363                (let ((state (match-string 1))
 364                      (patchsym (intern (match-string 3))))
 365                  (put-text-property
 366                   (match-beginning 3) (match-end 3) 'face
 367                   (cond ((string= state ">") 'stgit-top-patch-face)
 368                         ((string= state "+") 'stgit-applied-patch-face)
 369                         ((string= state "-") 'stgit-unapplied-patch-face)))
 370                  (put-text-property (match-beginning 4) (match-end 4)
 371                                     'face 'stgit-description-face)
 372                  (when (memq patchsym stgit-marked-patches)
 373                    (replace-match "*" nil nil nil 2)
 374                    (setq marked (cons patchsym marked)))
 375                  (put-text-property (match-beginning 0) (match-end 0)
 376                                     'stgit-patchsym patchsym)
 377                  (when (memq patchsym stgit-expanded-patches)
 378                    (stgit-expand-patch patchsym))
 379                  ))
 380               ((or (looking-at "stg series: Branch \".*\" not initialised")
 381                    (looking-at "stg series: .*: branch not initialized"))
 382                (forward-line 1)
 383                (insert "Run M-x stgit-init to initialise")))
 384         (forward-line 1))
 385       (setq stgit-marked-patches (nreverse marked)))))
 386
 387 (defun stgit-select ()
 388   "Expand or collapse the current entry"
 389   (interactive)
 390   (let ((curpatch (stgit-patch-at-point)))
 391     (if (not curpatch)
 392         (let ((patched-file (stgit-patched-file-at-point)))
 393           (unless patched-file
 394             (error "No patch or file on the current line"))
 395           (let ((filename (expand-file-name (cdr patched-file))))
 396             (unless (file-exists-p filename)
 397               (error "File does not exist"))
 398             (find-file filename)))
 399       (setq stgit-expanded-patches
 400             (if (memq curpatch stgit-expanded-patches)
 401                 (delq curpatch stgit-expanded-patches)
 402               (cons curpatch stgit-expanded-patches)))
 403       (stgit-reload))))
 404
 405 (defun stgit-find-file-other-window ()
 406   "Open file at point in other window"
 407   (interactive)
 408   (let ((patched-file (stgit-patched-file-at-point)))
 409     (unless patched-file
 410       (error "No file on the current line"))
 411     (let ((filename (expand-file-name (cdr patched-file))))
 412       (unless (file-exists-p filename)
 413         (error "File does not exist"))
 414       (find-file-other-window filename))))
 415
 416 (defun stgit-quit ()
 417   "Hide the stgit buffer."
 418   (interactive)
 419   (bury-buffer))
 420
 421 (defun stgit-git-status ()
 422   "Show status using `git-status'."
 423   (interactive)
 424   (unless (fboundp 'git-status)
 425     (error "The stgit-git-status command requires git-status"))
 426   (let ((dir default-directory))
 427     (save-selected-window
 428       (pop-to-buffer nil)
 429       (git-status dir))))
 430
 431 (defun stgit-next-line (&optional arg try-vscroll)
 432   "Move cursor vertically down ARG lines"
 433   (interactive "p\np")
 434   (next-line arg try-vscroll)
 435   (when (looking-at "  \\S-")
 436     (forward-char 2)))
 437
 438 (defun stgit-previous-line (&optional arg try-vscroll)
 439   "Move cursor vertically up ARG lines"
 440   (interactive "p\np")
 441   (previous-line arg try-vscroll)
 442   (when (looking-at "  \\S-")
 443     (forward-char 2)))
 444
 445 (defun stgit-next-patch (&optional arg)
 446   "Move cursor down ARG patches"
 447   (interactive "p")
 448   (unless arg
 449     (setq arg 1))
 450   (if (< arg 0)
 451       (stgit-previous-patch (- arg))
 452     (while (not (zerop arg))
 453       (setq arg (1- arg))
 454       (while (progn (stgit-next-line)
 455                     (not (stgit-patch-at-point)))))))
 456
 457 (defun stgit-previous-patch (&optional arg)
 458   "Move cursor up ARG patches"
 459   (interactive "p")
 460   (unless arg
 461     (setq arg 1))
 462   (if (< arg 0)
 463       (stgit-next-patch (- arg))
 464     (while (not (zerop arg))
 465       (setq arg (1- arg))
 466       (while (progn (stgit-previous-line)
 467                     (not (stgit-patch-at-point)))))))
 468
 469 (defvar stgit-mode-hook nil
 470   "Run after `stgit-mode' is setup.")
 471
 472 (defvar stgit-mode-map nil
 473   "Keymap for StGit major mode.")
 474
 475 (unless stgit-mode-map
 476   (setq stgit-mode-map (make-keymap))
 477   (suppress-keymap stgit-mode-map)
 478   (mapc (lambda (arg) (define-key stgit-mode-map (car arg) (cdr arg)))
 479         '((" " .        stgit-mark)
 480           ("m" .        stgit-mark)
 481           ("\d" .       stgit-unmark-up)
 482           ("u" .        stgit-unmark-down)
 483           ("?" .        stgit-help)
 484           ("h" .        stgit-help)
 485           ("p" .        stgit-previous-line)
 486           ("n" .        stgit-next-line)
 487           ("\C-p" .     stgit-previous-patch)
 488           ("\C-n" .     stgit-next-patch)
 489           ("\M-{" .     stgit-previous-patch)
 490           ("\M-}" .     stgit-next-patch)
 491           ("s" .        stgit-git-status)
 492           ("g" .        stgit-reload)
 493           ("r" .        stgit-refresh)
 494           ("\C-c\C-r" . stgit-rename)
 495           ("e" .        stgit-edit)
 496           ("c" .        stgit-coalesce)
 497           ("N" .        stgit-new)
 498           ("R" .        stgit-repair)
 499           ("C" .        stgit-commit)
 500           ("U" .        stgit-uncommit)
 501           ("\r" .       stgit-select)
 502           ("o" .        stgit-find-file-other-window)
 503           (">" .        stgit-push-next)
 504           ("<" .        stgit-pop-next)
 505           ("P" .        stgit-push-or-pop)
 506           ("G" .        stgit-goto)
 507           ("=" .        stgit-show)
 508           ("D" .        stgit-delete)
 509           ([(control ?/)] . stgit-undo)
 510           ("\C-_" .     stgit-undo)
 511           ("q" . stgit-quit))))
 512
 513 (defun stgit-mode ()
 514   "Major mode for interacting with StGit.
 515 Commands:
 516 \\{stgit-mode-map}"
 517   (kill-all-local-variables)
 518   (buffer-disable-undo)
 519   (setq mode-name "StGit"
 520         major-mode 'stgit-mode
 521         goal-column 2)
 522   (use-local-map stgit-mode-map)
 523   (set (make-local-variable 'list-buffers-directory) default-directory)
 524   (set (make-local-variable 'stgit-marked-patches) nil)
 525   (set (make-local-variable 'stgit-expanded-patches) nil)
 526   (set-variable 'truncate-lines 't)
 527   (run-hooks 'stgit-mode-hook))
 528
 529 (defun stgit-add-mark (patchsym)
 530   "Mark the patch PATCHSYM."
 531   (setq stgit-marked-patches (cons patchsym stgit-marked-patches)))
 532
 533 (defun stgit-remove-mark (patchsym)
 534   "Unmark the patch PATCHSYM."
 535   (setq stgit-marked-patches (delq patchsym stgit-marked-patches)))
 536
 537 (defun stgit-clear-marks ()
 538   "Unmark all patches."
 539   (setq stgit-marked-patches '()))
 540
 541 (defun stgit-patch-at-point (&optional cause-error allow-file)
 542   "Return the patch name on the current line as a symbol.
 543 If CAUSE-ERROR is not nil, signal an error if none found.
 544 If ALLOW-FILE is not nil, also handle when point is on a file of
 545 a patch."
 546   (or (get-text-property (point) 'stgit-patchsym)
 547       (and allow-file
 548            (get-text-property (point) 'stgit-file-patchsym))
 549       (when cause-error
 550         (error "No patch on this line"))))
 551
 552 (defun stgit-patched-file-at-point (&optional both-files)
 553   "Returns a cons of the patchsym and file name at point. For
 554 copies and renames, return the new file if the patch is either
 555 applied. If BOTH-FILES is non-nil, return a cons of the old and
 556 the new file names instead of just one name."
 557   (let ((patchsym (get-text-property (point) 'stgit-file-patchsym))
 558         (file     (get-text-property (point) 'stgit-file)))
 559     (cond ((not patchsym) nil)
 560           (file (cons patchsym file))
 561           (both-files
 562            (cons patchsym (cons (get-text-property (point) 'stgit-old-file)
 563                                 (get-text-property (point) 'stgit-new-file))))
 564           (t
 565            (let ((file-sym (save-excursion
 566                              (stgit-previous-patch)
 567                              (unless (eq (stgit-patch-at-point)
 568                                          patchsym)
 569                                (error "Cannot find the %s patch" patchsym))
 570                              (beginning-of-line)
 571                              (if (= (char-after) ?-)
 572                                  'stgit-old-file
 573                                'stgit-new-file))))
 574              (cons patchsym (get-text-property (point) file-sym)))))))
 575
 576 (defun stgit-patches-marked-or-at-point ()
 577   "Return the symbols of the marked patches, or the patch on the current line."
 578   (if stgit-marked-patches
 579       stgit-marked-patches
 580     (let ((patch (stgit-patch-at-point)))
 581       (if patch
 582           (list patch)
 583         '()))))
 584
 585 (defun stgit-goto-patch (patchsym)
 586   "Move point to the line containing patch PATCHSYM.
 587 If that patch cannot be found, return nil."
 588   (let ((p (text-property-any (point-min) (point-max)
 589                               'stgit-patchsym patchsym)))
 590     (when p
 591       (goto-char p)
 592       (move-to-column goal-column))))
 593
 594 (defun stgit-init ()
 595   "Run stg init."
 596   (interactive)
 597   (stgit-capture-output nil
 598     (stgit-run "init"))
 599   (stgit-reload))
 600
 601 (defun stgit-mark ()
 602   "Mark the patch under point."
 603   (interactive)
 604   (let ((patch (stgit-patch-at-point t)))
 605     (stgit-add-mark patch)
 606     (stgit-reload))
 607   (stgit-next-patch))
 608
 609 (defun stgit-unmark-up ()
 610   "Remove mark from the patch on the previous line."
 611   (interactive)
 612   (stgit-previous-patch)
 613   (stgit-remove-mark (stgit-patch-at-point t))
 614   (stgit-reload))
 615
 616 (defun stgit-unmark-down ()
 617   "Remove mark from the patch on the current line."
 618   (interactive)
 619   (stgit-remove-mark (stgit-patch-at-point t))
 620   (stgit-reload)
 621   (stgit-next-patch))
 622
 623 (defun stgit-rename (name)
 624   "Rename the patch under point to NAME."
 625   (interactive (list (read-string "Patch name: "
 626                                   (symbol-name (stgit-patch-at-point t)))))
 627   (let ((old-patchsym (stgit-patch-at-point t)))
 628     (stgit-capture-output nil
 629       (stgit-run "rename" old-patchsym name))
 630     (let ((name-sym (intern name)))
 631       (when (memq old-patchsym stgit-expanded-patches)
 632         (setq stgit-expanded-patches
 633             (cons name-sym (delq old-patchsym stgit-expanded-patches))))
 634       (when (memq old-patchsym stgit-marked-patches)
 635         (setq stgit-marked-patches
 636             (cons name-sym (delq old-patchsym stgit-marked-patches))))
 637       (stgit-reload)
 638       (stgit-goto-patch name-sym))))
 639
 640 (defun stgit-repair ()
 641   "Run stg repair."
 642   (interactive)
 643   (stgit-capture-output nil
 644     (stgit-run "repair"))
 645   (stgit-reload))
 646
 647 (defun stgit-commit ()
 648   "Run stg commit."
 649   (interactive)
 650   (stgit-capture-output nil (stgit-run "commit"))
 651   (stgit-reload))
 652
 653 (defun stgit-uncommit (arg)
 654   "Run stg uncommit. Numeric arg determines number of patches to uncommit."
 655   (interactive "p")
 656   (stgit-capture-output nil (stgit-run "uncommit" "-n" arg))
 657   (stgit-reload))
 658
 659 (defun stgit-push-next (npatches)
 660   "Push the first unapplied patch.
 661 With numeric prefix argument, push that many patches."
 662   (interactive "p")
 663   (stgit-capture-output nil (stgit-run "push" "-n" npatches))
 664   (stgit-reload)
 665   (stgit-refresh-git-status))
 666
 667 (defun stgit-pop-next (npatches)
 668   "Pop the topmost applied patch.
 669 With numeric prefix argument, pop that many patches."
 670   (interactive "p")
 671   (stgit-capture-output nil (stgit-run "pop" "-n" npatches))
 672   (stgit-reload)
 673   (stgit-refresh-git-status))
 674
 675 (defun stgit-applied-at-point ()
 676   "Is the patch on the current line applied?"
 677   (save-excursion
 678     (beginning-of-line)
 679     (looking-at "[>+]")))
 680
 681 (defun stgit-push-or-pop ()
 682   "Push or pop the patch on the current line."
 683   (interactive)
 684   (let ((patchsym (stgit-patch-at-point t))
 685         (applied (stgit-applied-at-point)))
 686     (stgit-capture-output nil
 687       (stgit-run (if applied "pop" "push") patchsym))
 688     (stgit-reload)))
 689
 690 (defun stgit-goto ()
 691   "Go to the patch on the current line."
 692   (interactive)
 693   (let ((patchsym (stgit-patch-at-point t)))
 694     (stgit-capture-output nil
 695       (stgit-run "goto" patchsym))
 696     (stgit-reload)))
 697
 698 (defun stgit-id (patchsym)
 699   "Return the git commit id for PATCHSYM."
 700   (let ((result (with-output-to-string
 701                   (stgit-run-silent "id" patchsym))))
 702     (unless (string-match "^\\([0-9A-Fa-f]\\{40\\}\\)$" result)
 703       (error "Cannot find commit id for %s" patchsym))
 704     (match-string 1 result)))
 705
 706 (defun stgit-show ()
 707   "Show the patch on the current line."
 708   (interactive)
 709   (stgit-capture-output "*StGit patch*"
 710     (let ((patchsym (stgit-patch-at-point)))
 711       (if (not patchsym)
 712           (let ((patched-file (stgit-patched-file-at-point t)))
 713             (unless patched-file
 714               (error "No patch or file at point"))
 715             (let ((id (stgit-id (car patched-file))))
 716               (with-output-to-temp-buffer "*StGit diff*"
 717                 (if (consp (cdr patched-file))
 718                     ;; two files (copy or rename)
 719                     (stgit-run-git "diff" "-C" "-C" (concat id "^") id "--"
 720                                    (cadr patched-file) (cddr patched-file))
 721                   ;; just one file
 722                   (stgit-run-git "diff" (concat id "^") id "--"
 723                                  (cdr patched-file)))
 724                 (with-current-buffer standard-output
 725                   (diff-mode)))))
 726         (stgit-run "show" patchsym)
 727         (with-current-buffer standard-output
 728           (goto-char (point-min))
 729           (diff-mode))))))
 730
 731 (defun stgit-edit ()
 732   "Edit the patch on the current line."
 733   (interactive)
 734   (let ((patchsym (stgit-patch-at-point t))
 735         (edit-buf (get-buffer-create "*StGit edit*"))
 736         (dir default-directory))
 737     (log-edit 'stgit-confirm-edit t nil edit-buf)
 738     (set (make-local-variable 'stgit-edit-patchsym) patchsym)
 739     (setq default-directory dir)
 740     (let ((standard-output edit-buf))
 741       (stgit-run-silent "edit" "--save-template=-" patchsym))))
 742
 743 (defun stgit-confirm-edit ()
 744   (interactive)
 745   (let ((file (make-temp-file "stgit-edit-")))
 746     (write-region (point-min) (point-max) file)
 747     (stgit-capture-output nil
 748       (stgit-run "edit" "-f" file stgit-edit-patchsym))
 749     (with-current-buffer log-edit-parent-buffer
 750       (stgit-reload))))
 751
 752 (defun stgit-new (add-sign)
 753   "Create a new patch.
 754 With a prefix argument, include a \"Signed-off-by:\" line at the
 755 end of the patch."
 756   (interactive "P")
 757   (let ((edit-buf (get-buffer-create "*StGit edit*"))
 758         (dir default-directory))
 759     (log-edit 'stgit-confirm-new t nil edit-buf)
 760     (setq default-directory dir)
 761     (when add-sign
 762       (save-excursion
 763         (let ((standard-output (current-buffer)))
 764           (stgit-run-silent "new" "--sign" "--save-template=-"))))))
 765
 766 (defun stgit-confirm-new ()
 767   (interactive)
 768   (let ((file (make-temp-file "stgit-edit-")))
 769     (write-region (point-min) (point-max) file)
 770     (stgit-capture-output nil
 771       (stgit-run "new" "-f" file))
 772     (with-current-buffer log-edit-parent-buffer
 773       (stgit-reload))))
 774
 775 (defun stgit-create-patch-name (description)
 776   "Create a patch name from a long description"
 777   (let ((patch ""))
 778     (while (> (length description) 0)
 779       (cond ((string-match "\\`[a-zA-Z_-]+" description)
 780              (setq patch (downcase (concat patch
 781                                            (match-string 0 description))))
 782              (setq description (substring description (match-end 0))))
 783             ((string-match "\\` +" description)
 784              (setq patch (concat patch "-"))
 785              (setq description (substring description (match-end 0))))
 786             ((string-match "\\`[^a-zA-Z_-]+" description)
 787              (setq description (substring description (match-end 0))))))
 788     (cond ((= (length patch) 0)
 789            "patch")
 790           ((> (length patch) 20)
 791            (substring patch 0 20))
 792           (t patch))))
 793
 794 (defun stgit-delete (patchsyms)
 795   "Delete the patches in PATCHSYMS.
 796 Interactively, delete the marked patches, or the patch at point."
 797   (interactive (list (stgit-patches-marked-or-at-point)))
 798   (let ((npatches (length patchsyms)))
 799     (if (zerop npatches)
 800         (error "No patches to delete")
 801       (when (yes-or-no-p (format "Really delete %d patch%s? "
 802                                  npatches
 803                                  (if (= 1 npatches) "" "es")))
 804         (stgit-capture-output nil
 805           (apply 'stgit-run "delete" patchsyms))
 806         (stgit-reload)))))
 807
 808 (defun stgit-coalesce (patchsyms)
 809   "Coalesce the patches in PATCHSYMS.
 810 Interactively, coalesce the marked patches."
 811   (interactive (list stgit-marked-patches))
 812   (when (< (length patchsyms) 2)
 813     (error "Need at least two patches to coalesce"))
 814   (let ((edit-buf (get-buffer-create "*StGit edit*"))
 815         (dir default-directory))
 816     (log-edit 'stgit-confirm-coalesce t nil edit-buf)
 817     (set (make-local-variable 'stgit-patchsyms) patchsyms)
 818     (setq default-directory dir)
 819     (let ((standard-output edit-buf))
 820       (apply 'stgit-run-silent "coalesce" "--save-template=-" patchsyms))))
 821
 822 (defun stgit-confirm-coalesce ()
 823   (interactive)
 824   (let ((file (make-temp-file "stgit-edit-")))
 825     (write-region (point-min) (point-max) file)
 826     (stgit-capture-output nil
 827       (apply 'stgit-run "coalesce" "-f" file stgit-patchsyms))
 828     (with-current-buffer log-edit-parent-buffer
 829       (stgit-clear-marks)
 830       ;; Go to first marked patch and stay there
 831       (goto-char (point-min))
 832       (re-search-forward (concat "^[>+-]\\*") nil t)
 833       (move-to-column goal-column)
 834       (let ((pos (point)))
 835         (stgit-reload)
 836         (goto-char pos)))))
 837
 838 (defun stgit-help ()
 839   "Display help for the StGit mode."
 840   (interactive)
 841   (describe-function 'stgit-mode))
 842
 843 (defun stgit-undo (&optional arg)
 844   "Run stg undo.
 845 With prefix argument, run it with the --hard flag."
 846   (interactive "P")
 847   (stgit-capture-output nil
 848     (if arg
 849         (stgit-run "undo" "--hard")
 850       (stgit-run "undo")))
 851   (stgit-reload))
 852
 853 (defun stgit-refresh (&optional arg)
 854   "Run stg refresh.
 855 With prefix argument, refresh the marked patch or the patch under point."
 856   (interactive "P")
 857   (let ((patchargs (if arg
 858                        (let ((patches (stgit-patches-marked-or-at-point)))
 859                          (cond ((null patches)
 860                                 (error "No patch to update"))
 861                                ((> (length patches) 1)
 862                                 (error "Too many patches selected"))
 863                                (t
 864                                 (cons "-p" patches))))
 865                      nil)))
 866     (stgit-capture-output nil
 867       (apply 'stgit-run "refresh" patchargs))
 868     (stgit-refresh-git-status))
 869   (stgit-reload))
 870
 871 (provide 'stgit)