chiark - git - mdw - stgit/blob - contrib/stgit.el

   1 ;; stgit.el: An emacs mode for StGit
   2 ;;
   3 ;; Copyright (C) 2007 David Kågedal <davidk@lysator.liu.se>
   4 ;;
   5 ;; To install: put this file on the load-path and place the following
   6 ;; in your .emacs file:
   7 ;;
   8 ;;    (require 'stgit)
   9 ;;
  10 ;; To start: `M-x stgit'
  11
  12 (require 'git nil t)
  13 (require 'cl)
  14 (require 'ewoc)
  15
  16 (defun stgit (dir)
  17   "Manage StGit patches for the tree in DIR."
  18   (interactive "DDirectory: \n")
  19   (switch-to-stgit-buffer (git-get-top-dir dir))
  20   (stgit-reload))
  21
  22 (unless (fboundp 'git-get-top-dir)
  23   (defun git-get-top-dir (dir)
  24     "Retrieve the top-level directory of a git tree."
  25     (let ((cdup (with-output-to-string
  26                   (with-current-buffer standard-output
  27                     (cd dir)
  28                     (unless (eq 0 (call-process "git" nil t nil
  29                                                 "rev-parse" "--show-cdup"))
  30                       (error "Cannot find top-level git tree for %s" dir))))))
  31       (expand-file-name (concat (file-name-as-directory dir)
  32                                 (car (split-string cdup "\n")))))))
  33
  34 (defun stgit-refresh-git-status (&optional dir)
  35   "If it exists, refresh the `git-status' buffer belonging to
  36 directory DIR or `default-directory'"
  37   (when (and (fboundp 'git-find-status-buffer)
  38              (fboundp 'git-refresh-status))
  39     (let* ((top-dir (git-get-top-dir (or dir default-directory)))
  40            (git-status-buffer (and top-dir (git-find-status-buffer top-dir))))
  41       (when git-status-buffer
  42         (with-current-buffer git-status-buffer
  43           (git-refresh-status))))))
  44
  45 (defun stgit-find-buffer (dir)
  46   "Return the buffer displaying StGit patches for DIR, or nil if none."
  47   (setq dir (file-name-as-directory dir))
  48   (let ((buffers (buffer-list)))
  49     (while (and buffers
  50                 (not (with-current-buffer (car buffers)
  51                        (and (eq major-mode 'stgit-mode)
  52                             (string= default-directory dir)))))
  53       (setq buffers (cdr buffers)))
  54     (and buffers (car buffers))))
  55
  56 (defun switch-to-stgit-buffer (dir)
  57   "Switch to a (possibly new) buffer displaying StGit patches for DIR."
  58   (setq dir (file-name-as-directory dir))
  59   (let ((buffer (stgit-find-buffer dir)))
  60     (switch-to-buffer (or buffer
  61                           (create-stgit-buffer dir)))))
  62
  63 (defstruct (stgit-patch)
  64   status name desc empty files-ewoc)
  65
  66 (defun stgit-patch-pp (patch)
  67   (let ((status (stgit-patch-status patch))
  68         (start (point))
  69         (name (stgit-patch-name patch)))
  70     (case name
  71        (:index (insert (propertize "  Index" 'face 'italic)))
  72        (:work (insert (propertize "  Work tree" 'face 'italic)))
  73        (t (insert (case status
  74                     ('applied "+")
  75                     ('top ">")
  76                     ('unapplied "-"))
  77                   (if (memq name stgit-marked-patches)
  78                       "*" " ")
  79                   (propertize (format "%-30s"
  80                                       (symbol-name name))
  81                               'face (case status
  82                                       ('applied 'stgit-applied-patch-face)
  83                                       ('top 'stgit-top-patch-face)
  84                                       ('unapplied 'stgit-unapplied-patch-face)
  85                                       ('index nil)
  86                                       ('work nil)))
  87                   "  "
  88                   (if (stgit-patch-empty patch) "(empty) " "")
  89                   (propertize (or (stgit-patch-desc patch) "")
  90                               'face 'stgit-description-face))))
  91     (put-text-property start (point) 'entry-type 'patch)
  92     (when (memq name stgit-expanded-patches)
  93       (stgit-insert-patch-files patch))
  94     (put-text-property start (point) 'patch-data patch)))
  95
  96 (defun create-stgit-buffer (dir)
  97   "Create a buffer for showing StGit patches.
  98 Argument DIR is the repository path."
  99   (let ((buf (create-file-buffer (concat dir "*stgit*")))
 100         (inhibit-read-only t))
 101     (with-current-buffer buf
 102       (setq default-directory dir)
 103       (stgit-mode)
 104       (set (make-local-variable 'stgit-ewoc)
 105            (ewoc-create #'stgit-patch-pp "Branch:\n" "--"))
 106       (setq buffer-read-only t))
 107     buf))
 108
 109 (defmacro stgit-capture-output (name &rest body)
 110   "Capture StGit output and, if there was any output, show it in a window
 111 at the end.
 112 Returns nil if there was no output."
 113   (declare (debug ([&or stringp null] body))
 114            (indent 1))
 115   `(let ((output-buf (get-buffer-create ,(or name "*StGit output*")))
 116          (stgit-dir default-directory)
 117          (inhibit-read-only t))
 118      (with-current-buffer output-buf
 119        (erase-buffer)
 120        (setq default-directory stgit-dir)
 121        (setq buffer-read-only t))
 122      (let ((standard-output output-buf))
 123        ,@body)
 124      (with-current-buffer output-buf
 125        (set-buffer-modified-p nil)
 126        (setq buffer-read-only t)
 127        (if (< (point-min) (point-max))
 128            (display-buffer output-buf t)))))
 129
 130 (defun stgit-make-run-args (args)
 131   "Return a copy of ARGS with its elements converted to strings."
 132   (mapcar (lambda (x)
 133             ;; don't use (format "%s" ...) to limit type errors
 134             (cond ((stringp x) x)
 135                   ((integerp x) (number-to-string x))
 136                   ((symbolp x) (symbol-name x))
 137                   (t
 138                    (error "Bad element in stgit-make-run-args args: %S" x))))
 139           args))
 140
 141 (defun stgit-run-silent (&rest args)
 142   (setq args (stgit-make-run-args args))
 143   (apply 'call-process "stg" nil standard-output nil args))
 144
 145 (defun stgit-run (&rest args)
 146   (setq args (stgit-make-run-args args))
 147   (let ((msgcmd (mapconcat #'identity args " ")))
 148     (message "Running stg %s..." msgcmd)
 149     (apply 'call-process "stg" nil standard-output nil args)
 150     (message "Running stg %s...done" msgcmd)))
 151
 152 (defun stgit-run-git (&rest args)
 153   (setq args (stgit-make-run-args args))
 154   (let ((msgcmd (mapconcat #'identity args " ")))
 155     (message "Running git %s..." msgcmd)
 156     (apply 'call-process "git" nil standard-output nil args)
 157     (message "Running git %s...done" msgcmd)))
 158
 159 (defun stgit-run-git-silent (&rest args)
 160   (setq args (stgit-make-run-args args))
 161   (apply 'call-process "git" nil standard-output nil args))
 162
 163 (defun stgit-index-empty-p ()
 164   "Returns non-nil if the index contains no changes from HEAD."
 165   (zerop (stgit-run-git-silent "diff-index" "--cached" "--quiet" "HEAD")))
 166
 167 (defvar stgit-index-node)
 168 (defvar stgit-worktree-node)
 169
 170 (defun stgit-refresh-index ()
 171   (when stgit-index-node
 172     (ewoc-invalidate (car stgit-index-node) (cdr stgit-index-node))))
 173
 174 (defun stgit-refresh-worktree ()
 175   (when stgit-worktree-node
 176     (ewoc-invalidate (car stgit-worktree-node) (cdr stgit-worktree-node))))
 177
 178 (defun stgit-run-series (ewoc)
 179   (let ((first-line t))
 180     (with-temp-buffer
 181       (let ((exit-status (stgit-run-silent "series" "--description" "--empty")))
 182         (goto-char (point-min))
 183         (if (not (zerop exit-status))
 184             (cond ((looking-at "stg series: \\(.*\\)")
 185                    (ewoc-set-hf ewoc (car (ewoc-get-hf ewoc))
 186                                 "-- not initialized (run M-x stgit-init)"))
 187                   ((looking-at ".*")
 188                    (error "Error running stg: %s"
 189                           (match-string 0))))
 190           (while (not (eobp))
 191             (unless (looking-at
 192                      "\\([0 ]\\)\\([>+-]\\)\\( \\)\\([^ ]+\\) *[|#] \\(.*\\)")
 193               (error "Syntax error in output from stg series"))
 194             (let* ((state-str (match-string 2))
 195                    (state (cond ((string= state-str ">") 'top)
 196                                 ((string= state-str "+") 'applied)
 197                                 ((string= state-str "-") 'unapplied))))
 198               (ewoc-enter-last ewoc
 199                                (make-stgit-patch
 200                                 :status state
 201                                 :name (intern (match-string 4))
 202                                 :desc (match-string 5)
 203                                 :empty (string= (match-string 1) "0"))))
 204             (setq first-line nil)
 205             (forward-line 1)))))
 206     (if stgit-show-worktree
 207         (setq stgit-index-node (cons ewoc (ewoc-enter-last ewoc
 208                                                            (make-stgit-patch
 209                                                             :status 'index
 210                                                             :name :index
 211                                                             :desc nil
 212                                                             :empty nil)))
 213               stgit-worktree-node (cons ewoc (ewoc-enter-last ewoc
 214                                                               (make-stgit-patch
 215                                                                :status 'work
 216                                                                :name :work
 217                                                                :desc nil
 218                                                                :empty nil))))
 219       (setq stgit-worktree-node nil))))
 220
 221
 222 (defun stgit-reload ()
 223   "Update the contents of the StGit buffer."
 224   (interactive)
 225   (let ((inhibit-read-only t)
 226         (curline (line-number-at-pos))
 227         (curpatch (stgit-patch-name-at-point)))
 228     (ewoc-filter stgit-ewoc #'(lambda (x) nil))
 229     (ewoc-set-hf stgit-ewoc
 230                  (concat "Branch: "
 231                          (propertize
 232                           (with-temp-buffer
 233                             (stgit-run-silent "branch")
 234                             (buffer-substring (point-min) (1- (point-max))))
 235                           'face 'stgit-branch-name-face)
 236                          "\n")
 237                  (if stgit-show-worktree
 238                      "--"
 239                    (propertize
 240                     (substitute-command-keys "--\n\"\\[stgit-toggle-worktree]\"\
 241  shows the working tree\n")
 242                    'face 'stgit-description-face)))
 243     (stgit-run-series stgit-ewoc)
 244     (if curpatch
 245         (stgit-goto-patch curpatch)
 246       (goto-line curline)))
 247   (stgit-refresh-git-status))
 248
 249 (defgroup stgit nil
 250   "A user interface for the StGit patch maintenance tool."
 251   :group 'tools)
 252
 253 (defface stgit-description-face
 254   '((((background dark)) (:foreground "tan"))
 255     (((background light)) (:foreground "dark red")))
 256   "The face used for StGit descriptions"
 257   :group 'stgit)
 258
 259 (defface stgit-branch-name-face
 260   '((t :inherit bold))
 261   "The face used for the StGit branch name"
 262   :group 'stgit)
 263
 264 (defface stgit-top-patch-face
 265   '((((background dark)) (:weight bold :foreground "yellow"))
 266     (((background light)) (:weight bold :foreground "purple"))
 267     (t (:weight bold)))
 268   "The face used for the top patch names"
 269   :group 'stgit)
 270
 271 (defface stgit-applied-patch-face
 272   '((((background dark)) (:foreground "light yellow"))
 273     (((background light)) (:foreground "purple"))
 274     (t ()))
 275   "The face used for applied patch names"
 276   :group 'stgit)
 277
 278 (defface stgit-unapplied-patch-face
 279   '((((background dark)) (:foreground "gray80"))
 280     (((background light)) (:foreground "orchid"))
 281     (t ()))
 282   "The face used for unapplied patch names"
 283   :group 'stgit)
 284
 285 (defface stgit-modified-file-face
 286   '((((class color) (background light)) (:foreground "purple"))
 287     (((class color) (background dark)) (:foreground "salmon")))
 288   "StGit mode face used for modified file status"
 289   :group 'stgit)
 290
 291 (defface stgit-unmerged-file-face
 292   '((((class color) (background light)) (:foreground "red" :bold t))
 293     (((class color) (background dark)) (:foreground "red" :bold t)))
 294   "StGit mode face used for unmerged file status"
 295   :group 'stgit)
 296
 297 (defface stgit-unknown-file-face
 298   '((((class color) (background light)) (:foreground "goldenrod" :bold t))
 299     (((class color) (background dark)) (:foreground "goldenrod" :bold t)))
 300   "StGit mode face used for unknown file status"
 301   :group 'stgit)
 302
 303 (defface stgit-file-permission-face
 304   '((((class color) (background light)) (:foreground "green" :bold t))
 305     (((class color) (background dark)) (:foreground "green" :bold t)))
 306   "StGit mode face used for permission changes."
 307   :group 'stgit)
 308
 309 (defcustom stgit-expand-find-copies-harder
 310   nil
 311   "Try harder to find copied files when listing patches.
 312
 313 When not nil, runs git diff-tree with the --find-copies-harder
 314 flag, which reduces performance."
 315   :type 'boolean
 316   :group 'stgit)
 317
 318 (defconst stgit-file-status-code-strings
 319   (mapcar (lambda (arg)
 320             (cons (car arg)
 321                   (propertize (cadr arg) 'face (car (cddr arg)))))
 322           '((add         "Added"       stgit-modified-file-face)
 323             (copy        "Copied"      stgit-modified-file-face)
 324             (delete      "Deleted"     stgit-modified-file-face)
 325             (modify      "Modified"    stgit-modified-file-face)
 326             (rename      "Renamed"     stgit-modified-file-face)
 327             (mode-change "Mode change" stgit-modified-file-face)
 328             (unmerged    "Unmerged"    stgit-unmerged-file-face)
 329             (unknown     "Unknown"     stgit-unknown-file-face)))
 330   "Alist of code symbols to description strings")
 331
 332 (defun stgit-file-status-code-as-string (file)
 333   "Return stgit status code for FILE as a string"
 334   (let* ((code (assq (stgit-file-status file)
 335                      stgit-file-status-code-strings))
 336          (score (stgit-file-cr-score file)))
 337     (when code
 338       (format "%-11s  "
 339               (if (and score (/= score 100))
 340                   (format "%s %s" (cdr code)
 341                           (propertize (format "%d%%" score)
 342                                       'face 'stgit-description-face))
 343                 (cdr code))))))
 344
 345 (defun stgit-file-status-code (str &optional score)
 346   "Return stgit status code from git status string"
 347   (let ((code (assoc str '(("A" . add)
 348                            ("C" . copy)
 349                            ("D" . delete)
 350                            ("M" . modify)
 351                            ("R" . rename)
 352                            ("T" . mode-change)
 353                            ("U" . unmerged)
 354                            ("X" . unknown)))))
 355     (setq code (if code (cdr code) 'unknown))
 356     (when (stringp score)
 357       (if (> (length score) 0)
 358           (setq score (string-to-number score))
 359         (setq score nil)))
 360     (if score (cons code score) code)))
 361
 362 (defconst stgit-file-type-strings
 363   '((#o100 . "file")
 364     (#o120 . "symlink")
 365     (#o160 . "subproject"))
 366   "Alist of names of file types")
 367
 368 (defun stgit-file-type-string (type)
 369   "Return string describing file type TYPE (the high bits of file permission).
 370 Cf. `stgit-file-type-strings' and `stgit-file-type-change-string'."
 371   (let ((type-str (assoc type stgit-file-type-strings)))
 372     (or (and type-str (cdr type-str))
 373         (format "unknown type %o" type))))
 374
 375 (defun stgit-file-type-change-string (old-perm new-perm)
 376   "Return string describing file type change from OLD-PERM to NEW-PERM.
 377 Cf. `stgit-file-type-string'."
 378   (let ((old-type (lsh old-perm -9))
 379         (new-type (lsh new-perm -9)))
 380     (cond ((= old-type new-type) "")
 381           ((zerop new-type) "")
 382           ((zerop old-type)
 383            (if (= new-type #o100)
 384                ""
 385              (format "   (%s)" (stgit-file-type-string new-type))))
 386           (t (format "   (%s -> %s)"
 387                      (stgit-file-type-string old-type)
 388                      (stgit-file-type-string new-type))))))
 389
 390 (defun stgit-file-mode-change-string (old-perm new-perm)
 391   "Return string describing file mode change from OLD-PERM to NEW-PERM.
 392 Cf. `stgit-file-type-change-string'."
 393   (setq old-perm (logand old-perm #o777)
 394         new-perm (logand new-perm #o777))
 395   (if (or (= old-perm new-perm)
 396           (zerop old-perm)
 397           (zerop new-perm))
 398       ""
 399     (let* ((modified       (logxor old-perm new-perm))
 400            (not-x-modified (logand (logxor old-perm new-perm) #o666)))
 401       (cond ((zerop modified) "")
 402             ((and (zerop not-x-modified)
 403                   (or (and (eq #o111 (logand old-perm #o111))
 404                            (propertize "-x" 'face 'stgit-file-permission-face))
 405                       (and (eq #o111 (logand new-perm #o111))
 406                            (propertize "+x" 'face
 407                                        'stgit-file-permission-face)))))
 408             (t (concat (propertize (format "%o" old-perm)
 409                                    'face 'stgit-file-permission-face)
 410                        (propertize " -> "
 411                                    'face 'stgit-description-face)
 412                        (propertize (format "%o" new-perm)
 413                                    'face 'stgit-file-permission-face)))))))
 414
 415 (defstruct (stgit-file)
 416   old-perm new-perm copy-or-rename cr-score cr-from cr-to status file)
 417
 418 (defun stgit-file-pp (file)
 419   (let ((status (stgit-file-status file))
 420         (name (if (stgit-file-copy-or-rename file)
 421                   (concat (stgit-file-cr-from file)
 422                           (propertize " -> "
 423                                       'face 'stgit-description-face)
 424                           (stgit-file-cr-to file))
 425                 (stgit-file-file file)))
 426         (mode-change (stgit-file-mode-change-string
 427                       (stgit-file-old-perm file)
 428                       (stgit-file-new-perm file)))
 429         (start (point)))
 430     (insert (format "    %-12s%1s%s%s\n"
 431                     (stgit-file-status-code-as-string file)
 432                     mode-change
 433                     name
 434                     (propertize (stgit-file-type-change-string
 435                                  (stgit-file-old-perm file)
 436                                  (stgit-file-new-perm file))
 437                                 'face 'stgit-description-face)))
 438     (add-text-properties start (point)
 439                          (list 'entry-type 'file
 440                                'file-data file))))
 441
 442 (defun stgit-insert-patch-files (patch)
 443   "Expand (show modification of) the patch PATCH after the line
 444 at point."
 445   (let* ((patchsym (stgit-patch-name patch))
 446          (end (progn (insert "#") (prog1 (point-marker) (forward-char -1))))
 447          (args (list "-z" (if stgit-expand-find-copies-harder
 448                               "--find-copies-harder"
 449                             "-C")))
 450          (ewoc (ewoc-create #'stgit-file-pp nil nil t)))
 451     (setf (stgit-patch-files-ewoc patch) ewoc)
 452     (with-temp-buffer
 453       (apply 'stgit-run-git
 454              (cond ((eq patchsym :work)
 455                     `("diff-files" ,@args))
 456                    ((eq patchsym :index)
 457                     `("diff-index" ,@args "--cached" "HEAD"))
 458                    (t
 459                     `("diff-tree" ,@args "-r" ,(stgit-id patchsym)))))
 460       (goto-char (point-min))
 461       (unless (or (eobp) (memq patchsym '(:work :index)))
 462         (forward-char 41))
 463       (while (looking-at ":\\([0-7]+\\) \\([0-7]+\\) [0-9A-Fa-f]\\{40\\} [0-9A-Fa-f]\\{40\\} ")
 464         (let ((old-perm (string-to-number (match-string 1) 8))
 465               (new-perm (string-to-number (match-string 2) 8)))
 466           (goto-char (match-end 0))
 467           (let ((file
 468                  (cond ((looking-at
 469                          "\\([CR]\\)\\([0-9]*\\)\0\\([^\0]*\\)\0\\([^\0]*\\)\0")
 470                         (make-stgit-file
 471                          :old-perm       old-perm
 472                          :new-perm       new-perm
 473                          :copy-or-rename t
 474                          :cr-score       (string-to-number (match-string 2))
 475                          :cr-from        (match-string 3)
 476                          :cr-to          (match-string 4)
 477                          :status         (stgit-file-status-code (match-string 1))
 478                          :file           (match-string 3)))
 479                        ((looking-at "\\([ABD-QS-Z]\\)\0\\([^\0]*\\)\0")
 480                         (make-stgit-file
 481                          :old-perm       old-perm
 482                          :new-perm       new-perm
 483                          :copy-or-rename nil
 484                          :cr-score       nil
 485                          :cr-from        nil
 486                          :cr-to          nil
 487                          :status         (stgit-file-status-code (match-string 1))
 488                          :file           (match-string 2))))))
 489             (ewoc-enter-last ewoc file))
 490           (goto-char (match-end 0))))
 491       (unless (ewoc-nth ewoc 0)
 492         (ewoc-set-hf ewoc "" (propertize "    <no files>\n"
 493                                          'face 'stgit-description-face))))
 494     (goto-char end)
 495     (delete-char -2)))
 496
 497 (defun stgit-select-file ()
 498   (let ((filename (expand-file-name
 499                    (stgit-file-file (stgit-patched-file-at-point)))))
 500     (unless (file-exists-p filename)
 501       (error "File does not exist"))
 502     (find-file filename)))
 503
 504 (defun stgit-select-patch ()
 505   (let ((patchname (stgit-patch-name-at-point)))
 506     (if (memq patchname stgit-expanded-patches)
 507         (setq stgit-expanded-patches (delq patchname stgit-expanded-patches))
 508       (setq stgit-expanded-patches (cons patchname stgit-expanded-patches)))
 509     (ewoc-invalidate stgit-ewoc (ewoc-locate stgit-ewoc)))
 510   (move-to-column (stgit-goal-column)))
 511
 512 (defun stgit-select ()
 513   "Expand or collapse the current entry"
 514   (interactive)
 515   (case (get-text-property (point) 'entry-type)
 516     ('patch
 517      (stgit-select-patch))
 518     ('file
 519      (stgit-select-file))
 520     (t
 521      (error "No patch or file on line"))))
 522
 523 (defun stgit-find-file-other-window ()
 524   "Open file at point in other window"
 525   (interactive)
 526   (let ((patched-file (stgit-patched-file-at-point)))
 527     (unless patched-file
 528       (error "No file on the current line"))
 529     (let ((filename (expand-file-name (stgit-file-file patched-file))))
 530       (unless (file-exists-p filename)
 531         (error "File does not exist"))
 532       (find-file-other-window filename))))
 533
 534 (defun stgit-quit ()
 535   "Hide the stgit buffer."
 536   (interactive)
 537   (bury-buffer))
 538
 539 (defun stgit-git-status ()
 540   "Show status using `git-status'."
 541   (interactive)
 542   (unless (fboundp 'git-status)
 543     (error "The stgit-git-status command requires git-status"))
 544   (let ((dir default-directory))
 545     (save-selected-window
 546       (pop-to-buffer nil)
 547       (git-status dir))))
 548
 549 (defun stgit-goal-column ()
 550   "Return goal column for the current line"
 551   (case (get-text-property (point) 'entry-type)
 552     ('patch 2)
 553     ('file 4)
 554     (t 0)))
 555
 556 (defun stgit-next-line (&optional arg)
 557   "Move cursor vertically down ARG lines"
 558   (interactive "p")
 559   (next-line arg)
 560   (move-to-column (stgit-goal-column)))
 561
 562 (defun stgit-previous-line (&optional arg)
 563   "Move cursor vertically up ARG lines"
 564   (interactive "p")
 565   (previous-line arg)
 566   (move-to-column (stgit-goal-column)))
 567
 568 (defun stgit-next-patch (&optional arg)
 569   "Move cursor down ARG patches."
 570   (interactive "p")
 571   (ewoc-goto-next stgit-ewoc (or arg 1))
 572   (move-to-column goal-column))
 573
 574 (defun stgit-previous-patch (&optional arg)
 575   "Move cursor up ARG patches."
 576   (interactive "p")
 577   (ewoc-goto-prev stgit-ewoc (or arg 1))
 578   (move-to-column goal-column))
 579
 580 (defvar stgit-mode-hook nil
 581   "Run after `stgit-mode' is setup.")
 582
 583 (defvar stgit-mode-map nil
 584   "Keymap for StGit major mode.")
 585
 586 (unless stgit-mode-map
 587   (let ((toggle-map (make-keymap)))
 588     (suppress-keymap toggle-map)
 589     (mapc (lambda (arg) (define-key toggle-map (car arg) (cdr arg)))
 590           '(("t" .        stgit-toggle-worktree)))
 591     (setq stgit-mode-map (make-keymap))
 592     (suppress-keymap stgit-mode-map)
 593     (mapc (lambda (arg) (define-key stgit-mode-map (car arg) (cdr arg)))
 594           `((" " .        stgit-mark)
 595             ("m" .        stgit-mark)
 596             ("\d" .       stgit-unmark-up)
 597             ("u" .        stgit-unmark-down)
 598             ("?" .        stgit-help)
 599             ("h" .        stgit-help)
 600             ("\C-p" .     stgit-previous-line)
 601             ("\C-n" .     stgit-next-line)
 602             ([up] .       stgit-previous-line)
 603             ([down] .     stgit-next-line)
 604             ("p" .        stgit-previous-patch)
 605             ("n" .        stgit-next-patch)
 606             ("\M-{" .     stgit-previous-patch)
 607             ("\M-}" .     stgit-next-patch)
 608             ("s" .        stgit-git-status)
 609             ("g" .        stgit-reload-or-repair)
 610             ("r" .        stgit-refresh)
 611             ("\C-c\C-r" . stgit-rename)
 612             ("e" .        stgit-edit)
 613             ("M" .        stgit-move-patches)
 614             ("S" .        stgit-squash)
 615             ("N" .        stgit-new)
 616             ("\C-c\C-c" . stgit-commit)
 617             ("\C-c\C-u" . stgit-uncommit)
 618             ("U" .        stgit-revert-file)
 619             ("\r" .       stgit-select)
 620             ("o" .        stgit-find-file-other-window)
 621             ("i" .        stgit-file-toggle-index)
 622             (">" .        stgit-push-next)
 623             ("<" .        stgit-pop-next)
 624             ("P" .        stgit-push-or-pop)
 625             ("G" .        stgit-goto)
 626             ("=" .        stgit-show)
 627             ("D" .        stgit-delete)
 628             ([(control ?/)] . stgit-undo)
 629             ("\C-_" .     stgit-undo)
 630             ("B" .        stgit-branch)
 631             ("t" .        ,toggle-map)
 632             ("q" .        stgit-quit)))))
 633
 634 (defun stgit-mode ()
 635   "Major mode for interacting with StGit.
 636 Commands:
 637 \\{stgit-mode-map}"
 638   (kill-all-local-variables)
 639   (buffer-disable-undo)
 640   (setq mode-name "StGit"
 641         major-mode 'stgit-mode
 642         goal-column 2)
 643   (use-local-map stgit-mode-map)
 644   (set (make-local-variable 'list-buffers-directory) default-directory)
 645   (set (make-local-variable 'stgit-marked-patches) nil)
 646   (set (make-local-variable 'stgit-expanded-patches) nil)
 647   (set (make-local-variable 'stgit-show-worktree) stgit-default-show-worktree)
 648   (set (make-local-variable 'stgit-index-node) nil)
 649   (set (make-local-variable 'stgit-worktree-node) nil)
 650   (set-variable 'truncate-lines 't)
 651   (add-hook 'after-save-hook 'stgit-update-saved-file)
 652   (run-hooks 'stgit-mode-hook))
 653
 654 (defun stgit-update-saved-file ()
 655   (let* ((file (expand-file-name buffer-file-name))
 656          (dir (file-name-directory file))
 657          (gitdir (condition-case nil (git-get-top-dir dir)
 658                    (error nil)))
 659          (buffer (and gitdir (stgit-find-buffer gitdir))))
 660     (when buffer
 661       (with-current-buffer buffer
 662         (stgit-refresh-worktree)))))
 663
 664 (defun stgit-add-mark (patchsym)
 665   "Mark the patch PATCHSYM."
 666   (setq stgit-marked-patches (cons patchsym stgit-marked-patches)))
 667
 668 (defun stgit-remove-mark (patchsym)
 669   "Unmark the patch PATCHSYM."
 670   (setq stgit-marked-patches (delq patchsym stgit-marked-patches)))
 671
 672 (defun stgit-clear-marks ()
 673   "Unmark all patches."
 674   (setq stgit-marked-patches '()))
 675
 676 (defun stgit-patch-at-point (&optional cause-error)
 677   (get-text-property (point) 'patch-data))
 678
 679 (defun stgit-patch-name-at-point (&optional cause-error)
 680   "Return the patch name on the current line as a symbol.
 681 If CAUSE-ERROR is not nil, signal an error if none found."
 682   (let ((patch (stgit-patch-at-point)))
 683     (cond (patch
 684            (stgit-patch-name patch))
 685           (cause-error
 686            (error "No patch on this line")))))
 687
 688 (defun stgit-patched-file-at-point ()
 689   (get-text-property (point) 'file-data))
 690
 691 (defun stgit-patches-marked-or-at-point ()
 692   "Return the symbols of the marked patches, or the patch on the current line."
 693   (if stgit-marked-patches
 694       stgit-marked-patches
 695     (let ((patch (stgit-patch-name-at-point)))
 696       (if patch
 697           (list patch)
 698         '()))))
 699
 700 (defun stgit-goto-patch (patchsym)
 701   "Move point to the line containing patch PATCHSYM.
 702 If that patch cannot be found, do nothing."
 703   (let ((node (ewoc-nth stgit-ewoc 0)))
 704     (while (and node (not (eq (stgit-patch-name (ewoc-data node))
 705                               patchsym)))
 706       (setq node (ewoc-next stgit-ewoc node)))
 707     (when node
 708       (ewoc-goto-node stgit-ewoc node)
 709       (move-to-column goal-column))))
 710
 711 (defun stgit-init ()
 712   "Run stg init."
 713   (interactive)
 714   (stgit-capture-output nil
 715     (stgit-run "init"))
 716   (stgit-reload))
 717
 718 (defun stgit-mark ()
 719   "Mark the patch under point."
 720   (interactive)
 721   (let* ((node (ewoc-locate stgit-ewoc))
 722          (patch (ewoc-data node)))
 723     (stgit-add-mark (stgit-patch-name patch))
 724     (ewoc-invalidate stgit-ewoc node))
 725   (stgit-next-patch))
 726
 727 (defun stgit-unmark-up ()
 728   "Remove mark from the patch on the previous line."
 729   (interactive)
 730   (stgit-previous-patch)
 731   (let* ((node (ewoc-locate stgit-ewoc))
 732          (patch (ewoc-data node)))
 733     (stgit-remove-mark (stgit-patch-name patch))
 734     (ewoc-invalidate stgit-ewoc node))
 735   (move-to-column (stgit-goal-column)))
 736
 737 (defun stgit-unmark-down ()
 738   "Remove mark from the patch on the current line."
 739   (interactive)
 740   (let* ((node (ewoc-locate stgit-ewoc))
 741          (patch (ewoc-data node)))
 742     (stgit-remove-mark (stgit-patch-name patch))
 743     (ewoc-invalidate stgit-ewoc node))
 744   (stgit-next-patch))
 745
 746 (defun stgit-rename (name)
 747   "Rename the patch under point to NAME."
 748   (interactive (list (read-string "Patch name: "
 749                                   (symbol-name (stgit-patch-name-at-point t)))))
 750   (let ((old-patchsym (stgit-patch-name-at-point t)))
 751     (stgit-capture-output nil
 752       (stgit-run "rename" old-patchsym name))
 753     (let ((name-sym (intern name)))
 754       (when (memq old-patchsym stgit-expanded-patches)
 755         (setq stgit-expanded-patches
 756             (cons name-sym (delq old-patchsym stgit-expanded-patches))))
 757       (when (memq old-patchsym stgit-marked-patches)
 758         (setq stgit-marked-patches
 759             (cons name-sym (delq old-patchsym stgit-marked-patches))))
 760       (stgit-reload)
 761       (stgit-goto-patch name-sym))))
 762
 763 (defun stgit-reload-or-repair (repair)
 764   "Update the contents of the StGit buffer (`stgit-reload').
 765
 766 With a prefix argument, repair the StGit metadata if the branch
 767 was modified with git commands (`stgit-repair')."
 768   (interactive "P")
 769   (if repair
 770       (stgit-repair)
 771     (stgit-reload)))
 772
 773 (defun stgit-repair ()
 774   "Run stg repair."
 775   (interactive)
 776   (stgit-capture-output nil
 777     (stgit-run "repair"))
 778   (stgit-reload))
 779
 780 (defun stgit-available-branches ()
 781   "Returns a list of the available stg branches"
 782   (let ((output (with-output-to-string
 783                   (stgit-run "branch" "--list")))
 784         (start 0)
 785         result)
 786     (while (string-match "^>?\\s-+s\\s-+\\(\\S-+\\)" output start)
 787       (setq result (cons (match-string 1 output) result))
 788       (setq start (match-end 0)))
 789     result))
 790
 791 (defun stgit-branch (branch)
 792   "Switch to branch BRANCH."
 793   (interactive (list (completing-read "Switch to branch: "
 794                                       (stgit-available-branches))))
 795   (stgit-capture-output nil (stgit-run "branch" "--" branch))
 796   (stgit-reload))
 797
 798 (defun stgit-commit (count)
 799   "Run stg commit on COUNT commits.
 800 Interactively, the prefix argument is used as COUNT."
 801   (interactive "p")
 802   (stgit-capture-output nil (stgit-run "commit" "-n" count))
 803   (stgit-reload))
 804
 805 (defun stgit-revert-file ()
 806   "Revert the file at point, which must be in the index or the
 807 working tree."
 808   (interactive)
 809   (let* ((patched-file (or (stgit-patched-file-at-point)
 810                            (error "No file on the current line")))
 811          (patch-name   (stgit-patch-name-at-point))
 812          (file-status  (stgit-file-status patched-file))
 813          (rm-file      (cond ((stgit-file-copy-or-rename patched-file)
 814                               (stgit-file-cr-to patched-file))
 815                              ((eq file-status 'add)
 816                               (stgit-file-file patched-file))))
 817          (co-file      (cond ((eq file-status 'rename)
 818                               (stgit-file-cr-from patched-file))
 819                              ((not (memq file-status '(copy add)))
 820                               (stgit-file-file patched-file)))))
 821
 822     (unless (memq patch-name '(:work :index))
 823       (error "No index or working tree file on this line"))
 824
 825     (let ((nfiles (+ (if rm-file 1 0) (if co-file 1 0))))
 826       (when (yes-or-no-p (format "Revert %d file%s? "
 827                                  nfiles
 828                                  (if (= nfiles 1) "" "s")))
 829         (stgit-capture-output nil
 830           (when rm-file
 831             (stgit-run-git "rm" "-f" "-q" "--" rm-file))
 832           (when co-file
 833             (stgit-run-git "checkout" "HEAD" co-file)))
 834         (stgit-reload)))))
 835
 836 (defun stgit-uncommit (count)
 837   "Run stg uncommit on COUNT commits.
 838 Interactively, the prefix argument is used as COUNT."
 839   (interactive "p")
 840   (stgit-capture-output nil (stgit-run "uncommit" "-n" count))
 841   (stgit-reload))
 842
 843 (defun stgit-push-next (npatches)
 844   "Push the first unapplied patch.
 845 With numeric prefix argument, push that many patches."
 846   (interactive "p")
 847   (stgit-capture-output nil (stgit-run "push" "-n" npatches))
 848   (stgit-reload)
 849   (stgit-refresh-git-status))
 850
 851 (defun stgit-pop-next (npatches)
 852   "Pop the topmost applied patch.
 853 With numeric prefix argument, pop that many patches."
 854   (interactive "p")
 855   (stgit-capture-output nil (stgit-run "pop" "-n" npatches))
 856   (stgit-reload)
 857   (stgit-refresh-git-status))
 858
 859 (defun stgit-applied-at-point ()
 860   "Is the patch on the current line applied?"
 861   (save-excursion
 862     (beginning-of-line)
 863     (looking-at "[>+]")))
 864
 865 (defun stgit-push-or-pop ()
 866   "Push or pop the patch on the current line."
 867   (interactive)
 868   (let ((patchsym (stgit-patch-name-at-point t))
 869         (applied (stgit-applied-at-point)))
 870     (stgit-capture-output nil
 871       (stgit-run (if applied "pop" "push") patchsym))
 872     (stgit-reload)))
 873
 874 (defun stgit-goto ()
 875   "Go to the patch on the current line."
 876   (interactive)
 877   (let ((patchsym (stgit-patch-name-at-point t)))
 878     (stgit-capture-output nil
 879       (stgit-run "goto" patchsym))
 880     (stgit-reload)))
 881
 882 (defun stgit-id (patchsym)
 883   "Return the git commit id for PATCHSYM.
 884 If PATCHSYM is a keyword, returns PATCHSYM unmodified."
 885   (if (keywordp patchsym)
 886       patchsym
 887     (let ((result (with-output-to-string
 888                     (stgit-run-silent "id" patchsym))))
 889       (unless (string-match "^\\([0-9A-Fa-f]\\{40\\}\\)$" result)
 890         (error "Cannot find commit id for %s" patchsym))
 891       (match-string 1 result))))
 892
 893 (defun stgit-show ()
 894   "Show the patch on the current line."
 895   (interactive)
 896   (stgit-capture-output "*StGit patch*"
 897     (case (get-text-property (point) 'entry-type)
 898       ('file
 899        (let* ((patched-file (stgit-patched-file-at-point))
 900               (patch-name (stgit-patch-name-at-point))
 901               (patch-id (stgit-id patch-name))
 902               (args (append (and (stgit-file-cr-from patched-file)
 903                                  (if stgit-expand-find-copies-harder
 904                                      '("--find-copies-harder")
 905                                    '("-C")))
 906                             (cond ((eq patch-id :index)
 907                                    '("--cached"))
 908                                   ((eq patch-id :work)
 909                                    nil)
 910                                   (t
 911                                    (list (concat patch-id "^") patch-id)))
 912                             '("--")
 913                               (if (stgit-file-copy-or-rename patched-file)
 914                                   (list (stgit-file-cr-from patched-file)
 915                                         (stgit-file-cr-to patched-file))
 916                                 (list (stgit-file-file patched-file))))))
 917          (apply 'stgit-run-git "diff" args)))
 918       ('patch
 919        (stgit-run "show" "-O" "--patch-with-stat" "-O" "-M"
 920                   (stgit-patch-name-at-point)))
 921       (t
 922        (error "No patch or file at point")))
 923     (with-current-buffer standard-output
 924       (goto-char (point-min))
 925       (diff-mode))))
 926
 927 (defun stgit-move-change-to-index (file)
 928   "Copies the workspace state of FILE to index, using git add or git rm"
 929   (let ((op (if (or (file-exists-p file) (file-symlink-p file))
 930                 '("add") '("rm" "-q"))))
 931     (stgit-capture-output "*git output*"
 932       (apply 'stgit-run-git (append op '("--") (list file))))))
 933
 934 (defun stgit-remove-change-from-index (file)
 935   "Unstages the change in FILE from the index"
 936   (stgit-capture-output "*git output*"
 937     (stgit-run-git "reset" "-q" "--" file)))
 938
 939 (defun stgit-file-toggle-index ()
 940   "Move modified file in or out of the index."
 941   (interactive)
 942   (let ((patched-file (stgit-patched-file-at-point)))
 943     (unless patched-file
 944       (error "No file on the current line"))
 945     (let ((patch-name (stgit-patch-name-at-point)))
 946       (cond ((eq patch-name :work)
 947              (stgit-move-change-to-index (stgit-file-file patched-file)))
 948             ((eq patch-name :index)
 949              (stgit-remove-change-from-index (stgit-file-file patched-file)))
 950             (t
 951              (error "Can only move files in the working tree to index")))))
 952   (stgit-refresh-worktree)
 953   (stgit-refresh-index))
 954
 955 (defun stgit-edit ()
 956   "Edit the patch on the current line."
 957   (interactive)
 958   (let ((patchsym (stgit-patch-name-at-point t))
 959         (edit-buf (get-buffer-create "*StGit edit*"))
 960         (dir default-directory))
 961     (log-edit 'stgit-confirm-edit t nil edit-buf)
 962     (set (make-local-variable 'stgit-edit-patchsym) patchsym)
 963     (setq default-directory dir)
 964     (let ((standard-output edit-buf))
 965       (stgit-run-silent "edit" "--save-template=-" patchsym))))
 966
 967 (defun stgit-confirm-edit ()
 968   (interactive)
 969   (let ((file (make-temp-file "stgit-edit-")))
 970     (write-region (point-min) (point-max) file)
 971     (stgit-capture-output nil
 972       (stgit-run "edit" "-f" file stgit-edit-patchsym))
 973     (with-current-buffer log-edit-parent-buffer
 974       (stgit-reload))))
 975
 976 (defun stgit-new (add-sign)
 977   "Create a new patch.
 978 With a prefix argument, include a \"Signed-off-by:\" line at the
 979 end of the patch."
 980   (interactive "P")
 981   (let ((edit-buf (get-buffer-create "*StGit edit*"))
 982         (dir default-directory))
 983     (log-edit 'stgit-confirm-new t nil edit-buf)
 984     (setq default-directory dir)
 985     (when add-sign
 986       (save-excursion
 987         (let ((standard-output (current-buffer)))
 988           (stgit-run-silent "new" "--sign" "--save-template=-"))))))
 989
 990 (defun stgit-confirm-new ()
 991   (interactive)
 992   (let ((file (make-temp-file "stgit-edit-")))
 993     (write-region (point-min) (point-max) file)
 994     (stgit-capture-output nil
 995       (stgit-run "new" "-f" file))
 996     (with-current-buffer log-edit-parent-buffer
 997       (stgit-reload))))
 998
 999 (defun stgit-create-patch-name (description)
1000   "Create a patch name from a long description"
1001   (let ((patch ""))
1002     (while (> (length description) 0)
1003       (cond ((string-match "\\`[a-zA-Z_-]+" description)
1004              (setq patch (downcase (concat patch
1005                                            (match-string 0 description))))
1006              (setq description (substring description (match-end 0))))
1007             ((string-match "\\` +" description)
1008              (setq patch (concat patch "-"))
1009              (setq description (substring description (match-end 0))))
1010             ((string-match "\\`[^a-zA-Z_-]+" description)
1011              (setq description (substring description (match-end 0))))))
1012     (cond ((= (length patch) 0)
1013            "patch")
1014           ((> (length patch) 20)
1015            (substring patch 0 20))
1016           (t patch))))
1017
1018 (defun stgit-delete (patchsyms &optional spill-p)
1019   "Delete the patches in PATCHSYMS.
1020 Interactively, delete the marked patches, or the patch at point.
1021
1022 With a prefix argument, or SPILL-P, spill the patch contents to
1023 the work tree and index."
1024   (interactive (list (stgit-patches-marked-or-at-point)
1025                      current-prefix-arg))
1026   (unless patchsyms
1027     (error "No patches to delete"))
1028   (let ((npatches (length patchsyms)))
1029     (when (yes-or-no-p (format "Really delete %d patch%s%s? "
1030                                npatches
1031                                (if (= 1 npatches) "" "es")
1032                                (if spill-p
1033                                    " (spilling contents to index)"
1034                                  "")))
1035       (let ((args (if spill-p
1036                       (cons "--spill" patchsyms)
1037                     patchsyms)))
1038         (stgit-capture-output nil
1039           (apply 'stgit-run "delete" args))
1040         (stgit-reload)))))
1041
1042 (defun stgit-move-patches-target ()
1043   "Return the patchsym indicating a target patch for
1044 `stgit-move-patches'.
1045
1046 This is either the patch at point, or one of :top and :bottom, if
1047 the point is after or before the applied patches."
1048
1049   (let ((patchsym (stgit-patch-name-at-point)))
1050     (cond (patchsym patchsym)
1051           ((save-excursion (re-search-backward "^>" nil t)) :top)
1052           (t :bottom))))
1053
1054 (defun stgit-sort-patches (patchsyms)
1055   "Returns the list of patches in PATCHSYMS sorted according to
1056 their position in the patch series, bottommost first.
1057
1058 PATCHSYMS may not contain duplicate entries."
1059   (let (sorted-patchsyms
1060         (series (with-output-to-string
1061                   (with-current-buffer standard-output
1062                     (stgit-run-silent "series" "--noprefix"))))
1063         start)
1064     (while (string-match "^\\(.+\\)" series start)
1065       (let ((patchsym (intern (match-string 1 series))))
1066         (when (memq patchsym patchsyms)
1067           (setq sorted-patchsyms (cons patchsym sorted-patchsyms))))
1068       (setq start (match-end 0)))
1069     (setq sorted-patchsyms (nreverse sorted-patchsyms))
1070
1071     (unless (= (length patchsyms) (length sorted-patchsyms))
1072       (error "Internal error"))
1073
1074     sorted-patchsyms))
1075
1076 (defun stgit-move-patches (patchsyms target-patch)
1077   "Move the patches in PATCHSYMS to below TARGET-PATCH.
1078 If TARGET-PATCH is :bottom or :top, move the patches to the
1079 bottom or top of the stack, respectively.
1080
1081 Interactively, move the marked patches to where the point is."
1082   (interactive (list stgit-marked-patches
1083                      (stgit-move-patches-target)))
1084   (unless patchsyms
1085     (error "Need at least one patch to move"))
1086
1087   (unless target-patch
1088     (error "Point not at a patch"))
1089
1090   (if (eq target-patch :top)
1091       (stgit-capture-output nil
1092         (apply 'stgit-run "float" patchsyms))
1093
1094     ;; need to have patchsyms sorted by position in the stack
1095     (let ((sorted-patchsyms (stgit-sort-patches patchsyms)))
1096       (while sorted-patchsyms
1097         (setq sorted-patchsyms
1098               (and (stgit-capture-output nil
1099                      (if (eq target-patch :bottom)
1100                          (stgit-run "sink" "--" (car sorted-patchsyms))
1101                        (stgit-run "sink" "--to" target-patch "--"
1102                                   (car sorted-patchsyms))))
1103                    (cdr sorted-patchsyms))))))
1104   (stgit-reload))
1105
1106 (defun stgit-squash (patchsyms)
1107   "Squash the patches in PATCHSYMS.
1108 Interactively, squash the marked patches.
1109
1110 Unless there are any conflicts, the patches will be merged into
1111 one patch, which will occupy the same spot in the series as the
1112 deepest patch had before the squash."
1113   (interactive (list stgit-marked-patches))
1114   (when (< (length patchsyms) 2)
1115     (error "Need at least two patches to squash"))
1116   (let ((stgit-buffer (current-buffer))
1117         (edit-buf (get-buffer-create "*StGit edit*"))
1118         (dir default-directory)
1119         (sorted-patchsyms (stgit-sort-patches patchsyms)))
1120     (log-edit 'stgit-confirm-squash t nil edit-buf)
1121     (set (make-local-variable 'stgit-patchsyms) sorted-patchsyms)
1122     (setq default-directory dir)
1123     (let ((result (let ((standard-output edit-buf))
1124                     (apply 'stgit-run-silent "squash"
1125                            "--save-template=-" sorted-patchsyms))))
1126
1127       ;; stg squash may have reordered the patches or caused conflicts
1128       (with-current-buffer stgit-buffer
1129         (stgit-reload))
1130
1131       (unless (eq 0 result)
1132         (fundamental-mode)
1133         (rename-buffer "*StGit error*")
1134         (resize-temp-buffer-window)
1135         (switch-to-buffer-other-window stgit-buffer)
1136         (error "stg squash failed")))))
1137
1138 (defun stgit-confirm-squash ()
1139   (interactive)
1140   (let ((file (make-temp-file "stgit-edit-")))
1141     (write-region (point-min) (point-max) file)
1142     (stgit-capture-output nil
1143       (apply 'stgit-run "squash" "-f" file stgit-patchsyms))
1144     (with-current-buffer log-edit-parent-buffer
1145       (stgit-clear-marks)
1146       ;; Go to first marked patch and stay there
1147       (goto-char (point-min))
1148       (re-search-forward (concat "^[>+-]\\*") nil t)
1149       (move-to-column goal-column)
1150       (let ((pos (point)))
1151         (stgit-reload)
1152         (goto-char pos)))))
1153
1154 (defun stgit-help ()
1155   "Display help for the StGit mode."
1156   (interactive)
1157   (describe-function 'stgit-mode))
1158
1159 (defun stgit-undo (&optional arg)
1160   "Run stg undo.
1161 With prefix argument, run it with the --hard flag."
1162   (interactive "P")
1163   (stgit-capture-output nil
1164     (if arg
1165         (stgit-run "undo" "--hard")
1166       (stgit-run "undo")))
1167   (stgit-reload))
1168
1169 (defun stgit-refresh (&optional arg)
1170   "Run stg refresh.
1171 With prefix argument, refresh the marked patch or the patch under point."
1172   (interactive "P")
1173   (let ((patchargs (if arg
1174                        (let ((patches (stgit-patches-marked-or-at-point)))
1175                          (cond ((null patches)
1176                                 (error "No patch to update"))
1177                                ((> (length patches) 1)
1178                                 (error "Too many patches selected"))
1179                                (t
1180                                 (cons "-p" patches))))
1181                      nil)))
1182     (stgit-capture-output nil
1183       (apply 'stgit-run "refresh" patchargs))
1184     (stgit-refresh-git-status))
1185   (stgit-reload))
1186
1187 (defcustom stgit-default-show-worktree
1188   nil
1189   "Set to non-nil to by default show the working tree in a new stgit buffer.
1190
1191 This value is used as the default value for `stgit-show-worktree'."
1192   :type 'boolean
1193   :group 'stgit)
1194
1195 (defvar stgit-show-worktree nil
1196   "Show work tree and index in the stgit buffer.
1197
1198 See `stgit-default-show-worktree' for its default value.")
1199
1200 (defun stgit-toggle-worktree (&optional arg)
1201   "Toggle the visibility of the work tree.
1202 With arg, show the work tree if arg is positive.
1203
1204 Its initial setting is controlled by `stgit-default-show-worktree'."
1205   (interactive)
1206   (setq stgit-show-worktree
1207         (if (numberp arg)
1208             (> arg 0)
1209           (not stgit-show-worktree)))
1210   (stgit-reload))
1211
1212 (provide 'stgit)