chiark - git - mdw - clg/blob - gtk/gtkobject.lisp

   1 ;; Common Lisp bindings for GTK+ v2.x
   2 ;; Copyright 1999-2005 Espen S. Johnsen <espen@users.sf.net>
   3 ;;
   4 ;; Permission is hereby granted, free of charge, to any person obtaining
   5 ;; a copy of this software and associated documentation files (the
   6 ;; "Software"), to deal in the Software without restriction, including
   7 ;; without limitation the rights to use, copy, modify, merge, publish,
   8 ;; distribute, sublicense, and/or sell copies of the Software, and to
   9 ;; permit persons to whom the Software is furnished to do so, subject to
  10 ;; the following conditions:
  11 ;;
  12 ;; The above copyright notice and this permission notice shall be
  13 ;; included in all copies or substantial portions of the Software.
  14 ;;
  15 ;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  16 ;; EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 ;; MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  18 ;; IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
  19 ;; CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 ;; TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 ;; SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 ;; $Id: gtkobject.lisp,v 1.46 2008/03/04 16:03:38 espen Exp $
  24
  25
  26 (in-package "GTK")
  27
  28
  29 ;;;; Superclass for the gtk class hierarchy
  30
  31 (eval-when (:compile-toplevel :load-toplevel :execute)
  32   (init-types-in-library gtk "libgtk-2.0")
  33
  34   (defclass %object (gobject)
  35     ()
  36     (:metaclass gobject-class)
  37     (:gtype |gtk_object_get_type|)))
  38
  39
  40 (defmethod initialize-instance ((object %object) &rest initargs &key signal)
  41   (declare (ignore signal))
  42   (call-next-method)
  43   (dolist (signal-definition (get-all initargs :signal))
  44     (apply #'signal-connect object signal-definition)))
  45
  46 (defmethod initialize-instance :around ((object %object) &rest initargs)
  47   (declare (ignore initargs))
  48   (call-next-method)
  49   ;; Add a temorary reference which will be removed when the object is
  50   ;; sinked
  51   (funcall (reference-function '%object) (foreign-location object))
  52   (%object-sink object))
  53
  54 (defbinding %object-sink () nil
  55   (object %object))
  56
  57 ;;;; Main loop and event handling
  58
  59 (defparameter *reentrant-main-iteration* t)
  60 (defvar *running-main-iteration* nil)
  61
  62 (defbinding events-pending-p () boolean)
  63
  64 (defbinding get-current-event () gdk:event)
  65
  66 (defbinding main-do-event () nil
  67   (event gdk:event))
  68
  69 (defbinding main () nil)
  70
  71 (defbinding main-level () int)
  72
  73 (defbinding main-quit () nil)
  74
  75 (defbinding main-iteration-do (&optional (blocking t)) boolean
  76   (blocking boolean))
  77
  78 (defun main-iterate-all (&rest args)
  79   (declare (ignore args))
  80   (unless (and (not *reentrant-main-iteration*) *running-main-iteration*)
  81     (let ((*running-main-iteration* t))
  82       (loop
  83        while (events-pending-p)
  84        do (main-iteration-do nil))))
  85   #+clisp 0)
  86
  87
  88 (define-callback fd-source-callback-marshal nil
  89     ((callback-id unsigned-int) (fd unsigned-int))
  90   (glib::invoke-source-callback callback-id fd))
  91
  92 (defbinding (input-add "gtk_input_add_full") (fd condition function) unsigned-int
  93   (fd unsigned-int)
  94   (condition gdk:input-condition)
  95   (fd-source-callback-marshal callback)
  96   (nil null)
  97   ((register-callback-function function) unsigned-long)
  98   (user-data-destroy-callback callback))
  99
 100
 101 ;;;; Metaclass for child classes
 102
 103 (defvar *container-to-child-class-mappings* (make-hash-table))
 104
 105 (eval-when (:compile-toplevel :load-toplevel :execute)
 106   (defclass container-child-class (virtual-slots-class)
 107     ())
 108
 109   (defclass direct-child-slot-definition (direct-virtual-slot-definition)
 110     ((pname :reader slot-definition-pname :initarg :pname)))
 111
 112   (defclass effective-child-slot-definition (effective-virtual-slot-definition)
 113     ((pname :reader slot-definition-pname :initarg :pname))))
 114
 115
 116 (defmethod shared-initialize ((class container-child-class) names &key container)
 117   (declare (ignore names))
 118   (call-next-method)
 119   (setf
 120    (gethash (find-class (first container)) *container-to-child-class-mappings*)
 121     class)
 122   #+clisp
 123   (loop
 124    for slotd in (class-direct-slots class)
 125    when (typep slotd 'direct-child-slot-definition)
 126    do (loop
 127        for reader in (slot-definition-readers slotd)
 128        do (add-reader-method class
 129            (ensure-generic-function reader :lambda-list '(object))
 130            (slot-definition-name slotd)))
 131       (loop
 132        for writer in (slot-definition-writers slotd)
 133        do (add-writer-method class
 134            (ensure-generic-function writer :lambda-list '(value object))
 135            (slot-definition-name slotd)))))
 136
 137 (defmethod direct-slot-definition-class ((class container-child-class) &rest initargs)
 138   (case (getf initargs :allocation)
 139     (:property (find-class 'direct-child-slot-definition))
 140     (t (call-next-method))))
 141
 142 (defmethod effective-slot-definition-class ((class container-child-class) &rest initargs)
 143   (case (getf initargs :allocation)
 144     (:property (find-class 'effective-child-slot-definition))
 145     (t (call-next-method))))
 146
 147 (defmethod compute-effective-slot-definition-initargs ((class container-child-class) direct-slotds)
 148   (if (eq (slot-definition-allocation (first direct-slotds)) :property)
 149       (nconc
 150        (list :pname (most-specific-slot-value direct-slotds 'pname))
 151        (call-next-method))
 152     (call-next-method)))
 153
 154 (defmethod slot-readable-p ((slotd effective-child-slot-definition))
 155   (declare (ignore slotd))
 156   t)
 157
 158 (defmethod compute-slot-reader-function ((slotd effective-child-slot-definition) &optional signal-unbound-p)
 159   (declare (ignore signal-unbound-p))
 160   (let* ((type (slot-definition-type slotd))
 161          (pname (slot-definition-pname slotd))
 162          (reader (reader-function type :ref :get)))
 163     #'(lambda (object)
 164         (with-slots (parent child) object
 165           (with-memory (gvalue +gvalue-size+)
 166             (glib::%gvalue-init gvalue (find-type-number type))
 167             (%container-child-get-property parent child pname gvalue)
 168             (funcall reader gvalue +gvalue-value-offset+))))))
 169
 170 (defmethod slot-writable-p ((slotd effective-child-slot-definition))
 171   (declare (ignore slotd))
 172   t)
 173
 174 (defmethod compute-slot-writer-function ((slotd effective-child-slot-definition))
 175   (let* ((type (slot-definition-type slotd))
 176          (pname (slot-definition-pname slotd))
 177          (writer (writer-function type :temp t))
 178          (destroy (destroy-function type :temp t)))
 179     #'(lambda (value object)
 180         (with-slots (parent child) object
 181           (with-memory (gvalue +gvalue-size+)
 182             (glib::%gvalue-init gvalue (find-type-number type))
 183             (funcall writer value gvalue +gvalue-value-offset+)
 184             (%container-child-set-property parent child pname gvalue)
 185             (funcall destroy gvalue +gvalue-value-offset+))
 186           value))))
 187
 188
 189 (defmethod add-reader-method ((class container-child-class) generic-function slot-name #?(sbcl>= 1 0 2)slot-documentation #?(sbcl>= 1 0 14)source-location)
 190   (add-method
 191    generic-function
 192    (make-instance 'standard-method
 193     :specializers (list (find-class 'widget))
 194     :lambda-list '(widget)
 195     :documentation (or #?(sbcl>= 1 0 2)slot-documentation "automatically generated reader method")
 196     :function #'(lambda (args next-methods)
 197                   (declare (ignore next-methods))
 198                   (child-property-value (first args) slot-name)))))
 199
 200 (defmethod add-writer-method ((class container-child-class) generic-function slot-name #?(sbcl>= 1 0 2)slot-documentation #?(sbcl>= 1 0 14)source-location)
 201   (add-method
 202    generic-function
 203    (make-instance 'standard-method
 204     :specializers (list (find-class t) (find-class 'widget))
 205     :lambda-list '(value widget)
 206     :documentation (or #?(sbcl>= 1 0 2)slot-documentation "automatically generated reader method")
 207     :function #'(lambda (args next-methods)
 208                   (declare (ignore next-methods))
 209                   (destructuring-bind (value widget) args
 210                     (setf (child-property-value widget slot-name) value))))))
 211
 212
 213 (defmethod validate-superclass ((class container-child-class) (super standard-class))
 214   ;(subtypep (class-name super) 'container-child)
 215   t)
 216
 217
 218 (defclass container-child (virtual-slots-object)
 219   ((parent :initarg :parent :type container)
 220    (child :initarg :child :type widget)))
 221
 222
 223 ;;;;
 224
 225 (defbinding %container-class-list-child-properties () pointer
 226   (class pointer)
 227   (n-properties unsigned-int :out))
 228
 229 (defun query-container-class-child-properties (type-number)
 230   (let ((class (type-class-ref type-number)))
 231     (multiple-value-bind (array length)
 232         (%container-class-list-child-properties class)
 233       (unwind-protect
 234           (map-c-vector 'list #'identity array 'param length)
 235         (deallocate-memory array)))))
 236
 237 (defun default-container-child-name (container-class)
 238   (intern (format nil "~A-CHILD" container-class)))
 239
 240 (defun expand-container-type (type forward-p options)
 241   (let* ((class (type-from-number type))
 242          (super (supertype type))
 243          (child-class (default-container-child-name class)))
 244     (if forward-p
 245         (expand-gobject-type type t options)
 246       `(progn
 247          ,(expand-gobject-type type nil options)
 248          (defclass ,child-class (,(default-container-child-name super))
 249            ,(slot-definitions child-class
 250              (query-container-class-child-properties type) nil)
 251            (:metaclass container-child-class)
 252            (:container ,class))))))
 253
 254 (defun container-child-class (container-class)
 255   (gethash container-class *container-to-child-class-mappings*))
 256
 257 (defun container-dependencies (type options)
 258   (delete-duplicates
 259    (append
 260     (gobject-dependencies type options)
 261     (mapcar #'param-value-type (query-container-class-child-properties type)))))
 262
 263 (register-derivable-type 'container "GtkContainer" 'expand-container-type 'container-dependencies)
 264
 265
 266 (defmacro define-callback-setter (name arg return-type &rest rest-args)
 267   (let ((callback (gensym)))
 268     (if arg
 269         `(progn
 270            (define-callback-marshal ,callback ,return-type
 271              ,(cons arg rest-args))
 272            (defbinding ,name () nil
 273              ,arg
 274              (,callback callback)
 275              (function user-callback)
 276              (user-data-destroy-callback callback)))
 277       `(progn
 278          (define-callback-marshal ,callback ,return-type ,rest-args)
 279          (defbinding ,name () nil
 280            (,callback callback)
 281            (function user-callback)
 282            (user-data-destroy-callback callback))))))
 283