chiark - git - mdw - sod/blob - src/module-parse.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Top-level parser for module syntax
   4 ;;;
   5 ;;; (c) 2010 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensible Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Toplevel syntax.
  30
  31 ;;; Type names.
  32
  33 (define-pluggable-parser module typename (scanner pset)
  34   ;; `typename' list[id] `;'
  35   (declare (ignore pset))
  36   (with-parser-context (token-scanner-context :scanner scanner)
  37     (parse (and "typename"
  38                 (skip-many ()
  39                   (error ()
  40                       (seq ((id :id))
  41                         (if (or (gethash id *module-type-map*)
  42                                 (find-simple-c-type id))
  43                             (cerror* "Type `~A' already defined" id)
  44                             (add-to-module *module*
  45                                            (make-instance 'type-item
  46                                                           :name id))))
  47                     (skip-until () #\, #\;))
  48                   #\,)
  49                 (must #\;)))))
  50
  51 ;;; Fragments.
  52
  53 (define-pluggable-parser module code (scanner pset)
  54   ;; `code' id `:' item-name [constraints] `{' c-fragment `}'
  55   ;;
  56   ;; constraints ::= `[' list[constraint] `]'
  57   ;; constraint ::= item-name+
  58   ;; item-name ::= id | `(' id+ `)'
  59   (declare (ignore pset))
  60   (with-parser-context (token-scanner-context :scanner scanner)
  61     (labels ((kw ()
  62                (parse (seq ((kw :id))
  63                         (intern (frob-identifier kw) 'keyword))))
  64              (item ()
  65                (parse (or (kw)
  66                           (seq (#\( (names (list (:min 1) (kw))) #\))
  67                             names)))))
  68       (parse (seq ("code"
  69                    (reason (must (kw)))
  70                    (nil (must #\:))
  71                    (name (must (item)))
  72                    (constraints (? (seq (#\[
  73                                          (constraints
  74                                           (list ()
  75                                             (list (:min 1)
  76                                               (error (:ignore-unconsumed t)
  77                                                   (item)
  78                                                 (skip-until ()
  79                                                   :id #\( #\, #\])))
  80                                             #\,))
  81                                          #\])
  82                                      constraints)))
  83                    (fragment (parse-delimited-fragment scanner #\{ #\})))
  84                (when name
  85                  (add-to-module *module*
  86                                 (make-instance 'code-fragment-item
  87                                                :fragment fragment
  88                                                :constraints constraints
  89                                                :reason reason
  90                                                :name name))))))))
  91
  92 ;;; External files.
  93
  94 (export 'read-module)
  95 (defun read-module (pathname &key (truename nil truep) location)
  96   "Parse the file at PATHNAME as a module, returning it.
  97
  98    This is the main entry point for parsing module files.  You may well know
  99    the file's TRUENAME already (e.g., because `probe-file' dropped it into
 100    your lap) so you can avoid repeating the search by providing it.
 101
 102    The LOCATION is the thing which wanted the module imported -- usually a
 103    `file-location' object, though it might be anything other than `t' which
 104    can be printed in the event of circular imports."
 105
 106   (setf pathname (merge-pathnames pathname
 107                                   (make-pathname :type "SOD" :case :common)))
 108   (unless truep (setf truename (truename pathname)))
 109   (define-module (pathname :location location :truename truename)
 110     (with-open-file (f-stream pathname :direction :input)
 111       (let* ((*readtable* (copy-readtable))
 112              (*package* (find-package '#:sod-user))
 113              (char-scanner (make-instance 'charbuf-scanner
 114                                           :stream f-stream
 115                                           :filename (namestring pathname)))
 116              (scanner (make-instance 'sod-token-scanner
 117                                      :char-scanner char-scanner)))
 118         (with-default-error-location (scanner)
 119           (with-parser-context (token-scanner-context :scanner scanner)
 120             (multiple-value-bind (result winp consumedp)
 121                 (parse (skip-many ()
 122                           (seq ((pset (parse-property-set scanner))
 123                                 (nil (error ()
 124                                          (plug module scanner pset)
 125                                        (skip-until (:keep-end nil)
 126                                          #\; #\}))))
 127                             (check-unused-properties pset))))
 128               (declare (ignore consumedp))
 129               (unless winp (syntax-error scanner result)))))))))
 130
 131 (define-pluggable-parser module test (scanner pset)
 132   ;; `demo' string `;'
 133   (declare (ignore pset))
 134   (with-parser-context (token-scanner-context :scanner scanner)
 135     (parse (seq ("demo" (string (must :string)) (nil (must #\;)))
 136              (format t ";; DEMO ~S~%" string)))))
 137
 138 (define-pluggable-parser module file (scanner pset)
 139   ;; `import' string `;'
 140   ;; `load' string `;'
 141   (declare (ignore pset))
 142   (flet ((common (name type what thunk)
 143            (when name
 144              (find-file (pathname (scanner-filename scanner))
 145                         (merge-pathnames name
 146                                          (make-pathname :type type
 147                                                         :case :common))
 148                         what
 149                         thunk))))
 150     (with-parser-context (token-scanner-context :scanner scanner)
 151       (parse (or (seq ("import" (name (must :string)) (nil (must #\;)))
 152                    (common name "SOD" "module"
 153                            (lambda (path true)
 154                              (handler-case
 155                                  (let ((module (read-module path
 156                                                             :truename true)))
 157                                    (when module
 158                                      (module-import module)
 159                                      (pushnew module
 160                                               (module-dependencies
 161                                                *module*))))
 162                                (file-error (error)
 163                                  (cerror* "Error reading module ~S: ~A"
 164                                           path error))
 165                                (error (error)
 166                                  (cerror* "Unexpected error reading ~
 167                                            module ~S: ~A"
 168                                           path error))))))
 169                  (seq ("load" (name (must :string)) (nil (must #\;)))
 170                    (common name "LISP" "Lisp file"
 171                            (lambda (path true)
 172                              (handler-case
 173                                  (load true :verbose nil :print nil)
 174                                (error (error)
 175                                  (cerror* "Error loading Lisp file ~S: ~A"
 176                                           path error)))))))))))
 177
 178 ;;; Setting properties.
 179
 180 (define-pluggable-parser module set (scanner pset)
 181   ;; `set' list[property] `;'
 182   (with-parser-context (token-scanner-context :scanner scanner)
 183     (parse (and "set"
 184                 (lisp (let ((module-pset (module-pset *module*)))
 185                         (when pset
 186                           (pset-map (lambda (prop)
 187                                       (add-property
 188                                        module-pset
 189                                        (p-name prop) (p-value prop)
 190                                        :type (p-type prop)
 191                                        :location (p-location prop))
 192                                       (setf (p-seenp prop) t))
 193                                     pset))
 194                         (parse (skip-many (:min (if pset 0 1))
 195                                  (error (:ignore-unconsumed t)
 196                                      (parse-property scanner module-pset)
 197                                    (skip-until () #\, #\;))
 198                                  #\,))))
 199                 #\;))))
 200
 201 ;;; Lisp escape.
 202
 203 (define-pluggable-parser module lisp (scanner pset)
 204   ;; `lisp' s-expression `;'
 205   (declare (ignore pset))
 206   (with-parser-context (token-scanner-context :scanner scanner)
 207     (parse (seq ((sexp (if (and (eql (token-type scanner) :id)
 208                                 (string= (token-value scanner) "lisp"))
 209                            (let* ((stream (make-scanner-stream scanner))
 210                                   (sexp (read stream t)))
 211                              (scanner-step scanner)
 212                              (values sexp t t))
 213                            (values '((:id "lisp")) nil nil)))
 214                  (nil (must #\;)))
 215              (eval sexp)))))
 216
 217 ;;;--------------------------------------------------------------------------
 218 ;;; Class declarations.
 219
 220 (export 'class-item)
 221
 222 (define-pluggable-parser class-item initfrags (scanner class pset)
 223   ;; raw-class-item ::= frag-keyword `{' c-fragment `}'
 224   ;; frag-keyword ::= `init' | `teardown'
 225   (with-parser-context (token-scanner-context :scanner scanner)
 226     (parse (seq ((make (or (seq ("init") #'make-sod-class-initfrag)
 227                            (seq ("teardown") #'make-sod-class-tearfrag)))
 228                  (frag (parse-delimited-fragment scanner #\{ #\})))
 229              (funcall make class frag pset :location scanner)))))
 230
 231 (define-pluggable-parser class-item initargs (scanner class pset)
 232   ;; initarg-item ::= `initarg' declspec+ list[init-declarator]
 233   ;; init-declarator ::= declarator [`=' initializer]
 234   (with-parser-context (token-scanner-context :scanner scanner)
 235     (parse (seq ("initarg"
 236                  (base-type (parse-c-type scanner))
 237                  (nil (skip-many (:min 1)
 238                         (seq ((declarator (parse-declarator scanner
 239                                                             base-type))
 240                               (init (? (parse-delimited-fragment
 241                                         scanner #\= (list #\; #\,)
 242                                         :keep-end t))))
 243                           (make-sod-user-initarg class
 244                                                  (cdr declarator)
 245                                                  (car declarator)
 246                                                  pset
 247                                                  :default init
 248                                                  :location scanner))
 249                         #\,))
 250                  (nil (must #\;)))))))
 251
 252 (defun synthetic-name ()
 253   "Return an obviously bogus synthetic not-identifier."
 254   (let ((ix *temporary-index*))
 255     (incf *temporary-index*)
 256     (make-instance 'temporary-variable :tag (format nil "%%#~A" ix))))
 257
 258 (defun parse-class-body (scanner pset name supers)
 259   ;; class-body ::= `{' class-item* `}'
 260   ;;
 261   ;; class-item ::= property-set raw-class-item
 262   (with-parser-context (token-scanner-context :scanner scanner)
 263     (when name (make-class-type name))
 264     (let* ((duff (null name))
 265            (superclasses
 266             (let ((superclasses (restart-case
 267                                     (mapcar #'find-sod-class
 268                                             (or supers (list "SodObject")))
 269                                   (continue ()
 270                                     (setf duff t)
 271                                     (list (find-sod-class "SodObject"))))))
 272               (find-duplicates (lambda (first second)
 273                                  (declare (ignore second))
 274                                  (setf duff t)
 275                                  (cerror* "Class `~A' has duplicate ~
 276                                            direct superclass `~A'"
 277                                           name first))
 278                                superclasses)
 279               (delete-duplicates superclasses)))
 280            (synthetic-name (or name
 281                                (let ((var (synthetic-name)))
 282                                  (unless pset
 283                                    (setf pset (make-property-set)))
 284                                  (unless (pset-get pset "nick")
 285                                    (add-property pset "nick" var :type :id))
 286                                  var)))
 287            (class (make-sod-class synthetic-name superclasses pset
 288                                   :location scanner))
 289            (nick (sod-class-nickname class)))
 290
 291       (labels ((must-id ()
 292                  (parse (must :id (progn (setf duff t) (synthetic-name)))))
 293
 294                (parse-maybe-dotted-name ()
 295                  ;; maybe-dotted-name ::= [id `.'] id
 296                  ;;
 297                  ;; A plain identifier is returned as a string, as usual; a
 298                  ;; dotted identifier is returned as a cons cell of the two
 299                  ;; names.
 300                  (parse (seq ((name-a (must-id))
 301                               (name-b (? (seq (#\. (id (must-id))) id))))
 302                           (if name-b (cons name-a name-b)
 303                               name-a))))
 304
 305                (parse-maybe-dotted-declarator (base-type)
 306                  ;; Parse a declarator or dotted-declarator, i.e., one whose
 307                  ;; centre is maybe-dotted-name above.
 308                  (parse-declarator scanner base-type
 309                                    :keywordp t
 310                                    :kernel #'parse-maybe-dotted-name))
 311
 312                (parse-message-item (sub-pset type name)
 313                  ;; message-item ::=
 314                  ;;     declspec+ declarator -!- (method-body | `;')
 315                  ;;
 316                  ;; Don't allow a method-body here if the message takes a
 317                  ;; varargs list, because we don't have a name for the
 318                  ;; `va_list' parameter.
 319                  (let ((message (make-sod-message class name type sub-pset
 320                                                   :location scanner)))
 321                    (if (varargs-message-p message)
 322                        (parse #\;)
 323                        (parse (or #\; (parse-method-item sub-pset
 324                                                          type nick name))))))
 325
 326                (parse-method-item (sub-pset type sub-nick name)
 327                  ;; method-item ::=
 328                  ;;     declspec+ dotted-declarator -!- method-body
 329                  ;;
 330                  ;; method-body ::= `{' c-fragment `}' | `extern' `;'
 331                  (parse (seq ((body (or (seq ("extern" #\;) nil)
 332                                         (parse-delimited-fragment
 333                                          scanner #\{ #\}))))
 334                           (restart-case
 335                               (make-sod-method class sub-nick name type
 336                                                body sub-pset
 337                                                :location scanner)
 338                             (continue () :report "Continue")))))
 339
 340                (parse-initializer ()
 341                  ;; initializer ::= `=' c-fragment
 342                  ;;
 343                  ;; Return a VALUE, ready for passing to a `sod-initializer'
 344                  ;; constructor.
 345                  (parse-delimited-fragment scanner #\= '(#\, #\;)
 346                                            :keep-end t))
 347
 348                (parse-slot-item (sub-pset base-type type name)
 349                  ;; slot-item ::=
 350                  ;;     declspec+ declarator -!- [initializer]
 351                  ;;             [`,' list[init-declarator]] `;'
 352                  ;;
 353                  ;; init-declarator ::= declarator [initializer]
 354                  (flet ((make-it (name type init)
 355                           (restart-case
 356                               (progn
 357                                 (make-sod-slot class name type sub-pset
 358                                                :location scanner)
 359                                 (when init
 360                                   (make-sod-instance-initializer
 361                                    class nick name init sub-pset
 362                                    :location scanner)))
 363                             (continue () :report "Continue"))))
 364                    (parse (and (error ()
 365                                    (seq ((init (? (parse-initializer))))
 366                                      (make-it name type init))
 367                                  (skip-until () #\, #\;))
 368                                (skip-many ()
 369                                  (error (:ignore-unconsumed t)
 370                                      (seq (#\,
 371                                            (ds (parse-declarator scanner
 372                                                                  base-type))
 373                                            (init (? (parse-initializer))))
 374                                        (make-it (cdr ds) (car ds) init))
 375                                    (skip-until () #\, #\;)))
 376                                (must #\;)))))
 377
 378                (parse-initializer-item (sub-pset must-init-p constructor)
 379                  ;; initializer-item ::=
 380                  ;;     [`class'] -!- list[slot-initializer] `;'
 381                  ;;
 382                  ;; slot-initializer ::= id `.' id [initializer]
 383                  (let ((parse-init (if must-init-p #'parse-initializer
 384                                        (parser () (? (parse-initializer))))))
 385                    (parse (and (skip-many ()
 386                                  (error (:ignore-unconsumed t)
 387                                      (seq ((name-a :id) #\.
 388                                            (name-b (must-id))
 389                                            (init (funcall parse-init)))
 390                                        (restart-case
 391                                            (funcall constructor class
 392                                                     name-a name-b init
 393                                                     sub-pset
 394                                                     :location scanner)
 395                                          (continue () :report "Continue")))
 396                                    (skip-until () #\, #\;))
 397                                  #\,)
 398                                (must #\;)))))
 399
 400                (class-item-dispatch (sub-pset base-type type name)
 401                  ;; Logically part of `parse-raw-class-item', but the
 402                  ;; indentation was getting crazy.  We're currently at
 403                  ;;
 404                  ;; raw-class-item ::=
 405                  ;;     declspec+ (declarator | dotted-declarator) -!- ...
 406                  ;;   | other-items
 407                  ;;
 408                  ;; If the declarator is dotted then this must be a method
 409                  ;; definition; otherwise it might be a message or slot.
 410                  (cond ((not (typep type 'c-function-type))
 411                         (when (consp name)
 412                           (cerror*
 413                            "Method declarations must have function type")
 414                           (setf name (cdr name)))
 415                         (parse-slot-item sub-pset base-type type name))
 416                        ((consp name)
 417                         (parse-method-item sub-pset type
 418                                            (car name) (cdr name)))
 419                        (t
 420                         (parse-message-item sub-pset type name))))
 421
 422                (parse-raw-class-item (sub-pset)
 423                  ;; raw-class-item ::=
 424                  ;;     message-item
 425                  ;;   | method-item
 426                  ;;   | slot-item
 427                  ;;   | initializer-item
 428                  ;;   | initfrag-item
 429                  ;;
 430                  ;; Most of the above begin with declspecs and a declarator
 431                  ;; (which might be dotted).  So we parse that here and
 432                  ;; dispatch based on what we find.
 433                  (parse (or (plug class-item scanner class sub-pset)
 434                             (peek
 435                              (seq ((ds (parse-c-type scanner))
 436                                    (dc (parse-maybe-dotted-declarator ds))
 437                                    (nil (commit))
 438                                    (nil (class-item-dispatch sub-pset
 439                                                              ds
 440                                                              (car dc)
 441                                                              (cdr dc))))))
 442                             (and "class"
 443                                  (parse-initializer-item sub-pset t
 444                                   #'make-sod-class-initializer))
 445                             (parse-initializer-item sub-pset nil
 446                              #'make-sod-instance-initializer)))))
 447
 448         (parse (seq ((nil (must #\{))
 449                      (nil (skip-many ()
 450                             (seq ((sub-pset (parse-property-set scanner))
 451                                   (nil (parse-raw-class-item sub-pset)))
 452                               (check-unused-properties sub-pset))))
 453                      (nil (must #\})))
 454                  (unless (finalize-sod-class class)
 455                    (setf duff t))
 456                  (unless duff
 457                    (add-to-module *module* class))))))))
 458
 459 (define-pluggable-parser module class (scanner pset)
 460   ;; `class' id `:' list[id] class-body
 461   ;; `class' id `;'
 462   (with-parser-context (token-scanner-context :scanner scanner)
 463     (parse (seq ("class"
 464                  (name (must :id))
 465                  (nil (or (seq (#\;)
 466                             (when name (make-class-type name)))
 467                           (seq ((supers (must (seq (#\:
 468                                                     (ids (list () :id #\,)))
 469                                                 ids)))
 470                                 (nil (parse-class-body
 471                                       scanner
 472                                       pset name supers)))))))))))
 473
 474 ;;;----- That's all, folks --------------------------------------------------