chiark - git - mdw - clg/blob - glib/proxy.lisp

   1 ;; Common Lisp bindings for GTK+ v2.0
   2 ;; Copyright (C) 2000 Espen S. Johnsen <esj@stud.cs.uit.no>
   3 ;;
   4 ;; This library is free software; you can redistribute it and/or
   5 ;; modify it under the terms of the GNU Lesser General Public
   6 ;; License as published by the Free Software Foundation; either
   7 ;; version 2 of the License, or (at your option) any later version.
   8 ;;
   9 ;; This library is distributed in the hope that it will be useful,
  10 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 ;; Lesser General Public License for more details.
  13 ;;
  14 ;; You should have received a copy of the GNU Lesser General Public
  15 ;; License along with this library; if not, write to the Free Software
  16 ;; Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18 ;; $Id: proxy.lisp,v 1.18 2005-01-12 13:35:19 espen Exp $
  19
  20 (in-package "GLIB")
  21
  22 ;;;; Superclass for all metaclasses implementing some sort of virtual slots
  23
  24 (eval-when (:compile-toplevel :load-toplevel :execute)
  25   (defclass virtual-slots-class (standard-class)
  26     ())
  27
  28   (defclass direct-virtual-slot-definition (standard-direct-slot-definition)
  29     ((setter :reader slot-definition-setter :initarg :setter)
  30      (getter :reader slot-definition-getter :initarg :getter)
  31      (unbound :reader slot-definition-unbound :initarg :unbound)
  32      (boundp :reader slot-definition-boundp :initarg :boundp)))
  33
  34   (defclass effective-virtual-slot-definition (standard-effective-slot-definition)
  35     ((setter :reader slot-definition-setter :initarg :setter)
  36      (getter :reader slot-definition-getter :initarg :getter)
  37      (unbound :reader slot-definition-unbound :initarg :unbound)
  38      (boundp :reader slot-definition-boundp :initarg :boundp)))
  39
  40   (defvar *unbound-marker* (gensym "UNBOUND-MARKER-"))
  41
  42   (defun most-specific-slot-value (instances slot &optional
  43                                    (default *unbound-marker*))
  44     (let ((object (find-if
  45                    #'(lambda (ob)
  46                        (and (slot-exists-p ob slot) (slot-boundp ob slot)))
  47                    instances)))
  48       (if object
  49           (slot-value object slot)
  50           default))))
  51
  52
  53
  54 (defmethod direct-slot-definition-class ((class virtual-slots-class) &rest initargs)
  55   (if (eq (getf initargs :allocation) :virtual)
  56       (find-class 'direct-virtual-slot-definition)
  57     (call-next-method)))
  58
  59 (defmethod effective-slot-definition-class ((class virtual-slots-class) &rest initargs)
  60   (if (eq (getf initargs :allocation) :virtual)
  61       (find-class 'effective-virtual-slot-definition)
  62     (call-next-method)))
  63
  64
  65 (defmethod initialize-internal-slot-functions ((slotd effective-virtual-slot-definition))
  66   (if (not (slot-boundp slotd 'getter))
  67       (setf
  68        (slot-value slotd 'reader-function)
  69        #'(lambda (object)
  70            (declare (ignore object))
  71            (error "Can't read slot: ~A" (slot-definition-name slotd)))
  72        (slot-value slotd 'boundp-function)
  73        #'(lambda (object) (declare (ignore object)) nil))
  74
  75     (let ((getter-function
  76            (let ((getter (slot-value slotd 'getter)))
  77              (etypecase getter
  78                (function getter)
  79                (symbol
  80                 #'(lambda (object)
  81                     (funcall getter object)))
  82                (string
  83                 (let ((reader nil))
  84                   (setf (slot-value slotd 'reader-function)
  85                         #'(lambda (object)
  86                             (unless reader
  87                               (setq reader
  88                                (mkbinding getter
  89                                 (slot-definition-type slotd) 'pointer)))
  90                             (funcall reader (proxy-location object))))))))))
  91
  92       (setf
  93        (slot-value slotd 'boundp-function)
  94        (cond
  95         ((slot-boundp slotd 'unbound)
  96          (let ((unbound-value (slot-value slotd 'unbound)))
  97            #'(lambda (object)
  98                (not (eq (funcall getter-function object) unbound-value)))))
  99         ((slot-boundp slotd 'boundp)
 100          (let ((boundp (slot-value slotd 'boundp)))
 101            (etypecase boundp
 102              (function boundp)
 103              (symbol #'(lambda (object)
 104                          (funcall boundp object)))
 105              (string (let ((reader ()))
 106                        #'(lambda (object)
 107                            (unless reader
 108                              (setq reader
 109                               (mkbinding boundp
 110                                (slot-definition-type slotd) 'pointer)))
 111                            (funcall reader (proxy-location object))))))))
 112         ((multiple-value-bind (unbound-p unbound-value)
 113              (unbound-value (slot-definition-type slotd))
 114            (when unbound-p
 115              #'(lambda (object)
 116                  (not (eq (funcall getter-function object) unbound-value))))))
 117         (#'(lambda (object) (declare (ignore object)) t))))
 118
 119       (setf
 120        (slot-value slotd 'reader-function)
 121        (cond
 122         ((slot-boundp slotd 'unbound)
 123          (let ((unbound (slot-value slotd 'unbound))
 124                (slot-name (slot-definition-name slotd)))
 125            #'(lambda (object)
 126                (let ((value (funcall getter-function object)))
 127                  (if (eq value unbound)
 128                      (slot-unbound (class-of object) object slot-name)
 129                    value)))))
 130         ((slot-boundp slotd 'boundp)
 131          (let ((boundp-function (slot-value slotd 'boundp-function)))
 132            #'(lambda (object)
 133                (and
 134                 (funcall boundp-function object)
 135                 (funcall getter-function object)))))
 136         ((multiple-value-bind (unbound-p unbound-value)
 137              (unbound-value (slot-definition-type slotd))
 138            (let ((slot-name (slot-definition-name slotd)))
 139              (when unbound-p
 140                #'(lambda (object)
 141                    (let ((value (funcall getter-function object)))
 142                      (if (eq value unbound-value)
 143                          (slot-unbound (class-of object) object slot-name)
 144                          value)))))))
 145         (getter-function)))))
 146
 147   (setf
 148    (slot-value slotd 'writer-function)
 149    (if (not (slot-boundp slotd 'setter))
 150        #'(lambda (object)
 151            (declare (ignore object))
 152            (error "Can't set slot: ~A" (slot-definition-name slotd)))
 153      (with-slots (setter) slotd
 154        (etypecase setter
 155          (function setter)
 156          ((or symbol cons)
 157           #'(lambda (value object)
 158               (funcall (fdefinition setter) value object)))
 159          (string
 160           (let ((writer ()))
 161             (setf
 162              (slot-value slotd 'writer-function)
 163              #'(lambda (value object)
 164                  (unless writer
 165                    (setq writer
 166                     (mkbinding setter 'nil 'pointer
 167                      (slot-definition-type slotd))))
 168                  (funcall writer (proxy-location object) value)))))))))
 169
 170   (initialize-internal-slot-gfs (slot-definition-name slotd)))
 171
 172
 173
 174 (defmethod compute-slot-accessor-info ((slotd effective-virtual-slot-definition) type gf)
 175   nil)
 176
 177 (defmethod compute-effective-slot-definition-initargs ((class virtual-slots-class) direct-slotds)
 178   (if (typep (first direct-slotds) 'direct-virtual-slot-definition)
 179       (let ((initargs ()))
 180         (let ((getter (most-specific-slot-value direct-slotds 'getter)))
 181           (unless (eq getter *unbound-marker*)
 182             (setf (getf initargs :getter) getter)))
 183         (let ((setter (most-specific-slot-value direct-slotds 'setter)))
 184           (unless (eq setter *unbound-marker*)
 185             (setf (getf initargs :setter) setter)))
 186         (let ((unbound (most-specific-slot-value direct-slotds 'unbound)))
 187           (unless (eq unbound *unbound-marker*)
 188             (setf (getf initargs :unbound) unbound)))
 189         (let ((boundp (most-specific-slot-value direct-slotds 'boundp)))
 190           (unless (eq boundp *unbound-marker*)
 191             (setf (getf initargs :boundp) boundp)))
 192         (nconc initargs (call-next-method)))
 193     (call-next-method)))
 194
 195
 196 (defmethod slot-value-using-class
 197     ((class virtual-slots-class) (object standard-object)
 198      (slotd effective-virtual-slot-definition))
 199   (if (funcall (slot-value slotd 'boundp-function) object)
 200       (funcall (slot-value slotd 'reader-function) object)
 201     (slot-unbound class object (slot-definition-name slotd))))
 202
 203 (defmethod slot-boundp-using-class
 204     ((class virtual-slots-class) (object standard-object)
 205      (slotd effective-virtual-slot-definition))
 206   (funcall (slot-value slotd 'boundp-function) object))
 207
 208 (defmethod (setf slot-value-using-class)
 209     (value (class virtual-slots-class) (object standard-object)
 210      (slotd effective-virtual-slot-definition))
 211   (funcall (slot-value slotd 'writer-function) value object))
 212
 213
 214 (defmethod validate-superclass
 215     ((class virtual-slots-class) (super standard-class))
 216   t)
 217
 218
 219 ;;;; Proxy cache
 220
 221 (internal *instance-cache*)
 222 (defvar *instance-cache* (make-hash-table :test #'eql))
 223
 224 (defun cache-instance (instance)
 225   (setf
 226    (gethash (system:sap-int (proxy-location instance)) *instance-cache*)
 227    (ext:make-weak-pointer instance)))
 228
 229 (defun find-cached-instance (location)
 230   (let ((ref (gethash (system:sap-int location) *instance-cache*)))
 231     (when ref
 232       (ext:weak-pointer-value ref))))
 233
 234 (defun instance-cached-p (location)
 235   (gethash (system:sap-int location) *instance-cache*))
 236
 237 (defun remove-cached-instance (location)
 238   (remhash (system:sap-int location) *instance-cache*))
 239
 240 ;; For debuging
 241 (defun cached-instances ()
 242   (let ((instances ()))
 243     (maphash #'(lambda (location ref)
 244                  (declare (ignore location))
 245                  (push (ext:weak-pointer-value ref) instances))
 246              *instance-cache*)
 247     instances))
 248
 249
 250
 251 ;;;; Proxy for alien instances
 252
 253 (defclass proxy ()
 254   ((location :reader proxy-location :type system-area-pointer)))
 255
 256 (defgeneric initialize-proxy (object &rest initargs))
 257 (defgeneric instance-finalizer (object))
 258 (defgeneric reference-foreign (class location))
 259 (defgeneric unreference-foreign (class location))
 260
 261 (defmethod reference-foreign ((name symbol) location)
 262   (reference-foreign (find-class name) location))
 263
 264 (defmethod unreference-foreign ((name symbol) location)
 265   (unreference-foreign (find-class name) location))
 266
 267 (defmethod unreference-foreign :around ((class class) location)
 268   (unless (null-pointer-p location)
 269 ;;     (format t "Unreferencing ~A at ~A" (class-name class) location)
 270 ;;     (finish-output *standard-output*)
 271     (call-next-method)
 272 ;;     (write-line " done")
 273 ;;     (finish-output *standard-output*)
 274     ))
 275
 276 (defmethod print-object ((instance proxy) stream)
 277   (print-unreadable-object (instance stream :type t :identity nil)
 278     (when (slot-boundp instance 'location)
 279       (format stream "at 0x~X" (sap-int (proxy-location instance))))))
 280
 281 (defmethod initialize-instance :around ((instance proxy) &key location)
 282   (if location
 283       (setf (slot-value instance 'location) location)
 284     (call-next-method))
 285   (cache-instance instance)
 286   (ext:finalize instance (instance-finalizer instance))
 287   instance)
 288
 289 (defmethod instance-finalizer ((instance proxy))
 290   (let ((location (proxy-location instance))
 291         (class (class-of instance)))
 292 ;;     (unless (find-method #'unreference-foreign nil (list (class-of class) t) nil)
 293 ;;       (error "No matching method for UNREFERENCE-INSTANCE when called with class ~A" class))
 294     #'(lambda ()
 295         (remove-cached-instance location)
 296         (unreference-foreign class location))))
 297
 298
 299 ;;;; Metaclass used for subclasses of proxy
 300
 301 (eval-when (:compile-toplevel :load-toplevel :execute)
 302   (defclass proxy-class (virtual-slots-class)
 303     ((size :reader proxy-instance-size)))
 304
 305   (defclass direct-alien-slot-definition (direct-virtual-slot-definition)
 306     ((allocation :initform :alien)
 307      (offset :reader slot-definition-offset :initarg :offset)))
 308
 309   (defclass effective-alien-slot-definition (effective-virtual-slot-definition)
 310     ((offset :reader slot-definition-offset :initarg :offset)))
 311
 312
 313   (defmethod most-specific-proxy-superclass ((class proxy-class))
 314     (find-if
 315      #'(lambda (class)
 316          (subtypep (class-name class) 'proxy))
 317      (cdr (compute-class-precedence-list class))))
 318
 319   (defmethod direct-proxy-superclass ((class proxy-class))
 320     (find-if
 321      #'(lambda (class)
 322          (subtypep (class-name class) 'proxy))
 323      (class-direct-superclasses class)))
 324
 325   (defmethod shared-initialize ((class proxy-class) names &key size)
 326     (call-next-method)
 327     (cond
 328       (size (setf (slot-value class 'size) (first size)))
 329       ((slot-boundp class 'size) (slot-makunbound class 'size))))
 330
 331   (defmethod direct-slot-definition-class ((class proxy-class) &rest initargs)
 332     (case (getf initargs :allocation)
 333       ((nil :alien) (find-class 'direct-alien-slot-definition))
 334       (t (call-next-method))))
 335
 336   (defmethod effective-slot-definition-class ((class proxy-class) &rest initargs)
 337     (case (getf initargs :allocation)
 338       (:alien (find-class 'effective-alien-slot-definition))
 339       (t (call-next-method))))
 340
 341
 342   (defmethod compute-effective-slot-definition-initargs ((class proxy-class) direct-slotds)
 343     (if (eq (most-specific-slot-value direct-slotds 'allocation) :alien)
 344         (nconc
 345          (list :offset (most-specific-slot-value direct-slotds 'offset))
 346          (call-next-method))
 347       (call-next-method)))
 348
 349
 350   (defmethod initialize-internal-slot-functions ((slotd effective-alien-slot-definition))
 351     (with-slots (offset) slotd
 352       (let ((type (slot-definition-type slotd)))
 353         (unless (slot-boundp slotd 'getter)
 354           (let ((reader (reader-function type)))
 355             (setf
 356              (slot-value slotd 'getter)
 357              #'(lambda (object)
 358                  (funcall reader (proxy-location object) offset)))))
 359
 360         (unless (slot-boundp slotd 'setter)
 361           (let ((writer (writer-function type))
 362                 (destroy (destroy-function type)))
 363             (setf
 364              (slot-value slotd 'setter)
 365              #'(lambda (value object)
 366                  (let ((location (proxy-location object)))
 367                    (funcall destroy location offset) ; destroy old value
 368                    (funcall writer value location offset))))))))
 369
 370     (call-next-method))
 371
 372
 373   ;; TODO: call some C code to detect this a compile time
 374   (defconstant +struct-alignmen+ 4)
 375
 376   (defmethod compute-slots ((class proxy-class))
 377     (loop
 378      with offset = (let ((size-of-super-classes
 379                           (proxy-instance-size
 380                            (most-specific-proxy-superclass class))))
 381                      (+ size-of-super-classes
 382                         (mod size-of-super-classes +struct-alignmen+)))
 383      with size = offset
 384      for slotd in (class-direct-slots class)
 385      when (eq (slot-definition-allocation slotd) :alien)
 386      do (if (not (slot-boundp slotd 'offset))
 387             (setf (slot-value slotd 'offset) offset)
 388           (setq offset (slot-value slotd 'offset)))
 389
 390         (incf offset (size-of (slot-definition-type slotd)))
 391         (incf offset (mod offset +struct-alignmen+))
 392         (setq size (max size offset))
 393
 394      finally (unless (slot-boundp class 'size)
 395                (setf (slot-value class 'size) size)))
 396     (call-next-method))
 397
 398
 399   (defmethod validate-superclass ((class proxy-class) (super standard-class))
 400     (subtypep (class-name super) 'proxy))
 401
 402   (defmethod proxy-instance-size (class)
 403     (declare (ignore class))
 404     0)
 405
 406   (defmethod proxy-instance-size ((class-name symbol))
 407     (proxy-instance-size (find-class class-name)))
 408 )
 409
 410 (defmethod alien-type ((class proxy-class) &rest args)
 411   (declare (ignore class args))
 412   (alien-type 'pointer))
 413
 414 (defmethod size-of ((class proxy-class) &rest args)
 415   (declare (ignore class args))
 416   (size-of 'pointer))
 417
 418 (defmethod from-alien-form (location (class proxy-class) &rest args)
 419   (declare (ignore args))
 420   `(ensure-proxy-instance ',(class-name class) ,location))
 421
 422 (defmethod from-alien-function ((class proxy-class) &rest args)
 423   (declare (ignore args))
 424   #'(lambda (location)
 425       (ensure-proxy-instance class location)))
 426
 427 (defmethod to-alien-form (instance (class proxy-class) &rest args)
 428   (declare (ignore class args))
 429   `(proxy-location ,instance))
 430
 431 (defmethod to-alien-function ((class proxy-class) &rest args)
 432   (declare (ignore class args))
 433   #'proxy-location)
 434
 435 (defmethod copy-from-alien-form (location (class proxy-class) &rest args)
 436   (declare (ignore args))
 437   (let ((class-name (class-name class)))
 438     `(ensure-proxy-instance ',class-name
 439       (reference-foreign ',class-name ,location))))
 440
 441 (defmethod copy-from-alien-function ((class proxy-class) &rest args)
 442   (declare (ignore args))
 443   #'(lambda (location)
 444       (ensure-proxy-instance class (reference-foreign class location))))
 445
 446 (defmethod copy-to-alien-form (instance (class proxy-class) &rest args)
 447   (declare (ignore args))
 448   `(reference-foreign ',(class-name class) (proxy-location ,instance)))
 449
 450 (defmethod copy-to-alien-function ((class proxy-class) &rest args)
 451   (declare (ignore class args))
 452   #'(lambda (instance)
 453       (reference-foreign class (proxy-location instance))))
 454
 455 (defmethod writer-function ((class proxy-class) &rest args)
 456   (declare (ignore args))
 457   #'(lambda (instance location &optional (offset 0))
 458       (assert (null-pointer-p (sap-ref-sap location offset)))
 459       (setf
 460        (sap-ref-sap location offset)
 461        (reference-foreign class (proxy-location instance)))))
 462
 463 (defmethod reader-function ((class proxy-class) &rest args)
 464   (declare (ignore args))
 465   #'(lambda (location &optional (offset 0))
 466       (let ((instance (sap-ref-sap location offset)))
 467         (unless (null-pointer-p instance)
 468           (ensure-proxy-instance class (reference-foreign class instance))))))
 469
 470 (defmethod destroy-function ((class proxy-class) &rest args)
 471   (declare (ignore args))
 472   #'(lambda (location &optional (offset 0))
 473       (unreference-foreign class (sap-ref-sap location offset))))
 474
 475 (defmethod unbound-value ((class proxy-class) &rest args)
 476   (declare (ignore args))
 477   (values t nil))
 478
 479 (defgeneric ensure-proxy-instance (class location)
 480   (:documentation "Returns a proxy object representing the foreign object at the give location."))
 481
 482 (defmethod ensure-proxy-instance :around (class location)
 483   (unless (null-pointer-p location)
 484     (or
 485      (find-cached-instance location)
 486      (call-next-method))))
 487
 488 (defmethod ensure-proxy-instance ((class symbol) location)
 489   (ensure-proxy-instance (find-class class) location))
 490
 491 (defmethod ensure-proxy-instance ((class proxy-class) location)
 492   (make-instance class :location location))
 493
 494
 495 ;;;; Superclasses for wrapping of C structures
 496
 497 (defclass struct (proxy)
 498   ()
 499   (:metaclass proxy-class))
 500
 501 (defmethod initialize-instance ((struct struct) &rest initargs)
 502   (declare (ignore initargs))
 503   (unless (slot-boundp struct 'location)
 504     (let ((size (proxy-instance-size (class-of struct))))
 505       (if (zerop size)
 506           (error "~A has zero size" (class-of struct))
 507         (setf (slot-value struct 'location) (allocate-memory size)))))
 508   (call-next-method))
 509
 510
 511 ;;;; Metaclasses used for subclasses of struct
 512
 513 (defclass struct-class (proxy-class)
 514   ())
 515
 516 (defmethod reference-foreign ((class struct-class) location)
 517   (copy-memory location (proxy-instance-size class)))
 518
 519 (defmethod unreference-foreign ((class struct-class) location)
 520   (deallocate-memory location))
 521
 522
 523 (defclass static-struct-class (struct-class)
 524   ())
 525
 526 (defmethod reference-foreign ((class static-struct-class) location)
 527   (declare (ignore class))
 528   location)
 529
 530 (defmethod unreference-foreign ((class static-struct-class) location)
 531   (declare (ignore class location))
 532   nil)