chiark - git - mdw - sod/blob - src/module-parse.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Top-level parser for module syntax
   4 ;;;
   5 ;;; (c) 2010 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensible Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Toplevel syntax.
  30
  31 ;;; Type names.
  32
  33 (define-pluggable-parser module typename (scanner pset)
  34   ;; `typename' id ( `,' id )* `;'
  35   (declare (ignore pset))
  36   (with-parser-context (token-scanner-context :scanner scanner)
  37     (parse (and "typename"
  38                 (skip-many (:min 1)
  39                   (seq ((id :id))
  40                     (if (gethash id *module-type-map*)
  41                         (cerror* "Type `~A' already defined" id)
  42                         (add-to-module *module*
  43                                        (make-instance 'type-item
  44                                                       :name id))))
  45                   #\,)
  46                 #\;))))
  47
  48 ;;; Fragments.
  49
  50 (define-pluggable-parser module code (scanner pset)
  51   ;; `code' id `:' item-name [constraints] `{' c-fragment `}'
  52   ;;
  53   ;; constrains ::= `[' constraint-list `]'
  54   ;; constraint ::= item-name+
  55   ;; item-name ::= id | `(' id+ `)'
  56   (declare (ignore pset))
  57   (with-parser-context (token-scanner-context :scanner scanner)
  58     (labels ((kw ()
  59                (parse (seq ((kw :id))
  60                         (intern (frob-identifier kw) 'keyword))))
  61              (item ()
  62                (parse (or (kw)
  63                           (seq (#\( (names (list (:min 1) (kw))) #\))
  64                             names)))))
  65       (parse (seq ("code"
  66                    (reason (kw))
  67                    #\:
  68                    (name (item))
  69                    (constraints (? (seq (#\[
  70                                          (constraints (list (:min 1)
  71                                                         (list (:min 1)
  72                                                           (item))
  73                                                         #\,))
  74                                          #\])
  75                                      constraints)))
  76                    (fragment (parse-delimited-fragment scanner #\{ #\})))
  77                (add-to-module *module*
  78                               (make-instance 'code-fragment-item
  79                                              :fragment fragment
  80                                              :constraints constraints
  81                                              :reason reason
  82                                              :name name)))))))
  83
  84 ;;; External files.
  85
  86 (export 'read-module)
  87 (defun read-module (pathname &key (truename nil truep) location)
  88   "Parse the file at PATHNAME as a module, returning it.
  89
  90    This is the main entry point for parsing module files.  You may well know
  91    the file's TRUENAME already (e.g., because `probe-file' dropped it into
  92    your lap) so you can avoid repeating the search by providing it.
  93
  94    The LOCATION is the thing which wanted the module imported -- usually a
  95    `file-location' object, though it might be anything other than `t' which
  96    can be printed in the event of circular imports."
  97
  98   (setf pathname (merge-pathnames pathname
  99                                   (make-pathname :type "SOD" :case :common)))
 100   (unless truep (setf truename (truename pathname)))
 101   (define-module (pathname :location location :truename truename)
 102     (with-open-file (f-stream pathname :direction :input)
 103       (let* ((*readtable* (copy-readtable))
 104              (*package* (find-package '#:sod-user))
 105              (char-scanner (make-instance 'charbuf-scanner
 106                                           :stream f-stream))
 107              (scanner (make-instance 'sod-token-scanner
 108                                      :char-scanner char-scanner)))
 109         (with-default-error-location (scanner)
 110           (with-parser-context (token-scanner-context :scanner scanner)
 111             (multiple-value-bind (result winp consumedp)
 112                 (parse (skip-many ()
 113                           (seq ((pset (parse-property-set scanner))
 114                                 (nil (error ()
 115                                        (plug module scanner pset))))
 116                             (check-unused-properties pset))))
 117               (declare (ignore consumedp))
 118               (unless winp (syntax-error scanner result)))))))))
 119
 120 (define-pluggable-parser module test (scanner pset)
 121   ;; `demo' string `;'
 122   (declare (ignore pset))
 123   (with-parser-context (token-scanner-context :scanner scanner)
 124     (parse (seq ("demo" (string :string) #\;)
 125              (format t ";; DEMO ~S~%" string)))))
 126
 127 (define-pluggable-parser module file (scanner pset)
 128   ;; `import' string `;'
 129   ;; `load' string `;'
 130   (declare (ignore pset))
 131   (flet ((common (name type what thunk)
 132            (find-file scanner
 133                       (merge-pathnames name
 134                                        (make-pathname :type type
 135                                                       :case :common))
 136                       what
 137                       thunk)))
 138     (with-parser-context (token-scanner-context :scanner scanner)
 139       (parse (or (seq ("import" (name :string) #\;)
 140                    (common name "SOD" "module"
 141                            (lambda (path true)
 142                              (handler-case
 143                                  (let ((module (read-module path
 144                                                             :truename true)))
 145                                    (when module
 146                                      (module-import module)
 147                                      (pushnew module
 148                                               (module-dependencies
 149                                                *module*))))
 150                                (file-error (error)
 151                                  (cerror* "Error reading module ~S: ~A"
 152                                           path error))))))
 153                  (seq ("load" (name :string) #\;)
 154                    (common name "LISP" "Lisp file"
 155                            (lambda (path true)
 156                              (handler-case
 157                                  (load true :verbose nil :print nil)
 158                                (error (error)
 159                                  (cerror* "Error loading Lisp file ~S: ~A"
 160                                           path error)))))))))))
 161
 162 ;;; Setting properties.
 163
 164 (define-pluggable-parser module set (scanner pset)
 165   ;; `set' property-list `;'
 166   (with-parser-context (token-scanner-context :scanner scanner)
 167     (parse (and "set"
 168                 (lisp (let ((module-pset (module-pset *module*)))
 169                         (when pset
 170                           (pset-map (lambda (prop)
 171                                       (add-property module-pset
 172                                                     (p-name prop)
 173                                                     (p-value prop)
 174                                                     :type (p-type prop)
 175                                                     :location (p-location prop))
 176                                       (setf (p-seenp prop) t))
 177                                     pset))
 178                         (parse (skip-many (:min 0)
 179                                  (error (:ignore-unconsumed t)
 180                                    (parse-property scanner module-pset)
 181                                    (skip-until (:keep-end t) #\, #\;))
 182                                  #\,))))
 183                 #\;))))
 184
 185 ;;; Lisp escape.
 186
 187 (define-pluggable-parser module lisp (scanner pset)
 188   ;; `lisp' s-expression `;'
 189   (declare (ignore pset))
 190   (with-parser-context (token-scanner-context :scanner scanner)
 191     (parse (seq ((sexp (if (and (eql (token-type scanner) :id)
 192                                 (string= (token-value scanner) "lisp"))
 193                            (let* ((stream (make-scanner-stream scanner))
 194                                   (sexp (read stream t)))
 195                              (scanner-step scanner)
 196                              (values sexp t t))
 197                            (values '((:id "lisp")) nil nil)))
 198                  #\;)
 199              (eval sexp)))))
 200
 201 ;;;--------------------------------------------------------------------------
 202 ;;; Class declarations.
 203
 204 (export 'class-item)
 205
 206 (define-pluggable-parser class-item initfrags (scanner class pset)
 207   ;; raw-class-item ::= frag-keyword `{' c-fragment `}'
 208   ;; frag-keyword ::= `init' | `teardown'
 209   (with-parser-context (token-scanner-context :scanner scanner)
 210     (parse (seq ((make (or (seq ("init") #'make-sod-class-initfrag)
 211                            (seq ("teardown") #'make-sod-class-tearfrag)))
 212                  (frag (parse-delimited-fragment scanner #\{ #\})))
 213              (funcall make class frag pset scanner)))))
 214
 215 (define-pluggable-parser class-item initargs (scanner class pset)
 216   ;; initarg-item ::= `initarg' declspec+ init-declarator-list
 217   ;; init-declarator ::= declarator [`=' initializer]
 218   (with-parser-context (token-scanner-context :scanner scanner)
 219     (parse (seq ("initarg"
 220                  (base-type (parse-c-type scanner))
 221                  (nil (skip-many (:min 1)
 222                         (seq ((declarator (parse-declarator scanner
 223                                                             base-type))
 224                               (init (? (parse-delimited-fragment
 225                                         scanner #\= (list #\; #\,)
 226                                         :keep-end t))))
 227                           (make-sod-user-initarg class
 228                                                  (cdr declarator)
 229                                                  (car declarator)
 230                                                  pset init scanner))
 231                         #\,))
 232                    #\;)))))
 233
 234 (defun parse-class-body (scanner pset name supers)
 235   ;; class-body ::= `{' class-item* `}'
 236   ;;
 237   ;; class-item ::= property-set raw-class-item
 238   (with-parser-context (token-scanner-context :scanner scanner)
 239     (make-class-type name)
 240     (let* ((class (make-sod-class name (mapcar #'find-sod-class supers)
 241                                   pset scanner))
 242            (nick (sod-class-nickname class)))
 243
 244       (labels ((parse-maybe-dotted-declarator (base-type)
 245                  ;; Parse a declarator or dotted-declarator, i.e., one whose
 246                  ;; centre is
 247                  ;;
 248                  ;; maybe-dotted-identifier ::= [id `.'] id
 249                  ;;
 250                  ;; A plain identifier is returned as a string, as usual; a
 251                  ;; dotted identifier is returned as a cons cell of the two
 252                  ;; names.
 253                  (parse-declarator
 254                   scanner base-type
 255                   :keywordp t
 256                   :kernel (parser ()
 257                             (seq ((name-a :id)
 258                                   (name-b (? (seq (#\. (id :id)) id))))
 259                               (if name-b (cons name-a name-b)
 260                                   name-a)))))
 261
 262                (parse-message-item (sub-pset type name)
 263                  ;; message-item ::=
 264                  ;;     declspec+ declarator -!- (method-body | `;')
 265                  ;;
 266                  ;; Don't allow a method-body here if the message takes a
 267                  ;; varargs list, because we don't have a name for the
 268                  ;; `va_list' parameter.
 269                  (let ((message (make-sod-message class name type
 270                                                   sub-pset scanner)))
 271                    (if (varargs-message-p message)
 272                        (parse #\;)
 273                        (parse (or #\; (parse-method-item sub-pset
 274                                                          type nick name))))))
 275
 276                (parse-method-item (sub-pset type sub-nick name)
 277                  ;; method-item ::=
 278                  ;;     declspec+ dotted-declarator -!- method-body
 279                  ;;
 280                  ;; method-body ::= `{' c-fragment `}' | `extern' `;'
 281                  (parse (seq ((body (or (seq ("extern" #\;) nil)
 282                                         (parse-delimited-fragment
 283                                          scanner #\{ #\}))))
 284                           (make-sod-method class sub-nick name type
 285                                            body sub-pset scanner))))
 286
 287                (parse-initializer ()
 288                  ;; initializer ::= `=' c-fragment
 289                  ;;
 290                  ;; Return a VALUE, ready for passing to a `sod-initializer'
 291                  ;; constructor.
 292                  (parse-delimited-fragment scanner #\= (list #\, #\;)
 293                                            :keep-end t))
 294
 295                (parse-slot-item (sub-pset base-type type name)
 296                  ;; slot-item ::=
 297                  ;;     declspec+ declarator -!- [initializer]
 298                  ;;             [`,' init-declarator-list] `;'
 299                  ;;
 300                  ;; init-declarator-list ::=
 301                  ;;     declarator [initializer] [`,' init-declarator-list]
 302                  (parse (and (seq ((init (? (parse-initializer))))
 303                                (make-sod-slot class name type
 304                                               sub-pset scanner)
 305                                (when init
 306                                  (make-sod-instance-initializer
 307                                   class nick name init sub-pset scanner)))
 308                              (skip-many ()
 309                                (seq (#\,
 310                                      (ds (parse-declarator scanner
 311                                                            base-type))
 312                                      (init (? (parse-initializer))))
 313                                  (make-sod-slot class (cdr ds) (car ds)
 314                                                 sub-pset scanner)
 315                                  (when init
 316                                    (make-sod-instance-initializer
 317                                     class nick (cdr ds) init
 318                                     sub-pset scanner))))
 319                              #\;)))
 320
 321                (parse-initializer-item (sub-pset must-init-p constructor)
 322                  ;; initializer-item ::=
 323                  ;;     [`class'] -!- slot-initializer-list `;'
 324                  ;;
 325                  ;; slot-initializer ::= id `.' id [initializer]
 326                  (let ((parse-init (if must-init-p
 327                                        #'parse-initializer
 328                                        (parser () (? (parse-initializer))))))
 329                    (parse (and (skip-many ()
 330                                  (seq ((name-a :id) #\. (name-b :id)
 331                                        (init (funcall parse-init)))
 332                                    (funcall constructor class
 333                                             name-a name-b init
 334                                             sub-pset scanner))
 335                                  #\,)
 336                                #\;))))
 337
 338                (class-item-dispatch (sub-pset base-type type name)
 339                  ;; Logically part of `parse-raw-class-item', but the
 340                  ;; indentation was getting crazy.  We're currently at
 341                  ;;
 342                  ;; raw-class-item ::=
 343                  ;;     declspec+ (declarator | dotted-declarator) -!- ...
 344                  ;;   | other-items
 345                  ;;
 346                  ;; If the declarator is dotted then this must be a method
 347                  ;; definition; otherwise it might be a message or slot.
 348                  (cond ((not (typep type 'c-function-type))
 349                         (when (consp name)
 350                           (cerror*-with-location
 351                            scanner
 352                            "Method declarations must have function type.")
 353                           (setf name (cdr name)))
 354                         (parse-slot-item sub-pset base-type type name))
 355                        ((consp name)
 356                         (parse-method-item sub-pset type
 357                                            (car name) (cdr name)))
 358                        (t
 359                         (parse-message-item sub-pset type name))))
 360
 361                (parse-raw-class-item (sub-pset)
 362                  ;; raw-class-item ::=
 363                  ;;     message-item
 364                  ;;   | method-item
 365                  ;;   | slot-item
 366                  ;;   | initializer-item
 367                  ;;   | initfrag-item
 368                  ;;
 369                  ;; Most of the above begin with declspecs and a declarator
 370                  ;; (which might be dotted).  So we parse that here and
 371                  ;; dispatch based on what we find.
 372                  (parse (or (plug class-item scanner class sub-pset)
 373                             (peek
 374                              (seq ((ds (parse-c-type scanner))
 375                                    (dc (parse-maybe-dotted-declarator ds))
 376                                    (nil (commit))
 377                                    (nil (class-item-dispatch sub-pset
 378                                                              ds
 379                                                              (car dc)
 380                                                              (cdr dc))))))
 381                             (and "class"
 382                                  (parse-initializer-item
 383                                   sub-pset t
 384                                   #'make-sod-class-initializer))
 385                             (parse-initializer-item
 386                              sub-pset nil
 387                              #'make-sod-instance-initializer)))))
 388
 389         (parse (seq (#\{
 390                      (nil (skip-many ()
 391                             (seq ((sub-pset (parse-property-set scanner))
 392                                   (nil (parse-raw-class-item sub-pset)))
 393                               (check-unused-properties sub-pset))))
 394                      (nil (error () #\})))
 395                  (finalize-sod-class class)
 396                  (add-to-module *module* class)))))))
 397
 398 (define-pluggable-parser module class (scanner pset)
 399   ;; `class' id [`:' id-list] class-body
 400   ;; `class' id `;'
 401   (with-parser-context (token-scanner-context :scanner scanner)
 402     (parse (seq ("class"
 403                  (name :id)
 404                  (nil (or (seq (#\;)
 405                             (make-class-type name))
 406                           (seq ((supers (? (seq (#\: (ids (list () :id #\,)))
 407                                              ids)))
 408                                 (nil (parse-class-body
 409                                       scanner
 410                                       pset name supers)))))))))))
 411
 412 ;;;----- That's all, folks --------------------------------------------------