chiark - git - mdw - sod/blob - src/module-parse.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Top-level parser for module syntax
   4 ;;;
   5 ;;; (c) 2010 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensble Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Toplevel syntax.
  30
  31 ;;; Type names.
  32
  33 (define-pluggable-parser module typename (scanner pset)
  34   ;; `typename' id ( `,' id )* `;'
  35   (declare (ignore pset))
  36   (with-parser-context (token-scanner-context :scanner scanner)
  37     (parse (and "typename"
  38                 (skip-many (:min 1)
  39                   (seq ((id :id))
  40                     (if (gethash id *module-type-map*)
  41                         (cerror* "Type `~A' already defined" id)
  42                         (add-to-module *module*
  43                                        (make-instance 'type-item
  44                                                       :name id))))
  45                   #\,)
  46                 #\;))))
  47
  48 ;;; Fragments.
  49
  50 (define-pluggable-parser module code (scanner pset)
  51   ;; `code' id `:' id [constraints] `{' c-fragment `}'
  52   ;;
  53   ;; constrains ::= `[' constraint-list `]'
  54   ;; constraint ::= id+
  55   (declare (ignore pset))
  56   (with-parser-context (token-scanner-context :scanner scanner)
  57     (flet ((kw ()
  58              (parse (seq ((kw :id)) (intern (string-upcase kw) 'keyword)))))
  59       (parse (seq ("code"
  60                    (reason (kw))
  61                    #\:
  62                    (name (kw))
  63                    (constraints (? (seq (#\[
  64                                          (constraints (list (:min 1)
  65                                                         (list (:min 1) (kw))
  66                                                         #\,))
  67                                          #\])
  68                                      constraints)))
  69                    (fragment (parse-delimited-fragment scanner #\{ #\})))
  70                (add-to-module *module*
  71                               (make-instance 'code-fragment-item
  72                                              :fragment fragment
  73                                              :constraints constraints
  74                                              :reason reason
  75                                              :name name)))))))
  76
  77 ;;; External files.
  78
  79 (export 'read-module)
  80 (defun read-module (pathname &key (truename nil truep) location)
  81   "Parse the file at PATHNAME as a module, returning it.
  82
  83    This is the main entry point for parsing module files.  You may well know
  84    the file's TRUENAME already (e.g., because `probe-file' dropped it into
  85    your lap) so you can avoid repeating the search by providing it.
  86
  87    The LOCATION is the thing which wanted the module imported -- usually a
  88    `file-location' object, though it might be anything other than `t' which
  89    can be printed in the event of circular imports."
  90
  91   (setf pathname (merge-pathnames pathname
  92                                   (make-pathname :type "SOD" :case :common)))
  93   (unless truep (setf truename (truename pathname)))
  94   (define-module (pathname :location location :truename truename)
  95     (with-open-file (f-stream pathname :direction :input)
  96       (let* ((*readtable* (copy-readtable))
  97              (char-scanner (make-instance 'charbuf-scanner
  98                                           :stream f-stream))
  99              (scanner (make-instance 'sod-token-scanner
 100                                      :char-scanner char-scanner)))
 101         (with-default-error-location (scanner)
 102           (with-parser-context (token-scanner-context :scanner scanner)
 103             (parse (skip-many ()
 104                      (seq ((pset (parse-property-set scanner))
 105                            (nil (error ()
 106                                   (plug module scanner pset))))
 107                        (check-unused-properties pset))))))))))
 108
 109 (define-pluggable-parser module test (scanner pset)
 110   ;; `demo' string `;'
 111   (declare (ignore pset))
 112   (with-parser-context (token-scanner-context :scanner scanner)
 113     (parse (seq ("demo" (string :string) #\;)
 114              (format t ";; DEMO ~S~%" string)))))
 115
 116 (define-pluggable-parser module file (scanner pset)
 117   ;; `import' string `;'
 118   ;; `load' string `;'
 119   (declare (ignore pset))
 120   (flet ((common (name type what thunk)
 121            (find-file scanner
 122                       (merge-pathnames name
 123                                        (make-pathname :type type
 124                                                       :case :common))
 125                       what
 126                       thunk)))
 127     (with-parser-context (token-scanner-context :scanner scanner)
 128       (parse (or (seq ("import" (name :string) #\;)
 129                    (common name "SOD" "module"
 130                            (lambda (path true)
 131                              (handler-case
 132                                  (let ((module (read-module path
 133                                                             :truename true)))
 134                                    (when module
 135                                      (module-import module)
 136                                      (pushnew module
 137                                               (module-dependencies
 138                                                *module*))))
 139                                (file-error (error)
 140                                  (cerror* "Error reading module ~S: ~A"
 141                                           path error))))))
 142                  (seq ("load" (name :string) #\;)
 143                    (common name "LISP" "Lisp file"
 144                            (lambda (path true)
 145                              (handler-case
 146                                  (load true :verbose nil :print nil)
 147                                (error (error)
 148                                  (cerror* "Error loading Lisp file ~S: ~A"
 149                                           path error)))))))))))
 150
 151 ;;; Lisp escape.
 152
 153 (define-pluggable-parser module lisp (scanner pset)
 154   ;; `lisp' s-expression `;'
 155   (declare (ignore pset))
 156   (with-parser-context (token-scanner-context :scanner scanner)
 157     (parse (seq ((sexp (if (and (eql (token-type scanner) :id)
 158                                 (string= (token-value scanner) "lisp"))
 159                            (let* ((stream (make-scanner-stream scanner))
 160                                   (sexp (read stream t)))
 161                              (scanner-step scanner)
 162                              (values sexp t t))
 163                            (values '((:id "lisp")) nil nil)))
 164                  #\;)
 165              (eval sexp)))))
 166
 167 ;;;--------------------------------------------------------------------------
 168 ;;; Class declarations.
 169
 170 (defun parse-class-body (scanner pset name supers)
 171   ;; class-body ::= `{' class-item* `}'
 172   ;;
 173   ;; class-item ::= property-set raw-class-item
 174   (with-parser-context (token-scanner-context :scanner scanner)
 175     (make-class-type name)
 176     (let* ((class (make-sod-class name (mapcar #'find-sod-class supers)
 177                                   pset scanner))
 178            (nick (sod-class-nickname class)))
 179
 180       (labels ((parse-maybe-dotted-declarator (base-type)
 181                  ;; Parse a declarator or dotted-declarator, i.e., one whose
 182                  ;; centre is
 183                  ;;
 184                  ;; maybe-dotted-identifier ::= [id `.'] id
 185                  ;;
 186                  ;; A plain identifier is returned as a string, as usual; a
 187                  ;; dotted identifier is returned as a cons cell of the two
 188                  ;; names.
 189                  (parse-declarator
 190                   scanner base-type
 191                   :kernel (parser ()
 192                             (seq ((name-a :id)
 193                                   (name-b (? (seq (#\. (id :id)) id))))
 194                               (if name-b (cons name-a name-b)
 195                                   name-a)))))
 196
 197                (parse-message-item (sub-pset type name)
 198                  ;; message-item ::=
 199                  ;;     declspec+ declarator -!- (method-body | `;')
 200                  ;;
 201                  ;; Don't allow a method-body here if the message takes a
 202                  ;; varargs list, because we don't have a name for the
 203                  ;; `va_list' parameter.
 204                  (let ((message (make-sod-message class name type
 205                                                   sub-pset scanner)))
 206                    (if (varargs-message-p message)
 207                        (parse #\;)
 208                        (parse (or #\; (parse-method-item sub-pset
 209                                                          type nick name))))))
 210
 211                (parse-method-item (sub-pset type sub-nick name)
 212                  ;; method-item ::=
 213                  ;;     declspec+ dotted-declarator -!- method-body
 214                  ;;
 215                  ;; method-body ::= `{' c-fragment `}' | `extern' `;'
 216                  (parse (seq ((body (or (seq ("extern" #\;) nil)
 217                                         (parse-delimited-fragment
 218                                          scanner #\{ #\}))))
 219                           (make-sod-method class sub-nick name type
 220                                            body sub-pset scanner))))
 221
 222                (parse-initializer ()
 223                  ;; initializer ::= `=' c-fragment | `=' `{' c-fragment `}'
 224                  ;;
 225                  ;; Return (VALUE-KIND . VALUE-FORM), ready for passing to a
 226                  ;; `sod-initializer' constructor.
 227
 228                  ;; This is kind of tricky because we have to juggle both
 229                  ;; layers of the parsing machinery.  The character scanner
 230                  ;; will already have consumed the lookahead token (which, if
 231                  ;; we're going to do anything, is `=').
 232                  (let ((char-scanner (token-scanner-char-scanner scanner)))
 233
 234                    ;; First, skip the character-scanner past any whitespace.
 235                    ;; We don't record this consumption, which is a bit
 236                    ;; naughty, but nobody will actually mind.
 237                    (loop
 238                      (when (or (scanner-at-eof-p char-scanner)
 239                                (not (whitespace-char-p
 240                                      (scanner-current-char char-scanner))))
 241                        (return))
 242                      (scanner-step char-scanner))
 243
 244                    ;; Now maybe read an initializer.
 245                    (cond ((not (eql (token-type scanner) #\=))
 246                           ;; It's not an `=' after all.  There's no
 247                           ;; initializer.
 248                           (values '(#\=) nil nil))
 249
 250                          ((and (not (scanner-at-eof-p char-scanner))
 251                                (char= (scanner-current-char char-scanner)
 252                                       #\{))
 253                           ;; There's a brace after the `=', so we should
 254                           ;; consume the `=' here, and read a compound
 255                           ;; initializer enclosed in braces.
 256                           (parse (seq (#\= (frag (parse-delimited-fragment
 257                                                   scanner #\{ #\})))
 258                                    (cons :compound frag))))
 259
 260                          (t
 261                           ;; No brace, so read from the `=' up to, but not
 262                           ;; including, the trailing `,' or `;' delimiter.
 263                           (parse (seq ((frag (parse-delimited-fragment
 264                                               scanner #\= '(#\; #\,)
 265                                               :keep-end t)))
 266                                    (cons :simple frag)))))))
 267
 268                (parse-slot-item (sub-pset base-type type name)
 269                  ;; slot-item ::=
 270                  ;;     declspec+ declarator -!- [initializer]
 271                  ;;             [`,' init-declarator-list] `;'
 272                  ;;
 273                  ;; init-declarator-list ::=
 274                  ;;     declarator [initializer] [`,' init-declarator-list]
 275                  (parse (and (seq ((init (? (parse-initializer))))
 276                                (make-sod-slot class name type
 277                                               sub-pset scanner)
 278                                (when init
 279                                  (make-sod-instance-initializer
 280                                   class nick name (car init) (cdr init)
 281                                   sub-pset scanner)))
 282                              (skip-many ()
 283                                (seq (#\,
 284                                      (ds (parse-declarator scanner
 285                                                            base-type))
 286                                      (init (? (parse-initializer))))
 287                                  (make-sod-slot class (cdr ds) (car ds)
 288                                                 sub-pset scanner)
 289                                  (when init
 290                                    (make-sod-instance-initializer
 291                                     class nick (cdr ds)
 292                                     (car init) (cdr init)
 293                                     sub-pset scanner))))
 294                              #\;)))
 295
 296                (parse-initializer-item (sub-pset constructor)
 297                  ;; initializer-item ::=
 298                  ;;     [`class'] -!- slot-initializer-list `;'
 299                  ;;
 300                  ;; slot-initializer ::= id `.' id initializer
 301                  (parse (and (skip-many ()
 302                                (seq ((name-a :id) #\. (name-b :id)
 303                                      (init (parse-initializer)))
 304                                  (funcall constructor class
 305                                           name-a name-b
 306                                           (car init) (cdr init)
 307                                           sub-pset scanner))
 308                                #\,)
 309                              #\;)))
 310
 311                (class-item-dispatch (sub-pset base-type type name)
 312                  ;; Logically part of `parse-raw-class-item', but the
 313                  ;; indentation was getting crazy.  We're currently at
 314                  ;;
 315                  ;; raw-class-item ::=
 316                  ;;     declspec+ (declarator | dotted-declarator) -!- ...
 317                  ;;   | other-items
 318                  ;;
 319                  ;; If the declarator is dotted then this must be a method
 320                  ;; definition; otherwise it might be a message or slot.
 321                  (cond ((not (typep type 'c-function-type))
 322                         (when (consp name)
 323                           (cerror*-with-location
 324                            scanner
 325                            "Method declarations must have function type.")
 326                           (setf name (cdr name)))
 327                         (parse-slot-item sub-pset base-type type name))
 328                        ((consp name)
 329                         (parse-method-item sub-pset type
 330                                            (car name) (cdr name)))
 331                        (t
 332                         (parse-message-item sub-pset type name))))
 333
 334                (parse-raw-class-item (sub-pset)
 335                  ;; raw-class-item ::=
 336                  ;;     message-item
 337                  ;;   | method-item
 338                  ;;   | slot-item
 339                  ;;   | initializer-item
 340                  ;;
 341                  ;; Most of the above begin with declspecs and a declarator
 342                  ;; (which might be dotted).  So we parse that here and
 343                  ;; dispatch based on what we find.
 344                  (parse (or (plug class-item scanner class sub-pset)
 345                             (peek
 346                              (seq ((ds (parse-c-type scanner))
 347                                    (dc (parse-maybe-dotted-declarator ds))
 348                                    (nil (class-item-dispatch sub-pset
 349                                                              ds
 350                                                              (car dc)
 351                                                              (cdr dc))))))
 352                             (and "class"
 353                                  (parse-initializer-item
 354                                   sub-pset
 355                                   #'make-sod-class-initializer))
 356                             (parse-initializer-item
 357                              sub-pset
 358                              #'make-sod-instance-initializer)))))
 359
 360         (parse (seq (#\{
 361                      (nil (skip-many ()
 362                             (seq ((sub-pset (parse-property-set scanner))
 363                                   (nil (parse-raw-class-item sub-pset)))
 364                               (check-unused-properties sub-pset))))
 365                      (nil (error () #\})))
 366                  (finalize-sod-class class)
 367                  (add-to-module *module* class)))))))
 368
 369 (define-pluggable-parser module class (scanner pset)
 370   ;; `class' id [`:' id-list] class-body
 371   ;; `class' id `;'
 372   (with-parser-context (token-scanner-context :scanner scanner)
 373     (parse (seq ("class"
 374                  (name :id)
 375                  (nil (or (seq (#\;)
 376                             (make-class-type name))
 377                           (seq ((supers (? (seq (#\: (ids (list () :id #\,)))
 378                                              ids)))
 379                                 (nil (parse-class-body
 380                                       scanner
 381                                       pset name supers)))))))))))
 382
 383 ;;;----- That's all, folks --------------------------------------------------