configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl This file is part of secnet.
   4 dnl See README for full list of copyright holders.
   5 dnl
   6 dnl secnet is free software; you can redistribute it and/or modify it
   7 dnl under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl secnet is distributed in the hope that it will be useful, but
  12 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 dnl General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl version 3 along with secnet; if not, see
  18 dnl https://www.gnu.org/licenses/gpl.html.
  19
  20 sinclude(ac_prog_cc_no_writeable_strings.m4)
  21
  22 m4_include(subdirmk/subdirmk.ac)
  23
  24 AC_INIT(secnet,0.1.18+,secnet@chiark.greenend.org.uk)
  25 AC_CONFIG_SRCDIR(secnet.c)
  26 AC_CONFIG_HEADER(config.h)
  27
  28 SUBDIRMK_SUBDIRS([test-example mtest stest])
  29
  30 AC_PREREQ(2.50)
  31 AC_REVISION($Id: configure.in,v 1.4 2002/09/09 22:05:02 steve Exp $)
  32
  33 AC_LANG_C
  34
  35 # If fink is on the path then it is assumed we should use it.
  36 AC_PATH_PROG([FINK],[fink])
  37 if test "x$FINK" != x; then
  38   finkdir=`echo $FINK|sed 's,/[[^/]]*/[[^/]]*$,,'`
  39   CPPFLAGS="-I$finkdir/include ${CPPFLAGS}"
  40   LDFLAGS="-L$finkdir/lib ${LDFLAGS}"
  41 fi
  42
  43 AC_PROG_MAKE_SET
  44 AC_PROG_CC
  45 AC_PROG_INSTALL
  46 AC_CHECK_HEADERS([net/if.h net/route.h])
  47 AC_CHECK_HEADERS([sys/socket.h])
  48 AC_CHECK_HEADERS([linux/if_tun.h], [], [],
  49 [#if HAVE_SYS_SOCKET_H
  50 # include <sys/socket.h>
  51 #endif
  52 ])
  53 AC_CHECK_HEADERS([stropts.h sys/sockio.h net/if_tun.h])
  54 AC_C_BIGENDIAN
  55 AC_PROG_CC_NO_WRITEABLE_STRINGS(WRITESTRINGS)
  56
  57 AC_ARG_ENABLE(hacky-parallel,
  58   [AS_HELP_STRING([--enable-hacky-parallel],
  59                   [parallelise slow cryptography (default is no)])], [
  60   case "$enableval" in
  61   n|0|no) ;;
  62   y|1|yes) CFLAGS="$CFLAGS -DHACKY_PARALLEL" ;;
  63   *) ;;
  64   esac
  65 ])
  66
  67 AC_DEFUN([REQUIRE_HEADER],[AC_CHECK_HEADER($1,,[AC_MSG_ERROR($1 not found)])])
  68
  69 dnl the order in which libraries is checked is important
  70 dnl eg. adns on Solaris 2.5.1 depends on -lnsl and -lsocket
  71 AC_CHECK_LIB(gmp,mpz_init_set_str)
  72 AC_CHECK_LIB(gmp2,mpz_init_set_str)
  73 AC_CHECK_LIB(gmp,__gmpz_init_set_str)
  74 REQUIRE_HEADER([gmp.h])
  75 dnl Would love to barf if no gmp was found, but how to test? Requiring the header will do for now.
  76 SECNET_C_GETFUNC(inet_ntoa,nsl)
  77 AC_CHECK_LIB(socket,socket)
  78 SECNET_C_GETFUNC(inet_aton,resolv)
  79 AC_CHECK_LIB(adns,adns_init)
  80 REQUIRE_HEADER([adns.h])
  81
  82 AC_MSG_NOTICE([Checking requirements for IPv6 support...])
  83 enable_ipv6=true
  84 m4_define(NO_IPV6,[enable_ipv6=false])
  85 AC_CHECK_DECL(AF_INET6,        [],[NO_IPV6],[#include <netinet/in.h>])
  86 AC_CHECK_FUNC(adns_addr2text,  [],[NO_IPV6])
  87 if $enable_ipv6; then
  88     AC_MSG_NOTICE([Enabling IPv6 support])
  89     AC_DEFINE(CONFIG_IPV6, 1,
  90               [Define to 1 to use IPv6 support in system and adns])
  91 else
  92     AC_MSG_WARN([Disabling IPv6 support])
  93 fi
  94
  95 SUBDIRMK_MAKEFILES(common.make)
  96
  97 AC_OUTPUT(,
  98           echo timestamp >config.stamp)
  99
 100 AH_TOP([
 101 #ifndef _CONFIG_H
 102 #define _CONFIG_H
 103 ])
 104
 105 AH_BOTTOM([
 106 /* -*- c -*- */
 107
 108 /* These used to be in config.h.bot, but are now in configure.in. */
 109
 110 #ifdef __GNUC__
 111 #define NORETURN(_x) void _x __attribute__ ((noreturn))
 112 #define FORMAT(_a,_b,_c) __attribute__ ((format (_a,_b,_c)))
 113 #else
 114 #define NORETURN(_x) _x
 115 #define FORMAT(_a,_b,_c)
 116 #endif
 117
 118 #endif /* _CONFIG_H */
 119 ])