chiark - git - mdw - clg/blob - gtk/gtkcontainer.lisp

   1 ;; Common Lisp bindings for GTK+ v2.0
   2 ;; Copyright (C) 2000 Espen S. Johnsen <esj@stud.cs.uit.no>
   3 ;;
   4 ;; This library is free software; you can redistribute it and/or
   5 ;; modify it under the terms of the GNU Lesser General Public
   6 ;; License as published by the Free Software Foundation; either
   7 ;; version 2 of the License, or (at your option) any later version.
   8 ;;
   9 ;; This library is distributed in the hope that it will be useful,
  10 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 ;; Lesser General Public License for more details.
  13 ;;
  14 ;; You should have received a copy of the GNU Lesser General Public
  15 ;; License along with this library; if not, write to the Free Software
  16 ;; Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18 ;; $Id: gtkcontainer.lisp,v 1.14 2004/12/20 20:09:54 espen Exp $
  19
  20 (in-package "GTK")
  21
  22
  23 (defmethod shared-initialize ((container container) names &rest initargs
  24                               &key child children child-args)
  25   (declare (ignore child children))
  26   (call-next-method)
  27   (initial-add container
  28    #'(lambda (container args)
  29        (apply #'container-add container (append (mklist args) child-args)))
  30    initargs :child :children))
  31
  32
  33 (defbinding %container-add () nil
  34   (container container)
  35   (widget widget))
  36
  37 (defmethod container-add ((container container) (widget widget) &rest args)
  38   (%container-add container widget)
  39   (when args
  40     (setf
  41      (slot-value widget 'child-properties)
  42      (apply
  43       #'make-instance
  44       (gethash (class-of container) *container-to-child-class-mappings*)
  45       :parent container :child widget args))))
  46
  47
  48 (defbinding %container-remove () nil
  49   (container container)
  50   (widget widget))
  51
  52 (defmethod container-remove ((container container) (widget widget))
  53   (%container-remove container widget)
  54   (slot-makunbound widget 'child-properties))
  55
  56
  57 (defbinding %container-child-get-property () nil
  58   (container container)
  59   (child widget)
  60   (property-name string)
  61   (value gvalue))
  62
  63 (defbinding %container-child-set-property () nil
  64   (container container)
  65   (child widget)
  66   (property-name string)
  67   (value gvalue))
  68
  69
  70 (defbinding container-check-resize () nil
  71   (container container))
  72
  73 (def-callback-marshal %foreach-callback (nil widget))
  74
  75 (defbinding %container-foreach (container callback-id) nil
  76   (container container)
  77   ((callback %foreach-callback) pointer)
  78   (callback-id unsigned-int))
  79
  80 (defun container-foreach (container function)
  81   (with-callback-function (id function)
  82     (%container-foreach container id)))
  83
  84 (defun map-container (seqtype func container)
  85   (case seqtype
  86     ((nil)
  87      (container-foreach container func)
  88      nil)
  89     (list
  90      (let ((list nil))
  91        (container-foreach
  92         container
  93         #'(lambda (child)
  94             (push (funcall func child) list)))
  95        (nreverse list)))
  96     (t
  97      (let ((seq (make-sequence seqtype (container-length container)))
  98            (index 0))
  99        (container-foreach
 100         container
 101         #'(lambda (child)
 102             (setf (elt seq index) (funcall func child))
 103             (incf index)))
 104        seq))))
 105
 106 (defmacro do-container ((var container &optional (result nil)) &body body)
 107   (let ((continue (make-symbol "CONTINUE")))
 108     `(let ((,continue t))
 109        (container-foreach
 110         ,container
 111         #'(lambda (,var)
 112             (when ,continue
 113               (setq ,continue nil)
 114               (block nil
 115                 ,@body
 116                 (setq ,continue t)))))
 117        ,result)))
 118
 119 ;; (defbinding %container-get-children () (glist widget)
 120 ;;   (container container))
 121
 122 (defmethod container-children ((container container))
 123 ;;   (%container-get-children container)
 124   (map-container 'list #'identity container))
 125
 126 (defmethod (setf container-children) (children (container container))
 127   (dolist (child (container-children container))
 128     (container-remove container child))
 129   (dolist (child children)
 130     (container-add container child))
 131   children)
 132
 133 (defun container-length (container)
 134   (let ((n 0))
 135     (container-foreach container
 136      #'(lambda (child)
 137          (declare (ignore child))
 138          (incf n)))
 139     n))
 140
 141 (defbinding container-resize-children () nil
 142   (container container))
 143
 144 (defbinding container-propagate-expose () nil
 145   (container container)
 146   (child widget)
 147   (event gdk:expose-event))
 148
 149
 150 (defbinding %container-get-focus-chain () boolean
 151   (container container)
 152   (focusable-widgets (glist widget) :out))
 153
 154 (defun container-focus-chain (container)
 155   (multiple-value-bind (chain-set-p focusable-widgets)
 156       (%container-get-focus-chain container)
 157     (and chain-set-p focusable-widgets)))
 158
 159 (defbinding %container-set-focus-chain () nil
 160   (container container)
 161   (focusable-widgets (glist widget)))
 162
 163 (defbinding %container-unset-focus-chain () nil
 164   (container container))
 165
 166 (defun (setf container-focus-chain) (focusable-widgets container)
 167   (if (null focusable-widgets)
 168       (%container-unset-focus-chain container)
 169     (%container-set-focus-chain container focusable-widgets)))