chiark - git - mdw - clg/blob - glib/gobject.lisp

   1 ;; Common Lisp bindings for GTK+ v2.x
   2 ;; Copyright 2000-2006 Espen S. Johnsen <espen@users.sf.net>
   3 ;;
   4 ;; Permission is hereby granted, free of charge, to any person obtaining
   5 ;; a copy of this software and associated documentation files (the
   6 ;; "Software"), to deal in the Software without restriction, including
   7 ;; without limitation the rights to use, copy, modify, merge, publish,
   8 ;; distribute, sublicense, and/or sell copies of the Software, and to
   9 ;; permit persons to whom the Software is furnished to do so, subject to
  10 ;; the following conditions:
  11 ;;
  12 ;; The above copyright notice and this permission notice shall be
  13 ;; included in all copies or substantial portions of the Software.
  14 ;;
  15 ;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  16 ;; EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 ;; MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  18 ;; IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
  19 ;; CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 ;; TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 ;; SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 ;; $Id: gobject.lisp,v 1.54 2006-08-16 12:09:03 espen Exp $
  24
  25 (in-package "GLIB")
  26
  27
  28 ;;;; Metaclass used for subclasses of gobject
  29
  30 (eval-when (:compile-toplevel :load-toplevel :execute)
  31 ;;   (push :debug-ref-counting *features*)
  32   (defclass gobject-class (ginstance-class)
  33     ((instance-slots-p :initform nil :reader instance-slots-p
  34       :documentation "Non NIL if the class has slots with instance allocation")))
  35   (defmethod shared-initialize ((class gobject-class) names &rest initargs)
  36     (declare (ignore names initargs))
  37     (call-next-method)
  38     (unless (slot-boundp class 'ref)
  39       (setf (slot-value class 'ref) '%object-ref))
  40     (unless (slot-boundp class 'unref)
  41       (setf (slot-value class 'unref) '%object-unref)))
  42
  43   (defmethod validate-superclass ((class gobject-class) (super standard-class))
  44 ;  (subtypep (class-name super) 'gobject)
  45     t))
  46
  47 (defclass direct-property-slot-definition (direct-virtual-slot-definition)
  48   ((pname :reader slot-definition-pname :initarg :pname)
  49    (readable :reader slot-readable-p :initarg :readable)
  50    (writable :reader slot-writable-p :initarg :writable)
  51    (construct-only :initarg :construct-only :reader construct-only-property-p)))
  52
  53 (defclass effective-property-slot-definition (effective-virtual-slot-definition)
  54   ((pname :reader slot-definition-pname :initarg :pname)
  55    (readable :initform t :reader slot-readable-p :initarg :readable)
  56    (writable :initform t :reader slot-writable-p :initarg :writable)
  57    (construct-only :initform nil :initarg :construct-only :reader construct-only-property-p)))
  58
  59 (defclass direct-user-data-slot-definition (direct-virtual-slot-definition)
  60   ())
  61
  62 (defclass effective-user-data-slot-definition (effective-virtual-slot-definition)
  63   ())
  64
  65
  66 (defbinding %object-ref () pointer
  67   (location pointer))
  68
  69 (defbinding %object-unref () nil
  70   (location pointer))
  71
  72 #?(pkg-exists-p "glib-2.0" :atleast-version "2.8.0")
  73 (progn
  74   (define-callback toggle-ref-callback nil
  75       ((data pointer) (location pointer) (last-ref-p boolean))
  76     (declare (ignore data))
  77     #+debug-ref-counting
  78     (if last-ref-p
  79         (format t "Object at 0x~8,'0X has no foreign references~%" (pointer-address location))
  80       (format t "Foreign reference added to object at 0x~8,'0X~%" (pointer-address location)))
  81     (if last-ref-p
  82         (cache-instance (find-cached-instance location) t)
  83       (cache-instance (find-cached-instance location) nil)))
  84
  85   (defbinding %object-add-toggle-ref (location) pointer
  86     (location pointer)
  87     (toggle-ref-callback callback)
  88     (nil null))
  89
  90   (defbinding %object-remove-toggle-ref (location) pointer
  91     (location pointer)
  92     (toggle-ref-callback callback)
  93     (nil null)))
  94
  95 #+debug-ref-counting
  96 (progn
  97   (define-callback weak-ref-callback nil ((data pointer) (location pointer))
  98     (format t "Object at 0x~8,'0X (~A) being finalized~%" (pointer-address location) (type-from-number (%type-number-of-ginstance location))))
  99
 100   (defbinding %object-weak-ref (location) pointer
 101     (location pointer)
 102     (weak-ref-callback callback)
 103     (nil null)))
 104
 105
 106 ; (defbinding object-class-install-param () nil
 107 ;   (class pointer)
 108 ;   (id unsigned-int)
 109 ;   (parameter parameter))
 110
 111 ; (defbinding object-class-find-param-spec () parameter
 112 ;   (class pointer)
 113 ;   (name string))
 114
 115 (defun signal-name-to-string (name)
 116   (substitute #\_ #\- (string-downcase (string name))))
 117
 118
 119 (defmethod direct-slot-definition-class ((class gobject-class) &rest initargs)
 120   (case (getf initargs :allocation)
 121     (:property (find-class 'direct-property-slot-definition))
 122     (:user-data (find-class 'direct-user-data-slot-definition))
 123     (t (call-next-method))))
 124
 125 (defmethod effective-slot-definition-class ((class gobject-class) &rest initargs)
 126   (case (getf initargs :allocation)
 127     (:property (find-class 'effective-property-slot-definition))
 128     (:user-data (find-class 'effective-user-data-slot-definition))
 129     (t (call-next-method))))
 130
 131 (defmethod compute-effective-slot-definition-initargs ((class gobject-class) direct-slotds)
 132   (if (eq (slot-definition-allocation (first direct-slotds)) :property)
 133       (nconc
 134        (compute-most-specific-initargs direct-slotds
 135         '(pname construct-only readable writable))
 136        (call-next-method))
 137     (call-next-method)))
 138
 139
 140 (defvar *ignore-setting-construct-only-property* nil)
 141 (declaim (special *ignore-setting-construct-only-property*))
 142
 143 (defmethod compute-slot-reader-function ((slotd effective-property-slot-definition) &optional signal-unbound-p)
 144   (declare (ignore signal-unbound-p))
 145   (let* ((type (slot-definition-type slotd))
 146          (pname (slot-definition-pname slotd))
 147          (reader (reader-function type :ref :get)))
 148     #'(lambda (object)
 149         (with-memory (gvalue +gvalue-size+)
 150           (%gvalue-init gvalue (find-type-number type))
 151           (%object-get-property object pname gvalue)
 152           (funcall reader gvalue +gvalue-value-offset+)))))
 153
 154 (defmethod compute-slot-writer-function :around ((slotd effective-property-slot-definition))
 155   (if (construct-only-property-p slotd)
 156       #'(lambda (value object)
 157           (declare (ignore value object))
 158           (unless *ignore-setting-construct-only-property*
 159             (error 'unwritable-slot :name (slot-definition-name slotd) :instance object)))
 160     (call-next-method)))
 161
 162 (defmethod compute-slot-writer-function ((slotd effective-property-slot-definition))
 163   (let* ((type (slot-definition-type slotd))
 164          (pname (slot-definition-pname slotd))
 165          (writer (writer-function type :temp t))
 166          (destroy (destroy-function type :temp t)))
 167     #'(lambda (value object)
 168         (with-memory (gvalue +gvalue-size+)
 169           (%gvalue-init gvalue (find-type-number type))
 170           (funcall writer value gvalue +gvalue-value-offset+)
 171           (%object-set-property object pname gvalue)
 172           (funcall destroy gvalue +gvalue-value-offset+))
 173         value)))
 174
 175 (defmethod slot-readable-p ((slotd effective-user-data-slot-definition))
 176   (declare (ignore slotd))
 177   t)
 178
 179 (defmethod compute-slot-reader-function ((slotd effective-user-data-slot-definition) &optional signal-unbound-p)
 180   (declare (ignore signal-unbound-p))
 181   (let ((slot-name (slot-definition-name slotd)))
 182     #'(lambda (object)
 183         (user-data object slot-name))))
 184
 185 (defmethod compute-slot-boundp-function ((slotd effective-user-data-slot-definition))
 186   (let ((slot-name (slot-definition-name slotd)))
 187     #'(lambda (object)
 188         (user-data-p object slot-name))))
 189
 190 (defmethod slot-writable-p ((slotd effective-user-data-slot-definition))
 191   (declare (ignore slotd))
 192   t)
 193
 194 (defmethod compute-slot-writer-function ((slotd effective-user-data-slot-definition))
 195   (let ((slot-name (slot-definition-name slotd)))
 196     #'(lambda (value object)
 197         (setf (user-data object slot-name) value))))
 198
 199 (defmethod compute-slot-makunbound-function ((slotd effective-user-data-slot-definition))
 200   (let ((slot-name (slot-definition-name slotd)))
 201     #'(lambda (object)
 202         (unset-user-data object slot-name))))
 203
 204 (defmethod compute-slots :around ((class gobject-class))
 205   (let ((slots (call-next-method)))
 206     (when (some #'(lambda (slotd)
 207                     (and
 208                      (eq (slot-definition-allocation slotd) :instance)
 209                      (not (typep slotd 'effective-special-slot-definition))))
 210                 slots)
 211       (setf (slot-value class 'instance-slots-p) t))
 212     slots))
 213
 214
 215 ;;;; Super class for all classes in the GObject type hierarchy
 216
 217 (eval-when (:compile-toplevel :load-toplevel :execute)
 218   (defclass gobject (ginstance)
 219     (#+debug-ref-counting
 220      (ref-count :allocation :alien :type int :reader ref-count))
 221     (:metaclass gobject-class)
 222     (:gtype "GObject")))
 223
 224 #+debug-ref-counting
 225 (defmethod print-object ((instance gobject) stream)
 226   (print-unreadable-object (instance stream :type t :identity nil)
 227     (if (proxy-valid-p instance)
 228         (format stream "at 0x~X (~D)" (pointer-address (foreign-location instance)) (ref-count instance))
 229       (write-string "at \"unbound\"" stream))))
 230
 231
 232 (define-type-method reader-function ((type gobject) &key (ref :read) inlined)
 233   (assert-not-inlined type inlined)
 234   (ecase ref
 235     ((:read :peek) (call-next-method type :ref :read))
 236     (:get
 237      #'(lambda (location &optional (offset 0))
 238          (let ((instance (ref-pointer location offset)))
 239            (unless (null-pointer-p instance)
 240              (multiple-value-bind (gobject new-p)
 241                  (ensure-proxy-instance 'gobject instance :reference nil)
 242                (unless new-p
 243                  (%object-unref instance))
 244                (setf (ref-pointer location offset) (make-pointer 0))
 245                gobject)))))))
 246
 247 (define-type-method callback-wrapper ((type gobject) var arg form)
 248   (let ((class (type-expand type)))
 249     `(let ((,var (ensure-proxy-instance ',class ,arg)))
 250        ,form)))
 251
 252 (defun initial-add (object function initargs key pkey)
 253   (loop
 254    as (initarg value . rest) = initargs then rest
 255    do (cond
 256        ((eq initarg key) (funcall function object value))
 257        ((eq initarg pkey) (mapc #'(lambda (value)
 258                                     (funcall function object value))
 259                                 value)))
 260        while rest))
 261
 262 (defun initial-apply-add (object function initargs key pkey)
 263   (initial-add object #'(lambda (object value)
 264                           (apply function object (mklist value)))
 265                initargs key pkey))
 266
 267
 268 (defmethod make-proxy-instance ((class gobject-class) location &rest initargs)
 269   (declare (ignore location initargs))
 270   (if (slot-value class 'instance-slots-p)
 271       (error "Objects of class ~A has instance slots and should only be created with MAKE-INSTANCE" class)
 272     (call-next-method)))
 273
 274
 275 (defmethod allocate-foreign ((object gobject) &rest initargs)
 276   (let ((init-slots ()))
 277     (flet ((value-from-initargs (slotd)
 278              (loop
 279               with slot-initargs = (slot-definition-initargs slotd)
 280               for (initarg value) on initargs by #'cddr
 281               when (find initarg slot-initargs)
 282               do (return (values value t)))))
 283
 284     (loop
 285      for slotd in (class-slots (class-of object))
 286      when (and
 287            (eq (slot-definition-allocation slotd) :property)
 288            (construct-only-property-p slotd))
 289      do (multiple-value-bind (value initarg-p) (value-from-initargs slotd)
 290           (cond
 291            (initarg-p (push (cons slotd value) init-slots))
 292            ((slot-definition-initfunction slotd)
 293             (push
 294              (cons slotd (funcall (slot-definition-initfunction slotd)))
 295              init-slots))))))
 296
 297     (cond
 298      (init-slots
 299       (let* ((pointer-size (size-of 'pointer))
 300              (element-size (+ +gvalue-size+ pointer-size))
 301              (num-slots (length init-slots)))
 302         (with-memory (params (* num-slots element-size))
 303           (loop
 304            with string-writer = (writer-function 'string)
 305            for (slotd . value) in init-slots
 306            as param = params then (pointer+ param element-size)
 307            as type = (slot-definition-type slotd)
 308            as pname = (slot-definition-pname slotd)
 309            do (funcall string-writer pname param)
 310               (gvalue-init (pointer+ param pointer-size) type value))
 311
 312           (unwind-protect
 313               (%gobject-newv (type-number-of object) num-slots params)
 314
 315             (loop
 316              with string-destroy = (destroy-function 'string)
 317              repeat num-slots
 318              as param = params then (pointer+ param element-size)
 319              do (funcall string-destroy param)
 320                 (gvalue-unset (pointer+ param pointer-size)))))))
 321
 322      (t (%gobject-new (type-number-of object))))))
 323
 324
 325 (defmethod shared-initialize ((object gobject) names &rest initargs)
 326   (declare (ignore names initargs))
 327   (let ((*ignore-setting-construct-only-property* t))
 328     (call-next-method)))
 329
 330 (defmethod initialize-instance :around ((object gobject) &rest initargs)
 331   (declare (ignore initargs))
 332   (prog1
 333       (call-next-method)
 334     #+debug-ref-counting(%object-weak-ref (foreign-location object))
 335     #?(pkg-exists-p "glib-2.0" :atleast-version "2.8.0")
 336     (when (slot-value (class-of object) 'instance-slots-p)
 337       (%object-add-toggle-ref (foreign-location object))
 338       (%object-unref (foreign-location object)))))
 339
 340
 341 (defmethod instance-finalizer ((instance gobject))
 342   (let ((location (foreign-location instance)))
 343     #?(pkg-exists-p "glib-2.0" :atleast-version "2.8.0")
 344     (if (slot-value (class-of instance) 'instance-slots-p)
 345         #'(lambda ()
 346             #+debug-ref-counting
 347             (format t "Finalizing proxy for 0x~8,'0X~%" (pointer-address location))
 348             (%object-remove-toggle-ref location))
 349       #'(lambda ()
 350           #+debug-ref-counting
 351           (format t "Finalizing proxy for 0x~8,'0X~%" (pointer-address location))
 352           (%object-unref location)))
 353     #?-(pkg-exists-p "glib-2.0" :atleast-version "2.8.0")
 354     #'(lambda ()
 355         (%object-unref location))))
 356
 357
 358 (defbinding (%gobject-new "g_object_new") () pointer
 359   (type type-number)
 360   (nil null))
 361
 362 (defbinding (%gobject-newv "g_object_newv") () pointer
 363   (type type-number)
 364   (n-parameters unsigned-int)
 365   (params pointer))
 366
 367
 368
 369 ;;;; Property stuff
 370
 371 (defbinding %object-set-property () nil
 372   (object gobject)
 373   (name string)
 374   (value gvalue))
 375
 376 (defbinding %object-get-property () nil
 377   (object gobject)
 378   (name string)
 379   (value gvalue))
 380
 381 (defbinding %object-notify () nil
 382   (object gobject)
 383   (name string))
 384
 385 (defbinding object-freeze-notify () nil
 386   (object gobject))
 387
 388 (defbinding object-thaw-notify () nil
 389   (object gobject))
 390
 391
 392 ;;;; User data
 393
 394 (defbinding %object-set-qdata-full () nil
 395   (object gobject)
 396   (id quark)
 397   (data unsigned-long)
 398   (destroy-marshal callback))
 399
 400 (define-callback user-data-destroy-callback nil ((id unsigned-int))
 401   (destroy-user-data id))
 402
 403 (defun (setf user-data) (data object key)
 404   (%object-set-qdata-full object (quark-intern key)
 405    (register-user-data data) user-data-destroy-callback)
 406   data)
 407
 408 (defbinding %object-get-qdata () unsigned-long
 409   (object gobject)
 410   (id quark))
 411
 412 (defun user-data (object key)
 413   (find-user-data (%object-get-qdata object (quark-intern key))))
 414
 415 (defun user-data-p (object key)
 416   (user-data-exists-p (%object-get-qdata object (quark-intern key))))
 417
 418 (defbinding %object-steal-qdata () unsigned-long
 419   (object gobject)
 420   (id quark))
 421
 422 (defun unset-user-data (object key)
 423   (destroy-user-data (%object-steal-qdata object (quark-intern key))))
 424
 425
 426 ;;;;
 427
 428 (defbinding %object-class-list-properties () pointer
 429   (class pointer)
 430   (n-properties unsigned-int :out))
 431
 432
 433 (defun %map-params (params length type inherited-p)
 434   (if inherited-p
 435       (map-c-vector 'list #'identity params 'param length)
 436     (let ((properties ()))
 437       (map-c-vector 'list
 438        #'(lambda (param)
 439            (when (eql (param-owner-type param) type)
 440              (push param properties)))
 441        params 'param length)
 442       (nreverse properties))))
 443
 444 (defun query-object-class-properties (type &optional inherited-p)
 445   (let* ((type-number (find-type-number type t))
 446          (class (type-class-ref type-number)))
 447     (unwind-protect
 448          (multiple-value-bind (array length)
 449              (%object-class-list-properties class)
 450            (unless (null-pointer-p array)
 451              (unwind-protect
 452                  (%map-params array length type-number inherited-p)
 453                (deallocate-memory array))))
 454 ;      (type-class-unref type-number)
 455       )))
 456
 457
 458 (defun default-slot-name (name)
 459   (let ((prefix-len (length (package-prefix))))
 460     (intern (substitute #\- #\_
 461              (string-upcase
 462               (if (and
 463                    (string-prefix-p (package-prefix) name)
 464                    (char= #\- (char name prefix-len)))
 465                   (subseq name (1+ prefix-len))
 466                 name))))))
 467
 468 (defun default-slot-accessor (class-name slot-name type)
 469   (intern
 470    (format
 471     nil "~A-~A~A" class-name slot-name
 472     (if (eq type 'boolean) "-P" ""))))
 473
 474
 475 (defun slot-definition-from-property (class property &optional slot-name args)
 476   (with-slots (name flags value-type documentation) property
 477     (let* ((slot-name (or slot-name (default-slot-name name)))
 478            (slot-type (or (getf args :type) (type-from-number value-type) 'pointer))
 479            (accessor (default-slot-accessor class slot-name slot-type)))
 480
 481       `(,slot-name
 482         :allocation :property :pname ,name
 483
 484         ,@(when (find :unbound args) (list :unbound (getf args :unbound)))
 485         ,@(when (find :getter args) (list :getter (getf args :getter)))
 486         ,@(when (find :setter args) (list :setter (getf args :setter)))
 487
 488         ;; accessors
 489         ,@(cond
 490            ((and
 491              (member :writable flags) (member :readable flags)
 492              (not (member :construct-only flags)))
 493             (list :accessor accessor))
 494            ((and (member :writable flags) (not (member :construct-only flags)))
 495             (list :writer `(setf ,accessor)))
 496            ((member :readable flags)
 497             (list :reader accessor)))
 498
 499         ;; readable/writable/construct
 500         ,@(when (or (not (member :writable flags))
 501                     (member :construct-only flags))
 502             '(:writable nil))
 503         ,@(when (not (member :readable flags))
 504             '(:readable nil))
 505         ,@(when (member :construct-only flags)
 506             '(:construct-only t))
 507
 508         ;; initargs
 509         ,@(if (find :initarg args)
 510               (let ((initarg (getf args :initarg)))
 511                 (etypecase initarg
 512                   (null ())
 513                   (symbol `(:initarg ,initarg))))
 514             (when (or (member :construct flags)
 515                       (member :construct-only flags)
 516                       (member :writable flags))
 517               (list :initarg (intern (string slot-name) "KEYWORD"))))
 518
 519         :type ,slot-type
 520         :documentation ,documentation))))
 521
 522
 523 (defun slot-definitions (class properties slots)
 524   (loop
 525    for property in properties
 526    as slot = (or
 527               (find (param-name property) slots
 528                :key #'(lambda (slot) (getf (rest slot) :pname))
 529                :test #'string=)
 530               (find (param-name property) slots
 531                :key #'first :test #'string-equal))
 532    do (cond
 533        ((not slot)
 534         (push (slot-definition-from-property class property) slots))
 535        ((getf (rest slot) :merge)
 536         (setf
 537          (rest slot)
 538          (rest (slot-definition-from-property class property (first slot) (rest slot)))))))
 539   (delete-if #'(lambda (slot) (getf (rest slot) :ignore)) slots))
 540
 541
 542 (defun expand-gobject-type (type forward-p options &optional (metaclass 'gobject-class))
 543   (let ((supers (cons (supertype type) (implements type)))
 544         (class  (type-from-number type))
 545         (slots (getf options :slots)))
 546     `(defclass ,class ,supers
 547          ,(unless forward-p
 548             (slot-definitions class (query-object-class-properties type) slots))
 549          (:metaclass ,metaclass)
 550          (:gtype ,(register-type-as type)))))
 551
 552 (defun gobject-dependencies (type options)
 553   (delete-duplicates
 554    (cons
 555     (supertype type)
 556     (append
 557      (type-interfaces type)
 558      (mapcar #'param-value-type (query-object-class-properties type))
 559      (getf options :dependencies)
 560      (loop
 561       for slot in (getf options :slots)
 562       as type = (getf (rest slot) :type)
 563       when (and type (symbolp type) (find-type-number type))
 564       collect (find-type-number type))))))
 565
 566
 567 (register-derivable-type 'gobject "GObject" 'expand-gobject-type 'gobject-dependencies)
 568
 569
 570 ;;; Pseudo type for gobject instances which have their reference count
 571 ;;; increased by the returning function
 572
 573 (deftype referenced (type) type)
 574
 575 (define-type-method from-alien-form ((type referenced) form &key (ref :free))
 576   (cond
 577    ((not (eq ref :free))
 578     (error "Keyword arg :REF to FROM-ALIEN-FORM should be :FREE for type ~A. It was give ~A" type ref))
 579    ((subtypep type 'gobject)
 580     (from-alien-form (second (type-expand-to 'referenced type)) form :ref ref))))
 581
 582 (define-type-method from-alien-function ((type referenced) &key (ref :free))
 583   (cond
 584    ((not (eq ref :free))
 585     (error "Keyword arg :REF to FROM-ALIEN-FUNCTION should be :FREE for type ~A. It was give ~A" type ref))
 586 ;   ((subtypep type 'gobject) (call-next-method type ref :free))))
 587    ((subtypep type 'gobject)
 588     (from-alien-function (second (type-expand-to 'referenced type)) :ref ref))))