dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2015 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37
  38 use Debian::Dgit;
  39
  40 our $our_version = 'UNRELEASED'; ###substituted###
  41
  42 our @rpushprotovsn_support = qw(3 2);
  43 our $protovsn;
  44
  45 our $isuite = 'unstable';
  46 our $idistro;
  47 our $package;
  48 our @ropts;
  49
  50 our $sign = 1;
  51 our $dryrun_level = 0;
  52 our $changesfile;
  53 our $buildproductsdir = '..';
  54 our $new_package = 0;
  55 our $ignoredirty = 0;
  56 our $rmonerror = 1;
  57 our @deliberatelies;
  58 our %previously;
  59 our $existing_package = 'dpkg';
  60 our $cleanmode = 'dpkg-source';
  61 our $changes_since_version;
  62 our $quilt_mode;
  63 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck';
  64 our $we_are_responder;
  65 our $initiator_tempdir;
  66
  67 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  68
  69 our $suite_re = '[-+.0-9a-z]+';
  70
  71 our (@git) = qw(git);
  72 our (@dget) = qw(dget);
  73 our (@curl) = qw(curl -f);
  74 our (@dput) = qw(dput);
  75 our (@debsign) = qw(debsign);
  76 our (@gpg) = qw(gpg);
  77 our (@sbuild) = qw(sbuild -A);
  78 our (@ssh) = 'ssh';
  79 our (@dgit) = qw(dgit);
  80 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  81 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  82 our (@dpkggenchanges) = qw(dpkg-genchanges);
  83 our (@mergechanges) = qw(mergechanges -f);
  84 our (@changesopts) = ('');
  85
  86 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
  87                      'curl' => \@curl,
  88                      'dput' => \@dput,
  89                      'debsign' => \@debsign,
  90                      'gpg' => \@gpg,
  91                      'sbuild' => \@sbuild,
  92                      'ssh' => \@ssh,
  93                      'dgit' => \@dgit,
  94                      'dpkg-source' => \@dpkgsource,
  95                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  96                      'dpkg-genchanges' => \@dpkggenchanges,
  97                      'ch' => \@changesopts,
  98                      'mergechanges' => \@mergechanges);
  99
 100 our %opts_opt_cmdonly = ('gpg' => 1);
 101 our %opts_cfg_insertpos = map {
 102     $_,
 103     scalar @{ $opts_opt_map{$_} }
 104 } keys %opts_opt_map;
 105
 106 sub finalise_opts_opts();
 107
 108 our $keyid;
 109
 110 autoflush STDOUT 1;
 111
 112 our $supplementary_message = '';
 113
 114 END {
 115     local ($@, $?);
 116     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 117 }
 118
 119 our $remotename = 'dgit';
 120 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 121 our $csuite;
 122 our $instead_distro;
 123
 124 sub lbranch () { return "$branchprefix/$csuite"; }
 125 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 126 sub lref () { return "refs/heads/".lbranch(); }
 127 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 128 sub rrref () { return server_ref($csuite); }
 129
 130 sub lrfetchrefs () { return "refs/dgit-fetch/$csuite"; }
 131
 132 sub stripepoch ($) {
 133     my ($vsn) = @_;
 134     $vsn =~ s/^\d+\://;
 135     return $vsn;
 136 }
 137
 138 sub srcfn ($$) {
 139     my ($vsn,$sfx) = @_;
 140     return "${package}_".(stripepoch $vsn).$sfx
 141 }
 142
 143 sub dscfn ($) {
 144     my ($vsn) = @_;
 145     return srcfn($vsn,".dsc");
 146 }
 147
 148 our $us = 'dgit';
 149 initdebug('');
 150
 151 our @end;
 152 END {
 153     local ($?);
 154     foreach my $f (@end) {
 155         eval { $f->(); };
 156         warn "$us: cleanup: $@" if length $@;
 157     }
 158 };
 159
 160 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 161
 162 sub no_such_package () {
 163     print STDERR "$us: package $package does not exist in suite $isuite\n";
 164     exit 4;
 165 }
 166
 167 sub fetchspec () {
 168     local $csuite = '*';
 169     return  "+".rrref().":".lrref();
 170 }
 171
 172 sub changedir ($) {
 173     my ($newdir) = @_;
 174     printdebug "CD $newdir\n";
 175     chdir $newdir or die "chdir: $newdir: $!";
 176 }
 177
 178 sub deliberately ($) {
 179     my ($enquiry) = @_;
 180     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 181 }
 182
 183 sub deliberately_not_fast_forward () {
 184     foreach (qw(not-fast-forward fresh-repo)) {
 185         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 186     }
 187 }
 188
 189 #---------- remote protocol support, common ----------
 190
 191 # remote push initiator/responder protocol:
 192 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 193 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 194 #  < dgit-remote-push-ready <actual-proto-vsn>
 195 #
 196 #  > file parsed-changelog
 197 #  [indicates that output of dpkg-parsechangelog follows]
 198 #  > data-block NBYTES
 199 #  > [NBYTES bytes of data (no newline)]
 200 #  [maybe some more blocks]
 201 #  > data-end
 202 #
 203 #  > file dsc
 204 #  [etc]
 205 #
 206 #  > file changes
 207 #  [etc]
 208 #
 209 #  > param head HEAD
 210 #
 211 #  > want signed-tag
 212 #  [indicates that signed tag is wanted]
 213 #  < data-block NBYTES
 214 #  < [NBYTES bytes of data (no newline)]
 215 #  [maybe some more blocks]
 216 #  < data-end
 217 #  < files-end
 218 #
 219 #  > want signed-dsc-changes
 220 #  < data-block NBYTES    [transfer of signed dsc]
 221 #  [etc]
 222 #  < data-block NBYTES    [transfer of signed changes]
 223 #  [etc]
 224 #  < files-end
 225 #
 226 #  > complete
 227
 228 our $i_child_pid;
 229
 230 sub i_child_report () {
 231     # Sees if our child has died, and reap it if so.  Returns a string
 232     # describing how it died if it failed, or undef otherwise.
 233     return undef unless $i_child_pid;
 234     my $got = waitpid $i_child_pid, WNOHANG;
 235     return undef if $got <= 0;
 236     die unless $got == $i_child_pid;
 237     $i_child_pid = undef;
 238     return undef unless $?;
 239     return "build host child ".waitstatusmsg();
 240 }
 241
 242 sub badproto ($$) {
 243     my ($fh, $m) = @_;
 244     fail "connection lost: $!" if $fh->error;
 245     fail "protocol violation; $m not expected";
 246 }
 247
 248 sub badproto_badread ($$) {
 249     my ($fh, $wh) = @_;
 250     fail "connection lost: $!" if $!;
 251     my $report = i_child_report();
 252     fail $report if defined $report;
 253     badproto $fh, "eof (reading $wh)";
 254 }
 255
 256 sub protocol_expect (&$) {
 257     my ($match, $fh) = @_;
 258     local $_;
 259     $_ = <$fh>;
 260     defined && chomp or badproto_badread $fh, "protocol message";
 261     if (wantarray) {
 262         my @r = &$match;
 263         return @r if @r;
 264     } else {
 265         my $r = &$match;
 266         return $r if $r;
 267     }
 268     badproto $fh, "\`$_'";
 269 }
 270
 271 sub protocol_send_file ($$) {
 272     my ($fh, $ourfn) = @_;
 273     open PF, "<", $ourfn or die "$ourfn: $!";
 274     for (;;) {
 275         my $d;
 276         my $got = read PF, $d, 65536;
 277         die "$ourfn: $!" unless defined $got;
 278         last if !$got;
 279         print $fh "data-block ".length($d)."\n" or die $!;
 280         print $fh $d or die $!;
 281     }
 282     PF->error and die "$ourfn $!";
 283     print $fh "data-end\n" or die $!;
 284     close PF;
 285 }
 286
 287 sub protocol_read_bytes ($$) {
 288     my ($fh, $nbytes) = @_;
 289     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 290     my $d;
 291     my $got = read $fh, $d, $nbytes;
 292     $got==$nbytes or badproto_badread $fh, "data block";
 293     return $d;
 294 }
 295
 296 sub protocol_receive_file ($$) {
 297     my ($fh, $ourfn) = @_;
 298     printdebug "() $ourfn\n";
 299     open PF, ">", $ourfn or die "$ourfn: $!";
 300     for (;;) {
 301         my ($y,$l) = protocol_expect {
 302             m/^data-block (.*)$/ ? (1,$1) :
 303             m/^data-end$/ ? (0,) :
 304             ();
 305         } $fh;
 306         last unless $y;
 307         my $d = protocol_read_bytes $fh, $l;
 308         print PF $d or die $!;
 309     }
 310     close PF or die $!;
 311 }
 312
 313 #---------- remote protocol support, responder ----------
 314
 315 sub responder_send_command ($) {
 316     my ($command) = @_;
 317     return unless $we_are_responder;
 318     # called even without $we_are_responder
 319     printdebug ">> $command\n";
 320     print PO $command, "\n" or die $!;
 321 }
 322
 323 sub responder_send_file ($$) {
 324     my ($keyword, $ourfn) = @_;
 325     return unless $we_are_responder;
 326     printdebug "]] $keyword $ourfn\n";
 327     responder_send_command "file $keyword";
 328     protocol_send_file \*PO, $ourfn;
 329 }
 330
 331 sub responder_receive_files ($@) {
 332     my ($keyword, @ourfns) = @_;
 333     die unless $we_are_responder;
 334     printdebug "[[ $keyword @ourfns\n";
 335     responder_send_command "want $keyword";
 336     foreach my $fn (@ourfns) {
 337         protocol_receive_file \*PI, $fn;
 338     }
 339     printdebug "[[\$\n";
 340     protocol_expect { m/^files-end$/ } \*PI;
 341 }
 342
 343 #---------- remote protocol support, initiator ----------
 344
 345 sub initiator_expect (&) {
 346     my ($match) = @_;
 347     protocol_expect { &$match } \*RO;
 348 }
 349
 350 #---------- end remote code ----------
 351
 352 sub progress {
 353     if ($we_are_responder) {
 354         my $m = join '', @_;
 355         responder_send_command "progress ".length($m) or die $!;
 356         print PO $m or die $!;
 357     } else {
 358         print @_, "\n";
 359     }
 360 }
 361
 362 our $ua;
 363
 364 sub url_get {
 365     if (!$ua) {
 366         $ua = LWP::UserAgent->new();
 367         $ua->env_proxy;
 368     }
 369     my $what = $_[$#_];
 370     progress "downloading $what...";
 371     my $r = $ua->get(@_) or die $!;
 372     return undef if $r->code == 404;
 373     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 374     return $r->decoded_content(charset => 'none');
 375 }
 376
 377 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 378
 379 sub runcmd {
 380     debugcmd "+",@_;
 381     $!=0; $?=0;
 382     failedcmd @_ if system @_;
 383 }
 384
 385 sub act_local () { return $dryrun_level <= 1; }
 386 sub act_scary () { return !$dryrun_level; }
 387
 388 sub printdone {
 389     if (!$dryrun_level) {
 390         progress "dgit ok: @_";
 391     } else {
 392         progress "would be ok: @_ (but dry run only)";
 393     }
 394 }
 395
 396 sub dryrun_report {
 397     printcmd(\*STDERR,$debugprefix."#",@_);
 398 }
 399
 400 sub runcmd_ordryrun {
 401     if (act_scary()) {
 402         runcmd @_;
 403     } else {
 404         dryrun_report @_;
 405     }
 406 }
 407
 408 sub runcmd_ordryrun_local {
 409     if (act_local()) {
 410         runcmd @_;
 411     } else {
 412         dryrun_report @_;
 413     }
 414 }
 415
 416 sub shell_cmd {
 417     my ($first_shell, @cmd) = @_;
 418     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 419 }
 420
 421 our $helpmsg = <<END;
 422 main usages:
 423   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 424   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 425   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 426   dgit [dgit-opts] push [dgit-opts] [suite]
 427   dgit [dgit-opts] rpush build-host:build-dir ...
 428 important dgit options:
 429   -k<keyid>           sign tag and package with <keyid> instead of default
 430   --dry-run -n        do not change anything, but go through the motions
 431   --damp-run -L       like --dry-run but make local changes, without signing
 432   --new -N            allow introducing a new package
 433   --debug -D          increase debug level
 434   -c<name>=<value>    set git config option (used directly by dgit too)
 435 END
 436
 437 our $later_warning_msg = <<END;
 438 Perhaps the upload is stuck in incoming.  Using the version from git.
 439 END
 440
 441 sub badusage {
 442     print STDERR "$us: @_\n", $helpmsg or die $!;
 443     exit 8;
 444 }
 445
 446 sub nextarg {
 447     @ARGV or badusage "too few arguments";
 448     return scalar shift @ARGV;
 449 }
 450
 451 sub cmd_help () {
 452     print $helpmsg or die $!;
 453     exit 0;
 454 }
 455
 456 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 457
 458 our %defcfg = ('dgit.default.distro' => 'debian',
 459                'dgit.default.username' => '',
 460                'dgit.default.archive-query-default-component' => 'main',
 461                'dgit.default.ssh' => 'ssh',
 462                'dgit.default.archive-query' => 'madison:',
 463                'dgit.default.sshpsql-dbname' => 'service=projectb',
 464                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 465                'dgit-distro.debian.git-check' => 'url',
 466                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 467                'dgit-distro.debian.new-private-pushers' => 't',
 468                'dgit-distro.debian/push.git-url' => '',
 469                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 470                'dgit-distro.debian/push.git-user-force' => 'dgit',
 471                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 472                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 473                'dgit-distro.debian/push.git-create' => 'true',
 474                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 475  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 476 # 'dgit-distro.debian.archive-query-tls-key',
 477 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 478 # ^ this does not work because curl is broken nowadays
 479 # Fixing #790093 properly will involve providing providing the key
 480 # in some pacagke and maybe updating these paths.
 481 #
 482 # 'dgit-distro.debian.archive-query-tls-curl-args',
 483 #   '--ca-path=/etc/ssl/ca-debian',
 484 # ^ this is a workaround but works (only) on DSA-administered machines
 485                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 486                'dgit-distro.debian.git-url-suffix' => '',
 487                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 488                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 489  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 490  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 491                'dgit-distro.ubuntu.git-check' => 'false',
 492  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 493                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 494                'dgit-distro.test-dummy.username' => "alice",
 495                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 496                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 497                'dgit-distro.test-dummy.git-url' => "$td/git",
 498                'dgit-distro.test-dummy.git-host' => "git",
 499                'dgit-distro.test-dummy.git-path' => "$td/git",
 500                'dgit-distro.test-dummy.archive-query' => "ftpmasterapi:",
 501                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 502                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 503                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 504                );
 505
 506 our %gitcfg;
 507
 508 sub git_slurp_config () {
 509     local ($debuglevel) = $debuglevel-2;
 510     local $/="\0";
 511
 512     my @cmd = (@git, qw(config -z --get-regexp .*));
 513     debugcmd "|",@cmd;
 514
 515     open GITS, "-|", @cmd or failedcmd @cmd;
 516     while (<GITS>) {
 517         chomp or die;
 518         printdebug "=> ", (messagequote $_), "\n";
 519         m/\n/ or die "$_ ?";
 520         push @{ $gitcfg{$`} }, $'; #';
 521     }
 522     $!=0; $?=0;
 523     close GITS
 524         or ($!==0 && $?==256)
 525         or failedcmd @cmd;
 526 }
 527
 528 sub git_get_config ($) {
 529     my ($c) = @_;
 530     my $l = $gitcfg{$c};
 531     printdebug"C $c ".(defined $l ? messagequote "'$l'" : "undef")."\n"
 532         if $debuglevel >= 4;
 533     $l or return undef;
 534     @$l==1 or badcfg "multiple values for $c" if @$l > 1;
 535     return $l->[0];
 536 }
 537
 538 sub cfg {
 539     foreach my $c (@_) {
 540         return undef if $c =~ /RETURN-UNDEF/;
 541         my $v = git_get_config($c);
 542         return $v if defined $v;
 543         my $dv = $defcfg{$c};
 544         return $dv if defined $dv;
 545     }
 546     badcfg "need value for one of: @_\n".
 547         "$us: distro or suite appears not to be (properly) supported";
 548 }
 549
 550 sub access_basedistro () {
 551     if (defined $idistro) {
 552         return $idistro;
 553     } else {
 554         return cfg("dgit-suite.$isuite.distro",
 555                    "dgit.default.distro");
 556     }
 557 }
 558
 559 sub access_quirk () {
 560     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 561     my $basedistro = access_basedistro();
 562     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 563                               'RETURN-UNDEF');
 564     if (defined $backports_quirk) {
 565         my $re = $backports_quirk;
 566         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 567         $re =~ s/\*/.*/g;
 568         $re =~ s/\%/([-0-9a-z_]+)/
 569             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 570         if ($isuite =~ m/^$re$/) {
 571             return ('backports',"$basedistro-backports",$1);
 572         }
 573     }
 574     return ('none',undef);
 575 }
 576
 577 our $access_forpush;
 578
 579 sub parse_cfg_bool ($$$) {
 580     my ($what,$def,$v) = @_;
 581     $v //= $def;
 582     return
 583         $v =~ m/^[ty1]/ ? 1 :
 584         $v =~ m/^[fn0]/ ? 0 :
 585         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 586 }
 587
 588 sub access_forpush_config () {
 589     my $d = access_basedistro();
 590
 591     return 1 if
 592         $new_package &&
 593         parse_cfg_bool('new-private-pushers', 0,
 594                        cfg("dgit-distro.$d.new-private-pushers",
 595                            'RETURN-UNDEF'));
 596
 597     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 598     $v //= 'a';
 599     return
 600         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 601         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 602         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 603         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 604 }
 605
 606 sub access_forpush () {
 607     $access_forpush //= access_forpush_config();
 608     return $access_forpush;
 609 }
 610
 611 sub pushing () {
 612     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 613     badcfg "pushing but distro is configured readonly"
 614         if access_forpush_config() eq '0';
 615     $access_forpush = 1;
 616     $supplementary_message = <<'END' unless $we_are_responder;
 617 Push failed, before we got started.
 618 You can retry the push, after fixing the problem, if you like.
 619 END
 620     finalise_opts_opts();
 621 }
 622
 623 sub notpushing () {
 624     finalise_opts_opts();
 625 }
 626
 627 sub supplementary_message ($) {
 628     my ($msg) = @_;
 629     if (!$we_are_responder) {
 630         $supplementary_message = $msg;
 631         return;
 632     } elsif ($protovsn >= 3) {
 633         responder_send_command "supplementary-message ".length($msg)
 634             or die $!;
 635         print PO $msg or die $!;
 636     }
 637 }
 638
 639 sub access_distros () {
 640     # Returns list of distros to try, in order
 641     #
 642     # We want to try:
 643     #    0. `instead of' distro name(s) we have been pointed to
 644     #    1. the access_quirk distro, if any
 645     #    2a. the user's specified distro, or failing that  } basedistro
 646     #    2b. the distro calculated from the suite          }
 647     my @l = access_basedistro();
 648
 649     my (undef,$quirkdistro) = access_quirk();
 650     unshift @l, $quirkdistro;
 651     unshift @l, $instead_distro;
 652     @l = grep { defined } @l;
 653
 654     if (access_forpush()) {
 655         @l = map { ("$_/push", $_) } @l;
 656     }
 657     @l;
 658 }
 659
 660 sub access_cfg_cfgs (@) {
 661     my (@keys) = @_;
 662     my @cfgs;
 663     # The nesting of these loops determines the search order.  We put
 664     # the key loop on the outside so that we search all the distros
 665     # for each key, before going on to the next key.  That means that
 666     # if access_cfg is called with a more specific, and then a less
 667     # specific, key, an earlier distro can override the less specific
 668     # without necessarily overriding any more specific keys.  (If the
 669     # distro wants to override the more specific keys it can simply do
 670     # so; whereas if we did the loop the other way around, it would be
 671     # impossible to for an earlier distro to override a less specific
 672     # key but not the more specific ones without restating the unknown
 673     # values of the more specific keys.
 674     my @realkeys;
 675     my @rundef;
 676     # We have to deal with RETURN-UNDEF specially, so that we don't
 677     # terminate the search prematurely.
 678     foreach (@keys) {
 679         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 680         push @realkeys, $_
 681     }
 682     foreach my $d (access_distros()) {
 683         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 684     }
 685     push @cfgs, map { "dgit.default.$_" } @realkeys;
 686     push @cfgs, @rundef;
 687     return @cfgs;
 688 }
 689
 690 sub access_cfg (@) {
 691     my (@keys) = @_;
 692     my (@cfgs) = access_cfg_cfgs(@keys);
 693     my $value = cfg(@cfgs);
 694     return $value;
 695 }
 696
 697 sub access_cfg_bool ($$) {
 698     my ($def, @keys) = @_;
 699     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 700 }
 701
 702 sub string_to_ssh ($) {
 703     my ($spec) = @_;
 704     if ($spec =~ m/\s/) {
 705         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 706     } else {
 707         return ($spec);
 708     }
 709 }
 710
 711 sub access_cfg_ssh () {
 712     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 713     if (!defined $gitssh) {
 714         return @ssh;
 715     } else {
 716         return string_to_ssh $gitssh;
 717     }
 718 }
 719
 720 sub access_runeinfo ($) {
 721     my ($info) = @_;
 722     return ": dgit ".access_basedistro()." $info ;";
 723 }
 724
 725 sub access_someuserhost ($) {
 726     my ($some) = @_;
 727     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 728     defined($user) && length($user) or
 729         $user = access_cfg("$some-user",'username');
 730     my $host = access_cfg("$some-host");
 731     return length($user) ? "$user\@$host" : $host;
 732 }
 733
 734 sub access_gituserhost () {
 735     return access_someuserhost('git');
 736 }
 737
 738 sub access_giturl (;$) {
 739     my ($optional) = @_;
 740     my $url = access_cfg('git-url','RETURN-UNDEF');
 741     my $suffix;
 742     if (!length $url) {
 743         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 744         return undef unless defined $proto;
 745         $url =
 746             $proto.
 747             access_gituserhost().
 748             access_cfg('git-path');
 749     } else {
 750         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 751     }
 752     $suffix //= '.git';
 753     return "$url/$package$suffix";
 754 }
 755
 756 sub parsecontrolfh ($$;$) {
 757     my ($fh, $desc, $allowsigned) = @_;
 758     our $dpkgcontrolhash_noissigned;
 759     my $c;
 760     for (;;) {
 761         my %opts = ('name' => $desc);
 762         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 763         $c = Dpkg::Control::Hash->new(%opts);
 764         $c->parse($fh,$desc) or die "parsing of $desc failed";
 765         last if $allowsigned;
 766         last if $dpkgcontrolhash_noissigned;
 767         my $issigned= $c->get_option('is_pgp_signed');
 768         if (!defined $issigned) {
 769             $dpkgcontrolhash_noissigned= 1;
 770             seek $fh, 0,0 or die "seek $desc: $!";
 771         } elsif ($issigned) {
 772             fail "control file $desc is (already) PGP-signed. ".
 773                 " Note that dgit push needs to modify the .dsc and then".
 774                 " do the signature itself";
 775         } else {
 776             last;
 777         }
 778     }
 779     return $c;
 780 }
 781
 782 sub parsecontrol {
 783     my ($file, $desc) = @_;
 784     my $fh = new IO::Handle;
 785     open $fh, '<', $file or die "$file: $!";
 786     my $c = parsecontrolfh($fh,$desc);
 787     $fh->error and die $!;
 788     close $fh;
 789     return $c;
 790 }
 791
 792 sub getfield ($$) {
 793     my ($dctrl,$field) = @_;
 794     my $v = $dctrl->{$field};
 795     return $v if defined $v;
 796     fail "missing field $field in ".$v->get_option('name');
 797 }
 798
 799 sub parsechangelog {
 800     my $c = Dpkg::Control::Hash->new();
 801     my $p = new IO::Handle;
 802     my @cmd = (qw(dpkg-parsechangelog), @_);
 803     open $p, '-|', @cmd or die $!;
 804     $c->parse($p);
 805     $?=0; $!=0; close $p or failedcmd @cmd;
 806     return $c;
 807 }
 808
 809 sub must_getcwd () {
 810     my $d = getcwd();
 811     defined $d or fail "getcwd failed: $!";
 812     return $d;
 813 }
 814
 815 our %rmad;
 816
 817 sub archive_query ($) {
 818     my ($method) = @_;
 819     my $query = access_cfg('archive-query','RETURN-UNDEF');
 820     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 821     my $proto = $1;
 822     my $data = $'; #';
 823     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 824 }
 825
 826 sub pool_dsc_subpath ($$) {
 827     my ($vsn,$component) = @_; # $package is implict arg
 828     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 829     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 830 }
 831
 832 #---------- `ftpmasterapi' archive query method (nascent) ----------
 833
 834 sub archive_api_query_cmd ($) {
 835     my ($subpath) = @_;
 836     my @cmd = qw(curl -sS);
 837     my $url = access_cfg('archive-query-url');
 838     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
 839         my $host = $1;
 840         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
 841         foreach my $key (split /\:/, $keys) {
 842             $key =~ s/\%HOST\%/$host/g;
 843             if (!stat $key) {
 844                 fail "for $url: stat $key: $!" unless $!==ENOENT;
 845                 next;
 846             }
 847             fail "config requested specific TLS key but do not know".
 848                 " how to get curl to use exactly that EE key ($key)";
 849 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
 850 #           # Sadly the above line does not work because of changes
 851 #           # to gnutls.   The real fix for #790093 may involve
 852 #           # new curl options.
 853             last;
 854         }
 855         # Fixing #790093 properly will involve providing a value
 856         # for this on clients.
 857         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
 858         push @cmd, split / /, $kargs if defined $kargs;
 859     }
 860     push @cmd, $url.$subpath;
 861     return @cmd;
 862 }
 863
 864 sub api_query ($$) {
 865     use JSON;
 866     my ($data, $subpath) = @_;
 867     badcfg "ftpmasterapi archive query method takes no data part"
 868         if length $data;
 869     my @cmd = archive_api_query_cmd($subpath);
 870     my $json = cmdoutput @cmd;
 871     return decode_json($json);
 872 }
 873
 874 sub canonicalise_suite_ftpmasterapi () {
 875     my ($proto,$data) = @_;
 876     my $suites = api_query($data, 'suites');
 877     my @matched;
 878     foreach my $entry (@$suites) {
 879         next unless grep {
 880             my $v = $entry->{$_};
 881             defined $v && $v eq $isuite;
 882         } qw(codename name);
 883         push @matched, $entry;
 884     }
 885     fail "unknown suite $isuite" unless @matched;
 886     my $cn;
 887     eval {
 888         @matched==1 or die "multiple matches for suite $isuite\n";
 889         $cn = "$matched[0]{codename}";
 890         defined $cn or die "suite $isuite info has no codename\n";
 891         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
 892     };
 893     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
 894         if length $@;
 895     return $cn;
 896 }
 897
 898 sub archive_query_ftpmasterapi () {
 899     my ($proto,$data) = @_;
 900     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
 901     my @rows;
 902     my $digester = Digest::SHA->new(256);
 903     foreach my $entry (@$info) {
 904         eval {
 905             my $vsn = "$entry->{version}";
 906             my ($ok,$msg) = version_check $vsn;
 907             die "bad version: $msg\n" unless $ok;
 908             my $component = "$entry->{component}";
 909             $component =~ m/^$component_re$/ or die "bad component";
 910             my $filename = "$entry->{filename}";
 911             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
 912                 or die "bad filename";
 913             my $sha256sum = "$entry->{sha256sum}";
 914             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
 915             push @rows, [ $vsn, "/pool/$component/$filename",
 916                           $digester, $sha256sum ];
 917         };
 918         die "bad ftpmaster api response: $@\n".Dumper($entry)
 919             if length $@;
 920     }
 921     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 922     return @rows;
 923 }
 924
 925 #---------- `madison' archive query method ----------
 926
 927 sub archive_query_madison {
 928     return map { [ @$_[0..1] ] } madison_get_parse(@_);
 929 }
 930
 931 sub madison_get_parse {
 932     my ($proto,$data) = @_;
 933     die unless $proto eq 'madison';
 934     if (!length $data) {
 935         $data= access_cfg('madison-distro','RETURN-UNDEF');
 936         $data //= access_basedistro();
 937     }
 938     $rmad{$proto,$data,$package} ||= cmdoutput
 939         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 940     my $rmad = $rmad{$proto,$data,$package};
 941
 942     my @out;
 943     foreach my $l (split /\n/, $rmad) {
 944         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 945                   \s*( [^ \t|]+ )\s* \|
 946                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 947                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
 948         $1 eq $package or die "$rmad $package ?";
 949         my $vsn = $2;
 950         my $newsuite = $3;
 951         my $component;
 952         if (defined $4) {
 953             $component = $4;
 954         } else {
 955             $component = access_cfg('archive-query-default-component');
 956         }
 957         $5 eq 'source' or die "$rmad ?";
 958         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
 959     }
 960     return sort { -version_compare($a->[0],$b->[0]); } @out;
 961 }
 962
 963 sub canonicalise_suite_madison {
 964     # madison canonicalises for us
 965     my @r = madison_get_parse(@_);
 966     @r or fail
 967         "unable to canonicalise suite using package $package".
 968         " which does not appear to exist in suite $isuite;".
 969         " --existing-package may help";
 970     return $r[0][2];
 971 }
 972
 973 #---------- `sshpsql' archive query method ----------
 974
 975 sub sshpsql ($$$) {
 976     my ($data,$runeinfo,$sql) = @_;
 977     if (!length $data) {
 978         $data= access_someuserhost('sshpsql').':'.
 979             access_cfg('sshpsql-dbname');
 980     }
 981     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
 982     my ($userhost,$dbname) = ($`,$'); #';
 983     my @rows;
 984     my @cmd = (access_cfg_ssh, $userhost,
 985                access_runeinfo("ssh-psql $runeinfo").
 986                " export LC_MESSAGES=C; export LC_CTYPE=C;".
 987                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
 988     debugcmd "|",@cmd;
 989     open P, "-|", @cmd or die $!;
 990     while (<P>) {
 991         chomp or die;
 992         printdebug(">|$_|\n");
 993         push @rows, $_;
 994     }
 995     $!=0; $?=0; close P or failedcmd @cmd;
 996     @rows or die;
 997     my $nrows = pop @rows;
 998     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
 999     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1000     @rows = map { [ split /\|/, $_ ] } @rows;
1001     my $ncols = scalar @{ shift @rows };
1002     die if grep { scalar @$_ != $ncols } @rows;
1003     return @rows;
1004 }
1005
1006 sub sql_injection_check {
1007     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1008 }
1009
1010 sub archive_query_sshpsql ($$) {
1011     my ($proto,$data) = @_;
1012     sql_injection_check $isuite, $package;
1013     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1014         SELECT source.version, component.name, files.filename, files.sha256sum
1015           FROM source
1016           JOIN src_associations ON source.id = src_associations.source
1017           JOIN suite ON suite.id = src_associations.suite
1018           JOIN dsc_files ON dsc_files.source = source.id
1019           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1020           JOIN component ON component.id = files_archive_map.component_id
1021           JOIN files ON files.id = dsc_files.file
1022          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1023            AND source.source='$package'
1024            AND files.filename LIKE '%.dsc';
1025 END
1026     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1027     my $digester = Digest::SHA->new(256);
1028     @rows = map {
1029         my ($vsn,$component,$filename,$sha256sum) = @$_;
1030         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1031     } @rows;
1032     return @rows;
1033 }
1034
1035 sub canonicalise_suite_sshpsql ($$) {
1036     my ($proto,$data) = @_;
1037     sql_injection_check $isuite;
1038     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1039         SELECT suite.codename
1040           FROM suite where suite_name='$isuite' or codename='$isuite';
1041 END
1042     @rows = map { $_->[0] } @rows;
1043     fail "unknown suite $isuite" unless @rows;
1044     die "ambiguous $isuite: @rows ?" if @rows>1;
1045     return $rows[0];
1046 }
1047
1048 #---------- `dummycat' archive query method ----------
1049
1050 sub canonicalise_suite_dummycat ($$) {
1051     my ($proto,$data) = @_;
1052     my $dpath = "$data/suite.$isuite";
1053     if (!open C, "<", $dpath) {
1054         $!==ENOENT or die "$dpath: $!";
1055         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1056         return $isuite;
1057     }
1058     $!=0; $_ = <C>;
1059     chomp or die "$dpath: $!";
1060     close C;
1061     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1062     return $_;
1063 }
1064
1065 sub archive_query_dummycat ($$) {
1066     my ($proto,$data) = @_;
1067     canonicalise_suite();
1068     my $dpath = "$data/package.$csuite.$package";
1069     if (!open C, "<", $dpath) {
1070         $!==ENOENT or die "$dpath: $!";
1071         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1072         return ();
1073     }
1074     my @rows;
1075     while (<C>) {
1076         next if m/^\#/;
1077         next unless m/\S/;
1078         die unless chomp;
1079         printdebug "dummycat query $csuite $package $dpath | $_\n";
1080         my @row = split /\s+/, $_;
1081         @row==2 or die "$dpath: $_ ?";
1082         push @rows, \@row;
1083     }
1084     C->error and die "$dpath: $!";
1085     close C;
1086     return sort { -version_compare($a->[0],$b->[0]); } @rows;
1087 }
1088
1089 #---------- archive query entrypoints and rest of program ----------
1090
1091 sub canonicalise_suite () {
1092     return if defined $csuite;
1093     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1094     $csuite = archive_query('canonicalise_suite');
1095     if ($isuite ne $csuite) {
1096         progress "canonical suite name for $isuite is $csuite";
1097     }
1098 }
1099
1100 sub get_archive_dsc () {
1101     canonicalise_suite();
1102     my @vsns = archive_query('archive_query');
1103     foreach my $vinfo (@vsns) {
1104         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
1105         $dscurl = access_cfg('mirror').$subpath;
1106         $dscdata = url_get($dscurl);
1107         if (!$dscdata) {
1108             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1109             next;
1110         }
1111         if ($digester) {
1112             $digester->reset();
1113             $digester->add($dscdata);
1114             my $got = $digester->hexdigest();
1115             $got eq $digest or
1116                 fail "$dscurl has hash $got but".
1117                     " archive told us to expect $digest";
1118         }
1119         my $dscfh = new IO::File \$dscdata, '<' or die $!;
1120         printdebug Dumper($dscdata) if $debuglevel>1;
1121         $dsc = parsecontrolfh($dscfh,$dscurl,1);
1122         printdebug Dumper($dsc) if $debuglevel>1;
1123         my $fmt = getfield $dsc, 'Format';
1124         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
1125         $dsc_checked = !!$digester;
1126         return;
1127     }
1128     $dsc = undef;
1129 }
1130
1131 sub check_for_git ();
1132 sub check_for_git () {
1133     # returns 0 or 1
1134     my $how = access_cfg('git-check');
1135     if ($how eq 'ssh-cmd') {
1136         my @cmd =
1137             (access_cfg_ssh, access_gituserhost(),
1138              access_runeinfo("git-check $package").
1139              " set -e; cd ".access_cfg('git-path').";".
1140              " if test -d $package.git; then echo 1; else echo 0; fi");
1141         my $r= cmdoutput @cmd;
1142         if ($r =~ m/^divert (\w+)$/) {
1143             my $divert=$1;
1144             my ($usedistro,) = access_distros();
1145             # NB that if we are pushing, $usedistro will be $distro/push
1146             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1147             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1148             progress "diverting to $divert (using config for $instead_distro)";
1149             return check_for_git();
1150         }
1151         failedcmd @cmd unless $r =~ m/^[01]$/;
1152         return $r+0;
1153     } elsif ($how eq 'url') {
1154         my $prefix = access_cfg('git-check-url','git-url');
1155         my $suffix = access_cfg('git-check-suffix','git-suffix',
1156                                 'RETURN-UNDEF') // '.git';
1157         my $url = "$prefix/$package$suffix";
1158         my @cmd = (qw(curl -sS -I), $url);
1159         my $result = cmdoutput @cmd;
1160         $result =~ m/^\S+ (404|200) /s or
1161             fail "unexpected results from git check query - ".
1162                 Dumper($prefix, $result);
1163         my $code = $1;
1164         if ($code eq '404') {
1165             return 0;
1166         } elsif ($code eq '200') {
1167             return 1;
1168         } else {
1169             die;
1170         }
1171     } elsif ($how eq 'true') {
1172         return 1;
1173     } elsif ($how eq 'false') {
1174         return 0;
1175     } else {
1176         badcfg "unknown git-check \`$how'";
1177     }
1178 }
1179
1180 sub create_remote_git_repo () {
1181     my $how = access_cfg('git-create');
1182     if ($how eq 'ssh-cmd') {
1183         runcmd_ordryrun
1184             (access_cfg_ssh, access_gituserhost(),
1185              access_runeinfo("git-create $package").
1186              "set -e; cd ".access_cfg('git-path').";".
1187              " cp -a _template $package.git");
1188     } elsif ($how eq 'true') {
1189         # nothing to do
1190     } else {
1191         badcfg "unknown git-create \`$how'";
1192     }
1193 }
1194
1195 our ($dsc_hash,$lastpush_hash);
1196
1197 our $ud = '.git/dgit/unpack';
1198
1199 sub prep_ud () {
1200     rmtree($ud);
1201     mkpath '.git/dgit';
1202     mkdir $ud or die $!;
1203 }
1204
1205 sub mktree_in_ud_here () {
1206     runcmd qw(git init -q);
1207     rmtree('.git/objects');
1208     symlink '../../../../objects','.git/objects' or die $!;
1209 }
1210
1211 sub git_write_tree () {
1212     my $tree = cmdoutput @git, qw(write-tree);
1213     $tree =~ m/^\w+$/ or die "$tree ?";
1214     return $tree;
1215 }
1216
1217 sub mktree_in_ud_from_only_subdir () {
1218     # changes into the subdir
1219     my (@dirs) = <*/.>;
1220     die unless @dirs==1;
1221     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1222     my $dir = $1;
1223     changedir $dir;
1224
1225     my @gitscmd = qw(find -name .git -prune -print0);
1226     debugcmd "|",@gitscmd;
1227     open GITS, "-|", @gitscmd or failedcmd @gitscmd;
1228     {
1229         local $/="\0";
1230         while (<GITS>) {
1231             chomp or die;
1232             print STDERR "$us: warning: removing from source package: ",
1233                 (messagequote $_), "\n";
1234             rmtree $_;
1235         }
1236     }
1237     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1238
1239     mktree_in_ud_here();
1240     my $format=get_source_format();
1241     if (madformat($format)) {
1242         rmtree '.pc';
1243     }
1244     runcmd @git, qw(add -Af);
1245     my $tree=git_write_tree();
1246     return ($tree,$dir);
1247 }
1248
1249 sub dsc_files_info () {
1250     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1251                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1252                        ['Files',           'Digest::MD5', 'new()']) {
1253         my ($fname, $module, $method) = @$csumi;
1254         my $field = $dsc->{$fname};
1255         next unless defined $field;
1256         eval "use $module; 1;" or die $@;
1257         my @out;
1258         foreach (split /\n/, $field) {
1259             next unless m/\S/;
1260             m/^(\w+) (\d+) (\S+)$/ or
1261                 fail "could not parse .dsc $fname line \`$_'";
1262             my $digester = eval "$module"."->$method;" or die $@;
1263             push @out, {
1264                 Hash => $1,
1265                 Bytes => $2,
1266                 Filename => $3,
1267                 Digester => $digester,
1268             };
1269         }
1270         return @out;
1271     }
1272     fail "missing any supported Checksums-* or Files field in ".
1273         $dsc->get_option('name');
1274 }
1275
1276 sub dsc_files () {
1277     map { $_->{Filename} } dsc_files_info();
1278 }
1279
1280 sub is_orig_file ($;$) {
1281     local ($_) = $_[0];
1282     my $base = $_[1];
1283     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1284     defined $base or return 1;
1285     return $` eq $base;
1286 }
1287
1288 sub make_commit ($) {
1289     my ($file) = @_;
1290     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1291 }
1292
1293 sub clogp_authline ($) {
1294     my ($clogp) = @_;
1295     my $author = getfield $clogp, 'Maintainer';
1296     $author =~ s#,.*##ms;
1297     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1298     my $authline = "$author $date";
1299     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1300         fail "unexpected commit author line format \`$authline'".
1301         " (was generated from changelog Maintainer field)";
1302     return $authline;
1303 }
1304
1305 sub vendor_patches_distro ($$) {
1306     my ($checkdistro, $what) = @_;
1307     return unless defined $checkdistro;
1308
1309     my $series = "debian/patches/\L$checkdistro\E.series";
1310     printdebug "checking for vendor-specific $series ($what)\n";
1311
1312     if (!open SERIES, "<", $series) {
1313         die "$series $!" unless $!==ENOENT;
1314         return;
1315     }
1316     while (<SERIES>) {
1317         next unless m/\S/;
1318         next if m/^\s+\#/;
1319
1320         print STDERR <<END;
1321
1322 Unfortunately, this source package uses a feature of dpkg-source where
1323 the same source package unpacks to different source code on different
1324 distros.  dgit cannot safely operate on such packages on affected
1325 distros, because the meaning of source packages is not stable.
1326
1327 Please ask the distro/maintainer to remove the distro-specific series
1328 files and use a different technique (if necessary, uploading actually
1329 different packages, if different distros are supposed to have
1330 different code).
1331
1332 END
1333         fail "Found active distro-specific series file for".
1334             " $checkdistro ($what): $series, cannot continue";
1335     }
1336     die "$series $!" if SERIES->error;
1337     close SERIES;
1338 }
1339
1340 sub check_for_vendor_patches () {
1341     # This dpkg-source feature doesn't seem to be documented anywhere!
1342     # But it can be found in the changelog (reformatted):
1343
1344     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
1345     #   Author: Raphael Hertzog <hertzog@debian.org>
1346     #   Date: Sun  Oct  3  09:36:48  2010 +0200
1347
1348     #   dpkg-source: correctly create .pc/.quilt_series with alternate
1349     #   series files
1350     #
1351     #   If you have debian/patches/ubuntu.series and you were
1352     #   unpacking the source package on ubuntu, quilt was still
1353     #   directed to debian/patches/series instead of
1354     #   debian/patches/ubuntu.series.
1355     #
1356     #   debian/changelog                        |    3 +++
1357     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
1358     #   2 files changed, 6 insertions(+), 1 deletion(-)
1359
1360     use Dpkg::Vendor;
1361     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
1362     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
1363                          "Dpkg::Vendor \`current vendor'");
1364     vendor_patches_distro(access_basedistro(),
1365                           "distro being accessed");
1366 }
1367
1368 sub generate_commit_from_dsc () {
1369     prep_ud();
1370     changedir $ud;
1371
1372     foreach my $fi (dsc_files_info()) {
1373         my $f = $fi->{Filename};
1374         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1375
1376         link "../../../$f", $f
1377             or $!==&ENOENT
1378             or die "$f $!";
1379
1380         complete_file_from_dsc('.', $fi);
1381
1382         if (is_orig_file($f)) {
1383             link $f, "../../../../$f"
1384                 or $!==&EEXIST
1385                 or die "$f $!";
1386         }
1387     }
1388
1389     my $dscfn = "$package.dsc";
1390
1391     open D, ">", $dscfn or die "$dscfn: $!";
1392     print D $dscdata or die "$dscfn: $!";
1393     close D or die "$dscfn: $!";
1394     my @cmd = qw(dpkg-source);
1395     push @cmd, '--no-check' if $dsc_checked;
1396     push @cmd, qw(-x --), $dscfn;
1397     runcmd @cmd;
1398
1399     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1400     check_for_vendor_patches() if madformat($dsc->{format});
1401     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1402     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1403     my $authline = clogp_authline $clogp;
1404     my $changes = getfield $clogp, 'Changes';
1405     open C, ">../commit.tmp" or die $!;
1406     print C <<END or die $!;
1407 tree $tree
1408 author $authline
1409 committer $authline
1410
1411 $changes
1412
1413 # imported from the archive
1414 END
1415     close C or die $!;
1416     my $outputhash = make_commit qw(../commit.tmp);
1417     my $cversion = getfield $clogp, 'Version';
1418     progress "synthesised git commit from .dsc $cversion";
1419     if ($lastpush_hash) {
1420         runcmd @git, qw(reset --hard), $lastpush_hash;
1421         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1422         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1423         my $oversion = getfield $oldclogp, 'Version';
1424         my $vcmp =
1425             version_compare($oversion, $cversion);
1426         if ($vcmp < 0) {
1427             # git upload/ is earlier vsn than archive, use archive
1428             open C, ">../commit2.tmp" or die $!;
1429             print C <<END or die $!;
1430 tree $tree
1431 parent $lastpush_hash
1432 parent $outputhash
1433 author $authline
1434 committer $authline
1435
1436 Record $package ($cversion) in archive suite $csuite
1437 END
1438             $outputhash = make_commit qw(../commit2.tmp);
1439         } elsif ($vcmp > 0) {
1440             print STDERR <<END or die $!;
1441
1442 Version actually in archive:    $cversion (older)
1443 Last allegedly pushed/uploaded: $oversion (newer or same)
1444 $later_warning_msg
1445 END
1446             $outputhash = $lastpush_hash;
1447         } else {
1448             $outputhash = $lastpush_hash;
1449         }
1450     }
1451     changedir '../../../..';
1452     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1453             'DGIT_ARCHIVE', $outputhash;
1454     cmdoutput @git, qw(log -n2), $outputhash;
1455     # ... gives git a chance to complain if our commit is malformed
1456     rmtree($ud);
1457     return $outputhash;
1458 }
1459
1460 sub complete_file_from_dsc ($$) {
1461     our ($dstdir, $fi) = @_;
1462     # Ensures that we have, in $dir, the file $fi, with the correct
1463     # contents.  (Downloading it from alongside $dscurl if necessary.)
1464
1465     my $f = $fi->{Filename};
1466     my $tf = "$dstdir/$f";
1467     my $downloaded = 0;
1468
1469     if (stat_exists $tf) {
1470         progress "using existing $f";
1471     } else {
1472         my $furl = $dscurl;
1473         $furl =~ s{/[^/]+$}{};
1474         $furl .= "/$f";
1475         die "$f ?" unless $f =~ m/^${package}_/;
1476         die "$f ?" if $f =~ m#/#;
1477         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1478         next if !act_local();
1479         $downloaded = 1;
1480     }
1481
1482     open F, "<", "$tf" or die "$tf: $!";
1483     $fi->{Digester}->reset();
1484     $fi->{Digester}->addfile(*F);
1485     F->error and die $!;
1486     my $got = $fi->{Digester}->hexdigest();
1487     $got eq $fi->{Hash} or
1488         fail "file $f has hash $got but .dsc".
1489             " demands hash $fi->{Hash} ".
1490             ($downloaded ? "(got wrong file from archive!)"
1491              : "(perhaps you should delete this file?)");
1492 }
1493
1494 sub ensure_we_have_orig () {
1495     foreach my $fi (dsc_files_info()) {
1496         my $f = $fi->{Filename};
1497         next unless is_orig_file($f);
1498         complete_file_from_dsc('..', $fi);
1499     }
1500 }
1501
1502 sub git_fetch_us () {
1503     my @specs = (fetchspec());
1504     push @specs,
1505         map { "+refs/$_/*:".lrfetchrefs."/$_/*" }
1506         qw(tags heads);
1507     runcmd_ordryrun_local @git, qw(fetch -p -n -q), access_giturl(), @specs;
1508
1509     my %here;
1510     my $tagpat = debiantag('*',access_basedistro);
1511
1512     git_for_each_ref("refs/tags/".$tagpat, sub {
1513         my ($objid,$objtype,$fullrefname,$reftail) = @_;
1514         printdebug "currently $fullrefname=$objid\n";
1515         $here{$fullrefname} = $objid;
1516     });
1517     git_for_each_ref(lrfetchrefs."/tags/".$tagpat, sub {
1518         my ($objid,$objtype,$fullrefname,$reftail) = @_;
1519         my $lref = "refs".substr($fullrefname, length lrfetchrefs);
1520         printdebug "offered $lref=$objid\n";
1521         if (!defined $here{$lref}) {
1522             my @upd = (@git, qw(update-ref), $lref, $objid, '');
1523             runcmd_ordryrun_local @upd;
1524         } elsif ($here{$lref} eq $objid) {
1525         } else {
1526             print STDERR \
1527                 "Not updateting $lref from $here{$lref} to $objid.\n";
1528         }
1529     });
1530 }
1531
1532 sub fetch_from_archive () {
1533     # ensures that lrref() is what is actually in the archive,
1534     #  one way or another
1535     get_archive_dsc();
1536
1537     if ($dsc) {
1538         foreach my $field (@ourdscfield) {
1539             $dsc_hash = $dsc->{$field};
1540             last if defined $dsc_hash;
1541         }
1542         if (defined $dsc_hash) {
1543             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1544             $dsc_hash = $&;
1545             progress "last upload to archive specified git hash";
1546         } else {
1547             progress "last upload to archive has NO git hash";
1548         }
1549     } else {
1550         progress "no version available from the archive";
1551     }
1552
1553     $lastpush_hash = git_get_ref(lrref());
1554     printdebug "previous reference hash=$lastpush_hash\n";
1555     my $hash;
1556     if (defined $dsc_hash) {
1557         fail "missing remote git history even though dsc has hash -".
1558             " could not find ref ".lrref().
1559             " (should have been fetched from ".access_giturl()."#".rrref().")"
1560             unless $lastpush_hash;
1561         $hash = $dsc_hash;
1562         ensure_we_have_orig();
1563         if ($dsc_hash eq $lastpush_hash) {
1564         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1565             print STDERR <<END or die $!;
1566
1567 Git commit in archive is behind the last version allegedly pushed/uploaded.
1568 Commit referred to by archive:  $dsc_hash
1569 Last allegedly pushed/uploaded: $lastpush_hash
1570 $later_warning_msg
1571 END
1572             $hash = $lastpush_hash;
1573         } else {
1574             fail "git head (".lrref()."=$lastpush_hash) is not a ".
1575                 "descendant of archive's .dsc hash ($dsc_hash)";
1576         }
1577     } elsif ($dsc) {
1578         $hash = generate_commit_from_dsc();
1579     } elsif ($lastpush_hash) {
1580         # only in git, not in the archive yet
1581         $hash = $lastpush_hash;
1582         print STDERR <<END or die $!;
1583
1584 Package not found in the archive, but has allegedly been pushed using dgit.
1585 $later_warning_msg
1586 END
1587     } else {
1588         printdebug "nothing found!\n";
1589         if (defined $skew_warning_vsn) {
1590             print STDERR <<END or die $!;
1591
1592 Warning: relevant archive skew detected.
1593 Archive allegedly contains $skew_warning_vsn
1594 But we were not able to obtain any version from the archive or git.
1595
1596 END
1597         }
1598         return 0;
1599     }
1600     printdebug "current hash=$hash\n";
1601     if ($lastpush_hash) {
1602         fail "not fast forward on last upload branch!".
1603             " (archive's version left in DGIT_ARCHIVE)"
1604             unless is_fast_fwd($lastpush_hash, $hash);
1605     }
1606     if (defined $skew_warning_vsn) {
1607         mkpath '.git/dgit';
1608         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1609         my $clogf = ".git/dgit/changelog.tmp";
1610         runcmd shell_cmd "exec >$clogf",
1611             @git, qw(cat-file blob), "$hash:debian/changelog";
1612         my $gotclogp = parsechangelog("-l$clogf");
1613         my $got_vsn = getfield $gotclogp, 'Version';
1614         printdebug "SKEW CHECK GOT $got_vsn\n";
1615         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1616             print STDERR <<END or die $!;
1617
1618 Warning: archive skew detected.  Using the available version:
1619 Archive allegedly contains    $skew_warning_vsn
1620 We were able to obtain only   $got_vsn
1621
1622 END
1623         }
1624     }
1625     if ($lastpush_hash ne $hash) {
1626         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1627         if (act_local()) {
1628             cmdoutput @upd_cmd;
1629         } else {
1630             dryrun_report @upd_cmd;
1631         }
1632     }
1633     return 1;
1634 }
1635
1636 sub set_local_git_config ($$) {
1637     my ($k, $v) = @_;
1638     runcmd @git, qw(config), $k, $v;
1639 }
1640
1641 sub setup_mergechangelogs (;$) {
1642     my ($always) = @_;
1643     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
1644
1645     my $driver = 'dpkg-mergechangelogs';
1646     my $cb = "merge.$driver";
1647     my $attrs = '.git/info/attributes';
1648     ensuredir '.git/info';
1649
1650     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
1651     if (!open ATTRS, "<", $attrs) {
1652         $!==ENOENT or die "$attrs: $!";
1653     } else {
1654         while (<ATTRS>) {
1655             chomp;
1656             next if m{^debian/changelog\s};
1657             print NATTRS $_, "\n" or die $!;
1658         }
1659         ATTRS->error and die $!;
1660         close ATTRS;
1661     }
1662     print NATTRS "debian/changelog merge=$driver\n" or die $!;
1663     close NATTRS;
1664
1665     set_local_git_config "$cb.name", 'debian/changelog merge driver';
1666     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
1667
1668     rename "$attrs.new", "$attrs" or die "$attrs: $!";
1669 }
1670
1671 sub clone ($) {
1672     my ($dstdir) = @_;
1673     canonicalise_suite();
1674     badusage "dry run makes no sense with clone" unless act_local();
1675     my $hasgit = check_for_git();
1676     mkdir $dstdir or die "$dstdir $!";
1677     changedir $dstdir;
1678     runcmd @git, qw(init -q);
1679     my $giturl = access_giturl(1);
1680     if (defined $giturl) {
1681         set_local_git_config "remote.$remotename.fetch", fetchspec();
1682         open H, "> .git/HEAD" or die $!;
1683         print H "ref: ".lref()."\n" or die $!;
1684         close H or die $!;
1685         runcmd @git, qw(remote add), 'origin', $giturl;
1686     }
1687     if ($hasgit) {
1688         progress "fetching existing git history";
1689         git_fetch_us();
1690         runcmd_ordryrun_local @git, qw(fetch origin);
1691     } else {
1692         progress "starting new git history";
1693     }
1694     fetch_from_archive() or no_such_package;
1695     my $vcsgiturl = $dsc->{'Vcs-Git'};
1696     if (length $vcsgiturl) {
1697         $vcsgiturl =~ s/\s+-b\s+\S+//g;
1698         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1699     }
1700     setup_mergechangelogs();
1701     runcmd @git, qw(reset --hard), lrref();
1702     printdone "ready for work in $dstdir";
1703 }
1704
1705 sub fetch () {
1706     if (check_for_git()) {
1707         git_fetch_us();
1708     }
1709     fetch_from_archive() or no_such_package();
1710     printdone "fetched into ".lrref();
1711 }
1712
1713 sub pull () {
1714     fetch();
1715     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1716         lrref();
1717     printdone "fetched to ".lrref()." and merged into HEAD";
1718 }
1719
1720 sub check_not_dirty () {
1721     return if $ignoredirty;
1722     my @cmd = (@git, qw(diff --quiet HEAD));
1723     debugcmd "+",@cmd;
1724     $!=0; $?=0; system @cmd;
1725     return if !$! && !$?;
1726     if (!$! && $?==256) {
1727         fail "working tree is dirty (does not match HEAD)";
1728     } else {
1729         failedcmd @cmd;
1730     }
1731 }
1732
1733 sub commit_admin ($) {
1734     my ($m) = @_;
1735     progress "$m";
1736     runcmd_ordryrun_local @git, qw(commit -m), $m;
1737 }
1738
1739 sub commit_quilty_patch () {
1740     my $output = cmdoutput @git, qw(status --porcelain);
1741     my %adds;
1742     foreach my $l (split /\n/, $output) {
1743         next unless $l =~ m/\S/;
1744         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1745             $adds{$1}++;
1746         }
1747     }
1748     delete $adds{'.pc'}; # if there wasn't one before, don't add it
1749     if (!%adds) {
1750         progress "nothing quilty to commit, ok.";
1751         return;
1752     }
1753     runcmd_ordryrun_local @git, qw(add), sort keys %adds;
1754     commit_admin "Commit Debian 3.0 (quilt) metadata";
1755 }
1756
1757 sub get_source_format () {
1758     if (!open F, "debian/source/format") {
1759         die $! unless $!==&ENOENT;
1760         return '';
1761     }
1762     $_ = <F>;
1763     F->error and die $!;
1764     chomp;
1765     return $_;
1766 }
1767
1768 sub madformat ($) {
1769     my ($format) = @_;
1770     return 0 unless $format eq '3.0 (quilt)';
1771     if ($quilt_mode eq 'nocheck') {
1772         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1773         return 0;
1774     }
1775     progress "Format \`$format', checking/updating patch stack";
1776     return 1;
1777 }
1778
1779 sub push_parse_changelog ($) {
1780     my ($clogpfn) = @_;
1781
1782     my $clogp = Dpkg::Control::Hash->new();
1783     $clogp->load($clogpfn) or die;
1784
1785     $package = getfield $clogp, 'Source';
1786     my $cversion = getfield $clogp, 'Version';
1787     my $tag = debiantag($cversion, access_basedistro);
1788     runcmd @git, qw(check-ref-format), $tag;
1789
1790     my $dscfn = dscfn($cversion);
1791
1792     return ($clogp, $cversion, $tag, $dscfn);
1793 }
1794
1795 sub push_parse_dsc ($$$) {
1796     my ($dscfn,$dscfnwhat, $cversion) = @_;
1797     $dsc = parsecontrol($dscfn,$dscfnwhat);
1798     my $dversion = getfield $dsc, 'Version';
1799     my $dscpackage = getfield $dsc, 'Source';
1800     ($dscpackage eq $package && $dversion eq $cversion) or
1801         fail "$dscfn is for $dscpackage $dversion".
1802             " but debian/changelog is for $package $cversion";
1803 }
1804
1805 sub push_mktag ($$$$$$$) {
1806     my ($head,$clogp,$tag,
1807         $dscfn,
1808         $changesfile,$changesfilewhat,
1809         $tfn) = @_;
1810
1811     $dsc->{$ourdscfield[0]} = $head;
1812     $dsc->save("$dscfn.tmp") or die $!;
1813
1814     my $changes = parsecontrol($changesfile,$changesfilewhat);
1815     foreach my $field (qw(Source Distribution Version)) {
1816         $changes->{$field} eq $clogp->{$field} or
1817             fail "changes field $field \`$changes->{$field}'".
1818                 " does not match changelog \`$clogp->{$field}'";
1819     }
1820
1821     my $cversion = getfield $clogp, 'Version';
1822     my $clogsuite = getfield $clogp, 'Distribution';
1823
1824     # We make the git tag by hand because (a) that makes it easier
1825     # to control the "tagger" (b) we can do remote signing
1826     my $authline = clogp_authline $clogp;
1827     my $delibs = join(" ", "",@deliberatelies);
1828     my $declaredistro = access_basedistro();
1829     open TO, '>', $tfn->('.tmp') or die $!;
1830     print TO <<END or die $!;
1831 object $head
1832 type commit
1833 tag $tag
1834 tagger $authline
1835
1836 $package release $cversion for $clogsuite ($csuite) [dgit]
1837 [dgit distro=$declaredistro$delibs]
1838 END
1839     foreach my $ref (sort keys %previously) {
1840                     print TO <<END or die $!;
1841 [dgit previously:$ref=$previously{$ref}]
1842 END
1843     }
1844
1845     close TO or die $!;
1846
1847     my $tagobjfn = $tfn->('.tmp');
1848     if ($sign) {
1849         if (!defined $keyid) {
1850             $keyid = access_cfg('keyid','RETURN-UNDEF');
1851         }
1852         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1853         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1854         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1855         push @sign_cmd, $tfn->('.tmp');
1856         runcmd_ordryrun @sign_cmd;
1857         if (act_scary()) {
1858             $tagobjfn = $tfn->('.signed.tmp');
1859             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1860                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1861         }
1862     }
1863
1864     return ($tagobjfn);
1865 }
1866
1867 sub sign_changes ($) {
1868     my ($changesfile) = @_;
1869     if ($sign) {
1870         my @debsign_cmd = @debsign;
1871         push @debsign_cmd, "-k$keyid" if defined $keyid;
1872         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1873         push @debsign_cmd, $changesfile;
1874         runcmd_ordryrun @debsign_cmd;
1875     }
1876 }
1877
1878 sub dopush ($) {
1879     my ($forceflag) = @_;
1880     printdebug "actually entering push\n";
1881     supplementary_message(<<'END');
1882 Push failed, while preparing your push.
1883 You can retry the push, after fixing the problem, if you like.
1884 END
1885     prep_ud();
1886
1887     access_giturl(); # check that success is vaguely likely
1888
1889     my $clogpfn = ".git/dgit/changelog.822.tmp";
1890     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1891
1892     responder_send_file('parsed-changelog', $clogpfn);
1893
1894     my ($clogp, $cversion, $tag, $dscfn) =
1895         push_parse_changelog("$clogpfn");
1896
1897     my $dscpath = "$buildproductsdir/$dscfn";
1898     stat_exists $dscpath or
1899         fail "looked for .dsc $dscfn, but $!;".
1900             " maybe you forgot to build";
1901
1902     responder_send_file('dsc', $dscpath);
1903
1904     push_parse_dsc($dscpath, $dscfn, $cversion);
1905
1906     my $format = getfield $dsc, 'Format';
1907     printdebug "format $format\n";
1908     if (madformat($format)) {
1909         commit_quilty_patch();
1910     }
1911     check_not_dirty();
1912     changedir $ud;
1913     progress "checking that $dscfn corresponds to HEAD";
1914     runcmd qw(dpkg-source -x --),
1915         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1916     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1917     check_for_vendor_patches() if madformat($dsc->{format});
1918     changedir '../../../..';
1919     my $diffopt = $debuglevel>0 ? '--exit-code' : '--quiet';
1920     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1921     debugcmd "+",@diffcmd;
1922     $!=0; $?=0;
1923     my $r = system @diffcmd;
1924     if ($r) {
1925         if ($r==256) {
1926             fail "$dscfn specifies a different tree to your HEAD commit;".
1927                 " perhaps you forgot to build".
1928                 ($diffopt eq '--exit-code' ? "" :
1929                  " (run with -D to see full diff output)");
1930         } else {
1931             failedcmd @diffcmd;
1932         }
1933     }
1934     my $head = git_rev_parse('HEAD');
1935     if (!$changesfile) {
1936         my $multi = "$buildproductsdir/".
1937             "${package}_".(stripepoch $cversion)."_multi.changes";
1938         if (stat_exists "$multi") {
1939             $changesfile = $multi;
1940         } else {
1941             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
1942             my @cs = glob "$buildproductsdir/$pat";
1943             fail "failed to find unique changes file".
1944                 " (looked for $pat in $buildproductsdir, or $multi);".
1945                 " perhaps you need to use dgit -C"
1946                 unless @cs==1;
1947             ($changesfile) = @cs;
1948         }
1949     } else {
1950         $changesfile = "$buildproductsdir/$changesfile";
1951     }
1952
1953     responder_send_file('changes',$changesfile);
1954     responder_send_command("param head $head");
1955     responder_send_command("param csuite $csuite");
1956
1957     if (deliberately_not_fast_forward) {
1958         git_for_each_ref(lrfetchrefs, sub {
1959             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
1960             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
1961             responder_send_command("previously $rrefname=$objid");
1962             $previously{$rrefname} = $objid;
1963         });
1964     }
1965
1966     my $tfn = sub { ".git/dgit/tag$_[0]"; };
1967     my $tagobjfn;
1968
1969     supplementary_message(<<'END');
1970 Push failed, while signing the tag.
1971 You can retry the push, after fixing the problem, if you like.
1972 END
1973     # If we manage to sign but fail to record it anywhere, it's fine.
1974     if ($we_are_responder) {
1975         $tagobjfn = $tfn->('.signed.tmp');
1976         responder_receive_files('signed-tag', $tagobjfn);
1977     } else {
1978         $tagobjfn =
1979             push_mktag($head,$clogp,$tag,
1980                        $dscpath,
1981                        $changesfile,$changesfile,
1982                        $tfn);
1983     }
1984     supplementary_message(<<'END');
1985 Push failed, *after* signing the tag.
1986 If you want to try again, you should use a new version number.
1987 END
1988
1989     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
1990     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
1991     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
1992
1993     supplementary_message(<<'END');
1994 Push failed, while updating the remote git repository - see messages above.
1995 If you want to try again, you should use a new version number.
1996 END
1997     if (!check_for_git()) {
1998         create_remote_git_repo();
1999     }
2000     runcmd_ordryrun @git, qw(push),access_giturl(),
2001         $forceflag."HEAD:".rrref(), $forceflag."refs/tags/$tag";
2002     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
2003
2004     supplementary_message(<<'END');
2005 Push failed, after updating the remote git repository.
2006 If you want to try again, you must use a new version number.
2007 END
2008     if ($we_are_responder) {
2009         my $dryrunsuffix = act_local() ? "" : ".tmp";
2010         responder_receive_files('signed-dsc-changes',
2011                                 "$dscpath$dryrunsuffix",
2012                                 "$changesfile$dryrunsuffix");
2013     } else {
2014         if (act_local()) {
2015             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
2016         } else {
2017             progress "[new .dsc left in $dscpath.tmp]";
2018         }
2019         sign_changes $changesfile;
2020     }
2021
2022     supplementary_message(<<'END');
2023 Push failed, while uploading package(s) to the archive server.
2024 You can retry the upload of exactly these same files with dput of:
2025   $changesfile
2026 If that .changes file is broken, you will need to use a new version
2027 number for your next attempt at the upload.
2028 END
2029     my $host = access_cfg('upload-host','RETURN-UNDEF');
2030     my @hostarg = defined($host) ? ($host,) : ();
2031     runcmd_ordryrun @dput, @hostarg, $changesfile;
2032     printdone "pushed and uploaded $cversion";
2033
2034     supplementary_message('');
2035     responder_send_command("complete");
2036 }
2037
2038 sub cmd_clone {
2039     parseopts();
2040     notpushing();
2041     my $dstdir;
2042     badusage "-p is not allowed with clone; specify as argument instead"
2043         if defined $package;
2044     if (@ARGV==1) {
2045         ($package) = @ARGV;
2046     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
2047         ($package,$isuite) = @ARGV;
2048     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
2049         ($package,$dstdir) = @ARGV;
2050     } elsif (@ARGV==3) {
2051         ($package,$isuite,$dstdir) = @ARGV;
2052     } else {
2053         badusage "incorrect arguments to dgit clone";
2054     }
2055     $dstdir ||= "$package";
2056
2057     if (stat_exists $dstdir) {
2058         fail "$dstdir already exists";
2059     }
2060
2061     my $cwd_remove;
2062     if ($rmonerror && !$dryrun_level) {
2063         $cwd_remove= getcwd();
2064         unshift @end, sub {
2065             return unless defined $cwd_remove;
2066             if (!chdir "$cwd_remove") {
2067                 return if $!==&ENOENT;
2068                 die "chdir $cwd_remove: $!";
2069             }
2070             rmtree($dstdir) or die "remove $dstdir: $!\n";
2071         };
2072     }
2073
2074     clone($dstdir);
2075     $cwd_remove = undef;
2076 }
2077
2078 sub branchsuite () {
2079     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
2080     if ($branch =~ m#$lbranch_re#o) {
2081         return $1;
2082     } else {
2083         return undef;
2084     }
2085 }
2086
2087 sub fetchpullargs () {
2088     notpushing();
2089     if (!defined $package) {
2090         my $sourcep = parsecontrol('debian/control','debian/control');
2091         $package = getfield $sourcep, 'Source';
2092     }
2093     if (@ARGV==0) {
2094 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
2095         if (!$isuite) {
2096             my $clogp = parsechangelog();
2097             $isuite = getfield $clogp, 'Distribution';
2098         }
2099         canonicalise_suite();
2100         progress "fetching from suite $csuite";
2101     } elsif (@ARGV==1) {
2102         ($isuite) = @ARGV;
2103         canonicalise_suite();
2104     } else {
2105         badusage "incorrect arguments to dgit fetch or dgit pull";
2106     }
2107 }
2108
2109 sub cmd_fetch {
2110     parseopts();
2111     fetchpullargs();
2112     fetch();
2113 }
2114
2115 sub cmd_pull {
2116     parseopts();
2117     fetchpullargs();
2118     pull();
2119 }
2120
2121 sub cmd_push {
2122     parseopts();
2123     pushing();
2124     badusage "-p is not allowed with dgit push" if defined $package;
2125     check_not_dirty();
2126     my $clogp = parsechangelog();
2127     $package = getfield $clogp, 'Source';
2128     my $specsuite;
2129     if (@ARGV==0) {
2130     } elsif (@ARGV==1) {
2131         ($specsuite) = (@ARGV);
2132     } else {
2133         badusage "incorrect arguments to dgit push";
2134     }
2135     $isuite = getfield $clogp, 'Distribution';
2136     if ($new_package) {
2137         local ($package) = $existing_package; # this is a hack
2138         canonicalise_suite();
2139     } else {
2140         canonicalise_suite();
2141     }
2142     if (defined $specsuite &&
2143         $specsuite ne $isuite &&
2144         $specsuite ne $csuite) {
2145             fail "dgit push: changelog specifies $isuite ($csuite)".
2146                 " but command line specifies $specsuite";
2147     }
2148     supplementary_message(<<'END');
2149 Push failed, while checking state of the archive.
2150 You can retry the push, after fixing the problem, if you like.
2151 END
2152     if (check_for_git()) {
2153         git_fetch_us();
2154     }
2155     my $forceflag = '';
2156     if (fetch_from_archive()) {
2157         if (is_fast_fwd(lrref(), 'HEAD')) {
2158             # ok
2159         } elsif (deliberately_not_fast_forward) {
2160             $forceflag = '+';
2161         } else {
2162             fail "dgit push: HEAD is not a descendant".
2163                 " of the archive's version.\n".
2164                 "dgit: To overwrite its contents,".
2165                 " use git merge -s ours ".lrref().".\n".
2166                 "dgit: To rewind history, if permitted by the archive,".
2167                 " use --deliberately-not-fast-forward";
2168         }
2169     } else {
2170         $new_package or
2171             fail "package appears to be new in this suite;".
2172                 " if this is intentional, use --new";
2173     }
2174     dopush($forceflag);
2175 }
2176
2177 #---------- remote commands' implementation ----------
2178
2179 sub cmd_remote_push_build_host {
2180     my ($nrargs) = shift @ARGV;
2181     my (@rargs) = @ARGV[0..$nrargs-1];
2182     @ARGV = @ARGV[$nrargs..$#ARGV];
2183     die unless @rargs;
2184     my ($dir,$vsnwant) = @rargs;
2185     # vsnwant is a comma-separated list; we report which we have
2186     # chosen in our ready response (so other end can tell if they
2187     # offered several)
2188     $debugprefix = ' ';
2189     $we_are_responder = 1;
2190     $us .= " (build host)";
2191
2192     pushing();
2193
2194     open PI, "<&STDIN" or die $!;
2195     open STDIN, "/dev/null" or die $!;
2196     open PO, ">&STDOUT" or die $!;
2197     autoflush PO 1;
2198     open STDOUT, ">&STDERR" or die $!;
2199     autoflush STDOUT 1;
2200
2201     $vsnwant //= 1;
2202     ($protovsn) = grep {
2203         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
2204     } @rpushprotovsn_support;
2205
2206     fail "build host has dgit rpush protocol versions ".
2207         (join ",", @rpushprotovsn_support).
2208         " but invocation host has $vsnwant"
2209         unless defined $protovsn;
2210
2211     responder_send_command("dgit-remote-push-ready $protovsn");
2212
2213     changedir $dir;
2214     &cmd_push;
2215 }
2216
2217 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
2218 # ... for compatibility with proto vsn.1 dgit (just so that user gets
2219 #     a good error message)
2220
2221 our $i_tmp;
2222
2223 sub i_cleanup {
2224     local ($@, $?);
2225     my $report = i_child_report();
2226     if (defined $report) {
2227         printdebug "($report)\n";
2228     } elsif ($i_child_pid) {
2229         printdebug "(killing build host child $i_child_pid)\n";
2230         kill 15, $i_child_pid;
2231     }
2232     if (defined $i_tmp && !defined $initiator_tempdir) {
2233         changedir "/";
2234         eval { rmtree $i_tmp; };
2235     }
2236 }
2237
2238 END { i_cleanup(); }
2239
2240 sub i_method {
2241     my ($base,$selector,@args) = @_;
2242     $selector =~ s/\-/_/g;
2243     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
2244 }
2245
2246 sub cmd_rpush {
2247     pushing();
2248     my $host = nextarg;
2249     my $dir;
2250     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
2251         $host = $1;
2252         $dir = $'; #';
2253     } else {
2254         $dir = nextarg;
2255     }
2256     $dir =~ s{^-}{./-};
2257     my @rargs = ($dir);
2258     push @rargs, join ",", @rpushprotovsn_support;
2259     my @rdgit;
2260     push @rdgit, @dgit;
2261     push @rdgit, @ropts;
2262     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
2263     push @rdgit, @ARGV;
2264     my @cmd = (@ssh, $host, shellquote @rdgit);
2265     debugcmd "+",@cmd;
2266
2267     if (defined $initiator_tempdir) {
2268         rmtree $initiator_tempdir;
2269         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
2270         $i_tmp = $initiator_tempdir;
2271     } else {
2272         $i_tmp = tempdir();
2273     }
2274     $i_child_pid = open2(\*RO, \*RI, @cmd);
2275     changedir $i_tmp;
2276     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
2277     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
2278     $supplementary_message = '' unless $protovsn >= 3;
2279     for (;;) {
2280         my ($icmd,$iargs) = initiator_expect {
2281             m/^(\S+)(?: (.*))?$/;
2282             ($1,$2);
2283         };
2284         i_method "i_resp", $icmd, $iargs;
2285     }
2286 }
2287
2288 sub i_resp_progress ($) {
2289     my ($rhs) = @_;
2290     my $msg = protocol_read_bytes \*RO, $rhs;
2291     progress $msg;
2292 }
2293
2294 sub i_resp_supplementary_message ($) {
2295     my ($rhs) = @_;
2296     $supplementary_message = protocol_read_bytes \*RO, $rhs;
2297 }
2298
2299 sub i_resp_complete {
2300     my $pid = $i_child_pid;
2301     $i_child_pid = undef; # prevents killing some other process with same pid
2302     printdebug "waiting for build host child $pid...\n";
2303     my $got = waitpid $pid, 0;
2304     die $! unless $got == $pid;
2305     die "build host child failed $?" if $?;
2306
2307     i_cleanup();
2308     printdebug "all done\n";
2309     exit 0;
2310 }
2311
2312 sub i_resp_file ($) {
2313     my ($keyword) = @_;
2314     my $localname = i_method "i_localname", $keyword;
2315     my $localpath = "$i_tmp/$localname";
2316     stat_exists $localpath and
2317         badproto \*RO, "file $keyword ($localpath) twice";
2318     protocol_receive_file \*RO, $localpath;
2319     i_method "i_file", $keyword;
2320 }
2321
2322 our %i_param;
2323
2324 sub i_resp_param ($) {
2325     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
2326     $i_param{$1} = $2;
2327 }
2328
2329 sub i_resp_previously ($) {
2330     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
2331         or badproto \*RO, "bad previously spec";
2332     my $r = system qw(git check-ref-format), $1;
2333     die "bad previously ref spec ($r)" if $r;
2334     $previously{$1} = $2;
2335 }
2336
2337 our %i_wanted;
2338
2339 sub i_resp_want ($) {
2340     my ($keyword) = @_;
2341     die "$keyword ?" if $i_wanted{$keyword}++;
2342     my @localpaths = i_method "i_want", $keyword;
2343     printdebug "[[  $keyword @localpaths\n";
2344     foreach my $localpath (@localpaths) {
2345         protocol_send_file \*RI, $localpath;
2346     }
2347     print RI "files-end\n" or die $!;
2348 }
2349
2350 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
2351
2352 sub i_localname_parsed_changelog {
2353     return "remote-changelog.822";
2354 }
2355 sub i_file_parsed_changelog {
2356     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
2357         push_parse_changelog "$i_tmp/remote-changelog.822";
2358     die if $i_dscfn =~ m#/|^\W#;
2359 }
2360
2361 sub i_localname_dsc {
2362     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2363     return $i_dscfn;
2364 }
2365 sub i_file_dsc { }
2366
2367 sub i_localname_changes {
2368     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2369     $i_changesfn = $i_dscfn;
2370     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
2371     return $i_changesfn;
2372 }
2373 sub i_file_changes { }
2374
2375 sub i_want_signed_tag {
2376     printdebug Dumper(\%i_param, $i_dscfn);
2377     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
2378         && defined $i_param{'csuite'}
2379         or badproto \*RO, "premature desire for signed-tag";
2380     my $head = $i_param{'head'};
2381     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
2382
2383     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
2384     $csuite = $&;
2385     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
2386
2387     my $tagobjfn =
2388         push_mktag $head, $i_clogp, $i_tag,
2389             $i_dscfn,
2390             $i_changesfn, 'remote changes',
2391             sub { "tag$_[0]"; };
2392
2393     return $tagobjfn;
2394 }
2395
2396 sub i_want_signed_dsc_changes {
2397     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
2398     sign_changes $i_changesfn;
2399     return ($i_dscfn, $i_changesfn);
2400 }
2401
2402 #---------- building etc. ----------
2403
2404 our $version;
2405 our $sourcechanges;
2406 our $dscfn;
2407
2408 #----- `3.0 (quilt)' handling -----
2409
2410 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
2411
2412 sub quiltify_dpkg_commit ($$$;$) {
2413     my ($patchname,$author,$msg, $xinfo) = @_;
2414     $xinfo //= '';
2415
2416     mkpath '.git/dgit';
2417     my $descfn = ".git/dgit/quilt-description.tmp";
2418     open O, '>', $descfn or die "$descfn: $!";
2419     $msg =~ s/\s+$//g;
2420     $msg =~ s/\n/\n /g;
2421     $msg =~ s/^\s+$/ ./mg;
2422     print O <<END or die $!;
2423 Description: $msg
2424 Author: $author
2425 $xinfo
2426 ---
2427
2428 END
2429     close O or die $!;
2430
2431     {
2432         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
2433         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
2434         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
2435         runcmd_ordryrun_local @dpkgsource, qw(--commit .), $patchname;
2436     }
2437 }
2438
2439 sub quiltify_trees_differ ($$) {
2440     my ($x,$y) = @_;
2441     # returns 1 iff the two tree objects differ other than in debian/
2442     local $/=undef;
2443     my @cmd = (@git, qw(diff-tree --name-only -z), $x, $y);
2444     my $diffs= cmdoutput @cmd;
2445     foreach my $f (split /\0/, $diffs) {
2446         next if $f eq 'debian';
2447         return 1;
2448     }
2449     return 0;
2450 }
2451
2452 sub quiltify_tree_sentinelfiles ($) {
2453     # lists the `sentinel' files present in the tree
2454     my ($x) = @_;
2455     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
2456         qw(-- debian/rules debian/control);
2457     $r =~ s/\n/,/g;
2458     return $r;
2459 }
2460
2461 sub quiltify ($$) {
2462     my ($clogp,$target) = @_;
2463
2464     # Quilt patchification algorithm
2465     #
2466     # We search backwards through the history of the main tree's HEAD
2467     # (T) looking for a start commit S whose tree object is identical
2468     # to to the patch tip tree (ie the tree corresponding to the
2469     # current dpkg-committed patch series).  For these purposes
2470     # `identical' disregards anything in debian/ - this wrinkle is
2471     # necessary because dpkg-source treates debian/ specially.
2472     #
2473     # We can only traverse edges where at most one of the ancestors'
2474     # trees differs (in changes outside in debian/).  And we cannot
2475     # handle edges which change .pc/ or debian/patches.  To avoid
2476     # going down a rathole we avoid traversing edges which introduce
2477     # debian/rules or debian/control.  And we set a limit on the
2478     # number of edges we are willing to look at.
2479     #
2480     # If we succeed, we walk forwards again.  For each traversed edge
2481     # PC (with P parent, C child) (starting with P=S and ending with
2482     # C=T) to we do this:
2483     #  - git checkout C
2484     #  - dpkg-source --commit with a patch name and message derived from C
2485     # After traversing PT, we git commit the changes which
2486     # should be contained within debian/patches.
2487
2488     changedir '../fake';
2489     mktree_in_ud_here();
2490     rmtree '.pc';
2491     runcmd @git, 'add', '.';
2492     my $oldtiptree=git_write_tree();
2493     changedir '../work';
2494
2495     # The search for the path S..T is breadth-first.  We maintain a
2496     # todo list containing search nodes.  A search node identifies a
2497     # commit, and looks something like this:
2498     #  $p = {
2499     #      Commit => $git_commit_id,
2500     #      Child => $c,                          # or undef if P=T
2501     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
2502     #      Nontrivial => true iff $p..$c has relevant changes
2503     #  };
2504
2505     my @todo;
2506     my @nots;
2507     my $sref_S;
2508     my $max_work=100;
2509     my %considered; # saves being exponential on some weird graphs
2510
2511     my $t_sentinels = quiltify_tree_sentinelfiles $target;
2512
2513     my $not = sub {
2514         my ($search,$whynot) = @_;
2515         printdebug " search NOT $search->{Commit} $whynot\n";
2516         $search->{Whynot} = $whynot;
2517         push @nots, $search;
2518         no warnings qw(exiting);
2519         next;
2520     };
2521
2522     push @todo, {
2523         Commit => $target,
2524     };
2525
2526     while (@todo) {
2527         my $c = shift @todo;
2528         next if $considered{$c->{Commit}}++;
2529
2530         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
2531
2532         printdebug "quiltify investigate $c->{Commit}\n";
2533
2534         # are we done?
2535         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
2536             printdebug " search finished hooray!\n";
2537             $sref_S = $c;
2538             last;
2539         }
2540
2541         if ($quilt_mode eq 'nofix') {
2542             fail "quilt fixup required but quilt mode is \`nofix'\n".
2543                 "HEAD commit $c->{Commit} differs from tree implied by ".
2544                 " debian/patches (tree object $oldtiptree)";
2545         }
2546         if ($quilt_mode eq 'smash') {
2547             printdebug " search quitting smash\n";
2548             last;
2549         }
2550
2551         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
2552         $not->($c, "has $c_sentinels not $t_sentinels")
2553             if $c_sentinels ne $t_sentinels;
2554
2555         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
2556         $commitdata =~ m/\n\n/;
2557         $commitdata =~ $`;
2558         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
2559         @parents = map { { Commit => $_, Child => $c } } @parents;
2560
2561         $not->($c, "root commit") if !@parents;
2562
2563         foreach my $p (@parents) {
2564             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
2565         }
2566         my $ndiffers = grep { $_->{Nontrivial} } @parents;
2567         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
2568
2569         foreach my $p (@parents) {
2570             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
2571
2572             my @cmd= (@git, qw(diff-tree -r --name-only),
2573                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
2574             my $patchstackchange = cmdoutput @cmd;
2575             if (length $patchstackchange) {
2576                 $patchstackchange =~ s/\n/,/g;
2577                 $not->($p, "changed $patchstackchange");
2578             }
2579
2580             printdebug " search queue P=$p->{Commit} ",
2581                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
2582             push @todo, $p;
2583         }
2584     }
2585
2586     if (!$sref_S) {
2587         printdebug "quiltify want to smash\n";
2588
2589         my $abbrev = sub {
2590             my $x = $_[0]{Commit};
2591             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
2592             return $;
2593         };
2594         my $reportnot = sub {
2595             my ($notp) = @_;
2596             my $s = $abbrev->($notp);
2597             my $c = $notp->{Child};
2598             $s .= "..".$abbrev->($c) if $c;
2599             $s .= ": ".$notp->{Whynot};
2600             return $s;
2601         };
2602         if ($quilt_mode eq 'linear') {
2603             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
2604             foreach my $notp (@nots) {
2605                 print STDERR "$us:  ", $reportnot->($notp), "\n";
2606             }
2607             fail "quilt fixup naive history linearisation failed.\n".
2608  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
2609         } elsif ($quilt_mode eq 'smash') {
2610         } elsif ($quilt_mode eq 'auto') {
2611             progress "quilt fixup cannot be linear, smashing...";
2612         } else {
2613             die "$quilt_mode ?";
2614         }
2615
2616         my $time = time;
2617         my $ncommits = 3;
2618         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
2619
2620         quiltify_dpkg_commit "auto-$version-$target-$time",
2621             (getfield $clogp, 'Maintainer'),
2622             "Automatically generated patch ($clogp->{Version})\n".
2623             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
2624         return;
2625     }
2626
2627     progress "quiltify linearisation planning successful, executing...";
2628
2629     for (my $p = $sref_S;
2630          my $c = $p->{Child};
2631          $p = $p->{Child}) {
2632         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
2633         next unless $p->{Nontrivial};
2634
2635         my $cc = $c->{Commit};
2636
2637         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
2638         $commitdata =~ m/\n\n/ or die "$c ?";
2639         $commitdata = $`;
2640         my $msg = $'; #';
2641         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
2642         my $author = $1;
2643
2644         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
2645
2646         my $title = $1;
2647         my $patchname = $title;
2648         $patchname =~ s/[.:]$//;
2649         $patchname =~ y/ A-Z/-a-z/;
2650         $patchname =~ y/-a-z0-9_.+=~//cd;
2651         $patchname =~ s/^\W/x-$&/;
2652         $patchname = substr($patchname,0,40);
2653         my $index;
2654         for ($index='';
2655              stat "debian/patches/$patchname$index";
2656              $index++) { }
2657         $!==ENOENT or die "$patchname$index $!";
2658
2659         runcmd @git, qw(checkout -q), $cc;
2660
2661         # We use the tip's changelog so that dpkg-source doesn't
2662         # produce complaining messages from dpkg-parsechangelog.  None
2663         # of the information dpkg-source gets from the changelog is
2664         # actually relevant - it gets put into the original message
2665         # which dpkg-source provides our stunt editor, and then
2666         # overwritten.
2667         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
2668
2669         quiltify_dpkg_commit "$patchname$index", $author, $msg,
2670             "X-Dgit-Generated: $clogp->{Version} $cc\n";
2671
2672         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
2673     }
2674
2675     runcmd @git, qw(checkout -q master);
2676 }
2677
2678 sub build_maybe_quilt_fixup () {
2679     my $format=get_source_format;
2680     return unless madformat $format;
2681     # sigh
2682
2683     check_for_vendor_patches();
2684
2685     # Our objective is:
2686     #  - honour any existing .pc in case it has any strangeness
2687     #  - determine the git commit corresponding to the tip of
2688     #    the patch stack (if there is one)
2689     #  - if there is such a git commit, convert each subsequent
2690     #    git commit into a quilt patch with dpkg-source --commit
2691     #  - otherwise convert all the differences in the tree into
2692     #    a single git commit
2693     #
2694     # To do this we:
2695
2696     # Our git tree doesn't necessarily contain .pc.  (Some versions of
2697     # dgit would include the .pc in the git tree.)  If there isn't
2698     # one, we need to generate one by unpacking the patches that we
2699     # have.
2700     #
2701     # We first look for a .pc in the git tree.  If there is one, we
2702     # will use it.  (This is not the normal case.)
2703     #
2704     # Otherwise need to regenerate .pc so that dpkg-source --commit
2705     # can work.  We do this as follows:
2706     #     1. Collect all relevant .orig from parent directory
2707     #     2. Generate a debian.tar.gz out of
2708     #         debian/{patches,rules,source/format}
2709     #     3. Generate a fake .dsc containing just these fields:
2710     #          Format Source Version Files
2711     #     4. Extract the fake .dsc
2712     #        Now the fake .dsc has a .pc directory.
2713     # (In fact we do this in every case, because in future we will
2714     # want to search for a good base commit for generating patches.)
2715     #
2716     # Then we can actually do the dpkg-source --commit
2717     #     1. Make a new working tree with the same object
2718     #        store as our main tree and check out the main
2719     #        tree's HEAD.
2720     #     2. Copy .pc from the fake's extraction, if necessary
2721     #     3. Run dpkg-source --commit
2722     #     4. If the result has changes to debian/, then
2723     #          - git-add them them
2724     #          - git-add .pc if we had a .pc in-tree
2725     #          - git-commit
2726     #     5. If we had a .pc in-tree, delete it, and git-commit
2727     #     6. Back in the main tree, fast forward to the new HEAD
2728
2729     my $clogp = parsechangelog();
2730     my $headref = git_rev_parse('HEAD');
2731
2732     prep_ud();
2733     changedir $ud;
2734
2735     my $upstreamversion=$version;
2736     $upstreamversion =~ s/-[^-]*$//;
2737
2738     my $fakeversion="$upstreamversion-~~DGITFAKE";
2739
2740     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
2741     print $fakedsc <<END or die $!;
2742 Format: 3.0 (quilt)
2743 Source: $package
2744 Version: $fakeversion
2745 Files:
2746 END
2747
2748     my $dscaddfile=sub {
2749         my ($b) = @_;
2750
2751         my $md = new Digest::MD5;
2752
2753         my $fh = new IO::File $b, '<' or die "$b $!";
2754         stat $fh or die $!;
2755         my $size = -s _;
2756
2757         $md->addfile($fh);
2758         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
2759     };
2760
2761     foreach my $f (<../../../../*>) { #/){
2762         my $b=$f; $b =~ s{.*/}{};
2763         next unless is_orig_file $b, srcfn $upstreamversion,'';
2764         link $f, $b or die "$b $!";
2765         $dscaddfile->($b);
2766     }
2767
2768     my @files=qw(debian/source/format debian/rules);
2769     if (stat_exists '../../../debian/patches') {
2770         push @files, 'debian/patches';
2771     }
2772
2773     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
2774     runcmd qw(env GZIP=-1 tar -zcf), "./$debtar", qw(-C ../../..), @files;
2775
2776     $dscaddfile->($debtar);
2777     close $fakedsc or die $!;
2778
2779     runcmd qw(sh -ec), 'exec dpkg-source --no-check -x fake.dsc >/dev/null';
2780
2781     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
2782     rename $fakexdir, "fake" or die "$fakexdir $!";
2783
2784     mkdir "work" or die $!;
2785     changedir "work";
2786     mktree_in_ud_here();
2787     runcmd @git, qw(reset --hard), $headref;
2788
2789     my $mustdeletepc=0;
2790     if (stat_exists ".pc") {
2791         -d _ or die;
2792         progress "Tree already contains .pc - will use it then delete it.";
2793         $mustdeletepc=1;
2794     } else {
2795         rename '../fake/.pc','.pc' or die $!;
2796     }
2797
2798     quiltify($clogp,$headref);
2799
2800     if (!open P, '>>', ".pc/applied-patches") {
2801         $!==&ENOENT or die $!;
2802     } else {
2803         close P;
2804     }
2805
2806     commit_quilty_patch();
2807
2808     if ($mustdeletepc) {
2809         runcmd @git, qw(rm -rqf .pc);
2810         commit_admin "Commit removal of .pc (quilt series tracking data)";
2811     }
2812
2813     changedir '../../../..';
2814     runcmd @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
2815 }
2816
2817 sub quilt_fixup_editor () {
2818     my $descfn = $ENV{$fakeeditorenv};
2819     my $editing = $ARGV[$#ARGV];
2820     open I1, '<', $descfn or die "$descfn: $!";
2821     open I2, '<', $editing or die "$editing: $!";
2822     unlink $editing or die "$editing: $!";
2823     open O, '>', $editing or die "$editing: $!";
2824     while (<I1>) { print O or die $!; } I1->error and die $!;
2825     my $copying = 0;
2826     while (<I2>) {
2827         $copying ||= m/^\-\-\- /;
2828         next unless $copying;
2829         print O or die $!;
2830     }
2831     I2->error and die $!;
2832     close O or die $1;
2833     exit 0;
2834 }
2835
2836 #----- other building -----
2837
2838 sub clean_tree () {
2839     if ($cleanmode eq 'dpkg-source') {
2840         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2841     } elsif ($cleanmode eq 'dpkg-source-d') {
2842         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
2843     } elsif ($cleanmode eq 'git') {
2844         runcmd_ordryrun_local @git, qw(clean -xdf);
2845     } elsif ($cleanmode eq 'git-ff') {
2846         runcmd_ordryrun_local @git, qw(clean -xdff);
2847     } elsif ($cleanmode eq 'check') {
2848         my $leftovers = cmdoutput @git, qw(clean -xdn);
2849         if (length $leftovers) {
2850             print STDERR $leftovers, "\n" or die $!;
2851             fail "tree contains uncommitted files and --clean=check specified";
2852         }
2853     } elsif ($cleanmode eq 'none') {
2854     } else {
2855         die "$cleanmode ?";
2856     }
2857 }
2858
2859 sub cmd_clean () {
2860     badusage "clean takes no additional arguments" if @ARGV;
2861     notpushing();
2862     clean_tree();
2863 }
2864
2865 sub build_prep () {
2866     notpushing();
2867     badusage "-p is not allowed when building" if defined $package;
2868     check_not_dirty();
2869     clean_tree();
2870     my $clogp = parsechangelog();
2871     $isuite = getfield $clogp, 'Distribution';
2872     $package = getfield $clogp, 'Source';
2873     $version = getfield $clogp, 'Version';
2874     build_maybe_quilt_fixup();
2875 }
2876
2877 sub changesopts () {
2878     my @opts =@changesopts[1..$#changesopts];
2879     if (!defined $changes_since_version) {
2880         my @vsns = archive_query('archive_query');
2881         my @quirk = access_quirk();
2882         if ($quirk[0] eq 'backports') {
2883             local $isuite = $quirk[2];
2884             local $csuite;
2885             canonicalise_suite();
2886             push @vsns, archive_query('archive_query');
2887         }
2888         if (@vsns) {
2889             @vsns = map { $_->[0] } @vsns;
2890             @vsns = sort { -version_compare($a, $b) } @vsns;
2891             $changes_since_version = $vsns[0];
2892             progress "changelog will contain changes since $vsns[0]";
2893         } else {
2894             $changes_since_version = '_';
2895             progress "package seems new, not specifying -v<version>";
2896         }
2897     }
2898     if ($changes_since_version ne '_') {
2899         unshift @opts, "-v$changes_since_version";
2900     }
2901     return @opts;
2902 }
2903
2904 sub massage_dbp_args ($) {
2905     my ($cmd) = @_;
2906     return unless $cleanmode =~ m/git|none/;
2907     debugcmd '#massaging#', @$cmd if $debuglevel>1;
2908     my @newcmd = shift @$cmd;
2909     # -nc has the side effect of specifying -b if nothing else specified
2910     push @newcmd, '-nc';
2911     # and some combinations of -S, -b, et al, are errors, rather than
2912     # later simply overriding earlier
2913     push @newcmd, '-F' unless grep { m/^-[bBASF]$/ } @$cmd;
2914     push @newcmd, @$cmd;
2915     @$cmd = @newcmd;
2916 }
2917
2918 sub cmd_build {
2919     build_prep();
2920     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts(), @ARGV);
2921     massage_dbp_args \@dbp;
2922     runcmd_ordryrun_local @dbp;
2923     printdone "build successful\n";
2924 }
2925
2926 sub cmd_git_build {
2927     build_prep();
2928     my @dbp = @dpkgbuildpackage;
2929     massage_dbp_args \@dbp;
2930     my @cmd =
2931         (qw(git-buildpackage -us -uc --git-no-sign-tags),
2932          "--git-builder=@dbp");
2933     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
2934         canonicalise_suite();
2935         push @cmd, "--git-debian-branch=".lbranch();
2936     }
2937     push @cmd, changesopts();
2938     runcmd_ordryrun_local @cmd, @ARGV;
2939     printdone "build successful\n";
2940 }
2941
2942 sub build_source {
2943     build_prep();
2944     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
2945     $dscfn = dscfn($version);
2946     if ($cleanmode eq 'dpkg-source') {
2947         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
2948             changesopts();
2949     } elsif ($cleanmode eq 'dpkg-source-d') {
2950         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S -d)),
2951             changesopts();
2952     } else {
2953         my $pwd = must_getcwd();
2954         my $leafdir = basename $pwd;
2955         changedir "..";
2956         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
2957         changedir $pwd;
2958         runcmd_ordryrun_local qw(sh -ec),
2959             'exec >$1; shift; exec "$@"','x',
2960             "../$sourcechanges",
2961             @dpkggenchanges, qw(-S), changesopts();
2962     }
2963 }
2964
2965 sub cmd_build_source {
2966     badusage "build-source takes no additional arguments" if @ARGV;
2967     build_source();
2968     printdone "source built, results in $dscfn and $sourcechanges";
2969 }
2970
2971 sub cmd_sbuild {
2972     build_source();
2973     changedir "..";
2974     my $pat = "${package}_".(stripepoch $version)."_*.changes";
2975     if (act_local()) {
2976         stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
2977         stat_exists $sourcechanges
2978             or fail "$sourcechanges (in parent directory): $!";
2979         foreach my $cf (glob $pat) {
2980             next if $cf eq $sourcechanges;
2981             unlink $cf or fail "remove $cf: $!";
2982         }
2983     }
2984     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
2985     my @changesfiles = glob $pat;
2986     @changesfiles = sort {
2987         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
2988             or $a cmp $b
2989     } @changesfiles;
2990     fail "wrong number of different changes files (@changesfiles)"
2991         unless @changesfiles;
2992     runcmd_ordryrun_local @mergechanges, @changesfiles;
2993     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
2994     if (act_local()) {
2995         stat_exists $multichanges or fail "$multichanges: $!";
2996     }
2997     printdone "build successful, results in $multichanges\n" or die $!;
2998 }
2999
3000 sub cmd_quilt_fixup {
3001     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
3002     my $clogp = parsechangelog();
3003     $version = getfield $clogp, 'Version';
3004     $package = getfield $clogp, 'Source';
3005     build_maybe_quilt_fixup();
3006 }
3007
3008 sub cmd_archive_api_query {
3009     badusage "need only 1 subpath argument" unless @ARGV==1;
3010     my ($subpath) = @ARGV;
3011     my @cmd = archive_api_query_cmd($subpath);
3012     debugcmd ">",@cmd;
3013     exec @cmd or fail "exec curl: $!\n";
3014 }
3015
3016 sub cmd_clone_dgit_repos_server {
3017     badusage "need destination argument" unless @ARGV==1;
3018     my ($destdir) = @ARGV;
3019     $package = '_dgit-repos-server';
3020     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
3021     debugcmd ">",@cmd;
3022     exec @cmd or fail "exec git clone: $!\n";
3023 }
3024
3025 sub cmd_setup_mergechangelogs {
3026     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
3027     setup_mergechangelogs(1);
3028 }
3029
3030 #---------- argument parsing and main program ----------
3031
3032 sub cmd_version {
3033     print "dgit version $our_version\n" or die $!;
3034     exit 0;
3035 }
3036
3037 sub parseopts () {
3038     my $om;
3039
3040     if (defined $ENV{'DGIT_SSH'}) {
3041         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
3042     } elsif (defined $ENV{'GIT_SSH'}) {
3043         @ssh = ($ENV{'GIT_SSH'});
3044     }
3045
3046     while (@ARGV) {
3047         last unless $ARGV[0] =~ m/^-/;
3048         $_ = shift @ARGV;
3049         last if m/^--?$/;
3050         if (m/^--/) {
3051             if (m/^--dry-run$/) {
3052                 push @ropts, $_;
3053                 $dryrun_level=2;
3054             } elsif (m/^--damp-run$/) {
3055                 push @ropts, $_;
3056                 $dryrun_level=1;
3057             } elsif (m/^--no-sign$/) {
3058                 push @ropts, $_;
3059                 $sign=0;
3060             } elsif (m/^--help$/) {
3061                 cmd_help();
3062             } elsif (m/^--version$/) {
3063                 cmd_version();
3064             } elsif (m/^--new$/) {
3065                 push @ropts, $_;
3066                 $new_package=1;
3067             } elsif (m/^--since-version=([^_]+|_)$/) {
3068                 push @ropts, $_;
3069                 $changes_since_version = $1;
3070             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
3071                      ($om = $opts_opt_map{$1}) &&
3072                      length $om->[0]) {
3073                 push @ropts, $_;
3074                 $om->[0] = $2;
3075             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
3076                      !$opts_opt_cmdonly{$1} &&
3077                      ($om = $opts_opt_map{$1})) {
3078                 push @ropts, $_;
3079                 push @$om, $2;
3080             } elsif (m/^--existing-package=(.*)/s) {
3081                 push @ropts, $_;
3082                 $existing_package = $1;
3083             } elsif (m/^--initiator-tempdir=(.*)/s) {
3084                 $initiator_tempdir = $1;
3085                 $initiator_tempdir =~ m#^/# or
3086                     badusage "--initiator-tempdir must be used specify an".
3087                         " absolute, not relative, directory."
3088             } elsif (m/^--distro=(.*)/s) {
3089                 push @ropts, $_;
3090                 $idistro = $1;
3091             } elsif (m/^--build-products-dir=(.*)/s) {
3092                 push @ropts, $_;
3093                 $buildproductsdir = $1;
3094             } elsif (m/^--clean=(dpkg-source(?:-d)?|git|git-ff|check|none)$/s) {
3095                 push @ropts, $_;
3096                 $cleanmode = $1;
3097             } elsif (m/^--clean=(.*)$/s) {
3098                 badusage "unknown cleaning mode \`$1'";
3099             } elsif (m/^--quilt=($quilt_modes_re)$/s) {
3100                 push @ropts, $_;
3101                 $quilt_mode = $1;
3102             } elsif (m/^--quilt=(.*)$/s) {
3103                 badusage "unknown quilt fixup mode \`$1'";
3104             } elsif (m/^--ignore-dirty$/s) {
3105                 push @ropts, $_;
3106                 $ignoredirty = 1;
3107             } elsif (m/^--no-quilt-fixup$/s) {
3108                 push @ropts, $_;
3109                 $quilt_mode = 'nocheck';
3110             } elsif (m/^--no-rm-on-error$/s) {
3111                 push @ropts, $_;
3112                 $rmonerror = 0;
3113             } elsif (m/^--deliberately-($deliberately_re)$/s) {
3114                 push @ropts, $_;
3115                 push @deliberatelies, $&;
3116             } else {
3117                 badusage "unknown long option \`$_'";
3118             }
3119         } else {
3120             while (m/^-./s) {
3121                 if (s/^-n/-/) {
3122                     push @ropts, $&;
3123                     $dryrun_level=2;
3124                 } elsif (s/^-L/-/) {
3125                     push @ropts, $&;
3126                     $dryrun_level=1;
3127                 } elsif (s/^-h/-/) {
3128                     cmd_help();
3129                 } elsif (s/^-D/-/) {
3130                     push @ropts, $&;
3131                     $debuglevel++;
3132                     enabledebug();
3133                 } elsif (s/^-N/-/) {
3134                     push @ropts, $&;
3135                     $new_package=1;
3136                 } elsif (s/^-v([^_]+|_)$//s) {
3137                     push @ropts, $&;
3138                     $changes_since_version = $1;
3139                 } elsif (m/^-m/) {
3140                     push @ropts, $&;
3141                     push @changesopts, $_;
3142                     $_ = '';
3143                 } elsif (s/^-c(.*=.*)//s) {
3144                     push @ropts, $&;
3145                     push @git, '-c', $1;
3146                 } elsif (s/^-d(.+)//s) {
3147                     push @ropts, $&;
3148                     $idistro = $1;
3149                 } elsif (s/^-C(.+)//s) {
3150                     push @ropts, $&;
3151                     $changesfile = $1;
3152                     if ($changesfile =~ s#^(.*)/##) {
3153                         $buildproductsdir = $1;
3154                     }
3155                 } elsif (s/^-k(.+)//s) {
3156                     $keyid=$1;
3157                 } elsif (m/^-[vdCk]$/) {
3158                     badusage
3159  "option \`$_' requires an argument (and no space before the argument)";
3160                 } elsif (s/^-wn$//s) {
3161                     push @ropts, $&;
3162                     $cleanmode = 'none';
3163                 } elsif (s/^-wg$//s) {
3164                     push @ropts, $&;
3165                     $cleanmode = 'git';
3166                 } elsif (s/^-wgf$//s) {
3167                     push @ropts, $&;
3168                     $cleanmode = 'git-ff';
3169                 } elsif (s/^-wd$//s) {
3170                     push @ropts, $&;
3171                     $cleanmode = 'dpkg-source';
3172                 } elsif (s/^-wdd$//s) {
3173                     push @ropts, $&;
3174                     $cleanmode = 'dpkg-source-d';
3175                 } elsif (s/^-wc$//s) {
3176                     push @ropts, $&;
3177                     $cleanmode = 'check';
3178                 } else {
3179                     badusage "unknown short option \`$_'";
3180                 }
3181             }
3182         }
3183     }
3184 }
3185
3186 sub finalise_opts_opts () {
3187     foreach my $k (keys %opts_opt_map) {
3188         my $om = $opts_opt_map{$k};
3189
3190         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
3191         if (defined $v) {
3192             badcfg "cannot set command for $k"
3193                 unless length $om->[0];
3194             $om->[0] = $v;
3195         }
3196
3197         foreach my $c (access_cfg_cfgs("opts-$k")) {
3198             my $vl = $gitcfg{$c};
3199             printdebug "CL $c ",
3200                 ($vl ? join " ", map { shellquote } @$vl : ""),
3201                 "\n" if $debuglevel >= 4;
3202             next unless $vl;
3203             badcfg "cannot configure options for $k"
3204                 if $opts_opt_cmdonly{$k};
3205             my $insertpos = $opts_cfg_insertpos{$k};
3206             @$om = ( @$om[0..$insertpos-1],
3207                      @$vl,
3208                      @$om[$insertpos..$#$om] );
3209         }
3210     }
3211 }
3212
3213 if ($ENV{$fakeeditorenv}) {
3214     git_slurp_config();
3215     quilt_fixup_editor();
3216 }
3217
3218 parseopts();
3219 git_slurp_config();
3220
3221 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
3222 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
3223     if $dryrun_level == 1;
3224 if (!@ARGV) {
3225     print STDERR $helpmsg or die $!;
3226     exit 8;
3227 }
3228 my $cmd = shift @ARGV;
3229 $cmd =~ y/-/_/;
3230
3231 if (!defined $quilt_mode) {
3232     local $access_forpush;
3233     $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
3234         // access_cfg('quilt-mode', 'RETURN-UNDEF')
3235         // 'linear';
3236     $quilt_mode =~ m/^($quilt_modes_re)$/
3237         or badcfg "unknown quilt-mode \`$quilt_mode'";
3238     $quilt_mode = $1;
3239 }
3240
3241 my $fn = ${*::}{"cmd_$cmd"};
3242 $fn or badusage "unknown operation $cmd";
3243 $fn->();