chiark - git - mdw - clg/blob - glib/proxy.lisp

   1 ;; Common Lisp bindings for GTK+ v2.x
   2 ;; Copyright 2000-2005 Espen S. Johnsen <espen@users.sf.net>
   3 ;;
   4 ;; Permission is hereby granted, free of charge, to any person obtaining
   5 ;; a copy of this software and associated documentation files (the
   6 ;; "Software"), to deal in the Software without restriction, including
   7 ;; without limitation the rights to use, copy, modify, merge, publish,
   8 ;; distribute, sublicense, and/or sell copies of the Software, and to
   9 ;; permit persons to whom the Software is furnished to do so, subject to
  10 ;; the following conditions:
  11 ;;
  12 ;; The above copyright notice and this permission notice shall be
  13 ;; included in all copies or substantial portions of the Software.
  14 ;;
  15 ;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  16 ;; EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 ;; MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  18 ;; IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
  19 ;; CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 ;; TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 ;; SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 ;; $Id: proxy.lisp,v 1.26 2006-02-06 11:52:24 espen Exp $
  24
  25 (in-package "GLIB")
  26
  27 ;;;; Superclass for all metaclasses implementing some sort of virtual slots
  28
  29 (eval-when (:compile-toplevel :load-toplevel :execute)
  30   (defclass virtual-slots-class (standard-class)
  31     ())
  32
  33   (defclass direct-virtual-slot-definition (standard-direct-slot-definition)
  34     ((setter :reader slot-definition-setter :initarg :setter)
  35      (getter :reader slot-definition-getter :initarg :getter)
  36      (unbound :reader slot-definition-unbound :initarg :unbound)
  37      (boundp :reader slot-definition-boundp :initarg :boundp)))
  38
  39   (defclass effective-virtual-slot-definition (standard-effective-slot-definition)
  40     ((setter :reader slot-definition-setter :initarg :setter)
  41      (getter :reader slot-definition-getter :initarg :getter)
  42      (unbound :reader slot-definition-unbound :initarg :unbound)
  43      (boundp :reader slot-definition-boundp :initarg :boundp)))
  44
  45   (defclass direct-special-slot-definition (standard-direct-slot-definition)
  46     ())
  47
  48   (defclass effective-special-slot-definition (standard-effective-slot-definition)
  49     ()))
  50
  51 (defvar *unbound-marker* (gensym "UNBOUND-MARKER-"))
  52
  53 (defun most-specific-slot-value (instances slot &optional (default *unbound-marker*))
  54   (let ((object (find-if
  55                  #'(lambda (ob)
  56                      (and (slot-exists-p ob slot) (slot-boundp ob slot)))
  57                  instances)))
  58     (if object
  59         (slot-value object slot)
  60       default)))
  61
  62 (defmethod initialize-instance ((slotd effective-special-slot-definition) &rest initargs)
  63   (declare (ignore initargs))
  64   (call-next-method)
  65   (setf (slot-value slotd 'allocation) :instance))
  66
  67
  68 (defmethod direct-slot-definition-class ((class virtual-slots-class) &rest initargs)
  69   (case (getf initargs :allocation)
  70     (:virtual (find-class 'direct-virtual-slot-definition))
  71     (:special (find-class 'direct-special-slot-definition))
  72     (t (call-next-method))))
  73
  74 (defmethod effective-slot-definition-class ((class virtual-slots-class) &rest initargs)
  75   (case (getf initargs :allocation)
  76     (:virtual (find-class 'effective-virtual-slot-definition))
  77     (:special (find-class 'effective-special-slot-definition))
  78     (t (call-next-method))))
  79
  80
  81 (defmethod initialize-internal-slot-functions ((slotd effective-virtual-slot-definition))
  82   (if (not (slot-boundp slotd 'getter))
  83       (setf
  84        (slot-value slotd 'reader-function)
  85        #'(lambda (object)
  86            (declare (ignore object))
  87            (error "Can't read slot: ~A" (slot-definition-name slotd)))
  88        (slot-value slotd 'boundp-function)
  89        #'(lambda (object) (declare (ignore object)) nil))
  90
  91     (let ((getter-function
  92            (let ((getter (slot-value slotd 'getter)))
  93              (etypecase getter
  94                (function getter)
  95                (symbol
  96                 #'(lambda (object)
  97                     (funcall getter object)))
  98                (string
  99                 (let ((reader nil))
 100                   (setf (slot-value slotd 'reader-function)
 101                         #'(lambda (object)
 102                             (unless reader
 103                               (setq reader
 104                                (mkbinding getter
 105                                 (slot-definition-type slotd) 'pointer)))
 106                             (funcall reader (foreign-location object))))))))))
 107
 108       (setf
 109        (slot-value slotd 'boundp-function)
 110        (cond
 111         ((slot-boundp slotd 'unbound)
 112          (let ((unbound-value (slot-value slotd 'unbound)))
 113            #'(lambda (object)
 114                (not (eq (funcall getter-function object) unbound-value)))))
 115         ((slot-boundp slotd 'boundp)
 116          (let ((boundp (slot-value slotd 'boundp)))
 117            (etypecase boundp
 118              (function boundp)
 119              (symbol #'(lambda (object)
 120                          (funcall boundp object)))
 121              (string (let ((reader ()))
 122                        #'(lambda (object)
 123                            (unless reader
 124                              (setq reader
 125                               (mkbinding boundp
 126                                (slot-definition-type slotd) 'pointer)))
 127                            (funcall reader (foreign-location object))))))))
 128         ((multiple-value-bind (unbound-p unbound-value)
 129              (unbound-value (slot-definition-type slotd))
 130            (when unbound-p
 131              #'(lambda (object)
 132                  (not (eq (funcall getter-function object) unbound-value))))))
 133         (#'(lambda (object) (declare (ignore object)) t))))
 134
 135       (setf
 136        (slot-value slotd 'reader-function)
 137        (cond
 138         ((slot-boundp slotd 'unbound)
 139          (let ((unbound (slot-value slotd 'unbound))
 140                (slot-name (slot-definition-name slotd)))
 141            #'(lambda (object)
 142                (let ((value (funcall getter-function object)))
 143                  (if (eq value unbound)
 144                      (slot-unbound (class-of object) object slot-name)
 145                    value)))))
 146         ((slot-boundp slotd 'boundp)
 147          (let ((boundp-function (slot-value slotd 'boundp-function)))
 148            #'(lambda (object)
 149                (and
 150                 (funcall boundp-function object)
 151                 (funcall getter-function object)))))
 152         ((multiple-value-bind (unbound-p unbound-value)
 153              (unbound-value (slot-definition-type slotd))
 154            (let ((slot-name (slot-definition-name slotd)))
 155              (when unbound-p
 156                #'(lambda (object)
 157                    (let ((value (funcall getter-function object)))
 158                      (if (eq value unbound-value)
 159                          (slot-unbound (class-of object) object slot-name)
 160                          value)))))))
 161         (getter-function)))))
 162
 163   (setf
 164    (slot-value slotd 'writer-function)
 165    (if (not (slot-boundp slotd 'setter))
 166        #'(lambda (object)
 167            (declare (ignore object))
 168            (error "Can't set slot: ~A" (slot-definition-name slotd)))
 169      (with-slots (setter) slotd
 170        (etypecase setter
 171          (function setter)
 172          ((or symbol cons)
 173           #'(lambda (value object)
 174               (funcall (fdefinition setter) value object)))
 175          (string
 176           (let ((writer ()))
 177             (setf
 178              (slot-value slotd 'writer-function)
 179              #'(lambda (value object)
 180                  (unless writer
 181                    (setq writer
 182                     (mkbinding setter 'nil 'pointer
 183                      (slot-definition-type slotd))))
 184                  (funcall writer (foreign-location object) value)))))))))
 185
 186   (initialize-internal-slot-gfs (slot-definition-name slotd)))
 187
 188
 189
 190 (defmethod compute-slot-accessor-info ((slotd effective-virtual-slot-definition) type gf)
 191   nil)
 192
 193 (defmethod compute-effective-slot-definition-initargs ((class virtual-slots-class) direct-slotds)
 194   (if (typep (first direct-slotds) 'direct-virtual-slot-definition)
 195       (let ((initargs ()))
 196         (let ((getter (most-specific-slot-value direct-slotds 'getter)))
 197           (unless (eq getter *unbound-marker*)
 198             (setf (getf initargs :getter) getter)))
 199         (let ((setter (most-specific-slot-value direct-slotds 'setter)))
 200           (unless (eq setter *unbound-marker*)
 201             (setf (getf initargs :setter) setter)))
 202         (let ((unbound (most-specific-slot-value direct-slotds 'unbound)))
 203           (unless (eq unbound *unbound-marker*)
 204             (setf (getf initargs :unbound) unbound)))
 205         (let ((boundp (most-specific-slot-value direct-slotds 'boundp)))
 206           (unless (eq boundp *unbound-marker*)
 207             (setf (getf initargs :boundp) boundp)))
 208         (nconc initargs (call-next-method)))
 209     (call-next-method)))
 210
 211
 212 (defmethod slot-value-using-class
 213     ((class virtual-slots-class) (object standard-object)
 214      (slotd effective-virtual-slot-definition))
 215   (if (funcall (slot-value slotd 'boundp-function) object)
 216       (funcall (slot-value slotd 'reader-function) object)
 217     (slot-unbound class object (slot-definition-name slotd))))
 218
 219 (defmethod slot-boundp-using-class
 220     ((class virtual-slots-class) (object standard-object)
 221      (slotd effective-virtual-slot-definition))
 222   (funcall (slot-value slotd 'boundp-function) object))
 223
 224 (defmethod (setf slot-value-using-class)
 225     (value (class virtual-slots-class) (object standard-object)
 226      (slotd effective-virtual-slot-definition))
 227   (funcall (slot-value slotd 'writer-function) value object))
 228
 229
 230 (defmethod validate-superclass
 231     ((class virtual-slots-class) (super standard-class))
 232   t)
 233
 234
 235 ;;;; Proxy cache
 236
 237 (internal *instance-cache*)
 238 (defvar *instance-cache* (make-hash-table :test #'eql))
 239
 240 (defun cache-instance (instance &optional (weak-ref t))
 241   (setf
 242    (gethash (sap-int (foreign-location instance)) *instance-cache*)
 243    (if weak-ref
 244        (make-weak-pointer instance)
 245      instance)))
 246
 247 (defun find-cached-instance (location)
 248   (let ((ref (gethash (sap-int location) *instance-cache*)))
 249     (when ref
 250       (if (weak-pointer-p ref)
 251           (weak-pointer-value ref)
 252         ref))))
 253
 254 (defun instance-cached-p (location)
 255   (gethash (sap-int location) *instance-cache*))
 256
 257 (defun remove-cached-instance (location)
 258   (remhash (sap-int location) *instance-cache*))
 259
 260 ;; For debuging
 261 (defun list-cached-instances ()
 262   (let ((instances ()))
 263     (maphash #'(lambda (location ref)
 264                  (declare (ignore location))
 265                  (push ref instances))
 266              *instance-cache*)
 267     instances))
 268
 269
 270
 271 ;;;; Proxy for alien instances
 272
 273 ;; TODO: add a ref-counted-proxy subclass
 274 (defclass proxy ()
 275   ((location :allocation :special :reader foreign-location :type pointer))
 276   (:metaclass virtual-slots-class))
 277
 278 (defgeneric instance-finalizer (object))
 279 (defgeneric reference-foreign (class location))
 280 (defgeneric unreference-foreign (class location))
 281 (defgeneric invalidate-instance (object))
 282
 283 (defmethod reference-foreign ((name symbol) location)
 284   (reference-foreign (find-class name) location))
 285
 286 (defmethod unreference-foreign ((name symbol) location)
 287   (unreference-foreign (find-class name) location))
 288
 289 (defmethod unreference-foreign :around ((class class) location)
 290   (unless (null-pointer-p location)
 291     (call-next-method)))
 292
 293 (defmethod print-object ((instance proxy) stream)
 294   (print-unreadable-object (instance stream :type t :identity nil)
 295     (if (slot-boundp instance 'location)
 296         (format stream "at 0x~X" (sap-int (foreign-location instance)))
 297       (write-string "at \"unbound\"" stream))))
 298
 299 (defmethod initialize-instance :around ((instance proxy) &rest initargs)
 300   (declare (ignore initargs))
 301   (prog1
 302       (call-next-method)
 303     (cache-instance instance)
 304     (finalize instance (instance-finalizer instance))))
 305
 306 (defmethod instance-finalizer ((instance proxy))
 307   (let ((location (foreign-location instance))
 308         (class (class-of instance)))
 309 ;;     (unless (find-method #'unreference-foreign nil (list (class-of class) t) nil)
 310 ;;       (error "No matching method for UNREFERENCE-INSTANCE when called with class ~A" class))
 311     #'(lambda ()
 312         (remove-cached-instance location)
 313         (unreference-foreign class location))))
 314
 315 (defmethod invalidate-instance ((instance proxy))
 316   (remove-cached-instance (foreign-location instance))
 317   (slot-makunbound instance 'location))
 318
 319
 320 ;;;; Metaclass used for subclasses of proxy
 321
 322 (defgeneric most-specific-proxy-superclass (class))
 323 (defgeneric direct-proxy-superclass (class))
 324 (defgeneric compute-foreign-size (class))
 325
 326
 327 (eval-when (:compile-toplevel :load-toplevel :execute)
 328   (defclass proxy-class (virtual-slots-class)
 329     ((size :reader foreign-size)))
 330
 331   (defclass direct-alien-slot-definition (direct-virtual-slot-definition)
 332     ((allocation :initform :alien)
 333      (offset :reader slot-definition-offset :initarg :offset)))
 334
 335   (defclass effective-alien-slot-definition (effective-virtual-slot-definition)
 336     ((offset :reader slot-definition-offset :initarg :offset)))
 337
 338   (defmethod most-specific-proxy-superclass ((class proxy-class))
 339     (find-if
 340      #'(lambda (class)
 341          (subtypep (class-name class) 'proxy))
 342      (cdr (compute-class-precedence-list class))))
 343
 344   (defmethod direct-proxy-superclass ((class proxy-class))
 345     (find-if
 346      #'(lambda (class)
 347          (subtypep (class-name class) 'proxy))
 348      (class-direct-superclasses class)))
 349
 350   (defmethod shared-initialize ((class proxy-class) names &key size)
 351     (call-next-method)
 352     (cond
 353       (size (setf (slot-value class 'size) (first size)))
 354       ((slot-boundp class 'size) (slot-makunbound class 'size))))
 355
 356   (defmethod direct-slot-definition-class ((class proxy-class) &rest initargs)
 357     (case (getf initargs :allocation)
 358       (:alien (find-class 'direct-alien-slot-definition))
 359       (t (call-next-method))))
 360
 361   (defmethod effective-slot-definition-class ((class proxy-class) &rest initargs)
 362     (case (getf initargs :allocation)
 363       (:alien (find-class 'effective-alien-slot-definition))
 364       (t (call-next-method))))
 365
 366
 367   (defmethod compute-effective-slot-definition-initargs ((class proxy-class) direct-slotds)
 368     (if (eq (most-specific-slot-value direct-slotds 'allocation) :alien)
 369         (nconc
 370          (list :offset (most-specific-slot-value direct-slotds 'offset))
 371          (call-next-method))
 372       (call-next-method)))
 373
 374
 375   (defmethod initialize-internal-slot-functions ((slotd effective-alien-slot-definition))
 376     (with-slots (offset) slotd
 377       (let ((type (slot-definition-type slotd)))
 378         (unless (slot-boundp slotd 'getter)
 379           (let ((reader (reader-function type)))
 380             (setf
 381              (slot-value slotd 'getter)
 382              #'(lambda (object)
 383                  (funcall reader (foreign-location object) offset)))))
 384
 385         (unless (slot-boundp slotd 'setter)
 386           (let ((writer (writer-function type))
 387                 (destroy (destroy-function type)))
 388             (setf
 389              (slot-value slotd 'setter)
 390              #'(lambda (value object)
 391                  (let ((location (foreign-location object)))
 392                    (funcall destroy location offset) ; destroy old value
 393                    (funcall writer value location offset))))))))
 394
 395     (call-next-method))
 396
 397   (defmethod compute-foreign-size ((class proxy-class))
 398     nil)
 399
 400   ;; TODO: call some C code to detect this a compile time
 401   (defconstant +struct-alignmen+ 4)
 402
 403   (defun align-offset (size)
 404     (if (zerop (mod size +struct-alignmen+))
 405         size
 406       (+ size (- +struct-alignmen+ (mod size +struct-alignmen+)))))
 407
 408   (defmethod compute-slots ((class proxy-class))
 409     (let ((alien-slots
 410            (remove-if-not
 411             #'(lambda (slotd)
 412                 (eq (slot-definition-allocation slotd) :alien))
 413             (class-direct-slots class))))
 414       (when alien-slots
 415         (loop
 416          as offset = (align-offset (foreign-size
 417                                     (most-specific-proxy-superclass class)))
 418                      then (align-offset
 419                            (+
 420                             (slot-definition-offset slotd)
 421                             (size-of (slot-definition-type slotd))))
 422        for slotd in alien-slots
 423        unless (slot-boundp slotd 'offset)
 424        do (setf (slot-value slotd 'offset) offset))))
 425     (call-next-method))
 426
 427   (defmethod compute-slots :after ((class proxy-class))
 428     (when (and (class-finalized-p class) (not (slot-boundp class 'size)))
 429       (let ((size (compute-foreign-size class)))
 430         (when size
 431           (setf (slot-value class 'size) size)))))
 432
 433   (defmethod validate-superclass ((class proxy-class) (super standard-class))
 434     (subtypep (class-name super) 'proxy))
 435
 436   (defmethod foreign-size ((class-name symbol))
 437     (foreign-size (find-class class-name))))
 438
 439 (defmethod foreign-size ((object proxy))
 440   (foreign-size (class-of object)))
 441
 442
 443 (defmethod alien-type ((class proxy-class) &rest args)
 444   (declare (ignore class args))
 445   (alien-type 'pointer))
 446
 447 (defmethod size-of ((class proxy-class) &rest args)
 448   (declare (ignore class args))
 449   (size-of 'pointer))
 450
 451 (defmethod from-alien-form (location (class proxy-class) &rest args)
 452   (declare (ignore args))
 453   `(ensure-proxy-instance ',(class-name class) ,location))
 454
 455 (defmethod from-alien-function ((class proxy-class) &rest args)
 456   (declare (ignore args))
 457   #'(lambda (location)
 458       (ensure-proxy-instance class location)))
 459
 460 (defmethod to-alien-form (instance (class proxy-class) &rest args)
 461   (declare (ignore class args))
 462   `(foreign-location ,instance))
 463
 464 (defmethod to-alien-function ((class proxy-class) &rest args)
 465   (declare (ignore class args))
 466   #'foreign-location)
 467
 468 (defmethod copy-from-alien-form (location (class proxy-class) &rest args)
 469   (declare (ignore args))
 470   (let ((class-name (class-name class)))
 471     `(ensure-proxy-instance ',class-name
 472       (reference-foreign ',class-name ,location))))
 473
 474 (defmethod copy-from-alien-function ((class proxy-class) &rest args)
 475   (declare (ignore args))
 476   #'(lambda (location)
 477       (ensure-proxy-instance class (reference-foreign class location))))
 478
 479 (defmethod copy-to-alien-form (instance (class proxy-class) &rest args)
 480   (declare (ignore args))
 481   `(reference-foreign ',(class-name class) (foreign-location ,instance)))
 482
 483 (defmethod copy-to-alien-function ((class proxy-class) &rest args)
 484   (declare (ignore args))
 485   #'(lambda (instance)
 486       (reference-foreign class (foreign-location instance))))
 487
 488 (defmethod writer-function ((class proxy-class) &rest args)
 489   (declare (ignore args))
 490   #'(lambda (instance location &optional (offset 0))
 491       (assert (null-pointer-p (sap-ref-sap location offset)))
 492       (setf
 493        (sap-ref-sap location offset)
 494        (reference-foreign class (foreign-location instance)))))
 495
 496 (defmethod reader-function ((class proxy-class) &rest args)
 497   (declare (ignore args))
 498   #'(lambda (location &optional (offset 0))
 499       (let ((instance (sap-ref-sap location offset)))
 500         (unless (null-pointer-p instance)
 501           (ensure-proxy-instance class (reference-foreign class instance))))))
 502
 503 (defmethod destroy-function ((class proxy-class) &rest args)
 504   (declare (ignore args))
 505   #'(lambda (location &optional (offset 0))
 506       (unreference-foreign class (sap-ref-sap location offset))))
 507
 508 (defmethod unbound-value ((class proxy-class) &rest args)
 509   (declare (ignore args))
 510   (values t nil))
 511
 512 (defun ensure-proxy-instance (class location &rest initargs)
 513   "Returns a proxy object representing the foreign object at the give
 514 location. If an existing object is not found in the cache
 515 MAKE-PROXY-INSTANCE is called to create one."
 516   (unless (null-pointer-p location)
 517     (or
 518      (let ((instance (find-cached-instance location)))
 519        (when instance
 520          (format t "Object found in cache: ~A~%" instance)
 521          instance))
 522      (let ((instance (apply #'make-proxy-instance class location initargs)))
 523        (cache-instance instance)
 524        instance))))
 525
 526 (defgeneric make-proxy-instance (class location &key weak)
 527   (:documentation "Creates a new proxy object representing the foreign
 528 object at the give location. If WEAK is non NIL the foreign memory
 529 will not be released when the proxy is garbage collected."))
 530
 531 (defmethod make-proxy-instance ((class symbol) location &rest initargs)
 532   (apply #'make-proxy-instance (find-class class) location initargs))
 533
 534 (defmethod make-proxy-instance ((class proxy-class) location &key weak)
 535   (let ((instance (allocate-instance class)))
 536     (setf (slot-value instance 'location) location)
 537     (unless weak
 538       (finalize instance (instance-finalizer instance)))
 539     instance))
 540
 541
 542 ;;;; Superclasses for wrapping of C structures
 543
 544 (defclass struct (proxy)
 545   ()
 546   (:metaclass proxy-class)
 547   (:size 0))
 548
 549 (defmethod initialize-instance ((struct struct) &rest initargs)
 550   (declare (ignore initargs))
 551   (unless (slot-boundp struct 'location)
 552     (let ((size (foreign-size (class-of struct))))
 553       (if (zerop size)
 554           (error "~A has zero size" (class-of struct))
 555         (setf (slot-value struct 'location) (allocate-memory size)))))
 556   (call-next-method))
 557
 558
 559 ;;;; Metaclasses used for subclasses of struct
 560
 561 (defclass struct-class (proxy-class)
 562   ())
 563
 564 (defmethod direct-slot-definition-class ((class struct-class) &rest initargs)
 565   (if (not (getf initargs :allocation))
 566       (find-class 'direct-alien-slot-definition)
 567     (call-next-method)))
 568
 569 (defmethod reference-foreign ((class struct-class) location)
 570   (copy-memory location (foreign-size class)))
 571
 572 (defmethod unreference-foreign ((class struct-class) location)
 573   (deallocate-memory location))
 574
 575 (defmethod compute-foreign-size ((class struct-class))
 576   (let ((size (loop
 577                for slotd in (class-slots class)
 578                when (eq (slot-definition-allocation slotd) :alien)
 579                maximize (+
 580                          (slot-definition-offset slotd)
 581                          (size-of (slot-definition-type slotd))))))
 582     (+ size (mod size +struct-alignmen+))))
 583
 584 (defmethod weak-reader-function ((class struct-class) &rest args)
 585   (declare (ignore args))
 586   #'(lambda (location &optional (offset 0))
 587       (let ((instance (sap-ref-sap location offset)))
 588         (unless (null-pointer-p instance)
 589           (ensure-proxy-instance class instance :weak t)))))
 590
 591
 592 (defclass static-struct-class (struct-class)
 593   ())
 594
 595 (defmethod reference-foreign ((class static-struct-class) location)
 596   (declare (ignore class))
 597   location)
 598
 599 (defmethod unreference-foreign ((class static-struct-class) location)
 600   (declare (ignore class location))
 601   nil)
 602
 603
 604 ;;; Pseudo type for structs which are inlined in other objects
 605
 606 (defmethod size-of ((type (eql 'inlined)) &rest args)
 607   (declare (ignore type))
 608   (foreign-size (first args)))
 609
 610 (defmethod reader-function ((type (eql 'inlined)) &rest args)
 611   (declare (ignore type))
 612   (destructuring-bind (class) args
 613     #'(lambda (location &optional (offset 0))
 614         (ensure-proxy-instance class
 615          (reference-foreign class (sap+ location offset))))))
 616
 617 (defmethod writer-function ((type (eql 'inlined)) &rest args)
 618   (declare (ignore type))
 619   (destructuring-bind (class) args
 620     #'(lambda (instance location &optional (offset 0))
 621         (copy-memory (foreign-location instance) (foreign-size class) (sap+ location offset)))))
 622
 623 (defmethod destroy-function ((type (eql 'inlined)) &rest args)
 624   (declare (ignore args))
 625   #'(lambda (location &optional (offset 0))
 626       (declare (ignore location offset))))
 627
 628 (export 'inlined)