chiark - git - mdw - clg/blob - glib/gtype.lisp

   1 ;; Common Lisp bindings for GTK+ v2.0
   2 ;; Copyright (C) 2000-2001 Espen S. Johnsen <esj@stud.cs.uit.no>
   3 ;;
   4 ;; This library is free software; you can redistribute it and/or
   5 ;; modify it under the terms of the GNU Lesser General Public
   6 ;; License as published by the Free Software Foundation; either
   7 ;; version 2 of the License, or (at your option) any later version.
   8 ;;
   9 ;; This library is distributed in the hope that it will be useful,
  10 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 ;; Lesser General Public License for more details.
  13 ;;
  14 ;; You should have received a copy of the GNU Lesser General Public
  15 ;; License along with this library; if not, write to the Free Software
  16 ;; Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18 ;; $Id: gtype.lisp,v 1.28 2005-03-11 10:56:58 espen Exp $
  19
  20 (in-package "GLIB")
  21
  22 (use-prefix "g")
  23
  24 ;; Initialize the glib type system
  25 (defbinding type-init () nil)
  26 (type-init)
  27
  28 (deftype type-number () '(unsigned 32))
  29
  30 (deftype gtype () 'symbol)
  31
  32 (defmethod alien-type ((type (eql 'gtype)) &rest args)
  33   (declare (ignore type args))
  34   (alien-type 'type-number))
  35
  36 (defmethod size-of ((type (eql 'gtype)) &rest args)
  37   (declare (ignore type args))
  38   (size-of 'type-number))
  39
  40 (defmethod to-alien-form (gtype (type (eql 'gtype)) &rest args)
  41   (declare (ignore type args))
  42   `(find-type-number ,gtype t))
  43
  44 (defmethod to-alien-function ((type (eql 'gtype)) &rest args)
  45   (declare (ignore type args))
  46   #'(lambda (gtype)
  47       (find-type-number gtype t)))
  48
  49 (defmethod from-alien-form (type-number (type (eql 'gtype)) &rest args)
  50   (declare (ignore type args))
  51   `(type-from-number ,type-number))
  52
  53 (defmethod from-alien-function ((type (eql 'gtype)) &rest args)
  54   (declare (ignore type args))
  55   #'(lambda (type-number)
  56       (type-from-number type-number)))
  57
  58 (defmethod writer-function ((type (eql 'gtype)) &rest args)
  59   (declare (ignore type args))
  60   (let ((writer (writer-function 'type-number)))
  61     #'(lambda (gtype location &optional (offset 0))
  62         (funcall writer (find-type-number gtype t) location offset))))
  63
  64 (defmethod reader-function ((type (eql 'gtype)) &rest args)
  65   (declare (ignore type args))
  66   (let ((reader (reader-function 'type-number)))
  67     #'(lambda (location &optional (offset 0))
  68         (type-from-number (funcall reader location offset)))))
  69
  70
  71 (eval-when (:compile-toplevel :load-toplevel :execute)
  72   (defclass type-query (struct)
  73     ((type-number :allocation :alien :type type-number)
  74      (name :allocation :alien :type string)
  75      (class-size :allocation :alien :type unsigned-int)
  76      (instance-size :allocation :alien :type unsigned-int))
  77     (:metaclass struct-class)))
  78
  79
  80 (defbinding type-query (type) nil
  81   ((find-type-number type t) type-number)
  82   ((make-instance 'type-query) type-query :return))
  83
  84 (defun type-instance-size (type)
  85   (slot-value (type-query type) 'instance-size))
  86
  87 (defun type-class-size (type)
  88   (slot-value (type-query type) 'class-size))
  89
  90 (defbinding type-class-ref (type) pointer
  91   ((find-type-number type t) type-number))
  92
  93 (defbinding type-class-unref (type) nil
  94   ((find-type-number type t) type-number))
  95
  96 (defbinding type-class-peek (type) pointer
  97   ((find-type-number type t) type-number))
  98
  99
 100 ;;;; Mapping between lisp types and glib types
 101
 102 (defvar *registered-types* ())
 103 (defvar *registered-type-aliases* ())
 104 (defvar *lisp-type-to-type-number* (make-hash-table))
 105 (defvar *type-number-to-lisp-type* (make-hash-table))
 106
 107 (defbinding %type-from-name () type-number
 108   (name string))
 109
 110 (defun type-number-from-glib-name (name &optional (error-p t))
 111   (let ((type-number (%type-from-name name)))
 112     (cond
 113      ((not (zerop type-number)) type-number)
 114      (error-p (error "Invalid gtype name: ~A" name)))))
 115
 116 (defun register-type (type id)
 117   (pushnew (cons type id) *registered-types* :key #'car)
 118   (let ((type-number
 119          (typecase id
 120            (string (type-number-from-glib-name id))
 121            (symbol (funcall id)))))
 122        (setf (gethash type *lisp-type-to-type-number*) type-number)
 123        (setf (gethash type-number *type-number-to-lisp-type*) type)
 124        type-number))
 125
 126 (defun register-type-alias (type alias)
 127   (pushnew (cons type alias) *registered-type-aliases* :key #'car)
 128   (setf
 129    (gethash type *lisp-type-to-type-number*)
 130    (find-type-number alias t)))
 131
 132 (defun reinitialize-all-types ()
 133   (clrhash *lisp-type-to-type-number*)
 134   (clrhash *type-number-to-lisp-type*)
 135   (type-init) ; initialize the glib type system
 136   (mapc #'(lambda (type)
 137             (register-type (car type) (cdr type)))
 138         *registered-types*)
 139   (mapc #'(lambda (type)
 140             (register-type-alias (car type) (cdr type)))
 141         *registered-type-aliases*))
 142
 143 (pushnew 'reinitialize-all-types
 144   #+cmu *after-save-initializations*
 145   #+sbcl *init-hooks*)
 146
 147 #+cmu
 148 (pushnew 'system::reinitialize-global-table ; we shouldn't have to do this?
 149  *after-save-initializations*)
 150
 151
 152 (defun find-type-number (type &optional error-p)
 153   (etypecase type
 154     (integer type)
 155     (string (type-number-from-glib-name type error-p))
 156     (symbol
 157      (or
 158       (gethash type *lisp-type-to-type-number*)
 159       (and error-p (error "Type not registered: ~A" type))))
 160     (class (find-type-number (class-name type) error-p))))
 161
 162 (defun type-from-number (type-number &optional error)
 163   (multiple-value-bind (type found)
 164       (gethash type-number *type-number-to-lisp-type*)
 165     (when (and error (not found))
 166       (let ((name (find-foreign-type-name type-number)))
 167         (if name
 168             (error "Type number not registered: ~A (~A)" type-number name)
 169           (error "Invalid type number: ~A" type-number))))
 170     type))
 171
 172 (defbinding (find-foreign-type-name "g_type_name") (type) (copy-of string)
 173   ((find-type-number type t) type-number))
 174
 175 (defun type-number-of (object)
 176   (find-type-number (type-of object) t))
 177
 178 (eval-when (:compile-toplevel :load-toplevel :execute)
 179   (defvar *type-initializers* ())
 180   (defun %find-types-in-library (pathname prefixes ignore)
 181     (let ((process (run-program
 182                     "/usr/bin/nm" (list "--defined-only" "-D" (namestring (truename pathname)))
 183                     :output :stream :wait nil)))
 184       (unwind-protect
 185           (loop
 186            as symbol = (let ((line (read-line (process-output process) nil)))
 187                          (when line (subseq line 11)))
 188            while symbol
 189            when (and
 190                  (> (length symbol) 9)
 191                  (or
 192                   (not prefixes)
 193                   (some #'(lambda (prefix)
 194                             (and
 195                              (> (length symbol) (length prefix))
 196                              (string= prefix symbol :end2 (length prefix))))
 197                         (mklist prefixes)))
 198                  (string= "_get_type" symbol :start2 (- (length symbol) 9))
 199                  (not (member symbol ignore :test #'string=)))
 200            collect symbol)
 201         (process-close process)))))
 202
 203
 204 (defmacro init-types-in-library (filename &key prefix ignore)
 205   (let ((names (%find-types-in-library filename prefix ignore)))
 206     `(progn
 207        ,@(mapcar #'(lambda (name)
 208                      `(progn
 209                         (defbinding (,(intern name) ,name) () type-number)
 210                         (,(intern name))
 211                         (pushnew ',(intern name) *type-initializers*)))
 212                  names))))
 213
 214 (defun find-type-init-function (type-number)
 215   (loop
 216    for type-init in *type-initializers*
 217    when (= type-number (funcall type-init))
 218    do (return type-init)))
 219
 220 (defun register-type-as (type-number)
 221   (or
 222    (find-type-init-function type-number)
 223    (find-foreign-type-name type-number)
 224    (error "Unknown type-number: ~A" type-number)))
 225
 226 (defun default-type-init-name (type)
 227   (find-symbol (format nil "~A_~A_get_type"
 228                 (package-prefix *package*)
 229                 (substitute #\_ #\- (string-downcase type)))))
 230
 231
 232
 233 ;;;; Metaclass for subclasses of ginstance
 234
 235 (eval-when (:compile-toplevel :load-toplevel :execute)
 236   (defclass ginstance-class (proxy-class)
 237     ()))
 238
 239
 240 (defmethod shared-initialize ((class ginstance-class) names &key name gtype)
 241   (declare (ignore names))
 242   (let* ((class-name (or name (class-name class)))
 243          (type-number
 244           (or
 245            (find-type-number class-name)
 246            (register-type class-name
 247              (or (first gtype) (default-type-init-name class-name))))))
 248     (call-next-method)
 249     (when (slot-boundp class 'size)
 250       (setf (slot-value class 'size) (type-instance-size type-number)))))
 251
 252
 253 (defmethod validate-superclass ((class ginstance-class) (super standard-class))
 254   (subtypep (class-name super) 'ginstance))
 255
 256
 257 ;;;; Superclass for wrapping types in the glib type system
 258
 259 (eval-when (:compile-toplevel :load-toplevel :execute)
 260   (defclass ginstance (proxy)
 261     ((class :allocation :alien :type pointer))
 262     (:metaclass proxy-class)))
 263
 264 (defun %type-of-ginstance (location)
 265   (let ((class (sap-ref-sap location 0)))
 266     (type-from-number (sap-ref-32 class 0))))
 267
 268 (defmethod ensure-proxy-instance ((class ginstance-class) location)
 269   (declare (ignore class))
 270   (let ((class (find-class (%type-of-ginstance location))))
 271     (if class
 272         (make-instance class :location (reference-foreign class location))
 273       ;; TODO: (make-instance 'ginstance ...)
 274       location)))
 275
 276 (defmethod copy-from-alien-form (location (class ginstance-class) &rest args)
 277   (declare (ignore location class args))
 278   (error "Doing copy-from-alien on a ref. counted class is most certainly an error, but if it really is what you want you should use REFERENCE-FOREIGN on the returned instance instead."))
 279
 280 (defmethod copy-from-alien-function ((class ginstance-class) &rest args)
 281   (declare (ignore class args))
 282   (error "Doing copy-from-alien on a ref. counted class is most certainly an error, but if it really is what you want you should use REFERENCE-FOREIGN on the returned instance instead."))
 283
 284 (defmethod reader-function ((class ginstance-class) &rest args)
 285   (declare (ignore args))
 286   #'(lambda (location &optional (offset 0))
 287       (ensure-proxy-instance class (sap-ref-sap location offset))))
 288
 289
 290 ;;;; Registering fundamental types
 291
 292 (register-type 'nil "void")
 293 (register-type 'pointer "gpointer")
 294 (register-type 'char "gchar")
 295 (register-type 'unsigned-char "guchar")
 296 (register-type 'boolean "gboolean")
 297 (register-type 'int "gint")
 298 (register-type-alias 'fixnum 'int)
 299 (register-type 'unsigned-int "guint")
 300 (register-type 'long "glong")
 301 (register-type 'unsigned-long "gulong")
 302 (register-type 'single-float "gfloat")
 303 (register-type 'double-float "gdouble")
 304 (register-type 'pathname "gchararray")
 305 (register-type 'string "gchararray")
 306
 307
 308 ;;;; Introspection of type information
 309
 310 (defvar *derivable-type-info* (make-hash-table))
 311
 312 (defun register-derivable-type (type id expander &optional dependencies)
 313   (register-type type id)
 314   (let ((type-number (register-type type id)))
 315     (setf
 316      (gethash type-number *derivable-type-info*)
 317      (list expander dependencies))))
 318
 319 (defun find-type-info (type)
 320   (dolist (super (cdr (type-hierarchy type)))
 321     (let ((info (gethash super *derivable-type-info*)))
 322       (return-if info))))
 323
 324 (defun expand-type-definition (type forward-p options)
 325   (let ((expander (first (find-type-info type))))
 326     (funcall expander (find-type-number type t) forward-p options)))
 327
 328 (defbinding type-parent (type) type-number
 329   ((find-type-number type t) type-number))
 330
 331 (defun supertype (type)
 332   (type-from-number (type-parent type)))
 333
 334 (defbinding %type-interfaces (type) pointer
 335   ((find-type-number type t) type-number)
 336   (n-interfaces unsigned-int :out))
 337
 338 (defun type-interfaces (type)
 339   (multiple-value-bind (array length) (%type-interfaces type)
 340     (unwind-protect
 341         (map-c-vector 'list #'identity array 'type-number length)
 342       (deallocate-memory array))))
 343
 344 (defun implements (type)
 345   (mapcar #'type-from-number (type-interfaces type)))
 346
 347 (defun type-hierarchy (type)
 348   (let ((type-number (find-type-number type t)))
 349     (unless (= type-number 0)
 350       (cons type-number (type-hierarchy (type-parent type-number))))))
 351
 352 (defbinding (type-is-p "g_type_is_a") (type super) boolean
 353   ((find-type-number type) type-number)
 354   ((find-type-number super) type-number))
 355
 356 (defbinding %type-children () pointer
 357   (type-number type-number)
 358   (num-children unsigned-int :out))
 359
 360 (defun map-subtypes (function type &optional prefix)
 361   (let ((type-number (find-type-number type t)))
 362     (multiple-value-bind (array length) (%type-children type-number)
 363       (unwind-protect
 364           (map-c-vector
 365            'nil
 366            #'(lambda (type-number)
 367                (when (or
 368                       (not prefix)
 369                       (string-prefix-p prefix (find-foreign-type-name type-number)))
 370                  (funcall function type-number))
 371                (map-subtypes function type-number prefix))
 372            array 'type-number length)
 373         (deallocate-memory array)))))
 374
 375 (defun find-types (prefix)
 376   (let ((type-list nil))
 377     (maphash
 378      #'(lambda (type-number expander)
 379          (declare (ignore expander))
 380          (map-subtypes
 381           #'(lambda (type-number)
 382               (pushnew type-number type-list))
 383           type-number prefix))
 384      *derivable-type-info*)
 385     type-list))
 386
 387 (defun find-type-dependencies (type)
 388   (let ((list-dependencies (second (find-type-info type))))
 389     (when list-dependencies
 390       (funcall list-dependencies (find-type-number type t)))))
 391
 392 (defun %sort-types-topologicaly (types)
 393   (let ((partial-sorted
 394          (sort
 395           (mapcar
 396            #'(lambda (type)
 397                (cons type (remove-if #'(lambda (dep)
 398                                          (not (find dep types)))
 399                                      (find-type-dependencies type))))
 400            types)
 401           #'(lambda (type1 type2) (type-is-p type2 type1)) :key #'car))
 402         (sorted ()))
 403
 404     (loop
 405      as tmp = partial-sorted then (or (rest tmp) partial-sorted)
 406      while tmp
 407      do (destructuring-bind (type . dependencies) (first tmp)
 408           (cond
 409            ((every #'(lambda (dep)
 410                        (assoc dep sorted))
 411                    dependencies)
 412             (push (cons type nil) sorted) ; no forward definition needed
 413             (setq partial-sorted (delete type partial-sorted :key #'first)))
 414            ((some #'(lambda (dep)
 415                       (find type (find-type-dependencies dep)))
 416                   dependencies)
 417             (push (cons type t) sorted) ; forward definition needed
 418             (setq partial-sorted (delete type partial-sorted :key #'first))))))
 419     (nreverse sorted)))
 420
 421
 422 (defun expand-type-definitions (prefix &optional args)
 423   (flet ((type-options (type-number)
 424            (let ((name (find-foreign-type-name type-number)))
 425              (cdr (assoc name args :test #'string=)))))
 426
 427    (let ((type-list
 428           (delete-if
 429            #'(lambda (type-number)
 430                (let ((name (find-foreign-type-name type-number)))
 431                  (or
 432                   (getf (type-options type-number) :ignore)
 433                   (find-if
 434                    #'(lambda (options)
 435                        (and
 436                         (string-prefix-p (first options) name)
 437                         (getf (cdr options) :ignore-prefix)
 438                         (not (some
 439                               #'(lambda (exception)
 440                                   (string= name exception))
 441                               (getf (cdr options) :except)))))
 442                    args))))
 443            (find-types prefix))))
 444
 445      (dolist (type-number type-list)
 446        (let ((name (find-foreign-type-name type-number)))
 447          (register-type
 448           (getf (type-options type-number) :type (default-type-name name))
 449           (register-type-as type-number))))
 450
 451      (let ((sorted-type-list (%sort-types-topologicaly type-list)))
 452        `(progn
 453           ,@(mapcar
 454              #'(lambda (pair)
 455                  (destructuring-bind (type . forward-p) pair
 456                    (expand-type-definition type forward-p (type-options type))))
 457              sorted-type-list)
 458           ,@(mapcar
 459              #'(lambda (pair)
 460                  (destructuring-bind (type . forward-p) pair
 461                    (when forward-p
 462                      (expand-type-definition type nil (type-options type)))))
 463              sorted-type-list))))))
 464
 465 (defmacro define-types-by-introspection (prefix &rest args)
 466   (expand-type-definitions prefix args))
 467
 468
 469 ;;;; Initialize all non static types in GObject
 470
 471 (init-types-in-library #.(concatenate 'string (pkg-config:pkg-variable "glib-2.0" "libdir") "/libgobject-2.0.so"))