chiark - git - mdw - sod/blob - src/module-parse.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Top-level parser for module syntax
   4 ;;;
   5 ;;; (c) 2010 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensible Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Toplevel syntax.
  30
  31 ;;; Type names.
  32
  33 (define-pluggable-parser module typename (scanner pset)
  34   ;; `typename' id ( `,' id )* `;'
  35   (declare (ignore pset))
  36   (with-parser-context (token-scanner-context :scanner scanner)
  37     (parse (and "typename"
  38                 (skip-many (:min 1)
  39                   (seq ((id :id))
  40                     (if (gethash id *module-type-map*)
  41                         (cerror* "Type `~A' already defined" id)
  42                         (add-to-module *module*
  43                                        (make-instance 'type-item
  44                                                       :name id))))
  45                   #\,)
  46                 #\;))))
  47
  48 ;;; Fragments.
  49
  50 (define-pluggable-parser module code (scanner pset)
  51   ;; `code' id `:' item-name [constraints] `{' c-fragment `}'
  52   ;;
  53   ;; constrains ::= `[' constraint-list `]'
  54   ;; constraint ::= item-name+
  55   ;; item-name ::= id | `(' id+ `)'
  56   (declare (ignore pset))
  57   (with-parser-context (token-scanner-context :scanner scanner)
  58     (labels ((kw ()
  59                (parse (seq ((kw :id))
  60                         (intern (frob-identifier kw) 'keyword))))
  61              (item ()
  62                (parse (or (kw)
  63                           (seq (#\( (names (list (:min 1) (kw))) #\))
  64                             names)))))
  65       (parse (seq ("code"
  66                    (reason (kw))
  67                    #\:
  68                    (name (item))
  69                    (constraints (? (seq (#\[
  70                                          (constraints (list (:min 1)
  71                                                         (list (:min 1)
  72                                                           (item))
  73                                                         #\,))
  74                                          #\])
  75                                      constraints)))
  76                    (fragment (parse-delimited-fragment scanner #\{ #\})))
  77                (add-to-module *module*
  78                               (make-instance 'code-fragment-item
  79                                              :fragment fragment
  80                                              :constraints constraints
  81                                              :reason reason
  82                                              :name name)))))))
  83
  84 ;;; External files.
  85
  86 (export 'read-module)
  87 (defun read-module (pathname &key (truename nil truep) location)
  88   "Parse the file at PATHNAME as a module, returning it.
  89
  90    This is the main entry point for parsing module files.  You may well know
  91    the file's TRUENAME already (e.g., because `probe-file' dropped it into
  92    your lap) so you can avoid repeating the search by providing it.
  93
  94    The LOCATION is the thing which wanted the module imported -- usually a
  95    `file-location' object, though it might be anything other than `t' which
  96    can be printed in the event of circular imports."
  97
  98   (setf pathname (merge-pathnames pathname
  99                                   (make-pathname :type "SOD" :case :common)))
 100   (unless truep (setf truename (truename pathname)))
 101   (define-module (pathname :location location :truename truename)
 102     (with-open-file (f-stream pathname :direction :input)
 103       (let* ((*readtable* (copy-readtable))
 104              (char-scanner (make-instance 'charbuf-scanner
 105                                           :stream f-stream))
 106              (scanner (make-instance 'sod-token-scanner
 107                                      :char-scanner char-scanner)))
 108         (with-default-error-location (scanner)
 109           (with-parser-context (token-scanner-context :scanner scanner)
 110             (parse (skip-many ()
 111                      (seq ((pset (parse-property-set scanner))
 112                            (nil (error ()
 113                                   (plug module scanner pset))))
 114                        (check-unused-properties pset))))))))))
 115
 116 (define-pluggable-parser module test (scanner pset)
 117   ;; `demo' string `;'
 118   (declare (ignore pset))
 119   (with-parser-context (token-scanner-context :scanner scanner)
 120     (parse (seq ("demo" (string :string) #\;)
 121              (format t ";; DEMO ~S~%" string)))))
 122
 123 (define-pluggable-parser module file (scanner pset)
 124   ;; `import' string `;'
 125   ;; `load' string `;'
 126   (declare (ignore pset))
 127   (flet ((common (name type what thunk)
 128            (find-file scanner
 129                       (merge-pathnames name
 130                                        (make-pathname :type type
 131                                                       :case :common))
 132                       what
 133                       thunk)))
 134     (with-parser-context (token-scanner-context :scanner scanner)
 135       (parse (or (seq ("import" (name :string) #\;)
 136                    (common name "SOD" "module"
 137                            (lambda (path true)
 138                              (handler-case
 139                                  (let ((module (read-module path
 140                                                             :truename true)))
 141                                    (when module
 142                                      (module-import module)
 143                                      (pushnew module
 144                                               (module-dependencies
 145                                                *module*))))
 146                                (file-error (error)
 147                                  (cerror* "Error reading module ~S: ~A"
 148                                           path error))))))
 149                  (seq ("load" (name :string) #\;)
 150                    (common name "LISP" "Lisp file"
 151                            (lambda (path true)
 152                              (handler-case
 153                                  (load true :verbose nil :print nil)
 154                                (error (error)
 155                                  (cerror* "Error loading Lisp file ~S: ~A"
 156                                           path error)))))))))))
 157
 158 ;;; Setting properties.
 159
 160 (define-pluggable-parser module set (scanner pset)
 161   ;; `set' property-list `;'
 162   (with-parser-context (token-scanner-context :scanner scanner)
 163     (parse (and "set"
 164                 (lisp (let ((module-pset (module-pset *module*)))
 165                         (when pset
 166                           (pset-map (lambda (prop)
 167                                       (add-property module-pset
 168                                                     (p-name prop)
 169                                                     (p-value prop)
 170                                                     :type (p-type prop)
 171                                                     :location (p-location prop))
 172                                       (setf (p-seenp prop) t))
 173                                     pset))
 174                         (parse (skip-many (:min 0)
 175                                  (error (:ignore-unconsumed t)
 176                                    (parse-property scanner module-pset)
 177                                    (skip-until (:keep-end t) #\, #\;))
 178                                  #\,))))
 179                 #\;))))
 180
 181 ;;; Lisp escape.
 182
 183 (define-pluggable-parser module lisp (scanner pset)
 184   ;; `lisp' s-expression `;'
 185   (declare (ignore pset))
 186   (with-parser-context (token-scanner-context :scanner scanner)
 187     (parse (seq ((sexp (if (and (eql (token-type scanner) :id)
 188                                 (string= (token-value scanner) "lisp"))
 189                            (let* ((stream (make-scanner-stream scanner))
 190                                   (sexp (read stream t)))
 191                              (scanner-step scanner)
 192                              (values sexp t t))
 193                            (values '((:id "lisp")) nil nil)))
 194                  #\;)
 195              (eval sexp)))))
 196
 197 ;;;--------------------------------------------------------------------------
 198 ;;; Class declarations.
 199
 200 (export 'class-item)
 201
 202 (define-pluggable-parser class-item initfrags (scanner class pset)
 203   ;; raw-class-item ::= frag-keyword `{' c-fragment `}'
 204   ;; frag-keyword ::= `init' | `teardown'
 205   (with-parser-context (token-scanner-context :scanner scanner)
 206     (parse (seq ((make (or (seq ("init") #'make-sod-class-initfrag)
 207                            (seq ("teardown") #'make-sod-class-tearfrag)))
 208                  (frag (parse-delimited-fragment scanner #\{ #\})))
 209              (funcall make class frag pset scanner)))))
 210
 211 (defun parse-class-body (scanner pset name supers)
 212   ;; class-body ::= `{' class-item* `}'
 213   ;;
 214   ;; class-item ::= property-set raw-class-item
 215   (with-parser-context (token-scanner-context :scanner scanner)
 216     (make-class-type name)
 217     (let* ((class (make-sod-class name (mapcar #'find-sod-class supers)
 218                                   pset scanner))
 219            (nick (sod-class-nickname class)))
 220
 221       (labels ((parse-maybe-dotted-declarator (base-type)
 222                  ;; Parse a declarator or dotted-declarator, i.e., one whose
 223                  ;; centre is
 224                  ;;
 225                  ;; maybe-dotted-identifier ::= [id `.'] id
 226                  ;;
 227                  ;; A plain identifier is returned as a string, as usual; a
 228                  ;; dotted identifier is returned as a cons cell of the two
 229                  ;; names.
 230                  (parse-declarator
 231                   scanner base-type
 232                   :keywordp t
 233                   :kernel (parser ()
 234                             (seq ((name-a :id)
 235                                   (name-b (? (seq (#\. (id :id)) id))))
 236                               (if name-b (cons name-a name-b)
 237                                   name-a)))))
 238
 239                (parse-message-item (sub-pset type name)
 240                  ;; message-item ::=
 241                  ;;     declspec+ declarator -!- (method-body | `;')
 242                  ;;
 243                  ;; Don't allow a method-body here if the message takes a
 244                  ;; varargs list, because we don't have a name for the
 245                  ;; `va_list' parameter.
 246                  (let ((message (make-sod-message class name type
 247                                                   sub-pset scanner)))
 248                    (if (varargs-message-p message)
 249                        (parse #\;)
 250                        (parse (or #\; (parse-method-item sub-pset
 251                                                          type nick name))))))
 252
 253                (parse-method-item (sub-pset type sub-nick name)
 254                  ;; method-item ::=
 255                  ;;     declspec+ dotted-declarator -!- method-body
 256                  ;;
 257                  ;; method-body ::= `{' c-fragment `}' | `extern' `;'
 258                  (parse (seq ((body (or (seq ("extern" #\;) nil)
 259                                         (parse-delimited-fragment
 260                                          scanner #\{ #\}))))
 261                           (make-sod-method class sub-nick name type
 262                                            body sub-pset scanner))))
 263
 264                (parse-initializer ()
 265                  ;; initializer ::= `=' c-fragment
 266                  ;;
 267                  ;; Return a VALUE, ready for passing to a `sod-initializer'
 268                  ;; constructor.
 269                  (parse-delimited-fragment scanner #\= (list #\, #\;)
 270                                            :keep-end t))
 271
 272                (parse-slot-item (sub-pset base-type type name)
 273                  ;; slot-item ::=
 274                  ;;     declspec+ declarator -!- [initializer]
 275                  ;;             [`,' init-declarator-list] `;'
 276                  ;;
 277                  ;; init-declarator-list ::=
 278                  ;;     declarator [initializer] [`,' init-declarator-list]
 279                  (parse (and (seq ((init (? (parse-initializer))))
 280                                (make-sod-slot class name type
 281                                               sub-pset scanner)
 282                                (when init
 283                                  (make-sod-instance-initializer
 284                                   class nick name init sub-pset scanner)))
 285                              (skip-many ()
 286                                (seq (#\,
 287                                      (ds (parse-declarator scanner
 288                                                            base-type))
 289                                      (init (? (parse-initializer))))
 290                                  (make-sod-slot class (cdr ds) (car ds)
 291                                                 sub-pset scanner)
 292                                  (when init
 293                                    (make-sod-instance-initializer
 294                                     class nick (cdr ds) init
 295                                     sub-pset scanner))))
 296                              #\;)))
 297
 298                (parse-initializer-item (sub-pset constructor)
 299                  ;; initializer-item ::=
 300                  ;;     [`class'] -!- slot-initializer-list `;'
 301                  ;;
 302                  ;; slot-initializer ::= id `.' id initializer
 303                  (parse (and (skip-many ()
 304                                (seq ((name-a :id) #\. (name-b :id)
 305                                      (init (parse-initializer)))
 306                                  (funcall constructor class
 307                                           name-a name-b init
 308                                           sub-pset scanner))
 309                                #\,)
 310                              #\;)))
 311
 312                (class-item-dispatch (sub-pset base-type type name)
 313                  ;; Logically part of `parse-raw-class-item', but the
 314                  ;; indentation was getting crazy.  We're currently at
 315                  ;;
 316                  ;; raw-class-item ::=
 317                  ;;     declspec+ (declarator | dotted-declarator) -!- ...
 318                  ;;   | other-items
 319                  ;;
 320                  ;; If the declarator is dotted then this must be a method
 321                  ;; definition; otherwise it might be a message or slot.
 322                  (cond ((not (typep type 'c-function-type))
 323                         (when (consp name)
 324                           (cerror*-with-location
 325                            scanner
 326                            "Method declarations must have function type.")
 327                           (setf name (cdr name)))
 328                         (parse-slot-item sub-pset base-type type name))
 329                        ((consp name)
 330                         (parse-method-item sub-pset type
 331                                            (car name) (cdr name)))
 332                        (t
 333                         (parse-message-item sub-pset type name))))
 334
 335                (parse-raw-class-item (sub-pset)
 336                  ;; raw-class-item ::=
 337                  ;;     message-item
 338                  ;;   | method-item
 339                  ;;   | slot-item
 340                  ;;   | initializer-item
 341                  ;;   | initfrag-item
 342                  ;;
 343                  ;; Most of the above begin with declspecs and a declarator
 344                  ;; (which might be dotted).  So we parse that here and
 345                  ;; dispatch based on what we find.
 346                  (parse (or (plug class-item scanner class sub-pset)
 347                             (peek
 348                              (seq ((ds (parse-c-type scanner))
 349                                    (dc (parse-maybe-dotted-declarator ds))
 350                                    (nil (class-item-dispatch sub-pset
 351                                                              ds
 352                                                              (car dc)
 353                                                              (cdr dc))))))
 354                             (and "class"
 355                                  (parse-initializer-item
 356                                   sub-pset
 357                                   #'make-sod-class-initializer))
 358                             (parse-initializer-item
 359                              sub-pset
 360                              #'make-sod-instance-initializer)))))
 361
 362         (parse (seq (#\{
 363                      (nil (skip-many ()
 364                             (seq ((sub-pset (parse-property-set scanner))
 365                                   (nil (parse-raw-class-item sub-pset)))
 366                               (check-unused-properties sub-pset))))
 367                      (nil (error () #\})))
 368                  (finalize-sod-class class)
 369                  (add-to-module *module* class)))))))
 370
 371 (define-pluggable-parser module class (scanner pset)
 372   ;; `class' id [`:' id-list] class-body
 373   ;; `class' id `;'
 374   (with-parser-context (token-scanner-context :scanner scanner)
 375     (parse (seq ("class"
 376                  (name :id)
 377                  (nil (or (seq (#\;)
 378                             (make-class-type name))
 379                           (seq ((supers (? (seq (#\: (ids (list () :id #\,)))
 380                                              ids)))
 381                                 (nil (parse-class-body
 382                                       scanner
 383                                       pset name supers)))))))))))
 384
 385 ;;;----- That's all, folks --------------------------------------------------