chiark - git - mdw - stgit/blob - contrib/stgit.el

   1 ;; stgit.el: An emacs mode for StGit
   2 ;;
   3 ;; Copyright (C) 2007 David Kågedal <davidk@lysator.liu.se>
   4 ;;
   5 ;; To install: put this file on the load-path and place the following
   6 ;; in your .emacs file:
   7 ;;
   8 ;;    (require 'stgit)
   9 ;;
  10 ;; To start: `M-x stgit'
  11
  12 (require 'git nil t)
  13 (require 'cl)
  14 (require 'ewoc)
  15
  16 (defun stgit (dir)
  17   "Manage StGit patches for the tree in DIR."
  18   (interactive "DDirectory: \n")
  19   (switch-to-stgit-buffer (git-get-top-dir dir))
  20   (stgit-reload))
  21
  22 (unless (fboundp 'git-get-top-dir)
  23   (defun git-get-top-dir (dir)
  24     "Retrieve the top-level directory of a git tree."
  25     (let ((cdup (with-output-to-string
  26                   (with-current-buffer standard-output
  27                     (cd dir)
  28                     (unless (eq 0 (call-process "git" nil t nil
  29                                                 "rev-parse" "--show-cdup"))
  30                       (error "Cannot find top-level git tree for %s" dir))))))
  31       (expand-file-name (concat (file-name-as-directory dir)
  32                                 (car (split-string cdup "\n")))))))
  33
  34 (defun stgit-refresh-git-status (&optional dir)
  35   "If it exists, refresh the `git-status' buffer belonging to
  36 directory DIR or `default-directory'"
  37   (when (and (fboundp 'git-find-status-buffer)
  38              (fboundp 'git-refresh-status))
  39     (let* ((top-dir (git-get-top-dir (or dir default-directory)))
  40            (git-status-buffer (and top-dir (git-find-status-buffer top-dir))))
  41       (when git-status-buffer
  42         (with-current-buffer git-status-buffer
  43           (git-refresh-status))))))
  44
  45 (defun stgit-find-buffer (dir)
  46   "Return the buffer displaying StGit patches for DIR, or nil if none."
  47   (setq dir (file-name-as-directory dir))
  48   (let ((buffers (buffer-list)))
  49     (while (and buffers
  50                 (not (with-current-buffer (car buffers)
  51                        (and (eq major-mode 'stgit-mode)
  52                             (string= default-directory dir)))))
  53       (setq buffers (cdr buffers)))
  54     (and buffers (car buffers))))
  55
  56 (defun switch-to-stgit-buffer (dir)
  57   "Switch to a (possibly new) buffer displaying StGit patches for DIR."
  58   (setq dir (file-name-as-directory dir))
  59   (let ((buffer (stgit-find-buffer dir)))
  60     (switch-to-buffer (or buffer
  61                           (create-stgit-buffer dir)))))
  62
  63 (defstruct (stgit-patch)
  64   status name desc empty files-ewoc)
  65
  66 (defun stgit-patch-pp (patch)
  67   (let ((status (stgit-patch-status patch))
  68         (start (point))
  69         (name (stgit-patch-name patch)))
  70     (case name
  71        (:index (insert (propertize "  Index" 'face 'italic)))
  72        (:work (insert (propertize "  Work tree" 'face 'italic)))
  73        (t (insert (case status
  74                     ('applied "+")
  75                     ('top ">")
  76                     ('unapplied "-"))
  77                   (if (memq name stgit-marked-patches)
  78                       "*" " ")
  79                   (propertize (format "%-30s"
  80                                       (symbol-name name))
  81                               'face (case status
  82                                       ('applied 'stgit-applied-patch-face)
  83                                       ('top 'stgit-top-patch-face)
  84                                       ('unapplied 'stgit-unapplied-patch-face)
  85                                       ('index nil)
  86                                       ('work nil)))
  87                   "  "
  88                   (if (stgit-patch-empty patch) "(empty) " "")
  89                   (propertize (or (stgit-patch-desc patch) "")
  90                               'face 'stgit-description-face))))
  91     (put-text-property start (point) 'entry-type 'patch)
  92     (when (memq name stgit-expanded-patches)
  93       (stgit-insert-patch-files patch))
  94     (put-text-property start (point) 'patch-data patch)))
  95
  96 (defun create-stgit-buffer (dir)
  97   "Create a buffer for showing StGit patches.
  98 Argument DIR is the repository path."
  99   (let ((buf (create-file-buffer (concat dir "*stgit*")))
 100         (inhibit-read-only t))
 101     (with-current-buffer buf
 102       (setq default-directory dir)
 103       (stgit-mode)
 104       (set (make-local-variable 'stgit-ewoc)
 105            (ewoc-create #'stgit-patch-pp "Branch:\n" "--"))
 106       (setq buffer-read-only t))
 107     buf))
 108
 109 (defmacro stgit-capture-output (name &rest body)
 110   "Capture StGit output and, if there was any output, show it in a window
 111 at the end.
 112 Returns nil if there was no output."
 113   (declare (debug ([&or stringp null] body))
 114            (indent 1))
 115   `(let ((output-buf (get-buffer-create ,(or name "*StGit output*")))
 116          (stgit-dir default-directory)
 117          (inhibit-read-only t))
 118      (with-current-buffer output-buf
 119        (erase-buffer)
 120        (setq default-directory stgit-dir)
 121        (setq buffer-read-only t))
 122      (let ((standard-output output-buf))
 123        ,@body)
 124      (with-current-buffer output-buf
 125        (set-buffer-modified-p nil)
 126        (setq buffer-read-only t)
 127        (if (< (point-min) (point-max))
 128            (display-buffer output-buf t)))))
 129
 130 (defun stgit-make-run-args (args)
 131   "Return a copy of ARGS with its elements converted to strings."
 132   (mapcar (lambda (x)
 133             ;; don't use (format "%s" ...) to limit type errors
 134             (cond ((stringp x) x)
 135                   ((integerp x) (number-to-string x))
 136                   ((symbolp x) (symbol-name x))
 137                   (t
 138                    (error "Bad element in stgit-make-run-args args: %S" x))))
 139           args))
 140
 141 (defun stgit-run-silent (&rest args)
 142   (setq args (stgit-make-run-args args))
 143   (apply 'call-process "stg" nil standard-output nil args))
 144
 145 (defun stgit-run (&rest args)
 146   (setq args (stgit-make-run-args args))
 147   (let ((msgcmd (mapconcat #'identity args " ")))
 148     (message "Running stg %s..." msgcmd)
 149     (apply 'call-process "stg" nil standard-output nil args)
 150     (message "Running stg %s...done" msgcmd)))
 151
 152 (defun stgit-run-git (&rest args)
 153   (setq args (stgit-make-run-args args))
 154   (let ((msgcmd (mapconcat #'identity args " ")))
 155     (message "Running git %s..." msgcmd)
 156     (apply 'call-process "git" nil standard-output nil args)
 157     (message "Running git %s...done" msgcmd)))
 158
 159 (defun stgit-run-git-silent (&rest args)
 160   (setq args (stgit-make-run-args args))
 161   (apply 'call-process "git" nil standard-output nil args))
 162
 163 (defun stgit-index-empty-p ()
 164   "Returns non-nil if the index contains no changes from HEAD."
 165   (zerop (stgit-run-git-silent "diff-index" "--cached" "--quiet" "HEAD")))
 166
 167 (defvar stgit-index-node nil)
 168 (defvar stgit-worktree-node nil)
 169
 170 (defun stgit-refresh-index ()
 171   (when stgit-index-node
 172     (ewoc-invalidate (car stgit-index-node) (cdr stgit-index-node))))
 173
 174 (defun stgit-refresh-worktree ()
 175   (when stgit-worktree-node
 176     (ewoc-invalidate (car stgit-worktree-node) (cdr stgit-worktree-node))))
 177
 178 (defun stgit-run-series (ewoc)
 179   (let ((first-line t))
 180     (with-temp-buffer
 181       (let ((exit-status (stgit-run-silent "series" "--description" "--empty")))
 182         (goto-char (point-min))
 183         (if (not (zerop exit-status))
 184             (cond ((looking-at "stg series: \\(.*\\)")
 185                    (ewoc-set-hf ewoc (car (ewoc-get-hf ewoc))
 186                                 "-- not initialized (run M-x stgit-init)"))
 187                   ((looking-at ".*")
 188                    (error "Error running stg: %s"
 189                           (match-string 0))))
 190           (while (not (eobp))
 191             (unless (looking-at
 192                      "\\([0 ]\\)\\([>+-]\\)\\( \\)\\([^ ]+\\) *[|#] \\(.*\\)")
 193               (error "Syntax error in output from stg series"))
 194             (let* ((state-str (match-string 2))
 195                    (state (cond ((string= state-str ">") 'top)
 196                                 ((string= state-str "+") 'applied)
 197                                 ((string= state-str "-") 'unapplied))))
 198               (ewoc-enter-last ewoc
 199                                (make-stgit-patch
 200                                 :status state
 201                                 :name (intern (match-string 4))
 202                                 :desc (match-string 5)
 203                                 :empty (string= (match-string 1) "0"))))
 204             (setq first-line nil)
 205             (forward-line 1)))))
 206     (if stgit-show-worktree
 207         (setq stgit-index-node (cons ewoc (ewoc-enter-last ewoc
 208                                                            (make-stgit-patch
 209                                                             :status 'index
 210                                                             :name :index
 211                                                             :desc nil
 212                                                             :empty nil)))
 213               stgit-worktree-node (cons ewoc (ewoc-enter-last ewoc
 214                                                               (make-stgit-patch
 215                                                                :status 'work
 216                                                                :name :work
 217                                                                :desc nil
 218                                                                :empty nil))))
 219       (setq stgit-worktree-node nil))))
 220
 221
 222 (defun stgit-reload ()
 223   "Update the contents of the StGit buffer."
 224   (interactive)
 225   (let ((inhibit-read-only t)
 226         (curline (line-number-at-pos))
 227         (curpatch (stgit-patch-name-at-point)))
 228     (ewoc-filter stgit-ewoc #'(lambda (x) nil))
 229     (ewoc-set-hf stgit-ewoc
 230                  (concat "Branch: "
 231                          (propertize
 232                           (with-temp-buffer
 233                             (stgit-run-silent "branch")
 234                             (buffer-substring (point-min) (1- (point-max))))
 235                           'face 'bold)
 236                          "\n")
 237                  (if stgit-show-worktree
 238                      "--"
 239                    (propertize
 240                     (substitute-command-keys "--\n\"\\[stgit-toggle-worktree]\"\
 241  shows the working tree\n")
 242                    'face 'stgit-description-face)))
 243     (stgit-run-series stgit-ewoc)
 244     (if curpatch
 245         (stgit-goto-patch curpatch)
 246       (goto-line curline)))
 247   (stgit-refresh-git-status))
 248
 249 (defgroup stgit nil
 250   "A user interface for the StGit patch maintenance tool."
 251   :group 'tools)
 252
 253 (defface stgit-description-face
 254   '((((background dark)) (:foreground "tan"))
 255     (((background light)) (:foreground "dark red")))
 256   "The face used for StGit descriptions"
 257   :group 'stgit)
 258
 259 (defface stgit-top-patch-face
 260   '((((background dark)) (:weight bold :foreground "yellow"))
 261     (((background light)) (:weight bold :foreground "purple"))
 262     (t (:weight bold)))
 263   "The face used for the top patch names"
 264   :group 'stgit)
 265
 266 (defface stgit-applied-patch-face
 267   '((((background dark)) (:foreground "light yellow"))
 268     (((background light)) (:foreground "purple"))
 269     (t ()))
 270   "The face used for applied patch names"
 271   :group 'stgit)
 272
 273 (defface stgit-unapplied-patch-face
 274   '((((background dark)) (:foreground "gray80"))
 275     (((background light)) (:foreground "orchid"))
 276     (t ()))
 277   "The face used for unapplied patch names"
 278   :group 'stgit)
 279
 280 (defface stgit-modified-file-face
 281   '((((class color) (background light)) (:foreground "purple"))
 282     (((class color) (background dark)) (:foreground "salmon")))
 283   "StGit mode face used for modified file status"
 284   :group 'stgit)
 285
 286 (defface stgit-unmerged-file-face
 287   '((((class color) (background light)) (:foreground "red" :bold t))
 288     (((class color) (background dark)) (:foreground "red" :bold t)))
 289   "StGit mode face used for unmerged file status"
 290   :group 'stgit)
 291
 292 (defface stgit-unknown-file-face
 293   '((((class color) (background light)) (:foreground "goldenrod" :bold t))
 294     (((class color) (background dark)) (:foreground "goldenrod" :bold t)))
 295   "StGit mode face used for unknown file status"
 296   :group 'stgit)
 297
 298 (defface stgit-file-permission-face
 299   '((((class color) (background light)) (:foreground "green" :bold t))
 300     (((class color) (background dark)) (:foreground "green" :bold t)))
 301   "StGit mode face used for permission changes."
 302   :group 'stgit)
 303
 304 (defcustom stgit-expand-find-copies-harder
 305   nil
 306   "Try harder to find copied files when listing patches.
 307
 308 When not nil, runs git diff-tree with the --find-copies-harder
 309 flag, which reduces performance."
 310   :type 'boolean
 311   :group 'stgit)
 312
 313 (defconst stgit-file-status-code-strings
 314   (mapcar (lambda (arg)
 315             (cons (car arg)
 316                   (propertize (cadr arg) 'face (car (cddr arg)))))
 317           '((add         "Added"       stgit-modified-file-face)
 318             (copy        "Copied"      stgit-modified-file-face)
 319             (delete      "Deleted"     stgit-modified-file-face)
 320             (modify      "Modified"    stgit-modified-file-face)
 321             (rename      "Renamed"     stgit-modified-file-face)
 322             (mode-change "Mode change" stgit-modified-file-face)
 323             (unmerged    "Unmerged"    stgit-unmerged-file-face)
 324             (unknown     "Unknown"     stgit-unknown-file-face)))
 325   "Alist of code symbols to description strings")
 326
 327 (defun stgit-file-status-code-as-string (file)
 328   "Return stgit status code for FILE as a string"
 329   (let* ((code (assq (stgit-file-status file)
 330                      stgit-file-status-code-strings))
 331          (score (stgit-file-cr-score file)))
 332     (when code
 333       (format "%-11s  "
 334               (if (and score (/= score 100))
 335                   (format "%s %s" (cdr code)
 336                           (propertize (format "%d%%" score)
 337                                       'face 'stgit-description-face))
 338                 (cdr code))))))
 339
 340 (defun stgit-file-status-code (str &optional score)
 341   "Return stgit status code from git status string"
 342   (let ((code (assoc str '(("A" . add)
 343                            ("C" . copy)
 344                            ("D" . delete)
 345                            ("M" . modify)
 346                            ("R" . rename)
 347                            ("T" . mode-change)
 348                            ("U" . unmerged)
 349                            ("X" . unknown)))))
 350     (setq code (if code (cdr code) 'unknown))
 351     (when (stringp score)
 352       (if (> (length score) 0)
 353           (setq score (string-to-number score))
 354         (setq score nil)))
 355     (if score (cons code score) code)))
 356
 357 (defconst stgit-file-type-strings
 358   '((#o100 . "file")
 359     (#o120 . "symlink")
 360     (#o160 . "subproject"))
 361   "Alist of names of file types")
 362
 363 (defun stgit-file-type-string (type)
 364   "Return string describing file type TYPE (the high bits of file permission).
 365 Cf. `stgit-file-type-strings' and `stgit-file-type-change-string'."
 366   (let ((type-str (assoc type stgit-file-type-strings)))
 367     (or (and type-str (cdr type-str))
 368         (format "unknown type %o" type))))
 369
 370 (defun stgit-file-type-change-string (old-perm new-perm)
 371   "Return string describing file type change from OLD-PERM to NEW-PERM.
 372 Cf. `stgit-file-type-string'."
 373   (let ((old-type (lsh old-perm -9))
 374         (new-type (lsh new-perm -9)))
 375     (cond ((= old-type new-type) "")
 376           ((zerop new-type) "")
 377           ((zerop old-type)
 378            (if (= new-type #o100)
 379                ""
 380              (format "   (%s)" (stgit-file-type-string new-type))))
 381           (t (format "   (%s -> %s)"
 382                      (stgit-file-type-string old-type)
 383                      (stgit-file-type-string new-type))))))
 384
 385 (defun stgit-file-mode-change-string (old-perm new-perm)
 386   "Return string describing file mode change from OLD-PERM to NEW-PERM.
 387 Cf. `stgit-file-type-change-string'."
 388   (setq old-perm (logand old-perm #o777)
 389         new-perm (logand new-perm #o777))
 390   (if (or (= old-perm new-perm)
 391           (zerop old-perm)
 392           (zerop new-perm))
 393       ""
 394     (let* ((modified       (logxor old-perm new-perm))
 395            (not-x-modified (logand (logxor old-perm new-perm) #o666)))
 396       (cond ((zerop modified) "")
 397             ((and (zerop not-x-modified)
 398                   (or (and (eq #o111 (logand old-perm #o111))
 399                            (propertize "-x" 'face 'stgit-file-permission-face))
 400                       (and (eq #o111 (logand new-perm #o111))
 401                            (propertize "+x" 'face
 402                                        'stgit-file-permission-face)))))
 403             (t (concat (propertize (format "%o" old-perm)
 404                                    'face 'stgit-file-permission-face)
 405                        (propertize " -> "
 406                                    'face 'stgit-description-face)
 407                        (propertize (format "%o" new-perm)
 408                                    'face 'stgit-file-permission-face)))))))
 409
 410 (defstruct (stgit-file)
 411   old-perm new-perm copy-or-rename cr-score cr-from cr-to status file)
 412
 413 (defun stgit-file-pp (file)
 414   (let ((status (stgit-file-status file))
 415         (name (if (stgit-file-copy-or-rename file)
 416                   (concat (stgit-file-cr-from file)
 417                           (propertize " -> "
 418                                       'face 'stgit-description-face)
 419                           (stgit-file-cr-to file))
 420                 (stgit-file-file file)))
 421         (mode-change (stgit-file-mode-change-string
 422                       (stgit-file-old-perm file)
 423                       (stgit-file-new-perm file)))
 424         (start (point)))
 425     (insert (format "    %-12s%1s%s%s\n"
 426                     (stgit-file-status-code-as-string file)
 427                     mode-change
 428                     name
 429                     (propertize (stgit-file-type-change-string
 430                                  (stgit-file-old-perm file)
 431                                  (stgit-file-new-perm file))
 432                                 'face 'stgit-description-face)))
 433     (add-text-properties start (point)
 434                          (list 'entry-type 'file
 435                                'file-data file))))
 436
 437 (defun stgit-insert-patch-files (patch)
 438   "Expand (show modification of) the patch PATCH after the line
 439 at point."
 440   (let* ((patchsym (stgit-patch-name patch))
 441          (end (progn (insert "#") (prog1 (point-marker) (forward-char -1))))
 442          (args (list "-z" (if stgit-expand-find-copies-harder
 443                               "--find-copies-harder"
 444                             "-C")))
 445          (ewoc (ewoc-create #'stgit-file-pp nil nil t)))
 446     (setf (stgit-patch-files-ewoc patch) ewoc)
 447     (with-temp-buffer
 448       (apply 'stgit-run-git
 449              (cond ((eq patchsym :work)
 450                     `("diff-files" ,@args))
 451                    ((eq patchsym :index)
 452                     `("diff-index" ,@args "--cached" "HEAD"))
 453                    (t
 454                     `("diff-tree" ,@args "-r" ,(stgit-id patchsym)))))
 455       (goto-char (point-min))
 456       (unless (or (eobp) (memq patchsym '(:work :index)))
 457         (forward-char 41))
 458       (while (looking-at ":\\([0-7]+\\) \\([0-7]+\\) [0-9A-Fa-f]\\{40\\} [0-9A-Fa-f]\\{40\\} ")
 459         (let ((old-perm (string-to-number (match-string 1) 8))
 460               (new-perm (string-to-number (match-string 2) 8)))
 461           (goto-char (match-end 0))
 462           (let ((file
 463                  (cond ((looking-at
 464                          "\\([CR]\\)\\([0-9]*\\)\0\\([^\0]*\\)\0\\([^\0]*\\)\0")
 465                         (make-stgit-file
 466                          :old-perm       old-perm
 467                          :new-perm       new-perm
 468                          :copy-or-rename t
 469                          :cr-score       (string-to-number (match-string 2))
 470                          :cr-from        (match-string 3)
 471                          :cr-to          (match-string 4)
 472                          :status         (stgit-file-status-code (match-string 1))
 473                          :file           (match-string 3)))
 474                        ((looking-at "\\([ABD-QS-Z]\\)\0\\([^\0]*\\)\0")
 475                         (make-stgit-file
 476                          :old-perm       old-perm
 477                          :new-perm       new-perm
 478                          :copy-or-rename nil
 479                          :cr-score       nil
 480                          :cr-from        nil
 481                          :cr-to          nil
 482                          :status         (stgit-file-status-code (match-string 1))
 483                          :file           (match-string 2))))))
 484             (ewoc-enter-last ewoc file))
 485           (goto-char (match-end 0))))
 486       (unless (ewoc-nth ewoc 0)
 487         (ewoc-set-hf ewoc "" (propertize "    <no files>\n"
 488                                          'face 'stgit-description-face))))
 489     (goto-char end)
 490     (delete-char -2)))
 491
 492 (defun stgit-select-file ()
 493   (let ((filename (expand-file-name
 494                    (stgit-file-file (stgit-patched-file-at-point)))))
 495     (unless (file-exists-p filename)
 496       (error "File does not exist"))
 497     (find-file filename)))
 498
 499 (defun stgit-select-patch ()
 500   (let ((patchname (stgit-patch-name-at-point)))
 501     (if (memq patchname stgit-expanded-patches)
 502         (setq stgit-expanded-patches (delq patchname stgit-expanded-patches))
 503       (setq stgit-expanded-patches (cons patchname stgit-expanded-patches)))
 504     (ewoc-invalidate stgit-ewoc (ewoc-locate stgit-ewoc)))
 505   (move-to-column (stgit-goal-column)))
 506
 507 (defun stgit-select ()
 508   "Expand or collapse the current entry"
 509   (interactive)
 510   (case (get-text-property (point) 'entry-type)
 511     ('patch
 512      (stgit-select-patch))
 513     ('file
 514      (stgit-select-file))
 515     (t
 516      (error "No patch or file on line"))))
 517
 518 (defun stgit-find-file-other-window ()
 519   "Open file at point in other window"
 520   (interactive)
 521   (let ((patched-file (stgit-patched-file-at-point)))
 522     (unless patched-file
 523       (error "No file on the current line"))
 524     (let ((filename (expand-file-name (stgit-file-file patched-file))))
 525       (unless (file-exists-p filename)
 526         (error "File does not exist"))
 527       (find-file-other-window filename))))
 528
 529 (defun stgit-quit ()
 530   "Hide the stgit buffer."
 531   (interactive)
 532   (bury-buffer))
 533
 534 (defun stgit-git-status ()
 535   "Show status using `git-status'."
 536   (interactive)
 537   (unless (fboundp 'git-status)
 538     (error "The stgit-git-status command requires git-status"))
 539   (let ((dir default-directory))
 540     (save-selected-window
 541       (pop-to-buffer nil)
 542       (git-status dir))))
 543
 544 (defun stgit-goal-column ()
 545   "Return goal column for the current line"
 546   (case (get-text-property (point) 'entry-type)
 547     ('patch 2)
 548     ('file 4)
 549     (t 0)))
 550
 551 (defun stgit-next-line (&optional arg)
 552   "Move cursor vertically down ARG lines"
 553   (interactive "p")
 554   (next-line arg)
 555   (move-to-column (stgit-goal-column)))
 556
 557 (defun stgit-previous-line (&optional arg)
 558   "Move cursor vertically up ARG lines"
 559   (interactive "p")
 560   (previous-line arg)
 561   (move-to-column (stgit-goal-column)))
 562
 563 (defun stgit-next-patch (&optional arg)
 564   "Move cursor down ARG patches."
 565   (interactive "p")
 566   (ewoc-goto-next stgit-ewoc (or arg 1))
 567   (move-to-column goal-column))
 568
 569 (defun stgit-previous-patch (&optional arg)
 570   "Move cursor up ARG patches."
 571   (interactive "p")
 572   (ewoc-goto-prev stgit-ewoc (or arg 1))
 573   (move-to-column goal-column))
 574
 575 (defvar stgit-mode-hook nil
 576   "Run after `stgit-mode' is setup.")
 577
 578 (defvar stgit-mode-map nil
 579   "Keymap for StGit major mode.")
 580
 581 (unless stgit-mode-map
 582   (let ((toggle-map (make-keymap)))
 583     (suppress-keymap toggle-map)
 584     (mapc (lambda (arg) (define-key toggle-map (car arg) (cdr arg)))
 585           '(("t" .        stgit-toggle-worktree)))
 586     (setq stgit-mode-map (make-keymap))
 587     (suppress-keymap stgit-mode-map)
 588     (mapc (lambda (arg) (define-key stgit-mode-map (car arg) (cdr arg)))
 589           `((" " .        stgit-mark)
 590             ("m" .        stgit-mark)
 591             ("\d" .       stgit-unmark-up)
 592             ("u" .        stgit-unmark-down)
 593             ("?" .        stgit-help)
 594             ("h" .        stgit-help)
 595             ("\C-p" .     stgit-previous-line)
 596             ("\C-n" .     stgit-next-line)
 597             ([up] .       stgit-previous-line)
 598             ([down] .     stgit-next-line)
 599             ("p" .        stgit-previous-patch)
 600             ("n" .        stgit-next-patch)
 601             ("\M-{" .     stgit-previous-patch)
 602             ("\M-}" .     stgit-next-patch)
 603             ("s" .        stgit-git-status)
 604             ("g" .        stgit-reload)
 605             ("r" .        stgit-refresh)
 606             ("\C-c\C-r" . stgit-rename)
 607             ("e" .        stgit-edit)
 608             ("M" .        stgit-move-patches)
 609             ("S" .        stgit-squash)
 610             ("N" .        stgit-new)
 611             ("R" .        stgit-repair)
 612             ("C" .        stgit-commit)
 613             ("U" .        stgit-uncommit)
 614             ("\r" .       stgit-select)
 615             ("o" .        stgit-find-file-other-window)
 616             ("i" .        stgit-file-toggle-index)
 617             (">" .        stgit-push-next)
 618             ("<" .        stgit-pop-next)
 619             ("P" .        stgit-push-or-pop)
 620             ("G" .        stgit-goto)
 621             ("=" .        stgit-show)
 622             ("D" .        stgit-delete)
 623             ([(control ?/)] . stgit-undo)
 624             ("\C-_" .     stgit-undo)
 625             ("B" .        stgit-branch)
 626             ("t" .        ,toggle-map)
 627             ("q" .        stgit-quit)))))
 628
 629 (defun stgit-mode ()
 630   "Major mode for interacting with StGit.
 631 Commands:
 632 \\{stgit-mode-map}"
 633   (kill-all-local-variables)
 634   (buffer-disable-undo)
 635   (setq mode-name "StGit"
 636         major-mode 'stgit-mode
 637         goal-column 2)
 638   (use-local-map stgit-mode-map)
 639   (set (make-local-variable 'list-buffers-directory) default-directory)
 640   (set (make-local-variable 'stgit-marked-patches) nil)
 641   (set (make-local-variable 'stgit-expanded-patches) nil)
 642   (set (make-local-variable 'stgit-show-worktree) stgit-default-show-worktree)
 643   (set-variable 'truncate-lines 't)
 644   (add-hook 'after-save-hook 'stgit-update-saved-file)
 645   (run-hooks 'stgit-mode-hook))
 646
 647 (defun stgit-update-saved-file ()
 648   (let* ((file (expand-file-name buffer-file-name))
 649          (dir (file-name-directory file))
 650          (gitdir (condition-case nil (git-get-top-dir dir)
 651                    (error nil)))
 652          (buffer (and gitdir (stgit-find-buffer gitdir))))
 653     (when buffer
 654       (with-current-buffer buffer
 655         (stgit-refresh-worktree)))))
 656
 657 (defun stgit-add-mark (patchsym)
 658   "Mark the patch PATCHSYM."
 659   (setq stgit-marked-patches (cons patchsym stgit-marked-patches)))
 660
 661 (defun stgit-remove-mark (patchsym)
 662   "Unmark the patch PATCHSYM."
 663   (setq stgit-marked-patches (delq patchsym stgit-marked-patches)))
 664
 665 (defun stgit-clear-marks ()
 666   "Unmark all patches."
 667   (setq stgit-marked-patches '()))
 668
 669 (defun stgit-patch-at-point (&optional cause-error)
 670   (get-text-property (point) 'patch-data))
 671
 672 (defun stgit-patch-name-at-point (&optional cause-error)
 673   "Return the patch name on the current line as a symbol.
 674 If CAUSE-ERROR is not nil, signal an error if none found."
 675   (let ((patch (stgit-patch-at-point)))
 676     (cond (patch
 677            (stgit-patch-name patch))
 678           (cause-error
 679            (error "No patch on this line")))))
 680
 681 (defun stgit-patched-file-at-point ()
 682   (get-text-property (point) 'file-data))
 683
 684 (defun stgit-patches-marked-or-at-point ()
 685   "Return the symbols of the marked patches, or the patch on the current line."
 686   (if stgit-marked-patches
 687       stgit-marked-patches
 688     (let ((patch (stgit-patch-name-at-point)))
 689       (if patch
 690           (list patch)
 691         '()))))
 692
 693 (defun stgit-goto-patch (patchsym)
 694   "Move point to the line containing patch PATCHSYM.
 695 If that patch cannot be found, do nothing."
 696   (let ((node (ewoc-nth stgit-ewoc 0)))
 697     (while (and node (not (eq (stgit-patch-name (ewoc-data node))
 698                               patchsym)))
 699       (setq node (ewoc-next stgit-ewoc node)))
 700     (when node
 701       (ewoc-goto-node stgit-ewoc node)
 702       (move-to-column goal-column))))
 703
 704 (defun stgit-init ()
 705   "Run stg init."
 706   (interactive)
 707   (stgit-capture-output nil
 708     (stgit-run "init"))
 709   (stgit-reload))
 710
 711 (defun stgit-mark ()
 712   "Mark the patch under point."
 713   (interactive)
 714   (let* ((node (ewoc-locate stgit-ewoc))
 715          (patch (ewoc-data node)))
 716     (stgit-add-mark (stgit-patch-name patch))
 717     (ewoc-invalidate stgit-ewoc node))
 718   (stgit-next-patch))
 719
 720 (defun stgit-unmark-up ()
 721   "Remove mark from the patch on the previous line."
 722   (interactive)
 723   (stgit-previous-patch)
 724   (let* ((node (ewoc-locate stgit-ewoc))
 725          (patch (ewoc-data node)))
 726     (stgit-remove-mark (stgit-patch-name patch))
 727     (ewoc-invalidate stgit-ewoc node))
 728   (move-to-column (stgit-goal-column)))
 729
 730 (defun stgit-unmark-down ()
 731   "Remove mark from the patch on the current line."
 732   (interactive)
 733   (let* ((node (ewoc-locate stgit-ewoc))
 734          (patch (ewoc-data node)))
 735     (stgit-remove-mark (stgit-patch-name patch))
 736     (ewoc-invalidate stgit-ewoc node))
 737   (stgit-next-patch))
 738
 739 (defun stgit-rename (name)
 740   "Rename the patch under point to NAME."
 741   (interactive (list (read-string "Patch name: "
 742                                   (symbol-name (stgit-patch-name-at-point t)))))
 743   (let ((old-patchsym (stgit-patch-name-at-point t)))
 744     (stgit-capture-output nil
 745       (stgit-run "rename" old-patchsym name))
 746     (let ((name-sym (intern name)))
 747       (when (memq old-patchsym stgit-expanded-patches)
 748         (setq stgit-expanded-patches
 749             (cons name-sym (delq old-patchsym stgit-expanded-patches))))
 750       (when (memq old-patchsym stgit-marked-patches)
 751         (setq stgit-marked-patches
 752             (cons name-sym (delq old-patchsym stgit-marked-patches))))
 753       (stgit-reload)
 754       (stgit-goto-patch name-sym))))
 755
 756 (defun stgit-repair ()
 757   "Run stg repair."
 758   (interactive)
 759   (stgit-capture-output nil
 760     (stgit-run "repair"))
 761   (stgit-reload))
 762
 763 (defun stgit-available-branches ()
 764   "Returns a list of the available stg branches"
 765   (let ((output (with-output-to-string
 766                   (stgit-run "branch" "--list")))
 767         (start 0)
 768         result)
 769     (while (string-match "^>?\\s-+s\\s-+\\(\\S-+\\)" output start)
 770       (setq result (cons (match-string 1 output) result))
 771       (setq start (match-end 0)))
 772     result))
 773
 774 (defun stgit-branch (branch)
 775   "Switch to branch BRANCH."
 776   (interactive (list (completing-read "Switch to branch: "
 777                                       (stgit-available-branches))))
 778   (stgit-capture-output nil (stgit-run "branch" "--" branch))
 779   (stgit-reload))
 780
 781 (defun stgit-commit (count)
 782   "Run stg commit on COUNT commits.
 783 Interactively, the prefix argument is used as COUNT."
 784   (interactive "p")
 785   (stgit-capture-output nil (stgit-run "commit" "-n" count))
 786   (stgit-reload))
 787
 788 (defun stgit-uncommit (count)
 789   "Run stg uncommit on COUNT commits.
 790 Interactively, the prefix argument is used as COUNT."
 791   (interactive "p")
 792   (stgit-capture-output nil (stgit-run "uncommit" "-n" count))
 793   (stgit-reload))
 794
 795 (defun stgit-push-next (npatches)
 796   "Push the first unapplied patch.
 797 With numeric prefix argument, push that many patches."
 798   (interactive "p")
 799   (stgit-capture-output nil (stgit-run "push" "-n" npatches))
 800   (stgit-reload)
 801   (stgit-refresh-git-status))
 802
 803 (defun stgit-pop-next (npatches)
 804   "Pop the topmost applied patch.
 805 With numeric prefix argument, pop that many patches."
 806   (interactive "p")
 807   (stgit-capture-output nil (stgit-run "pop" "-n" npatches))
 808   (stgit-reload)
 809   (stgit-refresh-git-status))
 810
 811 (defun stgit-applied-at-point ()
 812   "Is the patch on the current line applied?"
 813   (save-excursion
 814     (beginning-of-line)
 815     (looking-at "[>+]")))
 816
 817 (defun stgit-push-or-pop ()
 818   "Push or pop the patch on the current line."
 819   (interactive)
 820   (let ((patchsym (stgit-patch-name-at-point t))
 821         (applied (stgit-applied-at-point)))
 822     (stgit-capture-output nil
 823       (stgit-run (if applied "pop" "push") patchsym))
 824     (stgit-reload)))
 825
 826 (defun stgit-goto ()
 827   "Go to the patch on the current line."
 828   (interactive)
 829   (let ((patchsym (stgit-patch-name-at-point t)))
 830     (stgit-capture-output nil
 831       (stgit-run "goto" patchsym))
 832     (stgit-reload)))
 833
 834 (defun stgit-id (patchsym)
 835   "Return the git commit id for PATCHSYM.
 836 If PATCHSYM is a keyword, returns PATCHSYM unmodified."
 837   (if (keywordp patchsym)
 838       patchsym
 839     (let ((result (with-output-to-string
 840                     (stgit-run-silent "id" patchsym))))
 841       (unless (string-match "^\\([0-9A-Fa-f]\\{40\\}\\)$" result)
 842         (error "Cannot find commit id for %s" patchsym))
 843       (match-string 1 result))))
 844
 845 (defun stgit-show ()
 846   "Show the patch on the current line."
 847   (interactive)
 848   (stgit-capture-output "*StGit patch*"
 849     (case (get-text-property (point) 'entry-type)
 850       ('file
 851        (let* ((patched-file (stgit-patched-file-at-point))
 852               (patch-name (stgit-patch-name-at-point))
 853               (patch-id (stgit-id patch-name))
 854               (args (append (and (stgit-file-cr-from patched-file)
 855                                  (if stgit-expand-find-copies-harder
 856                                      '("--find-copies-harder")
 857                                    '("-C")))
 858                             (cond ((eq patch-id :index)
 859                                    '("--cached"))
 860                                   ((eq patch-id :work)
 861                                    nil)
 862                                   (t
 863                                    (list (concat patch-id "^") patch-id)))
 864                             '("--")
 865                               (if (stgit-file-copy-or-rename patched-file)
 866                                   (list (stgit-file-cr-from patched-file)
 867                                         (stgit-file-cr-to patched-file))
 868                                 (list (stgit-file-file patched-file))))))
 869          (apply 'stgit-run-git "diff" args)))
 870       ('patch
 871        (stgit-run "show" "-O" "--patch-with-stat" "-O" "-M"
 872                   (stgit-patch-name-at-point)))
 873       (t
 874        (error "No patch or file at point")))
 875     (with-current-buffer standard-output
 876       (goto-char (point-min))
 877       (diff-mode))))
 878
 879 (defun stgit-move-change-to-index (file)
 880   "Copies the workspace state of FILE to index, using git add or git rm"
 881   (let ((op (if (or (file-exists-p file) (file-symlink-p file))
 882                 '("add") '("rm" "-q"))))
 883     (stgit-capture-output "*git output*"
 884       (apply 'stgit-run-git (append op '("--") (list file))))))
 885
 886 (defun stgit-remove-change-from-index (file)
 887   "Unstages the change in FILE from the index"
 888   (stgit-capture-output "*git output*"
 889     (stgit-run-git "reset" "-q" "--" file)))
 890
 891 (defun stgit-file-toggle-index ()
 892   "Move modified file in or out of the index."
 893   (interactive)
 894   (let ((patched-file (stgit-patched-file-at-point)))
 895     (unless patched-file
 896       (error "No file on the current line"))
 897     (let ((patch-name (stgit-patch-name-at-point)))
 898       (cond ((eq patch-name :work)
 899              (stgit-move-change-to-index (stgit-file-file patched-file)))
 900             ((eq patch-name :index)
 901              (stgit-remove-change-from-index (stgit-file-file patched-file)))
 902             (t
 903              (error "Can only move files in the working tree to index")))))
 904   (stgit-refresh-worktree)
 905   (stgit-refresh-index))
 906
 907 (defun stgit-edit ()
 908   "Edit the patch on the current line."
 909   (interactive)
 910   (let ((patchsym (stgit-patch-name-at-point t))
 911         (edit-buf (get-buffer-create "*StGit edit*"))
 912         (dir default-directory))
 913     (log-edit 'stgit-confirm-edit t nil edit-buf)
 914     (set (make-local-variable 'stgit-edit-patchsym) patchsym)
 915     (setq default-directory dir)
 916     (let ((standard-output edit-buf))
 917       (stgit-run-silent "edit" "--save-template=-" patchsym))))
 918
 919 (defun stgit-confirm-edit ()
 920   (interactive)
 921   (let ((file (make-temp-file "stgit-edit-")))
 922     (write-region (point-min) (point-max) file)
 923     (stgit-capture-output nil
 924       (stgit-run "edit" "-f" file stgit-edit-patchsym))
 925     (with-current-buffer log-edit-parent-buffer
 926       (stgit-reload))))
 927
 928 (defun stgit-new (add-sign)
 929   "Create a new patch.
 930 With a prefix argument, include a \"Signed-off-by:\" line at the
 931 end of the patch."
 932   (interactive "P")
 933   (let ((edit-buf (get-buffer-create "*StGit edit*"))
 934         (dir default-directory))
 935     (log-edit 'stgit-confirm-new t nil edit-buf)
 936     (setq default-directory dir)
 937     (when add-sign
 938       (save-excursion
 939         (let ((standard-output (current-buffer)))
 940           (stgit-run-silent "new" "--sign" "--save-template=-"))))))
 941
 942 (defun stgit-confirm-new ()
 943   (interactive)
 944   (let ((file (make-temp-file "stgit-edit-")))
 945     (write-region (point-min) (point-max) file)
 946     (stgit-capture-output nil
 947       (stgit-run "new" "-f" file))
 948     (with-current-buffer log-edit-parent-buffer
 949       (stgit-reload))))
 950
 951 (defun stgit-create-patch-name (description)
 952   "Create a patch name from a long description"
 953   (let ((patch ""))
 954     (while (> (length description) 0)
 955       (cond ((string-match "\\`[a-zA-Z_-]+" description)
 956              (setq patch (downcase (concat patch
 957                                            (match-string 0 description))))
 958              (setq description (substring description (match-end 0))))
 959             ((string-match "\\` +" description)
 960              (setq patch (concat patch "-"))
 961              (setq description (substring description (match-end 0))))
 962             ((string-match "\\`[^a-zA-Z_-]+" description)
 963              (setq description (substring description (match-end 0))))))
 964     (cond ((= (length patch) 0)
 965            "patch")
 966           ((> (length patch) 20)
 967            (substring patch 0 20))
 968           (t patch))))
 969
 970 (defun stgit-delete (patchsyms &optional spill-p)
 971   "Delete the patches in PATCHSYMS.
 972 Interactively, delete the marked patches, or the patch at point.
 973
 974 With a prefix argument, or SPILL-P, spill the patch contents to
 975 the work tree and index."
 976   (interactive (list (stgit-patches-marked-or-at-point)
 977                      current-prefix-arg))
 978   (unless patchsyms
 979     (error "No patches to delete"))
 980   (let ((npatches (length patchsyms)))
 981     (when (yes-or-no-p (format "Really delete %d patch%s%s? "
 982                                npatches
 983                                (if (= 1 npatches) "" "es")
 984                                (if spill-p
 985                                    " (spilling contents to index)"
 986                                  "")))
 987       (let ((args (if spill-p
 988                       (cons "--spill" patchsyms)
 989                     patchsyms)))
 990         (stgit-capture-output nil
 991           (apply 'stgit-run "delete" args))
 992         (stgit-reload)))))
 993
 994 (defun stgit-move-patches-target ()
 995   "Return the patchsym indicating a target patch for
 996 `stgit-move-patches'.
 997
 998 This is either the patch at point, or one of :top and :bottom, if
 999 the point is after or before the applied patches."
1000
1001   (let ((patchsym (stgit-patch-name-at-point)))
1002     (cond (patchsym patchsym)
1003           ((save-excursion (re-search-backward "^>" nil t)) :top)
1004           (t :bottom))))
1005
1006 (defun stgit-sort-patches (patchsyms)
1007   "Returns the list of patches in PATCHSYMS sorted according to
1008 their position in the patch series, bottommost first.
1009
1010 PATCHSYMS may not contain duplicate entries."
1011   (let (sorted-patchsyms
1012         (series (with-output-to-string
1013                   (with-current-buffer standard-output
1014                     (stgit-run-silent "series" "--noprefix"))))
1015         start)
1016     (while (string-match "^\\(.+\\)" series start)
1017       (let ((patchsym (intern (match-string 1 series))))
1018         (when (memq patchsym patchsyms)
1019           (setq sorted-patchsyms (cons patchsym sorted-patchsyms))))
1020       (setq start (match-end 0)))
1021     (setq sorted-patchsyms (nreverse sorted-patchsyms))
1022
1023     (unless (= (length patchsyms) (length sorted-patchsyms))
1024       (error "Internal error"))
1025
1026     sorted-patchsyms))
1027
1028 (defun stgit-move-patches (patchsyms target-patch)
1029   "Move the patches in PATCHSYMS to below TARGET-PATCH.
1030 If TARGET-PATCH is :bottom or :top, move the patches to the
1031 bottom or top of the stack, respectively.
1032
1033 Interactively, move the marked patches to where the point is."
1034   (interactive (list stgit-marked-patches
1035                      (stgit-move-patches-target)))
1036   (unless patchsyms
1037     (error "Need at least one patch to move"))
1038
1039   (unless target-patch
1040     (error "Point not at a patch"))
1041
1042   (if (eq target-patch :top)
1043       (stgit-capture-output nil
1044         (apply 'stgit-run "float" patchsyms))
1045
1046     ;; need to have patchsyms sorted by position in the stack
1047     (let ((sorted-patchsyms (stgit-sort-patches patchsyms)))
1048       (while sorted-patchsyms
1049         (setq sorted-patchsyms
1050               (and (stgit-capture-output nil
1051                      (if (eq target-patch :bottom)
1052                          (stgit-run "sink" "--" (car sorted-patchsyms))
1053                        (stgit-run "sink" "--to" target-patch "--"
1054                                   (car sorted-patchsyms))))
1055                    (cdr sorted-patchsyms))))))
1056   (stgit-reload))
1057
1058 (defun stgit-squash (patchsyms)
1059   "Squash the patches in PATCHSYMS.
1060 Interactively, squash the marked patches.
1061
1062 Unless there are any conflicts, the patches will be merged into
1063 one patch, which will occupy the same spot in the series as the
1064 deepest patch had before the squash."
1065   (interactive (list stgit-marked-patches))
1066   (when (< (length patchsyms) 2)
1067     (error "Need at least two patches to squash"))
1068   (let ((stgit-buffer (current-buffer))
1069         (edit-buf (get-buffer-create "*StGit edit*"))
1070         (dir default-directory)
1071         (sorted-patchsyms (stgit-sort-patches patchsyms)))
1072     (log-edit 'stgit-confirm-squash t nil edit-buf)
1073     (set (make-local-variable 'stgit-patchsyms) sorted-patchsyms)
1074     (setq default-directory dir)
1075     (let ((result (let ((standard-output edit-buf))
1076                     (apply 'stgit-run-silent "squash"
1077                            "--save-template=-" sorted-patchsyms))))
1078
1079       ;; stg squash may have reordered the patches or caused conflicts
1080       (with-current-buffer stgit-buffer
1081         (stgit-reload))
1082
1083       (unless (eq 0 result)
1084         (fundamental-mode)
1085         (rename-buffer "*StGit error*")
1086         (resize-temp-buffer-window)
1087         (switch-to-buffer-other-window stgit-buffer)
1088         (error "stg squash failed")))))
1089
1090 (defun stgit-confirm-squash ()
1091   (interactive)
1092   (let ((file (make-temp-file "stgit-edit-")))
1093     (write-region (point-min) (point-max) file)
1094     (stgit-capture-output nil
1095       (apply 'stgit-run "squash" "-f" file stgit-patchsyms))
1096     (with-current-buffer log-edit-parent-buffer
1097       (stgit-clear-marks)
1098       ;; Go to first marked patch and stay there
1099       (goto-char (point-min))
1100       (re-search-forward (concat "^[>+-]\\*") nil t)
1101       (move-to-column goal-column)
1102       (let ((pos (point)))
1103         (stgit-reload)
1104         (goto-char pos)))))
1105
1106 (defun stgit-help ()
1107   "Display help for the StGit mode."
1108   (interactive)
1109   (describe-function 'stgit-mode))
1110
1111 (defun stgit-undo (&optional arg)
1112   "Run stg undo.
1113 With prefix argument, run it with the --hard flag."
1114   (interactive "P")
1115   (stgit-capture-output nil
1116     (if arg
1117         (stgit-run "undo" "--hard")
1118       (stgit-run "undo")))
1119   (stgit-reload))
1120
1121 (defun stgit-refresh (&optional arg)
1122   "Run stg refresh.
1123 With prefix argument, refresh the marked patch or the patch under point."
1124   (interactive "P")
1125   (let ((patchargs (if arg
1126                        (let ((patches (stgit-patches-marked-or-at-point)))
1127                          (cond ((null patches)
1128                                 (error "No patch to update"))
1129                                ((> (length patches) 1)
1130                                 (error "Too many patches selected"))
1131                                (t
1132                                 (cons "-p" patches))))
1133                      nil)))
1134     (stgit-capture-output nil
1135       (apply 'stgit-run "refresh" patchargs))
1136     (stgit-refresh-git-status))
1137   (stgit-reload))
1138
1139 (defcustom stgit-default-show-worktree
1140   nil
1141   "Set to non-nil to by default show the working tree in a new stgit buffer.
1142
1143 This value is used as the default value for `stgit-show-worktree'."
1144   :type 'boolean
1145   :group 'stgit)
1146
1147 (defvar stgit-show-worktree nil
1148   "Show work tree and index in the stgit buffer.
1149
1150 See `stgit-default-show-worktree' for its default value.")
1151
1152 (defun stgit-toggle-worktree (&optional arg)
1153   "Toggle the visibility of the work tree.
1154 With arg, show the work tree if arg is positive.
1155
1156 Its initial setting is controlled by `stgit-default-show-worktree'."
1157   (interactive)
1158   (setq stgit-show-worktree
1159         (if (numberp arg)
1160             (> arg 0)
1161           (not stgit-show-worktree)))
1162   (stgit-reload))
1163
1164 (provide 'stgit)