chiark - git - mdw - clg/blob - glib/gtype.lisp

   1 ;; Common Lisp bindings for GTK+ v2.x
   2 ;; Copyright 2000-2005 Espen S. Johnsen <espen@users.sf.net>
   3 ;;
   4 ;; Permission is hereby granted, free of charge, to any person obtaining
   5 ;; a copy of this software and associated documentation files (the
   6 ;; "Software"), to deal in the Software without restriction, including
   7 ;; without limitation the rights to use, copy, modify, merge, publish,
   8 ;; distribute, sublicense, and/or sell copies of the Software, and to
   9 ;; permit persons to whom the Software is furnished to do so, subject to
  10 ;; the following conditions:
  11 ;;
  12 ;; The above copyright notice and this permission notice shall be
  13 ;; included in all copies or substantial portions of the Software.
  14 ;;
  15 ;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  16 ;; EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 ;; MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  18 ;; IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
  19 ;; CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 ;; TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 ;; SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 ;; $Id: gtype.lisp,v 1.46 2006-02-19 22:25:31 espen Exp $
  24
  25 (in-package "GLIB")
  26
  27 (use-prefix "g")
  28
  29 ;; Initialize the glib type system
  30 (defbinding type-init () nil)
  31 (type-init)
  32
  33 (deftype type-number () '(unsigned 32))
  34
  35 (deftype gtype () 'symbol)
  36
  37 (defmethod alien-type ((type (eql 'gtype)) &rest args)
  38   (declare (ignore type args))
  39   (alien-type 'type-number))
  40
  41 (defmethod size-of ((type (eql 'gtype)) &rest args)
  42   (declare (ignore type args))
  43   (size-of 'type-number))
  44
  45 (defmethod to-alien-form (gtype (type (eql 'gtype)) &rest args)
  46   (declare (ignore type args))
  47   `(find-type-number ,gtype t))
  48
  49 (defmethod to-alien-function ((type (eql 'gtype)) &rest args)
  50   (declare (ignore type args))
  51   #'(lambda (gtype)
  52       (find-type-number gtype t)))
  53
  54 (defmethod from-alien-form (type-number (type (eql 'gtype)) &rest args)
  55   (declare (ignore type args))
  56   `(type-from-number ,type-number))
  57
  58 (defmethod from-alien-function ((type (eql 'gtype)) &rest args)
  59   (declare (ignore type args))
  60   #'(lambda (type-number)
  61       (type-from-number type-number)))
  62
  63 (defmethod writer-function ((type (eql 'gtype)) &rest args)
  64   (declare (ignore type args))
  65   (let ((writer (writer-function 'type-number)))
  66     #'(lambda (gtype location &optional (offset 0))
  67         (funcall writer (find-type-number gtype t) location offset))))
  68
  69 (defmethod reader-function ((type (eql 'gtype)) &rest args)
  70   (declare (ignore type args))
  71   (let ((reader (reader-function 'type-number)))
  72     #'(lambda (location &optional (offset 0) weak-p)
  73         (declare (ignore weak-p))
  74         (type-from-number (funcall reader location offset)))))
  75
  76
  77 (eval-when (:compile-toplevel :load-toplevel :execute)
  78   (defclass type-query (struct)
  79     ((type-number :allocation :alien :type type-number)
  80      (name :allocation :alien :type string)
  81      (class-size :allocation :alien :type unsigned-int)
  82      (instance-size :allocation :alien :type unsigned-int))
  83     (:metaclass struct-class)))
  84
  85
  86 (defbinding type-query (type) nil
  87   ((find-type-number type t) type-number)
  88   ((make-instance 'type-query) type-query :return))
  89
  90 (defun type-instance-size (type)
  91   (slot-value (type-query type) 'instance-size))
  92
  93 (defun type-class-size (type)
  94   (slot-value (type-query type) 'class-size))
  95
  96 (defbinding type-class-ref (type) pointer
  97   ((find-type-number type t) type-number))
  98
  99 (defbinding type-class-unref (type) nil
 100   ((find-type-number type t) type-number))
 101
 102 (defbinding type-class-peek (type) pointer
 103   ((find-type-number type t) type-number))
 104
 105
 106 ;;;; Mapping between lisp types and glib types
 107
 108 (defvar *registered-types* ())
 109 (defvar *registered-type-aliases* ())
 110 (defvar *registered-static-types* ())
 111 (defvar *lisp-type-to-type-number* (make-hash-table))
 112 (defvar *type-number-to-lisp-type* (make-hash-table))
 113
 114 (defbinding %type-from-name () type-number
 115   (name string))
 116
 117 (defun type-number-from-glib-name (name &optional (error-p t))
 118   (let ((type-number (%type-from-name name)))
 119     (cond
 120      ((not (zerop type-number)) type-number)
 121      (error-p (error "Invalid gtype name: ~A" name)))))
 122
 123 (defun register-type (type id)
 124   (pushnew (cons type id) *registered-types* :key #'car)
 125   (let ((type-number
 126          (typecase id
 127            (string (type-number-from-glib-name id))
 128            (symbol (funcall id)))))
 129        (setf (gethash type *lisp-type-to-type-number*) type-number)
 130        (setf (gethash type-number *type-number-to-lisp-type*) type)
 131        type-number))
 132
 133 (defun register-type-alias (type alias)
 134   (pushnew (cons type alias) *registered-type-aliases* :key #'car)
 135   (setf
 136    (gethash type *lisp-type-to-type-number*)
 137    (find-type-number alias t)))
 138
 139 (defun reinitialize-all-types ()
 140   (clrhash *lisp-type-to-type-number*)
 141   (clrhash *type-number-to-lisp-type*)
 142   (type-init) ; initialize the glib type system
 143   (mapc #'(lambda (type)
 144             (register-type (car type) (cdr type)))
 145         *registered-types*)
 146   (mapc #'(lambda (type)
 147             (register-type-alias (car type) (cdr type)))
 148         *registered-type-aliases*))
 149
 150 (pushnew 'reinitialize-all-types
 151   #+cmu *after-save-initializations*
 152   #+sbcl *init-hooks*)
 153
 154 #+cmu
 155 (pushnew 'system::reinitialize-global-table ; we shouldn't have to do this?
 156  *after-save-initializations*)
 157
 158
 159 (defun find-type-number (type &optional error-p)
 160   (etypecase type
 161     (integer type)
 162     (string (type-number-from-glib-name type error-p))
 163     (symbol
 164      (or
 165       (gethash type *lisp-type-to-type-number*)
 166       (and error-p (error "Type not registered: ~A" type))))
 167     (class (find-type-number (class-name type) error-p))))
 168
 169 (defun type-from-number (type-number &optional error)
 170   (multiple-value-bind (type found)
 171       (gethash type-number *type-number-to-lisp-type*)
 172     (if found
 173         type
 174       (let ((name (find-foreign-type-name type-number)))
 175         (cond
 176          ((and name (not (= (type-number-from-glib-name name nil) type-number)))
 177           ;; This is a hack because GdkEvent seems to be registered
 178           ;; multiple times
 179           (type-from-number (type-number-from-glib-name name)))
 180          ((and error name)
 181           (error "Type number not registered: ~A (~A)" type-number name))
 182          ((and error)
 183           (error "Invalid type number: ~A" type-number)))))))
 184
 185 (defbinding (find-foreign-type-name "g_type_name") (type) (copy-of string)
 186   ((find-type-number type t) type-number))
 187
 188 (defun type-number-of (object)
 189   (find-type-number (type-of object) t))
 190
 191 (eval-when (:compile-toplevel :load-toplevel :execute)
 192   (defvar *type-initializers* ())
 193   (defun %find-types-in-library (pathname prefixes ignore)
 194     (let ((process (run-program
 195                     "/usr/bin/nm" (list "--defined-only" "-D" (namestring (truename pathname)))
 196                     :output :stream :wait nil)))
 197       (unwind-protect
 198           (loop
 199            as symbol = (let ((line (read-line (process-output process) nil)))
 200                          (when line (subseq line 11)))
 201            while symbol
 202            when (and
 203                  (> (length symbol) 9)
 204                  (or
 205                   (not prefixes)
 206                   (some #'(lambda (prefix)
 207                             (and
 208                              (> (length symbol) (length prefix))
 209                              (string= prefix symbol :end2 (length prefix))))
 210                         (mklist prefixes)))
 211                  (string= "_get_type" symbol :start2 (- (length symbol) 9))
 212                  (not (member symbol ignore :test #'string=)))
 213            collect symbol)
 214         (process-close process)))))
 215
 216
 217 (defmacro init-types-in-library (filename &key prefix ignore)
 218   (let ((names (%find-types-in-library filename prefix ignore)))
 219     `(progn
 220        ,@(mapcar #'(lambda (name)
 221                      `(progn
 222                         (defbinding (,(intern name) ,name) () type-number)
 223                         (,(intern name))
 224                         (pushnew ',(intern name) *type-initializers*)))
 225                  names))))
 226
 227 (defun find-type-init-function (type-number)
 228   (loop
 229    for type-init in *type-initializers*
 230    when (= type-number (funcall type-init))
 231    do (return type-init)))
 232
 233 (defun register-type-as (type-number)
 234   (or
 235    (find-type-init-function type-number)
 236    (find-foreign-type-name type-number)
 237    (error "Unknown type-number: ~A" type-number)))
 238
 239 (defun default-type-init-name (type)
 240   (find-symbol (format nil "~A_~A_get_type"
 241                 (package-prefix *package*)
 242                 (substitute #\_ #\- (string-downcase type)))))
 243
 244
 245 (eval-when (:compile-toplevel :load-toplevel :execute)
 246   (defclass type-info (struct)
 247     ((class-size :allocation :alien :type (unsigned 16) :initarg :class-size)
 248      (base-init :allocation :alien :type pointer)
 249      (base-finalize :allocation :alien :type pointer)
 250      (class-init :allocation :alien :type pointer)
 251      (class-finalize :allocation :alien :type pointer)
 252      (class-data :allocation :alien :type pointer)
 253      (instance-size :allocation :alien :type (unsigned 16)
 254                     :initarg :instance-size)
 255      (n-preallocs :allocation :alien :type (unsigned 16))
 256      (instance-init :allocation :alien :type pointer)
 257      (value-table :allocation :alien :type pointer))
 258     (:metaclass struct-class)))
 259
 260 (defbinding %type-register-static () type-number
 261   (parent-type type-number)
 262   (name string)
 263   (info type-info)
 264   (0 unsigned-int))
 265
 266 (defun register-new-type (type parent &optional foreign-name)
 267   (let ((parent-info (type-query parent)))
 268     (with-slots ((parent-number type-number) class-size instance-size) parent-info
 269       (let ((type-number
 270              (%type-register-static
 271               parent-number
 272               (or foreign-name (default-alien-type-name type))
 273               (make-instance 'type-info :class-size class-size :instance-size instance-size))))
 274         (pushnew (list type parent foreign-name) *registered-static-types* :key #'car)
 275         (setf (gethash type *lisp-type-to-type-number*) type-number)
 276         (setf (gethash type-number *type-number-to-lisp-type*) type)
 277         type-number))))
 278
 279
 280
 281 ;;;; Metaclass for subclasses of ginstance
 282
 283 (eval-when (:compile-toplevel :load-toplevel :execute)
 284   (defclass ginstance-class (proxy-class)
 285     ((gtype :initarg :gtype :initform nil :reader ginstance-class-gtype))))
 286
 287
 288 (defun update-size (class)
 289   (let ((type-number (find-type-number class)))
 290     (cond
 291      ((not (slot-boundp class 'size))
 292       (setf (slot-value class 'size) (type-instance-size type-number)))
 293      ((and
 294        (slot-boundp class 'size)
 295        (not (= (type-instance-size type-number) (slot-value class 'size))))
 296       (warn "Size mismatch for class ~A" class)))))
 297
 298
 299 (defmethod finalize-inheritance ((class ginstance-class))
 300   (call-next-method)
 301   (let* ((class-name (class-name class))
 302          (super (most-specific-proxy-superclass class))
 303          (gtype (or
 304                  (first (ginstance-class-gtype class))
 305                  (default-alien-type-name class-name)))
 306          (type-number
 307           (or
 308            (find-type-number class-name)
 309            (let ((type-number
 310                   (if (or
 311                        (symbolp gtype)
 312                        (type-number-from-glib-name gtype nil))
 313                       (register-type class-name gtype)
 314                     (register-new-type class-name (class-name super) gtype))))
 315              (type-class-ref type-number)
 316              type-number))))
 317     (when (and
 318            (supertype type-number)
 319            (not (eq (class-name super) (supertype type-number))))
 320       (warn "~A is the super type for ~A in the gobject type system."
 321        (supertype type-number) class-name)))
 322
 323   (update-size class))
 324
 325
 326 (defmethod shared-initialize ((class ginstance-class) names &rest initargs)
 327   (declare (ignore initargs))
 328   (call-next-method)
 329   (when (class-finalized-p class)
 330     (update-size class)))
 331
 332
 333 (defmethod validate-superclass ((class ginstance-class) (super standard-class))
 334   (subtypep (class-name super) 'ginstance))
 335
 336
 337 ;;;; Superclass for wrapping types in the glib type system
 338
 339 (eval-when (:compile-toplevel :load-toplevel :execute)
 340   (defclass ginstance (proxy)
 341     (;(class :allocation :alien :type pointer :offset 0)
 342      )
 343     (:metaclass proxy-class)
 344     (:size #.(size-of 'pointer))))
 345
 346 (defun %type-number-of-ginstance (location)
 347   (let ((class (sap-ref-sap location 0)))
 348     (sap-ref-32 class 0)))
 349
 350 (defmethod make-proxy-instance :around ((class ginstance-class) location &rest initargs)
 351   (declare (ignore class))
 352   (let ((class (labels ((find-known-class (type-number)
 353                           (or
 354                            (find-class (type-from-number type-number) nil)
 355                            (unless (zerop type-number)
 356                              (find-known-class (type-parent type-number))))))
 357                  (find-known-class (%type-number-of-ginstance location)))))
 358     ;; Note that chancing the class argument must not alter "the
 359     ;; ordered set of applicable methods" as specified in the
 360     ;; Hyperspec
 361     (if class
 362         (apply #'call-next-method class location initargs)
 363       (error "Object at ~A has an unkown type number: ~A"
 364        location (%type-number-of-ginstance location)))))
 365
 366 (defmethod make-proxy-instance ((class ginstance-class) location &rest initargs)
 367   (declare (ignore initargs))
 368   (reference-foreign class location)
 369   ;; Since we make an explicit reference to the foreign object, we
 370   ;; always have to release it when the proxy is garbage collected
 371   ;; and therefor ignore the weak-p argument.
 372   (call-next-method class location :weak nil))
 373
 374 (defmethod invalidate-instance ((instance ginstance))
 375   (declare (ignore instance))
 376   ;; A ginstance should never be invalidated since it is ref counted
 377   nil)
 378
 379 (defmethod callback-from-alien-form (form (class ginstance-class) &rest args)
 380   (declare (ignore args))
 381   (from-alien-form form class))
 382
 383 (defmethod copy-from-alien-form (location (class ginstance-class) &rest args)
 384   (declare (ignore location class args))
 385   (error "Doing copy-from-alien on a ref. counted class is most certainly an error, but if it really is what you want you should use REFERENCE-FOREIGN on the returned instance instead."))
 386
 387 (defmethod copy-from-alien-function ((class ginstance-class) &rest args)
 388   (declare (ignore class args))
 389   (error "Doing copy-from-alien on a ref. counted class is most certainly an error, but if it really is what you want you should use REFERENCE-FOREIGN on the returned instance instead."))
 390
 391 (defmethod reader-function ((class ginstance-class) &rest args)
 392   (declare (ignore args))
 393   #'(lambda (location &optional (offset 0) weak-p)
 394       (declare (ignore weak-p))
 395       (ensure-proxy-instance class (sap-ref-sap location offset))))
 396
 397
 398 ;;;; Registering fundamental types
 399
 400 (register-type 'nil "void")
 401 (register-type 'pointer "gpointer")
 402 (register-type 'char "gchar")
 403 (register-type 'unsigned-char "guchar")
 404 (register-type 'boolean "gboolean")
 405 (register-type 'int "gint")
 406 (register-type-alias 'integer 'int)
 407 (register-type-alias 'fixnum 'int)
 408 (register-type 'unsigned-int "guint")
 409 (register-type 'long "glong")
 410 (register-type 'unsigned-long "gulong")
 411 (register-type 'single-float "gfloat")
 412 (register-type 'double-float "gdouble")
 413 (register-type 'pathname "gchararray")
 414 (register-type 'string "gchararray")
 415
 416
 417 ;;;; Introspection of type information
 418
 419 (defvar *derivable-type-info* (make-hash-table))
 420
 421 (defun register-derivable-type (type id expander &optional dependencies)
 422   (register-type type id)
 423   (let ((type-number (register-type type id)))
 424     (setf
 425      (gethash type-number *derivable-type-info*)
 426      (list expander dependencies))))
 427
 428 (defun find-type-info (type)
 429   (dolist (super (cdr (type-hierarchy type)))
 430     (let ((info (gethash super *derivable-type-info*)))
 431       (return-if info))))
 432
 433 (defun expand-type-definition (type forward-p options)
 434   (let ((expander (first (find-type-info type))))
 435     (funcall expander (find-type-number type t) forward-p options)))
 436
 437 (defbinding type-parent (type) type-number
 438   ((find-type-number type t) type-number))
 439
 440 (defun supertype (type)
 441   (type-from-number (type-parent type)))
 442
 443 (defbinding %type-interfaces (type) pointer
 444   ((find-type-number type t) type-number)
 445   (n-interfaces unsigned-int :out))
 446
 447 (defun type-interfaces (type)
 448   (multiple-value-bind (array length) (%type-interfaces type)
 449     (unwind-protect
 450         (map-c-vector 'list #'identity array 'type-number length)
 451       (deallocate-memory array))))
 452
 453 (defun implements (type)
 454   (mapcar #'type-from-number (type-interfaces type)))
 455
 456 (defun type-hierarchy (type)
 457   (let ((type-number (find-type-number type t)))
 458     (unless (= type-number 0)
 459       (cons type-number (type-hierarchy (type-parent type-number))))))
 460
 461 (defbinding (type-is-p "g_type_is_a") (type super) boolean
 462   ((find-type-number type) type-number)
 463   ((find-type-number super) type-number))
 464
 465 (defbinding %type-children () pointer
 466   (type-number type-number)
 467   (num-children unsigned-int :out))
 468
 469 (defun map-subtypes (function type &optional prefix)
 470   (let ((type-number (find-type-number type t)))
 471     (multiple-value-bind (array length) (%type-children type-number)
 472       (unwind-protect
 473           (map-c-vector
 474            'nil
 475            #'(lambda (type-number)
 476                (when (or
 477                       (not prefix)
 478                       (string-prefix-p prefix (find-foreign-type-name type-number)))
 479                  (funcall function type-number))
 480                (map-subtypes function type-number prefix))
 481            array 'type-number length)
 482         (deallocate-memory array)))))
 483
 484 (defun find-types (prefix)
 485   (let ((type-list nil))
 486     (maphash
 487      #'(lambda (type-number expander)
 488          (declare (ignore expander))
 489          (map-subtypes
 490           #'(lambda (type-number)
 491               (pushnew type-number type-list))
 492           type-number prefix))
 493      *derivable-type-info*)
 494     type-list))
 495
 496 (defun find-type-dependencies (type)
 497   (let ((list-dependencies (second (find-type-info type))))
 498     (when list-dependencies
 499       (funcall list-dependencies (find-type-number type t)))))
 500
 501 (defun %sort-types-topologicaly (types)
 502   (let ((partial-sorted
 503          (sort
 504           (mapcar
 505            #'(lambda (type)
 506                (cons type (remove-if #'(lambda (dep)
 507                                          (not (find dep types)))
 508                                      (find-type-dependencies type))))
 509            types)
 510           #'(lambda (type1 type2) (type-is-p type2 type1)) :key #'car))
 511         (sorted ()))
 512
 513     (loop
 514      as tmp = partial-sorted then (or (rest tmp) partial-sorted)
 515      while tmp
 516      do (destructuring-bind (type . dependencies) (first tmp)
 517           (cond
 518            ((every #'(lambda (dep)
 519                        (assoc dep sorted))
 520                    dependencies)
 521             (push (cons type nil) sorted) ; no forward definition needed
 522             (setq partial-sorted (delete type partial-sorted :key #'first)))
 523            ((some #'(lambda (dep)
 524                       (find type (find-type-dependencies dep)))
 525                   dependencies)
 526             (push (cons type t) sorted) ; forward definition needed
 527             (setq partial-sorted (delete type partial-sorted :key #'first))))))
 528     (nreverse sorted)))
 529
 530
 531 (defun expand-type-definitions (prefix &optional args)
 532   (flet ((type-options (type-number)
 533            (let ((name (find-foreign-type-name type-number)))
 534              (cdr (assoc name args :test #'string=)))))
 535
 536    (let ((type-list
 537           (delete-if
 538            #'(lambda (type-number)
 539                (let ((name (find-foreign-type-name type-number)))
 540                  (or
 541                   (getf (type-options type-number) :ignore)
 542                   (find-if
 543                    #'(lambda (options)
 544                        (and
 545                         (string-prefix-p (first options) name)
 546                         (getf (cdr options) :ignore-prefix)
 547                         (not (some
 548                               #'(lambda (exception)
 549                                   (string= name exception))
 550                               (getf (cdr options) :except)))))
 551                    args))))
 552            (find-types prefix))))
 553
 554      (dolist (type-number type-list)
 555        (let ((name (find-foreign-type-name type-number)))
 556          (register-type
 557           (getf (type-options type-number) :type (default-type-name name))
 558           (register-type-as type-number))))
 559
 560      (let ((sorted-type-list (%sort-types-topologicaly type-list)))
 561        `(progn
 562           ,@(mapcar
 563              #'(lambda (pair)
 564                  (destructuring-bind (type . forward-p) pair
 565                    (expand-type-definition type forward-p (type-options type))))
 566              sorted-type-list)
 567           ,@(mapcar
 568              #'(lambda (pair)
 569                  (destructuring-bind (type . forward-p) pair
 570                    (when forward-p
 571                      (expand-type-definition type nil (type-options type)))))
 572              sorted-type-list))))))
 573
 574 (defmacro define-types-by-introspection (prefix &rest args)
 575   (expand-type-definitions prefix args))
 576
 577
 578 ;;;; Initialize all non static types in GObject
 579
 580 (init-types-in-library #.(concatenate 'string (pkg-config:pkg-variable "glib-2.0" "libdir") "/libgobject-2.0.so"))