belt-slot-cut-jig.scad

   1 // -*- C -*-
   2
   3 // todo
   4 //  various registration marks
   5 //   protrustions at ends at strap width and middle
   6 //   grooves on top face at 1/4,1/2,3/4 length and 1/2 width
   7
   8 crewpunch_slop = 0.3;
   9
  10 holder_min_wall = 2;
  11 holder_attach_near_wall = 3;
  12
  13 holder_attach_xsz = 5;
  14 holder_ctie_width = 4.0 + 0.5;
  15 holder_ctie_thick = 3.0 + 0.5;
  16 holder_attach_walls = 3;
  17 holder_attach_roof = 2.5;
  18
  19 jig_interval = 25;
  20 strap_width = 26.75 + 0.7;
  21 strap_thick = 3;
  22 edgewall_width = 3;
  23
  24 punch_travel = 8;
  25
  26 main_slop = 0.5;
  27
  28 jig_max_len = 160; // print diagonally
  29 //jig_max_len = 30;
  30
  31 registrationgroove_width = 0.8;
  32 registrationgroove_depth = 1.2;
  33
  34 registrationprotrusion_poke = 3;
  35 registrationprotrusion_slope = 0.75;
  36
  37 jig_overlap = 1;
  38
  39 // from careful measurement
  40
  41 crewpunch_shape =
  42   [[  6, [0.6, 6.0], [1.6, 12.3] ],
  43    [  8, [1.1, 6.2], [1.9, 12.5] ],
  44    [ 10, [1.6, 6.5], [2.1, 12.8] ],
  45    [ 12, [1.8, 6.6], [2.3, 12.7] ],
  46    [ 14, [2.1, 6.8], [2.6, 13.0] ],
  47    [ 16, [2.4, 6.9], [2.7, 13.2] ],
  48    [ 18, [2.5, 7.0], [2.9, 13.3] ],
  49    [ 22, [3.1, 7.1], [3.2, 13.4] ],
  50    [ 26, [3.3, 7.2], [3.5, 13.6] ],
  51    ];
  52
  53 crewpunch_shaft_max_y = 3.5;
  54
  55 crewpunch_systematic_size_error = +0.36;
  56
  57 crewpunch_smallest_shape = crewpunch_shape[0];
  58 crewpunch_biggest_shape = crewpunch_shape[len(crewpunch_shape)-1];
  59
  60 crewpunch_skew_angle = 3.5; //degrees
  61 crewpunch_skew_yoff = -1.1; //mm
  62
  63 // computed
  64
  65 attach_ysz = holder_attach_walls*2 + holder_ctie_width;
  66
  67 holder_block_zsz = crewpunch_biggest_shape[0] - crewpunch_smallest_shape[0];
  68 holder_xsz = crewpunch_biggest_shape[2][0] + crewpunch_biggest_shape[2][1] +
  69   holder_min_wall*2;
  70
  71 holder_skewangle_yextra = holder_xsz/2 * sin(abs(crewpunch_skew_angle));
  72
  73 holder_front_all = crewpunch_shaft_max_y - crewpunch_biggest_shape[1][0]
  74   + attach_ysz + crewpunch_systematic_size_error + crewpunch_skew_yoff
  75   + holder_skewangle_yextra;
  76
  77 crewpunch_biggest_y =
  78   crewpunch_biggest_shape[1][0] + crewpunch_biggest_shape[1][1];
  79 holder_ysz = crewpunch_biggest_y + holder_min_wall + holder_front_all
  80   + max(0, -crewpunch_skew_yoff);
  81
  82 attach_offset = 0.5 * (holder_front_all - holder_attach_near_wall);
  83
  84 jig_main_zsz = holder_block_zsz + punch_travel;
  85
  86 jig_ends_extra = 2;
  87
  88 //jig_iters = (jig_max_len - jig_ends_extra) / jig_interval;
  89 jig_iters=2;
  90 echo(jig_iters);
  91
  92 // objects
  93
  94 module CrewPunch(){
  95   ourslop = crewpunch_slop - crewpunch_systematic_size_error;
  96   hull(){
  97     for(layer=crewpunch_shape){
  98       translate([0,0, layer[0]]){
  99         for(xind=[0,1]) //translate([xind?0:1,0,0])
 100           for(yind=[0,1]) //translate([0,yind?0.5:0,0])
 101             mirror([xind?1:0,0,0]) mirror([0,yind?0:1,0]){
 102               translate([-0.1,-0.1,-0.1])
 103                 cube([0.1 + layer[2][xind] + ourslop,
 104                       0.1 + layer[1][1-yind] + ourslop,
 105                       0.2]);
 106             }
 107       }
 108     }
 109   }
 110 }
 111
 112 module PunchHolder(cutouts=true){
 113   translations=[-holder_xsz/2,
 114                 -holder_ysz + holder_min_wall + crewpunch_biggest_y/2,
 115                 0];
 116   translate(translations){
 117     difference(){
 118       translate([0,attach_offset,0])
 119         cube([holder_xsz, holder_ysz - attach_offset, holder_block_zsz]);
 120       if (cutouts)
 121         translate([0,-crewpunch_skew_yoff])
 122         translate(-translations)
 123         rotate([0,0,-crewpunch_skew_angle])
 124         translate(translations)
 125         translate([crewpunch_biggest_shape[2][1] + holder_min_wall,
 126                    crewpunch_biggest_shape[1][1] + holder_front_all,
 127                    -crewpunch_smallest_shape[0]])
 128           CrewPunch();
 129     }
 130     difference(){
 131       translate([holder_xsz/2 - holder_attach_xsz/2, 0, 0])
 132         cube([holder_attach_xsz,
 133               attach_ysz,
 134               holder_block_zsz + punch_travel
 135               + holder_ctie_thick + holder_attach_roof + 1]);
 136       if (cutouts)
 137         translate([-30,
 138                    holder_attach_walls,
 139                    holder_block_zsz + punch_travel])
 140           cube([60, holder_ctie_width, holder_ctie_thick]);
 141     }
 142   }
 143 }
 144
 145 module RegistrationGroove(l){
 146   // runs along the +ve X axis for length l but at correct z pos
 147   translate([0, 0, jig_main_zsz + 0.1]) {
 148     rotate([90,0,90])
 149       linear_extrude(height=l)
 150       polygon([[-registrationgroove_width/2, 0],
 151                [ +registrationgroove_width/2, 0],
 152                [ 0, -registrationgroove_depth ]]);
 153   }
 154 }
 155
 156 module OneJig(){
 157   difference(){
 158     translate([-(jig_interval/2 + jig_overlap),
 159                -(strap_width/2 + edgewall_width) - attach_offset,
 160                -strap_thick])
 161       cube([jig_interval + 2,
 162             strap_width + edgewall_width*2 + attach_offset,
 163             jig_main_zsz + strap_thick]);
 164     minkowski(){
 165       cube([main_slop*2, main_slop*2, 50], center=true);
 166       PunchHolder(false);
 167     }
 168     translate([-100, -strap_width/2, -10])
 169       cube([200, strap_width, 10]);
 170    translate([-100,0,0])
 171      RegistrationGroove(200);
 172    for (xfrac=[-1/4,0,+1/4])
 173      translate([jig_interval * xfrac, -100, 0])
 174        rotate([0,0,90])
 175        RegistrationGroove(200);
 176   }
 177 }
 178
 179 module RegistrationProtrusion(){
 180   // points towards the positive x axis
 181   xsz = registrationprotrusion_poke;
 182   ysz = registrationprotrusion_poke;
 183   diag_sz = xsz * sqrt(2);
 184   zsz = diag_sz / registrationprotrusion_slope;
 185   hull(){
 186     translate([0, 0, 0.1]){
 187       linear_extrude(height=0.1)
 188         polygon([[   0, -ysz ],
 189                  [ xsz,    0 ],
 190                  [   0,  ysz ]]);
 191       translate([-0.1, 0, zsz ])
 192         rotate([0,0,45])
 193         cube(0.1);
 194     }
 195   }
 196 }
 197
 198 module Jig(){
 199   for(end=[0,1]){
 200     for(yfrac=[-1/2, 0, 1/2]){
 201       translate([ end
 202                   ? jig_interval * (jig_iters - 0.5)
 203                   : -jig_interval/2,
 204                  yfrac * strap_width,
 205                  0])
 206         rotate([0,0, end ? 0 : 180])
 207         translate([ jig_overlap, 0, 0 ])
 208         RegistrationProtrusion();
 209     }
 210   }
 211   for (i=[0:jig_iters-1]) {
 212     translate([jig_interval * i, 0, 0])
 213       OneJig();
 214   }
 215 }
 216
 217 module JigT(){ ////toplevel
 218   translate([0,0,jig_main_zsz])
 219     rotate([180,0,0])
 220     Jig();
 221 }
 222
 223 module PunchHolderT(){ ////toplevel
 224   PunchHolder(true);
 225 }
 226
 227 module Demo(){ ////toplevel
 228   %PunchHolder();
 229   Jig();
 230 }
 231
 232 module Kit(){ ////toplevel
 233   rotate([0,0,-45]){
 234     JigT();
 235     translate([(jig_iters-1)*jig_interval/2,
 236                -strap_width,
 237                0])
 238       PunchHolder();
 239   }
 240 }
 241
 242 //CrewPunch();
 243 //PunchHolder();
 244 //PunchHolder(false);
 245 //OneJig();
 246 //Jig();
 247 Demo();
 248 //JigT();
 249 //RegistrationProtrusion();
 250 //PunchHolderT();
 251 //Kit();