chiark - git - mdw - clg/blob - glib/proxy.lisp

   1 ;; Common Lisp bindings for GTK+ v2.x
   2 ;; Copyright 2000-2005 Espen S. Johnsen <espen@users.sf.net>
   3 ;;
   4 ;; Permission is hereby granted, free of charge, to any person obtaining
   5 ;; a copy of this software and associated documentation files (the
   6 ;; "Software"), to deal in the Software without restriction, including
   7 ;; without limitation the rights to use, copy, modify, merge, publish,
   8 ;; distribute, sublicense, and/or sell copies of the Software, and to
   9 ;; permit persons to whom the Software is furnished to do so, subject to
  10 ;; the following conditions:
  11 ;;
  12 ;; The above copyright notice and this permission notice shall be
  13 ;; included in all copies or substantial portions of the Software.
  14 ;;
  15 ;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  16 ;; EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 ;; MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  18 ;; IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
  19 ;; CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 ;; TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 ;; SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 ;; $Id: proxy.lisp,v 1.29 2006-02-07 13:20:39 espen Exp $
  24
  25 (in-package "GLIB")
  26
  27 ;;;; Superclass for all metaclasses implementing some sort of virtual slots
  28
  29 (eval-when (:compile-toplevel :load-toplevel :execute)
  30   (defclass virtual-slots-class (standard-class)
  31     ())
  32
  33   (defclass direct-virtual-slot-definition (standard-direct-slot-definition)
  34     ((setter :reader slot-definition-setter :initarg :setter)
  35      (getter :reader slot-definition-getter :initarg :getter)
  36      (unbound :reader slot-definition-unbound :initarg :unbound)
  37      (boundp :reader slot-definition-boundp :initarg :boundp)))
  38
  39   (defclass effective-virtual-slot-definition (standard-effective-slot-definition)
  40     ((setter :reader slot-definition-setter :initarg :setter)
  41      (getter :reader slot-definition-getter :initarg :getter)
  42      (unbound :reader slot-definition-unbound :initarg :unbound)
  43      (boundp :reader slot-definition-boundp :initarg :boundp)))
  44
  45   (defclass direct-special-slot-definition (standard-direct-slot-definition)
  46     ())
  47
  48   (defclass effective-special-slot-definition (standard-effective-slot-definition)
  49     ()))
  50
  51 (defvar *unbound-marker* (gensym "UNBOUND-MARKER-"))
  52
  53 (defun most-specific-slot-value (instances slot &optional (default *unbound-marker*))
  54   (let ((object (find-if
  55                  #'(lambda (ob)
  56                      (and (slot-exists-p ob slot) (slot-boundp ob slot)))
  57                  instances)))
  58     (if object
  59         (slot-value object slot)
  60       default)))
  61
  62 (defmethod initialize-instance ((slotd effective-special-slot-definition) &rest initargs)
  63   (declare (ignore initargs))
  64   (call-next-method)
  65   (setf (slot-value slotd 'allocation) :instance))
  66
  67
  68 (defmethod direct-slot-definition-class ((class virtual-slots-class) &rest initargs)
  69   (case (getf initargs :allocation)
  70     (:virtual (find-class 'direct-virtual-slot-definition))
  71     (:special (find-class 'direct-special-slot-definition))
  72     (t (call-next-method))))
  73
  74 (defmethod effective-slot-definition-class ((class virtual-slots-class) &rest initargs)
  75   (case (getf initargs :allocation)
  76     (:virtual (find-class 'effective-virtual-slot-definition))
  77     (:special (find-class 'effective-special-slot-definition))
  78     (t (call-next-method))))
  79
  80
  81 (defmethod initialize-internal-slot-functions ((slotd effective-virtual-slot-definition))
  82   (if (not (slot-boundp slotd 'getter))
  83       (setf
  84        (slot-value slotd 'reader-function)
  85        #'(lambda (object)
  86            (declare (ignore object))
  87            (error "Can't read slot: ~A" (slot-definition-name slotd)))
  88        (slot-value slotd 'boundp-function)
  89        #'(lambda (object) (declare (ignore object)) nil))
  90
  91     (let ((getter-function
  92            (let ((getter (slot-value slotd 'getter)))
  93              (etypecase getter
  94                (function getter)
  95                (symbol
  96                 #'(lambda (object)
  97                     (funcall getter object)))
  98                (string
  99                 (let ((reader nil))
 100                   (setf (slot-value slotd 'reader-function)
 101                         #'(lambda (object)
 102                             (unless reader
 103                               (setq reader
 104                                (mkbinding getter
 105                                 (slot-definition-type slotd) 'pointer)))
 106                             (funcall reader (foreign-location object))))))))))
 107
 108       (setf
 109        (slot-value slotd 'boundp-function)
 110        (cond
 111         ((slot-boundp slotd 'unbound)
 112          (let ((unbound-value (slot-value slotd 'unbound)))
 113            #'(lambda (object)
 114                (not (eq (funcall getter-function object) unbound-value)))))
 115         ((slot-boundp slotd 'boundp)
 116          (let ((boundp (slot-value slotd 'boundp)))
 117            (etypecase boundp
 118              (function boundp)
 119              (symbol #'(lambda (object)
 120                          (funcall boundp object)))
 121              (string (let ((reader ()))
 122                        #'(lambda (object)
 123                            (unless reader
 124                              (setq reader
 125                               (mkbinding boundp
 126                                (slot-definition-type slotd) 'pointer)))
 127                            (funcall reader (foreign-location object))))))))
 128         ((multiple-value-bind (unbound-p unbound-value)
 129              (unbound-value (slot-definition-type slotd))
 130            (when unbound-p
 131              #'(lambda (object)
 132                  (not (eq (funcall getter-function object) unbound-value))))))
 133         (#'(lambda (object) (declare (ignore object)) t))))
 134
 135       (setf
 136        (slot-value slotd 'reader-function)
 137        (cond
 138         ((slot-boundp slotd 'unbound)
 139          (let ((unbound (slot-value slotd 'unbound))
 140                (slot-name (slot-definition-name slotd)))
 141            #'(lambda (object)
 142                (let ((value (funcall getter-function object)))
 143                  (if (eq value unbound)
 144                      (slot-unbound (class-of object) object slot-name)
 145                    value)))))
 146         ((slot-boundp slotd 'boundp)
 147          (let ((boundp-function (slot-value slotd 'boundp-function)))
 148            #'(lambda (object)
 149                (and
 150                 (funcall boundp-function object)
 151                 (funcall getter-function object)))))
 152         ((multiple-value-bind (unbound-p unbound-value)
 153              (unbound-value (slot-definition-type slotd))
 154            (let ((slot-name (slot-definition-name slotd)))
 155              (when unbound-p
 156                #'(lambda (object)
 157                    (let ((value (funcall getter-function object)))
 158                      (if (eq value unbound-value)
 159                          (slot-unbound (class-of object) object slot-name)
 160                          value)))))))
 161         (getter-function)))))
 162
 163   (setf
 164    (slot-value slotd 'writer-function)
 165    (if (not (slot-boundp slotd 'setter))
 166        #'(lambda (object)
 167            (declare (ignore object))
 168            (error "Can't set slot: ~A" (slot-definition-name slotd)))
 169      (with-slots (setter) slotd
 170        (etypecase setter
 171          (function setter)
 172          ((or symbol cons)
 173           #'(lambda (value object)
 174               (funcall (fdefinition setter) value object)))
 175          (string
 176           (let ((writer ()))
 177             (setf
 178              (slot-value slotd 'writer-function)
 179              #'(lambda (value object)
 180                  (unless writer
 181                    (setq writer
 182                     (mkbinding setter 'nil 'pointer
 183                      (slot-definition-type slotd))))
 184                  (funcall writer (foreign-location object) value)))))))))
 185
 186   (initialize-internal-slot-gfs (slot-definition-name slotd)))
 187
 188
 189
 190 (defmethod compute-slot-accessor-info ((slotd effective-virtual-slot-definition) type gf)
 191   nil)
 192
 193 (defmethod compute-effective-slot-definition-initargs ((class virtual-slots-class) direct-slotds)
 194   (if (typep (first direct-slotds) 'direct-virtual-slot-definition)
 195       (let ((initargs ()))
 196         (let ((getter (most-specific-slot-value direct-slotds 'getter)))
 197           (unless (eq getter *unbound-marker*)
 198             (setf (getf initargs :getter) getter)))
 199         (let ((setter (most-specific-slot-value direct-slotds 'setter)))
 200           (unless (eq setter *unbound-marker*)
 201             (setf (getf initargs :setter) setter)))
 202         (let ((unbound (most-specific-slot-value direct-slotds 'unbound)))
 203           (unless (eq unbound *unbound-marker*)
 204             (setf (getf initargs :unbound) unbound)))
 205         (let ((boundp (most-specific-slot-value direct-slotds 'boundp)))
 206           (unless (eq boundp *unbound-marker*)
 207             (setf (getf initargs :boundp) boundp)))
 208         (nconc initargs (call-next-method)))
 209     (call-next-method)))
 210
 211
 212 (defmethod slot-value-using-class
 213     ((class virtual-slots-class) (object standard-object)
 214      (slotd effective-virtual-slot-definition))
 215   (if (funcall (slot-value slotd 'boundp-function) object)
 216       (funcall (slot-value slotd 'reader-function) object)
 217     (slot-unbound class object (slot-definition-name slotd))))
 218
 219 (defmethod slot-boundp-using-class
 220     ((class virtual-slots-class) (object standard-object)
 221      (slotd effective-virtual-slot-definition))
 222   (funcall (slot-value slotd 'boundp-function) object))
 223
 224 (defmethod (setf slot-value-using-class)
 225     (value (class virtual-slots-class) (object standard-object)
 226      (slotd effective-virtual-slot-definition))
 227   (funcall (slot-value slotd 'writer-function) value object))
 228
 229
 230 (defmethod validate-superclass
 231     ((class virtual-slots-class) (super standard-class))
 232   t)
 233
 234
 235 ;;;; Proxy cache
 236
 237 (defvar *instance-cache* (make-hash-table :test #'eql))
 238
 239 (defun cache-instance (instance &optional (weak-ref t))
 240   (setf
 241    (gethash (sap-int (foreign-location instance)) *instance-cache*)
 242    (if weak-ref
 243        (make-weak-pointer instance)
 244      instance)))
 245
 246 (defun find-cached-instance (location)
 247   (let ((ref (gethash (sap-int location) *instance-cache*)))
 248     (when ref
 249       (if (weak-pointer-p ref)
 250           (weak-pointer-value ref)
 251         ref))))
 252
 253 (defun instance-cached-p (location)
 254   (gethash (sap-int location) *instance-cache*))
 255
 256 (defun remove-cached-instance (location)
 257   (remhash (sap-int location) *instance-cache*))
 258
 259 ;; For debuging
 260 (defun list-cached-instances ()
 261   (let ((instances ()))
 262     (maphash #'(lambda (location ref)
 263                  (declare (ignore location))
 264                  (push ref instances))
 265              *instance-cache*)
 266     instances))
 267
 268 ;; Instances that gets invalidated tend to be short lived, but created
 269 ;; in large numbers. So we're keeping them in a hash table to be able
 270 ;; to reuse them (and thus reduce consing)
 271 (defvar *invalidated-instance-cache* (make-hash-table :test #'eql))
 272
 273 (defun cache-invalidated-instance (instance)
 274   (push instance
 275    (gethash (class-of instance) *invalidated-instance-cache*)))
 276
 277 (defun find-invalidated-instance (class)
 278   (when (gethash class *invalidated-instance-cache*)
 279     (pop (gethash class *invalidated-instance-cache*))))
 280
 281 (defun list-invalidated-instances ()
 282   (let ((instances ()))
 283     (maphash #'(lambda (location ref)
 284                  (declare (ignore location))
 285                  (push ref instances))
 286              *invalidated-instance-cache*)
 287     instances))
 288
 289
 290
 291 ;;;; Proxy for alien instances
 292
 293 ;; TODO: add a ref-counted-proxy subclass
 294 (defclass proxy ()
 295   ((location :allocation :special :reader foreign-location :type pointer))
 296   (:metaclass virtual-slots-class))
 297
 298 (defgeneric instance-finalizer (object))
 299 (defgeneric reference-foreign (class location))
 300 (defgeneric unreference-foreign (class location))
 301 (defgeneric invalidate-instance (object))
 302
 303 (defmethod reference-foreign ((name symbol) location)
 304   (reference-foreign (find-class name) location))
 305
 306 (defmethod unreference-foreign ((name symbol) location)
 307   (unreference-foreign (find-class name) location))
 308
 309 (defmethod unreference-foreign :around ((class class) location)
 310   (unless (null-pointer-p location)
 311     (call-next-method)))
 312
 313 (defmethod print-object ((instance proxy) stream)
 314   (print-unreadable-object (instance stream :type t :identity nil)
 315     (if (slot-boundp instance 'location)
 316         (format stream "at 0x~X" (sap-int (foreign-location instance)))
 317       (write-string "at \"unbound\"" stream))))
 318
 319 (defmethod initialize-instance :around ((instance proxy) &rest initargs)
 320   (declare (ignore initargs))
 321   (prog1
 322       (call-next-method)
 323     (cache-instance instance)
 324     (finalize instance (instance-finalizer instance))))
 325
 326 (defmethod instance-finalizer ((instance proxy))
 327   (let ((location (foreign-location instance))
 328         (class (class-of instance)))
 329 ;;     (unless (find-method #'unreference-foreign nil (list (class-of class) t) nil)
 330 ;;       (error "No matching method for UNREFERENCE-INSTANCE when called with class ~A" class))
 331     #'(lambda ()
 332         (remove-cached-instance location)
 333         (unreference-foreign class location))))
 334
 335 ;; Any reference to the foreign object the instance may have held
 336 ;; should be released before this method is invoked
 337 (defmethod invalidate-instance ((instance proxy))
 338   (remove-cached-instance (foreign-location instance))
 339   (slot-makunbound instance 'location)
 340   (cancel-finalization instance)
 341   (cache-invalidated-instance instance))
 342
 343
 344 ;;;; Metaclass used for subclasses of proxy
 345
 346 (defgeneric most-specific-proxy-superclass (class))
 347 (defgeneric direct-proxy-superclass (class))
 348 (defgeneric compute-foreign-size (class))
 349
 350
 351 (eval-when (:compile-toplevel :load-toplevel :execute)
 352   (defclass proxy-class (virtual-slots-class)
 353     ((size :reader foreign-size)))
 354
 355   (defclass direct-alien-slot-definition (direct-virtual-slot-definition)
 356     ((allocation :initform :alien)
 357      (offset :reader slot-definition-offset :initarg :offset)))
 358
 359   (defclass effective-alien-slot-definition (effective-virtual-slot-definition)
 360     ((offset :reader slot-definition-offset :initarg :offset)))
 361
 362   (defmethod most-specific-proxy-superclass ((class proxy-class))
 363     (find-if
 364      #'(lambda (class)
 365          (subtypep (class-name class) 'proxy))
 366      (cdr (compute-class-precedence-list class))))
 367
 368   (defmethod direct-proxy-superclass ((class proxy-class))
 369     (find-if
 370      #'(lambda (class)
 371          (subtypep (class-name class) 'proxy))
 372      (class-direct-superclasses class)))
 373
 374   (defmethod shared-initialize ((class proxy-class) names &key size)
 375     (call-next-method)
 376     (cond
 377       (size (setf (slot-value class 'size) (first size)))
 378       ((slot-boundp class 'size) (slot-makunbound class 'size))))
 379
 380   (defmethod direct-slot-definition-class ((class proxy-class) &rest initargs)
 381     (case (getf initargs :allocation)
 382       (:alien (find-class 'direct-alien-slot-definition))
 383       (t (call-next-method))))
 384
 385   (defmethod effective-slot-definition-class ((class proxy-class) &rest initargs)
 386     (case (getf initargs :allocation)
 387       (:alien (find-class 'effective-alien-slot-definition))
 388       (t (call-next-method))))
 389
 390
 391   (defmethod compute-effective-slot-definition-initargs ((class proxy-class) direct-slotds)
 392     (if (eq (most-specific-slot-value direct-slotds 'allocation) :alien)
 393         (nconc
 394          (list :offset (most-specific-slot-value direct-slotds 'offset))
 395          (call-next-method))
 396       (call-next-method)))
 397
 398
 399   (defmethod initialize-internal-slot-functions ((slotd effective-alien-slot-definition))
 400     (with-slots (offset) slotd
 401       (let ((type (slot-definition-type slotd)))
 402         (unless (slot-boundp slotd 'getter)
 403           (let ((reader (reader-function type)))
 404             (setf
 405              (slot-value slotd 'getter)
 406              #'(lambda (object)
 407                  (funcall reader (foreign-location object) offset)))))
 408
 409         (unless (slot-boundp slotd 'setter)
 410           (let ((writer (writer-function type))
 411                 (destroy (destroy-function type)))
 412             (setf
 413              (slot-value slotd 'setter)
 414              #'(lambda (value object)
 415                  (let ((location (foreign-location object)))
 416                    (funcall destroy location offset) ; destroy old value
 417                    (funcall writer value location offset))))))))
 418
 419     (call-next-method))
 420
 421   (defmethod compute-foreign-size ((class proxy-class))
 422     nil)
 423
 424   ;; TODO: call some C code to detect this a compile time
 425   (defconstant +struct-alignmen+ 4)
 426
 427   (defun align-offset (size)
 428     (if (zerop (mod size +struct-alignmen+))
 429         size
 430       (+ size (- +struct-alignmen+ (mod size +struct-alignmen+)))))
 431
 432   (defmethod compute-slots ((class proxy-class))
 433     (let ((alien-slots
 434            (remove-if-not
 435             #'(lambda (slotd)
 436                 (eq (slot-definition-allocation slotd) :alien))
 437             (class-direct-slots class))))
 438       (when alien-slots
 439         (loop
 440          as offset = (align-offset (foreign-size
 441                                     (most-specific-proxy-superclass class)))
 442                      then (align-offset
 443                            (+
 444                             (slot-definition-offset slotd)
 445                             (size-of (slot-definition-type slotd))))
 446        for slotd in alien-slots
 447        unless (slot-boundp slotd 'offset)
 448        do (setf (slot-value slotd 'offset) offset))))
 449     (call-next-method))
 450
 451   (defmethod compute-slots :after ((class proxy-class))
 452     (when (and (class-finalized-p class) (not (slot-boundp class 'size)))
 453       (let ((size (compute-foreign-size class)))
 454         (when size
 455           (setf (slot-value class 'size) size)))))
 456
 457   (defmethod validate-superclass ((class proxy-class) (super standard-class))
 458     (subtypep (class-name super) 'proxy))
 459
 460   (defmethod foreign-size ((class-name symbol))
 461     (foreign-size (find-class class-name))))
 462
 463 (defmethod foreign-size ((object proxy))
 464   (foreign-size (class-of object)))
 465
 466
 467 (defmethod alien-type ((class proxy-class) &rest args)
 468   (declare (ignore class args))
 469   (alien-type 'pointer))
 470
 471 (defmethod size-of ((class proxy-class) &rest args)
 472   (declare (ignore class args))
 473   (size-of 'pointer))
 474
 475 (defmethod from-alien-form (location (class proxy-class) &rest args)
 476   (declare (ignore args))
 477   `(ensure-proxy-instance ',(class-name class) ,location))
 478
 479 (defmethod from-alien-function ((class proxy-class) &rest args)
 480   (declare (ignore args))
 481   #'(lambda (location)
 482       (ensure-proxy-instance class location)))
 483
 484 (defmethod to-alien-form (instance (class proxy-class) &rest args)
 485   (declare (ignore class args))
 486   `(foreign-location ,instance))
 487
 488 (defmethod to-alien-function ((class proxy-class) &rest args)
 489   (declare (ignore class args))
 490   #'foreign-location)
 491
 492 (defmethod copy-from-alien-form (location (class proxy-class) &rest args)
 493   (declare (ignore args))
 494   (let ((class-name (class-name class)))
 495     `(ensure-proxy-instance ',class-name
 496       (reference-foreign ',class-name ,location))))
 497
 498 (defmethod copy-from-alien-function ((class proxy-class) &rest args)
 499   (declare (ignore args))
 500   #'(lambda (location)
 501       (ensure-proxy-instance class (reference-foreign class location))))
 502
 503 (defmethod copy-to-alien-form (instance (class proxy-class) &rest args)
 504   (declare (ignore args))
 505   `(reference-foreign ',(class-name class) (foreign-location ,instance)))
 506
 507 (defmethod copy-to-alien-function ((class proxy-class) &rest args)
 508   (declare (ignore args))
 509   #'(lambda (instance)
 510       (reference-foreign class (foreign-location instance))))
 511
 512 (defmethod writer-function ((class proxy-class) &rest args)
 513   (declare (ignore args))
 514   #'(lambda (instance location &optional (offset 0))
 515       (assert (null-pointer-p (sap-ref-sap location offset)))
 516       (setf
 517        (sap-ref-sap location offset)
 518        (reference-foreign class (foreign-location instance)))))
 519
 520 (defmethod reader-function ((class proxy-class) &rest args)
 521   (declare (ignore args))
 522   #'(lambda (location &optional (offset 0) weak-p)
 523       (declare (ignore weak-p))
 524       (let ((instance (sap-ref-sap location offset)))
 525         (unless (null-pointer-p instance)
 526           (ensure-proxy-instance class (reference-foreign class instance))))))
 527
 528 (defmethod destroy-function ((class proxy-class) &rest args)
 529   (declare (ignore args))
 530   #'(lambda (location &optional (offset 0))
 531       (unreference-foreign class (sap-ref-sap location offset))))
 532
 533 (defmethod unbound-value ((class proxy-class) &rest args)
 534   (declare (ignore args))
 535   (values t nil))
 536
 537 (defun ensure-proxy-instance (class location &rest initargs)
 538   "Returns a proxy object representing the foreign object at the give
 539 location. If an existing object is not found in the cache
 540 MAKE-PROXY-INSTANCE is called to create one."
 541   (unless (null-pointer-p location)
 542     (or
 543      #-debug-ref-counting(find-cached-instance location)
 544      #+debug-ref-counting
 545      (let ((instance (find-cached-instance location)))
 546        (when instance
 547          (format t "Object found in cache: ~A~%" instance)
 548          instance))
 549      (let ((instance (apply #'make-proxy-instance class location initargs)))
 550        (cache-instance instance)
 551        instance))))
 552
 553 (defgeneric make-proxy-instance (class location &key weak)
 554   (:documentation "Creates a new proxy object representing the foreign
 555 object at the give location. If WEAK is non NIL the foreign memory
 556 will not be released when the proxy is garbage collected."))
 557
 558 (defmethod make-proxy-instance ((class symbol) location &rest initargs)
 559   (apply #'make-proxy-instance (find-class class) location initargs))
 560
 561 (defmethod make-proxy-instance ((class proxy-class) location &key weak)
 562   (let ((instance
 563          (or
 564           (find-invalidated-instance class)
 565           (allocate-instance class))))
 566     (setf (slot-value instance 'location) location)
 567     (unless weak
 568       (finalize instance (instance-finalizer instance)))
 569     instance))
 570
 571
 572 ;;;; Superclasses for wrapping of C structures
 573
 574 (defclass struct (proxy)
 575   ()
 576   (:metaclass proxy-class)
 577   (:size 0))
 578
 579 (defmethod initialize-instance ((struct struct) &rest initargs)
 580   (declare (ignore initargs))
 581   (unless (slot-boundp struct 'location)
 582     (let ((size (foreign-size (class-of struct))))
 583       (if (zerop size)
 584           (error "~A has zero size" (class-of struct))
 585         (setf (slot-value struct 'location) (allocate-memory size)))))
 586   (call-next-method))
 587
 588
 589 ;;;; Metaclasses used for subclasses of struct
 590
 591 (defclass struct-class (proxy-class)
 592   ())
 593
 594 (defmethod direct-slot-definition-class ((class struct-class) &rest initargs)
 595   (if (not (getf initargs :allocation))
 596       (find-class 'direct-alien-slot-definition)
 597     (call-next-method)))
 598
 599 (defmethod reference-foreign ((class struct-class) location)
 600   (copy-memory location (foreign-size class)))
 601
 602 (defmethod unreference-foreign ((class struct-class) location)
 603   (deallocate-memory location))
 604
 605 (defmethod compute-foreign-size ((class struct-class))
 606   (let ((size (loop
 607                for slotd in (class-slots class)
 608                when (eq (slot-definition-allocation slotd) :alien)
 609                maximize (+
 610                          (slot-definition-offset slotd)
 611                          (size-of (slot-definition-type slotd))))))
 612     (+ size (mod size +struct-alignmen+))))
 613
 614 (defmethod reader-function ((class struct-class) &rest args)
 615   (declare (ignore args))
 616   #'(lambda (location &optional (offset 0) weak-p)
 617       (let ((instance (sap-ref-sap location offset)))
 618         (unless (null-pointer-p instance)
 619           (if weak-p
 620               (ensure-proxy-instance class instance :weak t)
 621             (ensure-proxy-instance class (reference-foreign class instance)))))))
 622
 623
 624 (defclass static-struct-class (struct-class)
 625   ())
 626
 627 (defmethod reference-foreign ((class static-struct-class) location)
 628   (declare (ignore class))
 629   location)
 630
 631 (defmethod unreference-foreign ((class static-struct-class) location)
 632   (declare (ignore class location))
 633   nil)
 634
 635 (defmethod reader-function ((class struct-class) &rest args)
 636   (declare (ignore args))
 637   #'(lambda (location &optional (offset 0) weak-p)
 638       (declare (ignore weak-p))
 639       (let ((instance (sap-ref-sap location offset)))
 640         (unless (null-pointer-p instance)
 641           (ensure-proxy-instance class instance :weak t)))))
 642
 643
 644 ;;; Pseudo type for structs which are inlined in other objects
 645
 646 (defmethod size-of ((type (eql 'inlined)) &rest args)
 647   (declare (ignore type))
 648   (foreign-size (first args)))
 649
 650 (defmethod reader-function ((type (eql 'inlined)) &rest args)
 651   (declare (ignore type))
 652   (destructuring-bind (class) args
 653     #'(lambda (location &optional (offset 0) weak-p)
 654         (declare (ignore weak-p))
 655         (ensure-proxy-instance class
 656          (reference-foreign class (sap+ location offset))))))
 657
 658 (defmethod writer-function ((type (eql 'inlined)) &rest args)
 659   (declare (ignore type))
 660   (destructuring-bind (class) args
 661     #'(lambda (instance location &optional (offset 0))
 662         (copy-memory (foreign-location instance) (foreign-size class) (sap+ location offset)))))
 663
 664 (defmethod destroy-function ((type (eql 'inlined)) &rest args)
 665   (declare (ignore args))
 666   #'(lambda (location &optional (offset 0))
 667       (declare (ignore location offset))))
 668
 669 (export 'inlined)