Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31 use IPC::Open2;
  32 use File::Path;
  33 use File::Basename;
  34 use Dpkg::Control::Hash;
  35 use Debian::Dgit::ExitStatus;
  36
  37 BEGIN {
  38     use Exporter   ();
  39     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  40
  41     $VERSION     = 1.00;
  42     @ISA         = qw(Exporter);
  43     @EXPORT      = qw(setup_sigwarn forkcheck_setup forkcheck_mainprocess
  44                       dep14_version_mangle
  45                       debiantags debiantag_old debiantag_new
  46                       debiantag_maintview
  47                       upstreamversion
  48                       stripepoch source_file_leafname is_orig_file_of_p_v
  49                       server_branch server_ref
  50                       stat_exists link_ltarget
  51                       hashfile
  52                       fail failmsg ensuredir must_getcwd executable_on_path
  53                       waitstatusmsg failedcmd_waitstatus
  54                       failedcmd_report_cmd failedcmd
  55                       runcmd shell_cmd cmdoutput cmdoutput_errok
  56                       git_rev_parse git_cat_file
  57                       git_get_ref git_get_symref git_for_each_ref
  58                       git_for_each_tag_referring is_fast_fwd
  59                       git_check_unmodified
  60                       git_reflog_action_msg  git_update_ref_cmd
  61                       make_commit_text
  62                       reflog_cache_insert reflog_cache_lookup
  63                       $package_re $component_re $deliberately_re
  64                       $distro_re $versiontag_re $series_filename_re
  65                       $orig_f_comp_re $orig_f_sig_re $orig_f_tail_re
  66                       $extra_orig_namepart_re
  67                       $git_null_obj
  68                       $branchprefix
  69                       $ffq_refprefix $gdrlast_refprefix
  70                       initdebug enabledebug enabledebuglevel
  71                       printdebug debugcmd
  72                       $printdebug_when_debuglevel $debugcmd_when_debuglevel
  73                       $debugprefix *debuglevel *DEBUG
  74                       shellquote printcmd messagequote
  75                       $negate_harmful_gitattrs
  76                       changedir git_slurp_config_src
  77                       gdr_ffq_prev_branchinfo
  78                       parsecontrolfh parsecontrol parsechangelog
  79                       getfield parsechangelog_loop
  80                       playtree_setup);
  81     # implicitly uses $main::us
  82     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)],
  83                      playground => [qw(record_maindir $maindir $local_git_cfg
  84                                        $maindir_gitdir $maindir_gitcommon
  85                                        fresh_playground
  86                                        ensure_a_playground)]);
  87     @EXPORT_OK   = ( @{ $EXPORT_TAGS{policyflags} },
  88                      @{ $EXPORT_TAGS{playground} } );
  89 }
  90
  91 our @EXPORT_OK;
  92
  93 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  94 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  95 our $deliberately_re = "(?:TEST-)?$package_re";
  96 our $distro_re = $component_re;
  97 our $versiontag_re = qr{[-+.\%_0-9a-zA-Z/]+};
  98 our $branchprefix = 'dgit';
  99 our $series_filename_re = qr{(?:^|\.)series(?!\n)$}s;
 100 our $extra_orig_namepart_re = qr{[-0-9a-z]+};
 101 our $orig_f_comp_re = qr{orig(?:-$extra_orig_namepart_re)?};
 102 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
 103 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
 104 our $git_null_obj = '0' x 40;
 105 our $ffq_refprefix = 'ffq-prev';
 106 our $gdrlast_refprefix = 'debrebase-last';
 107 our $printdebug_when_debuglevel = 1;
 108 our $debugcmd_when_debuglevel = 1;
 109
 110 # these three all go together, only valid after record_maindir
 111 our $maindir;
 112 our $maindir_gitdir;
 113 our $maindir_gitcommon;
 114
 115 # policy hook exit status bits
 116 # see dgit-repos-server head comment for documentation
 117 # 1 is reserved in case something fails with `exit 1' and to spot
 118 # dynamic loader, runtime, etc., failures, which report 127 or 255
 119 sub NOFFCHECK () { return 0x2; }
 120 sub FRESHREPO () { return 0x4; }
 121 sub NOCOMMITCHECK () { return 0x8; }
 122
 123 our $debugprefix;
 124 our $debuglevel = 0;
 125
 126 our $negate_harmful_gitattrs =
 127     "-text -eol -crlf -ident -filter -working-tree-encoding";
 128     # ^ when updating this, alter the regexp in dgit:is_gitattrs_setup
 129
 130 our $forkcheck_mainprocess;
 131
 132 sub forkcheck_setup () {
 133     $forkcheck_mainprocess = $$;
 134 }
 135
 136 sub forkcheck_mainprocess () {
 137     # You must have called forkcheck_setup or setup_sigwarn already
 138     getppid != $forkcheck_mainprocess;
 139 }
 140
 141 sub setup_sigwarn () {
 142     forkcheck_setup();
 143     $SIG{__WARN__} = sub {
 144         confess $_[0] if forkcheck_mainprocess;
 145     };
 146 }
 147
 148 sub initdebug ($) {
 149     ($debugprefix) = @_;
 150     open DEBUG, ">/dev/null" or die $!;
 151 }
 152
 153 sub enabledebug () {
 154     open DEBUG, ">&STDERR" or die $!;
 155     DEBUG->autoflush(1);
 156     $debuglevel ||= 1;
 157 }
 158
 159 sub enabledebuglevel ($) {
 160     my ($newlevel) = @_; # may be undef (eg from env var)
 161     die if $debuglevel;
 162     $newlevel //= 0;
 163     $newlevel += 0;
 164     return unless $newlevel;
 165     $debuglevel = $newlevel;
 166     enabledebug();
 167 }
 168
 169 sub printdebug {
 170     # Prints a prefix, and @_, to DEBUG.  @_ should normally contain
 171     # a trailing \n.
 172
 173     # With no (or only empty) arguments just prints the prefix and
 174     # leaves the caller to do more with DEBUG.  The caller should make
 175     # sure then to call printdebug with something ending in "\n" to
 176     # get the prefix right in subsequent calls.
 177
 178     return unless $debuglevel >= $printdebug_when_debuglevel;
 179     our $printdebug_noprefix;
 180     print DEBUG $debugprefix unless $printdebug_noprefix;
 181     pop @_ while @_ and !length $_[-1];
 182     return unless @_;
 183     print DEBUG @_ or die $!;
 184     $printdebug_noprefix = $_[-1] !~ m{\n$};
 185 }
 186
 187 sub messagequote ($) {
 188     local ($_) = @_;
 189     s{\\}{\\\\}g;
 190     s{\n}{\\n}g;
 191     s{\x08}{\\b}g;
 192     s{\t}{\\t}g;
 193     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 194     $_;
 195 }
 196
 197 sub shellquote {
 198     my @out;
 199     local $_;
 200     defined or confess 'internal error' foreach @_;
 201     foreach my $a (@_) {
 202         $_ = $a;
 203         if (!length || m{[^-=_./:0-9a-z]}i) {
 204             s{['\\]}{'\\$&'}g;
 205             push @out, "'$_'";
 206         } else {
 207             push @out, $_;
 208         }
 209     }
 210     return join ' ', @out;
 211 }
 212
 213 sub printcmd {
 214     my $fh = shift @_;
 215     my $intro = shift @_;
 216     print $fh $intro," " or die $!;
 217     print $fh shellquote @_ or die $!;
 218     print $fh "\n" or die $!;
 219 }
 220
 221 sub debugcmd {
 222     my $extraprefix = shift @_;
 223     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_)
 224         if $debuglevel >= $debugcmd_when_debuglevel;
 225 }
 226
 227 sub dep14_version_mangle ($) {
 228     my ($v) = @_;
 229     # DEP-14 patch proposed 2016-11-09  "Version Mangling"
 230     $v =~ y/~:/_%/;
 231     $v =~ s/\.(?=\.|$|lock$)/.#/g;
 232     return $v;
 233 }
 234
 235 sub debiantag_old ($$) {
 236     my ($v,$distro) = @_;
 237     return "$distro/". dep14_version_mangle $v;
 238 }
 239
 240 sub debiantag_new ($$) {
 241     my ($v,$distro) = @_;
 242     return "archive/$distro/".dep14_version_mangle $v;
 243 }
 244
 245 sub debiantag_maintview ($$) {
 246     my ($v,$distro) = @_;
 247     return "$distro/".dep14_version_mangle $v;
 248 }
 249
 250 sub debiantags ($$) {
 251     my ($version,$distro) = @_;
 252     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 253 }
 254
 255 sub stripepoch ($) {
 256     my ($vsn) = @_;
 257     $vsn =~ s/^\d+\://;
 258     return $vsn;
 259 }
 260
 261 sub upstreamversion ($) {
 262     my ($vsn) = @_;
 263     $vsn =~ s/-[^-]+$//;
 264     return $vsn;
 265 }
 266
 267 sub source_file_leafname ($$$) {
 268     my ($package,$vsn,$sfx) = @_;
 269     return "${package}_".(stripepoch $vsn).$sfx
 270 }
 271
 272 sub is_orig_file_of_p_v ($$$) {
 273     my ($f, $package, $upstreamvsn) = @_;
 274     my $base = source_file_leafname $package, $upstreamvsn, '';
 275     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
 276     return 1;
 277 }
 278
 279 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 280 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 281
 282 sub stat_exists ($) {
 283     my ($f) = @_;
 284     return 1 if stat $f;
 285     return 0 if $!==&ENOENT;
 286     die "stat $f: $!";
 287 }
 288
 289 sub _us () {
 290     $::us // ($0 =~ m#[^/]*$#, $&);
 291 }
 292
 293 sub failmsg {
 294     my $s = "error: @_\n";
 295     $s =~ s/\n\n$/\n/g;
 296     my $prefix = _us().": ";
 297     $s =~ s/^/$prefix/gm;
 298     return "\n".$s;
 299 }
 300
 301 sub fail {
 302     die failmsg @_;
 303 }
 304
 305 sub ensuredir ($) {
 306     my ($dir) = @_; # does not create parents
 307     return if mkdir $dir;
 308     return if $! == EEXIST;
 309     die "mkdir $dir: $!";
 310 }
 311
 312 sub must_getcwd () {
 313     my $d = getcwd();
 314     defined $d or fail "getcwd failed: $!";
 315     return $d;
 316 }
 317
 318 sub executable_on_path ($) {
 319     my ($program) = @_;
 320     return 1 if $program =~ m{/};
 321     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 322     foreach my $pe (@path) {
 323         my $here = "$pe/$program";
 324         return $here if stat_exists $here && -x _;
 325     }
 326     return undef;
 327 }
 328
 329 our @signames = split / /, $Config{sig_name};
 330
 331 sub waitstatusmsg () {
 332     if (!$?) {
 333         return "terminated, reporting successful completion";
 334     } elsif (!($? & 255)) {
 335         return "failed with error exit status ".WEXITSTATUS($?);
 336     } elsif (WIFSIGNALED($?)) {
 337         my $signum=WTERMSIG($?);
 338         return "died due to fatal signal ".
 339             ($signames[$signum] // "number $signum").
 340             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 341     } else {
 342         return "failed with unknown wait status ".$?;
 343     }
 344 }
 345
 346 sub failedcmd_report_cmd {
 347     my $intro = shift @_;
 348     $intro //= "failed command";
 349     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or die $!; };
 350 }
 351
 352 sub failedcmd_waitstatus {
 353     if ($? < 0) {
 354         return "failed to fork/exec: $!";
 355     } elsif ($?) {
 356         return "subprocess ".waitstatusmsg();
 357     } else {
 358         return "subprocess produced invalid output";
 359     }
 360 }
 361
 362 sub failedcmd {
 363     # Expects $!,$? as set by close - see below.
 364     # To use with system(), set $?=-1 first.
 365     #
 366     # Actual behaviour of perl operations:
 367     #   success              $!==0       $?==0       close of piped open
 368     #   program failed       $!==0       $? >0       close of piped open
 369     #   syscall failure      $! >0       $?=-1       close of piped open
 370     #   failure              $! >0       unchanged   close of something else
 371     #   success              trashed     $?==0       system
 372     #   program failed       trashed     $? >0       system
 373     #   syscall failure      $! >0       unchanged   system
 374     failedcmd_report_cmd undef, @_;
 375     fail failedcmd_waitstatus();
 376 }
 377
 378 sub runcmd {
 379     debugcmd "+",@_;
 380     $!=0; $?=-1;
 381     failedcmd @_ if system @_;
 382 }
 383
 384 sub shell_cmd {
 385     my ($first_shell, @cmd) = @_;
 386     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 387 }
 388
 389 sub cmdoutput_errok {
 390     confess Dumper(\@_)." ?" if grep { !defined } @_;
 391     local $printdebug_when_debuglevel = $debugcmd_when_debuglevel;
 392     debugcmd "|",@_;
 393     open P, "-|", @_ or die "$_[0] $!";
 394     my $d;
 395     $!=0; $?=0;
 396     { local $/ = undef; $d = <P>; }
 397     die $! if P->error;
 398     if (!close P) { printdebug "=>!$?\n"; return undef; }
 399     chomp $d;
 400     if ($debuglevel > 0) {
 401         $d =~ m/^.*/;
 402         my $dd = $&;
 403         my $more = (length $' ? '...' : ''); #');
 404         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 405         printdebug "=> \`$dd'",$more,"\n";
 406     }
 407     return $d;
 408 }
 409
 410 sub cmdoutput {
 411     my $d = cmdoutput_errok @_;
 412     defined $d or failedcmd @_;
 413     return $d;
 414 }
 415
 416 sub link_ltarget ($$) {
 417     my ($old,$new) = @_;
 418     lstat $old or return undef;
 419     if (-l _) {
 420         $old = cmdoutput qw(realpath  --), $old;
 421     }
 422     my $r = link $old, $new;
 423     $r = symlink $old, $new if !$r && $!==EXDEV;
 424     $r or die "(sym)link $old $new: $!";
 425 }
 426
 427 sub hashfile ($) {
 428     my ($fn) = @_;
 429     my $h = Digest::SHA->new(256);
 430     $h->addfile($fn);
 431     return $h->hexdigest();
 432 }
 433
 434 sub git_rev_parse ($) {
 435     return cmdoutput qw(git rev-parse), "$_[0]~0";
 436 }
 437
 438 sub git_cat_file ($;$) {
 439     my ($objname, $etype) = @_;
 440     # => ($type, $data) or ('missing', undef)
 441     # in scalar context, just the data
 442     # if $etype defined, dies unless type is $etype or in @$etype
 443     our ($gcf_pid, $gcf_i, $gcf_o);
 444     local $printdebug_when_debuglevel = $debugcmd_when_debuglevel;
 445     my $chk = sub {
 446         my ($gtype, $data) = @_;
 447         if ($etype) {
 448             $etype = [$etype] unless ref $etype;
 449             confess "$objname expected @$etype but is $gtype"
 450                 unless grep { $gtype eq $_ } @$etype;
 451         }
 452         return ($gtype, $data);
 453     };
 454     if (!$gcf_pid) {
 455         my @cmd = qw(git cat-file --batch);
 456         debugcmd "GCF|", @cmd;
 457         $gcf_pid = open2 $gcf_o, $gcf_i, @cmd or die $!;
 458     }
 459     printdebug "GCF>| ", $objname, "\n";
 460     print $gcf_i $objname, "\n" or die $!;
 461     my $x = <$gcf_o>;
 462     printdebug "GCF<| ", $x;
 463     if ($x =~ m/ (missing)$/) { return $chk->($1, undef); }
 464     my ($type, $size) = $x =~ m/^.* (\w+) (\d+)\n/ or die "$objname ?";
 465     my $data;
 466     (read $gcf_o, $data, $size) == $size or die "$objname $!";
 467     $x = <$gcf_o>;
 468     $x eq "\n" or die "$objname ($_) $!";
 469     return $chk->($type, $data);
 470 }
 471
 472 sub git_get_symref (;$) {
 473     my ($symref) = @_;  $symref //= 'HEAD';
 474     # => undef if not a symref, otherwise refs/...
 475     my @cmd = (qw(git symbolic-ref -q HEAD));
 476     my $branch = cmdoutput_errok @cmd;
 477     if (!defined $branch) {
 478         $?==256 or failedcmd @cmd;
 479     } else {
 480         chomp $branch;
 481     }
 482     return $branch;
 483 }
 484
 485 sub git_for_each_ref ($$;$) {
 486     my ($pattern,$func,$gitdir) = @_;
 487     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 488     # $reftail is RHS of ref after refs/[^/]+/
 489     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 490     # $pattern may be an array ref to mean multiple patterns
 491     $pattern = [ $pattern ] unless ref $pattern;
 492     my @cmd = (qw(git for-each-ref), @$pattern);
 493     if (defined $gitdir) {
 494         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 495     }
 496     open GFER, "-|", @cmd or die $!;
 497     debugcmd "|", @cmd;
 498     while (<GFER>) {
 499         chomp or die "$_ ?";
 500         printdebug "|> ", $_, "\n";
 501         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 502         $func->($1,$2,$3,$4);
 503     }
 504     $!=0; $?=0; close GFER or die "$pattern $? $!";
 505 }
 506
 507 sub git_get_ref ($) {
 508     # => '' if no such ref
 509     my ($refname) = @_;
 510     local $_ = $refname;
 511     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 512     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 513 }
 514
 515 sub git_for_each_tag_referring ($$) {
 516     my ($objreferring, $func) = @_;
 517     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 518     printdebug "git_for_each_tag_referring ",
 519         ($objreferring // 'UNDEF'),"\n";
 520     git_for_each_ref('refs/tags', sub {
 521         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 522         return unless $objtype eq 'tag';
 523         my $refobjid = git_rev_parse $tagobjid;
 524         return unless
 525             !defined $objreferring # caller wants them all
 526             or $tagobjid eq $objreferring
 527             or $refobjid eq $objreferring;
 528         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 529     });
 530 }
 531
 532 sub git_check_unmodified () {
 533     foreach my $cached (qw(0 1)) {
 534         my @cmd = qw(git diff --quiet);
 535         push @cmd, qw(--cached) if $cached;
 536         push @cmd, qw(HEAD);
 537         debugcmd "+",@cmd;
 538         $!=0; $?=-1; system @cmd;
 539         return if !$?;
 540         if ($?==256) {
 541             fail
 542                 $cached
 543                 ? "git index contains changes (does not match HEAD)"
 544                 : "working tree is dirty (does not match HEAD)";
 545         } else {
 546             failedcmd @cmd;
 547         }
 548     }
 549 }
 550
 551 sub is_fast_fwd ($$) {
 552     my ($ancestor,$child) = @_;
 553     my @cmd = (qw(git merge-base), $ancestor, $child);
 554     my $mb = cmdoutput_errok @cmd;
 555     if (defined $mb) {
 556         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 557     } else {
 558         $?==256 or failedcmd @cmd;
 559         return 0;
 560     }
 561 }
 562
 563 sub git_reflog_action_msg ($) {
 564     my ($msg) = @_;
 565     my $rla = $ENV{GIT_REFLOG_ACTION};
 566     $msg = "$rla: $msg" if length $rla;
 567     return $msg;
 568 }
 569
 570 sub git_update_ref_cmd {
 571     # returns  qw(git update-ref), qw(-m), @_
 572     # except that message may be modified to honour GIT_REFLOG_ACTION
 573     my $msg = shift @_;
 574     $msg = git_reflog_action_msg $msg;
 575     return qw(git update-ref -m), $msg, @_;
 576 }
 577
 578 sub changedir ($) {
 579     my ($newdir) = @_;
 580     printdebug "CD $newdir\n";
 581     chdir $newdir or confess "chdir: $newdir: $!";
 582 }
 583
 584 sub git_slurp_config_src ($) {
 585     my ($src) = @_;
 586     # returns $r such that $r->{KEY}[] = VALUE
 587     my @cmd = (qw(git config -z --get-regexp), "--$src", qw(.*));
 588     debugcmd "|",@cmd;
 589
 590     local ($debuglevel) = $debuglevel-2;
 591     local $/="\0";
 592
 593     my $r = { };
 594     open GITS, "-|", @cmd or die $!;
 595     while (<GITS>) {
 596         chomp or die;
 597         printdebug "=> ", (messagequote $_), "\n";
 598         m/\n/ or die "$_ ?";
 599         push @{ $r->{$`} }, $'; #';
 600     }
 601     $!=0; $?=0;
 602     close GITS
 603         or ($!==0 && $?==256)
 604         or failedcmd @cmd;
 605     return $r;
 606 }
 607
 608 sub gdr_ffq_prev_branchinfo ($) {
 609     my ($symref) = @_;
 610     # => ('status', "message", [$symref, $ffq_prev, $gdrlast])
 611     # 'status' may be
 612     #    branch         message is undef
 613     #    weird-symref   } no $symref,
 614     #    notbranch      }  no $ffq_prev
 615     return ('detached', 'detached HEAD') unless defined $symref;
 616     return ('weird-symref', 'HEAD symref is not to refs/')
 617         unless $symref =~ m{^refs/};
 618     my $ffq_prev = "refs/$ffq_refprefix/$'";
 619     my $gdrlast = "refs/$gdrlast_refprefix/$'";
 620     printdebug "ffq_prev_branchinfo branch current $symref\n";
 621     return ('branch', undef, $symref, $ffq_prev, $gdrlast);
 622 }
 623
 624 sub parsecontrolfh ($$;$) {
 625     my ($fh, $desc, $allowsigned) = @_;
 626     our $dpkgcontrolhash_noissigned;
 627     my $c;
 628     for (;;) {
 629         my %opts = ('name' => $desc);
 630         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 631         $c = Dpkg::Control::Hash->new(%opts);
 632         $c->parse($fh,$desc) or die "parsing of $desc failed";
 633         last if $allowsigned;
 634         last if $dpkgcontrolhash_noissigned;
 635         my $issigned= $c->get_option('is_pgp_signed');
 636         if (!defined $issigned) {
 637             $dpkgcontrolhash_noissigned= 1;
 638             seek $fh, 0,0 or die "seek $desc: $!";
 639         } elsif ($issigned) {
 640             fail "control file $desc is (already) PGP-signed. ".
 641                 " Note that dgit push needs to modify the .dsc and then".
 642                 " do the signature itself";
 643         } else {
 644             last;
 645         }
 646     }
 647     return $c;
 648 }
 649
 650 sub parsecontrol {
 651     my ($file, $desc, $allowsigned) = @_;
 652     my $fh = new IO::Handle;
 653     open $fh, '<', $file or die "$file: $!";
 654     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 655     $fh->error and die $!;
 656     close $fh;
 657     return $c;
 658 }
 659
 660 sub parsechangelog {
 661     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 662     my $p = new IO::Handle;
 663     my @cmd = (qw(dpkg-parsechangelog), @_);
 664     open $p, '-|', @cmd or die $!;
 665     $c->parse($p);
 666     $?=0; $!=0; close $p or failedcmd @cmd;
 667     return $c;
 668 }
 669
 670 sub getfield ($$) {
 671     my ($dctrl,$field) = @_;
 672     my $v = $dctrl->{$field};
 673     return $v if defined $v;
 674     fail "missing field $field in ".$dctrl->get_option('name');
 675 }
 676
 677 sub parsechangelog_loop ($$$) {
 678     my ($clogcmd, $descbase, $fn) = @_;
 679     # @$clogcmd is qw(dpkg-parsechangelog ...some...options...)
 680     # calls $fn->($thisstanza, $desc);
 681     debugcmd "|",@$clogcmd;
 682     open CLOGS, "-|", @$clogcmd or die $!;
 683     for (;;) {
 684         my $stanzatext = do { local $/=""; <CLOGS>; };
 685         printdebug "clogp stanza ".Dumper($stanzatext) if $debuglevel>1;
 686         last if !defined $stanzatext;
 687
 688         my $desc = "$descbase, entry no.$.";
 689         open my $stanzafh, "<", \$stanzatext or die;
 690         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
 691
 692         $fn->($thisstanza, $desc);
 693     }
 694     die $! if CLOGS->error;
 695     close CLOGS or $?==SIGPIPE or failedcmd @$clogcmd;
 696 }
 697
 698 sub make_commit_text ($) {
 699     my ($text) = @_;
 700     my ($out, $in);
 701     my @cmd = (qw(git hash-object -w -t commit --stdin));
 702     debugcmd "|",@cmd;
 703     print Dumper($text) if $debuglevel > 1;
 704     my $child = open2($out, $in, @cmd) or die $!;
 705     my $h;
 706     eval {
 707         print $in $text or die $!;
 708         close $in or die $!;
 709         $h = <$out>;
 710         $h =~ m/^\w+$/ or die;
 711         $h = $&;
 712         printdebug "=> $h\n";
 713     };
 714     close $out;
 715     waitpid $child, 0 == $child or die "$child $!";
 716     $? and failedcmd @cmd;
 717     return $h;
 718 }
 719
 720 sub reflog_cache_insert ($$$) {
 721     my ($ref, $cachekey, $value) = @_;
 722     # you must call this in $maindir
 723     # you must have called record_maindir
 724
 725     # When we no longer need to support squeeze, use --create-reflog
 726     # instead of this:
 727     my $parent = $ref; $parent =~ s{/[^/]+$}{};
 728     ensuredir "$maindir_gitcommon/logs/$parent";
 729     my $makelogfh = new IO::File "$maindir_gitcommon/logs/$ref", '>>'
 730       or die $!;
 731
 732     my $oldcache = git_get_ref $ref;
 733
 734     if ($oldcache eq $value) {
 735         my $tree = cmdoutput qw(git rev-parse), "$value:";
 736         # git update-ref doesn't always update, in this case.  *sigh*
 737         my $authline = (ucfirst _us()).
 738             ' <'._us().'@example.com> 1000000000 +0000';
 739         my $dummy = make_commit_text <<END;
 740 tree $tree
 741 parent $value
 742 author $authline
 743 committer $authline
 744
 745 Dummy commit - do not use
 746 END
 747         runcmd qw(git update-ref -m), _us()." - dummy", $ref, $dummy;
 748     }
 749     runcmd qw(git update-ref -m), $cachekey, $ref, $value;
 750 }
 751
 752 sub reflog_cache_lookup ($$) {
 753     my ($ref, $cachekey) = @_;
 754     # you may call this in $maindir or in a playtree
 755     # you must have called record_maindir
 756     my @cmd = (qw(git log -g), '--pretty=format:%H %gs', $ref);
 757     debugcmd "|(probably)",@cmd;
 758     my $child = open GC, "-|";  defined $child or die $!;
 759     if (!$child) {
 760         chdir $maindir or die $!;
 761         if (!stat "$maindir_gitcommon/logs/$ref") {
 762             $! == ENOENT or die $!;
 763             printdebug ">(no reflog)\n";
 764             finish 0;
 765         }
 766         exec @cmd; die $!;
 767     }
 768     while (<GC>) {
 769         chomp;
 770         printdebug ">| ", $_, "\n" if $debuglevel > 1;
 771         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $cachekey;
 772         close GC;
 773         return $1;
 774     }
 775     die $! if GC->error;
 776     failedcmd unless close GC;
 777     return undef;
 778 }
 779
 780 # ========== playground handling ==========
 781
 782 # terminology:
 783 #
 784 #   $maindir      user's git working tree
 785 #   playground    area in .git/ where we can make files, unpack, etc. etc.
 786 #   playtree      git working tree sharing object store with the user's
 787 #                 inside playground, or identical to it
 788 #
 789 # other globals
 790 #
 791 #   $local_git_cfg    hash of arrays of values: git config from $maindir
 792 #
 793 # expected calling pattern
 794 #
 795 #  firstly
 796 #
 797 #    [record_maindir]
 798 #      must be run in directory containing .git
 799 #      assigns to $maindir if not already set
 800 #      also calls git_slurp_config_src to record git config
 801 #        in $local_git_cfg, unless it's already set
 802 #
 803 #    fresh_playground SUBDIR_PATH_COMPONENTS
 804 #      e.g fresh_playground 'dgit/unpack' ('.git/' is implied)
 805 #      default SUBDIR_PATH_COMPONENTS is playground_subdir
 806 #      calls record_maindir
 807 #      sets up a new playground (destroying any old one)
 808 #      returns playground pathname
 809 #      caller may call multiple times with different subdir paths
 810 #       createing different playgrounds
 811 #
 812 #    ensure_a_playground SUBDIR_PATH_COMPONENTS
 813 #      like fresh_playground except:
 814 #      merely ensures the directory exists; does not delete an existing one
 815 #
 816 #  then can use
 817 #
 818 #    changedir playground
 819 #    changedir $maindir
 820 #
 821 #    playtree_setup $local_git_cfg
 822 #            # ^ call in some (perhaps trivial) subdir of playground
 823 #
 824 #    rmtree playground
 825
 826 # ----- maindir -----
 827
 828 our $local_git_cfg;
 829
 830 sub record_maindir () {
 831     if (!defined $maindir) {
 832         $maindir = must_getcwd();
 833         if (!stat "$maindir/.git") {
 834             fail "cannot stat $maindir/.git: $!";
 835         }
 836         if (-d _) {
 837             # we fall back to this in case we have a pre-worktree
 838             # git, which may not know git rev-parse --git-common-dir
 839             $maindir_gitdir    = "$maindir/.git";
 840             $maindir_gitcommon = "$maindir/.git";
 841         } else {
 842             $maindir_gitdir    = cmdoutput qw(git rev-parse --git-dir);
 843             $maindir_gitcommon = cmdoutput qw(git rev-parse --git-common-dir);
 844         }
 845     }
 846     $local_git_cfg //= git_slurp_config_src 'local';
 847 }
 848
 849 # ----- playgrounds -----
 850
 851 sub ensure_a_playground_parent ($) {
 852     my ($spc) = @_;
 853     record_maindir();
 854     $spc = "$maindir_gitdir/$spc";
 855     my $parent = dirname $spc;
 856     mkdir $parent or $!==EEXIST
 857         or fail "failed to mkdir playground parent $parent: $!";
 858     return $spc;
 859 }
 860
 861 sub ensure_a_playground ($) {
 862     my ($spc) = @_;
 863     $spc = ensure_a_playground_parent $spc;
 864     mkdir $spc or $!==EEXIST or fail "failed to mkdir a playground $spc: $!";
 865     return $spc;
 866 }
 867
 868 sub fresh_playground ($) {
 869     my ($spc) = @_;
 870     $spc = ensure_a_playground_parent $spc;
 871     rmtree $spc;
 872     mkdir $spc or fail "failed to mkdir the playground $spc: $!";
 873     return $spc;
 874 }
 875
 876 # ----- playtrees -----
 877
 878 sub playtree_setup (;$) {
 879     my ($t_local_git_cfg) = @_;
 880     $t_local_git_cfg //= $local_git_cfg;
 881     # for use in the playtree
 882     # $maindir must be set, eg by calling record_maindir or fresh_playground
 883     runcmd qw(git init -q);
 884     runcmd qw(git config gc.auto 0);
 885     foreach my $copy (qw(user.email user.name user.useConfigOnly
 886                          core.sharedRepository
 887                          core.compression core.looseCompression
 888                          core.bigFileThreshold core.fsyncObjectFiles)) {
 889         my $v = $t_local_git_cfg->{$copy};
 890         next unless $v;
 891         runcmd qw(git config), $copy, $_ foreach @$v;
 892     }
 893     # this is confusing: we have
 894     #   .                   playtree, not a worktree, has .git/, our cwd
 895     #   $maindir            might be a worktree so
 896     #   $maindir_gitdir     contains our main working "dgit", HEAD, etc.
 897     #   $maindir_gitcommon  the shared stuff, including .objects
 898     rmtree('.git/objects');
 899     symlink "$maindir_gitcommon/objects",'.git/objects' or die $!;
 900     ensuredir '.git/info';
 901     open GA, "> .git/info/attributes" or die $!;
 902     print GA "* $negate_harmful_gitattrs\n" or die $!;
 903     close GA or die $!;
 904 }
 905
 906 1;