chiark - git - mdw - clg/blob - cairo/cairo.lisp

   1 ;; Common Lisp bindings for Cairo
   2 ;; Copyright 2005 Espen S. Johnsen <espen@users.sf.net>
   3 ;;
   4 ;; Permission is hereby granted, free of charge, to any person obtaining
   5 ;; a copy of this software and associated documentation files (the
   6 ;; "Software"), to deal in the Software without restriction, including
   7 ;; without limitation the rights to use, copy, modify, merge, publish,
   8 ;; distribute, sublicense, and/or sell copies of the Software, and to
   9 ;; permit persons to whom the Software is furnished to do so, subject to
  10 ;; the following conditions:
  11 ;;
  12 ;; The above copyright notice and this permission notice shall be
  13 ;; included in all copies or substantial portions of the Software.
  14 ;;
  15 ;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  16 ;; EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 ;; MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  18 ;; IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
  19 ;; CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 ;; TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 ;; SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 ;; $Id: cairo.lisp,v 1.15 2007-09-07 07:13:55 espen Exp $
  24
  25 (in-package "CAIRO")
  26
  27 (eval-when (:compile-toplevel :load-toplevel :execute)
  28   (define-enum-type surface-format :argb32 :rgb24 :a8 :a1)
  29   (define-enum-type content :color :alpha :color-alpha)
  30   (define-enum-type svg-version :svg-1.1 :svg-1.2)
  31
  32   (define-enum-type status
  33     :success :no-memory :invalid-restore :invalid-pop-group
  34     :no-current-point :invalid-matrix :invalid-status :null-pointer
  35     :invalid-string :invalid-path-data :read-error :write-error
  36     :surface-finished :surface-type-mismatch :pattern-type-mismatch
  37     :invalid-content :invalid-format :invalid-visual :file-not-found
  38     :invalid-dash)
  39
  40   (define-enum-type fill-rule :winding :even-odd)
  41   (define-enum-type line-cap :butt :round :square)
  42   (define-enum-type line-join :miter :round :bevel)
  43   (define-enum-type font-slant :normal :italic :oblique)
  44   (define-enum-type font-weight :normal :bold)
  45
  46   (define-enum-type operator
  47    :clear :source :over :in :out :atop :dest :dest-over
  48    :dest-in :dest-out :dest-atop :xor :add :saturate)
  49
  50   (define-enum-type antialias :default :none :gray :subpixel)
  51   (define-enum-type extend :none :repeat :reflect)
  52   (define-enum-type filter :fast :good :best :nearest :bilinear :gaussian)
  53   (define-enum-type subpixel-order :default :rgb :bgr :vrgb :vbgr)
  54   (define-enum-type hint-style :default :none :slight :medium :full)
  55   (define-enum-type hint-metrics :default :off :on)
  56
  57
  58   (define-enum-type surface-type
  59     image-surface pdf-surface ps-surface xlib-surface xcb-surface
  60     glitz-surface quartz-surface win32-surface beos-surface
  61     directfb-surface svg-surface os2-surface)
  62
  63   (defclass surface-class (proxy-class)
  64     ())
  65
  66   (defmethod validate-superclass ((class surface-class) (super standard-class))
  67     (subtypep (class-name super) 'surface))
  68
  69   (defclass glyph (struct)
  70     ((index
  71       :allocation :alien
  72       :initarg :index
  73       :accessor glyph-index
  74       :type unsigned-long)
  75      (x
  76       :allocation :alien
  77       :initarg :x
  78       :accessor glyph-x
  79       :type double-float)
  80      (y
  81       :allocation :alien
  82       :initarg :y
  83       :accessor glyph-y
  84       :type double-float))
  85     (:metaclass struct-class))
  86
  87   (defclass font-face (ref-counted-object)
  88     ()
  89     (:metaclass proxy-class)
  90     (:ref %font-face-reference)
  91     (:unref %font-face-destroy))
  92
  93   (defclass font-options (ref-counted-object)
  94     ((antialias
  95       :allocation :virtual
  96       :getter "font_options_get_antialias"
  97       :setter "font_options_set_antialias"
  98       :accessor font-options-antialias
  99       :type antialias)
 100      (subpixel-order
 101       :allocation :virtual
 102       :getter "font_options_get_subpixel_order"
 103       :setter "font_options_set_subpixel_order"
 104       :accessor font-options-subpixel-order
 105       :type subpixel-order)
 106      (hint-style
 107       :allocation :virtual
 108       :getter "font_options_get_hint_style"
 109       :setter "font_options_set_hint_style"
 110       :accessor font-options-hint-style
 111       :type hint-style)
 112      (hint-metrics
 113       :allocation :virtual
 114       :getter "font_options_get_hint_metrics"
 115       :setter "font_options_set_hint_metrics"
 116       :accessor font-options-hint-metrics
 117       :type hint-metrics))
 118     (:metaclass proxy-class)
 119     (:ref %font-options-reference)
 120     (:unref %font-options-destroy))
 121
 122   (defclass scaled-font (ref-counted-object)
 123     ()
 124     (:metaclass proxy-class)
 125     (:ref %scaled-font-reference)
 126     (:unref %scaled-font-destroy))
 127
 128   (defclass matrix (struct)
 129     ((xx :allocation :alien :initarg :xx :initform 1.0
 130          :accessor matrix-xx :type double-float)
 131      (yx :allocation :alien  :initarg :yx :initform 0.0
 132          :accessor matrix-yx :type double-float)
 133      (xy :allocation :alien  :initarg :xy :initform 1.0
 134          :accessor matrix-xy :type double-float)
 135      (yy :allocation :alien  :initarg :yy :initform 0.0
 136          :accessor matrix-yy :type double-float)
 137      (x0 :allocation :alien  :initarg :x0 :initform 0.0
 138          :accessor matrix-x0 :type double-float)
 139      (y0 :allocation :alien  :initarg :y0 :initform 0.0
 140          :accessor matrix-y0 :type double-float))
 141     (:metaclass struct-class))
 142
 143
 144   (defclass text-extents (struct)
 145     ((x-bearing :allocation :alien :reader text-extents-x-bearing :type double-float)
 146      (y-bearing :allocation :alien :reader text-extents-y-bearing :type double-float)
 147      (width :allocation :alien :reader text-extents-width :type double-float)
 148      (height :allocation :alien :reader text-extents-height :type double-float)
 149      (x-advance :allocation :alien :reader text-extents-x-advance :type double-float)
 150      (y-advance :allocation :alien :reader text-extents-y-advance :type double-float))
 151     (:metaclass struct-class))
 152
 153   (defclass pattern (ref-counted-object)
 154     ((extend
 155       :allocation :virtual
 156       :getter "cairo_pattern_get_extend"
 157       :setter "cairo_pattern_set_extend"
 158       :accessor pattern-extend
 159       :type extend)
 160      (filter
 161       :allocation :virtual
 162       :getter "cairo_pattern_get_filter"
 163       :setter "cairo_pattern_set_filter"
 164       :accessor pattern-filter
 165       :type filter)
 166      (matrix
 167       :allocation :virtual
 168       :getter "cairo_pattern_get_matrix"
 169       :setter "cairo_pattern_set_matrix"
 170       :accessor pattern-matrix
 171       :type matrix))
 172     (:metaclass proxy-class)
 173     (:ref %pattern-reference)
 174     (:unref %pattern-destroy))
 175
 176
 177   (defclass surface (ref-counted-object)
 178     ((content
 179       :allocation :virtual
 180       :getter "cairo_surface_get_content"
 181       :reader surface-content
 182       :type content))
 183     (:metaclass surface-class))
 184
 185   (defclass image-surface (surface)
 186     ((data
 187       :allocation :virtual
 188       :getter "cairo_image_surface_get_data"
 189       :reader surface-data
 190       :type pointer)
 191      (format
 192       :allocation :virtual
 193       :getter "cairo_image_surface_get_format"
 194       :reader surface-format
 195       :type surface-format)
 196      (width
 197       :allocation :virtual
 198       :getter "cairo_image_surface_get_width"
 199       :reader surface-width
 200       :type int)
 201      (height
 202       :allocation :virtual
 203       :getter "cairo_image_surface_get_height"
 204       :reader surface-height
 205       :type int)
 206      (stride
 207       :allocation :virtual
 208       :getter "cairo_image_surface_get_stride"
 209       :reader surface-height
 210       :type int))
 211     (:metaclass surface-class))
 212
 213   (defclass xlib-surface (surface)
 214     ((width
 215       :allocation :virtual
 216       :getter "cairo_xlib_surface_get_width"
 217       :reader surface-width
 218       :type int)
 219      (height
 220       :allocation :virtual
 221       :getter "cairo_xlib_surface_get_height"
 222       :reader surface-height
 223       :type int))
 224     (:metaclass surface-class))
 225
 226   (defclass pdf-surface (surface)
 227     ()
 228     (:metaclass surface-class))
 229
 230   (defclass ps-surface (surface)
 231     ()
 232     (:metaclass surface-class))
 233
 234   (defclass svg-surface (surface)
 235     ()
 236     (:metaclass surface-class))
 237
 238
 239   (defclass context (ref-counted-object)
 240     ((target
 241       :allocation :virtual
 242       :getter "cairo_get_target"
 243       :reader target
 244       :type surface)
 245      (source
 246       :allocation :virtual
 247       :getter "cairo_get_source"
 248       :setter "cairo_set_source"
 249       :accessor source
 250       :type pattern)
 251      (antialias
 252       :allocation :virtual
 253       :getter "cairo_get_antialias"
 254       :setter "cairo_set_antialias"
 255       :accessor antialias
 256       :type antialias)
 257      (tolerance
 258       :allocation :virtual
 259       :getter "cairo_get_tolerance"
 260       :setter "cairo_set_tolerance"
 261       :accessor tolerance
 262       :type double-float)
 263      (fill-rule
 264       :allocation :virtual
 265       :getter "cairo_get_fill_rule"
 266       :setter "cairo_set_fill_rule"
 267       :accessor fill-rule
 268       :type fill-rule)
 269      (line-width
 270       :allocation :virtual
 271       :getter "cairo_get_line_width"
 272       :setter "cairo_set_line_width"
 273       :accessor line-width
 274       :type double-float)
 275      (line-cap
 276       :allocation :virtual
 277       :getter "cairo_get_line_cap"
 278       :setter "cairo_set_line_cap"
 279       :accessor line-cap
 280       :type line-cap)
 281      (line-join
 282       :allocation :virtual
 283       :getter "cairo_get_line_join"
 284       :setter "cairo_set_line_join"
 285       :accessor line-join
 286       :type line-join)
 287      (miter-limit
 288       :allocation :virtual
 289       :getter "cairo_get_miter_limit"
 290       :setter "cairo_set_miter_limit"
 291       :accessor miter-limit
 292       :type double-float)
 293      (font-matrix
 294       :allocation :virtual
 295       :getter "cairo_get_font_matrix"
 296       :setter "cairo_set_font_matrix"
 297       :accessor font-matrix
 298       :type matrix)
 299      (font-options
 300       :allocation :virtual
 301       :getter "cairo_get_font_options"
 302       :setter "cairo_set_font_options"
 303       :accessor font-options
 304       :type font-options)
 305      (font-face
 306       :allocation :virtual
 307       :getter "cairo_get_font_face"
 308       :setter "cairo_set_font_face"
 309       :accessor font-face
 310       :type font-face)
 311      (operator
 312       :allocation :virtual
 313       :getter "cairo_get_operator"
 314       :setter "cairo_set_operator"
 315       :accessor operator
 316       :type operator)
 317      (matrix
 318       :allocation :virtual
 319       :getter matrix
 320       :setter "cairo_set_matrix"
 321       :writer (setf matrix)
 322       :type matrix)
 323      )
 324     (:metaclass proxy-class)
 325     (:ref %reference)
 326     (:unref %destroy))
 327
 328
 329 ;;   (defclass path (proxy)
 330 ;;     ()
 331 ;;     (:metaclass proxy-class))
 332
 333   )
 334
 335
 336 ;;; Cairo context
 337
 338 (defmethod allocate-foreign ((context context) &key target)
 339   (%create-context target))
 340
 341 (defbinding (%create-context "cairo_create") () pointer
 342   (target surface))
 343
 344 (defbinding %reference () pointer
 345   (location pointer))
 346
 347 (defbinding %destroy () nil
 348   (location pointer))
 349
 350 (defbinding (save-context "cairo_save") () nil
 351   (cr context))
 352
 353 (defbinding (restore-context "cairo_restore") () nil
 354   (cr context))
 355
 356 (defmacro with-context ((cr &optional var) &body body)
 357   (let ((context (or var (make-symbol "CONTEXT"))))
 358     `(let ((,context ,cr))
 359        (save-context ,context)
 360        (unwind-protect
 361            (progn ,@body)
 362          (restore-context ,context)))))
 363
 364 (defbinding status () status
 365   (cr context))
 366
 367 (defun ensure-color-component (component)
 368   (etypecase component
 369     (float component)
 370     (integer (/ component 256.0))))
 371
 372 (defbinding (set-source-color "cairo_set_source_rgba") (cr red green blue &optional (alpha 1.0)) nil
 373   (cr context)
 374   ((ensure-color-component red) double-float)
 375   ((ensure-color-component green) double-float)
 376   ((ensure-color-component blue) double-float)
 377   ((ensure-color-component alpha) double-float))
 378
 379 (defbinding set-source-surface (cr surface &optional (x 0.0) (y 0.0)) nil
 380   (cr context)
 381   (surface surface)
 382   (x double-float)
 383   (y double-float))
 384
 385 (defun set-source (cr source)
 386   (etypecase source
 387     (pattern (setf (source cr) source))
 388     (surface (set-source-surface cr source))
 389     (null (set-source-color cr 0.0 0.0 0.0))
 390     (list (apply #'set-source-color cr source))
 391     (vector (apply #'set-source-color cr (coerce source 'list)))))
 392
 393 (defbinding set-dash (cr dashes &optional (offset 0.0)) nil
 394   (cr context)
 395   (dashes (vector double-float))
 396   ((length dashes) int)
 397   (offset double-float))
 398
 399 (defbinding (paint "cairo_paint_with_alpha") (cr &optional (alpha 1.0)) nil
 400   (cr context)
 401   (alpha double-float))
 402
 403 (defbinding mask () nil
 404   (cr context)
 405   (pattern pattern))
 406
 407 (defbinding mask-surface () nil
 408   (cr context)
 409   (surface surface)
 410   (surface-x double-float)
 411   (surface-y double-float))
 412
 413 (defmacro defoperator (name &optional clip-p)
 414   (let ((iname (intern (format nil "%~A" name)))
 415         (pname (intern (format nil "%~A-PRESERVE" name))))
 416     `(progn
 417        (defbinding ,iname () nil
 418          (cr context))
 419        (defbinding ,pname () nil
 420          (cr context))
 421        (defun ,name (cr &optional preserve)
 422          (if preserve
 423              (,pname cr)
 424            (,iname cr)))
 425        ,(unless clip-p
 426           (let ((tname (intern (format nil "IN-~A-P" name)))
 427                 (ename (intern (format nil "~A-EXTENTS" name))))
 428             `(progn
 429                (defbinding ,tname () boolean
 430                  (cr context)
 431                  (x double-float)
 432                  (y double-float))
 433                (defbinding ,ename () nil
 434                  (cr context)
 435                  (x1 double-float :out)
 436                  (y1 double-float :out)
 437                  (x2 double-float :out)
 438                  (y2 double-float :out))))))))
 439
 440 (defoperator clip t)
 441 (defoperator stroke)
 442 (defoperator fill)
 443
 444 (defbinding reset-clip () nil
 445   (cr context))
 446
 447 (defbinding copy-page () nil
 448   (cr context))
 449
 450 (defbinding show-page () nil
 451   (cr context))
 452
 453
 454 ;;; Paths
 455
 456 (defbinding get-current-point () nil
 457   (cr context)
 458   (x double-float :out)
 459   (y double-float :out))
 460
 461 (defbinding new-path () nil
 462   (cr context))
 463
 464 #?(pkg-exists-p "cairo" :atleast-version "1.2")
 465 (defbinding new-sub-path () nil
 466   (cr context))
 467
 468 (defbinding close-path () nil
 469   (cr context))
 470
 471 (defmacro defpath (name args &optional relative-p)
 472   (flet ((def (name type)
 473            `(progn
 474               ,(when (eq type 'optimized-double-float)
 475                  `(declaim (inline ,(first name))))
 476               (defbinding ,name () nil
 477                 (cr context)
 478                 ,@(mapcar #'(lambda (arg) (list arg type)) args)))))
 479
 480   `(progn
 481      ,(def name 'double-float)
 482      ,(let ((name (intern (format nil "FAST-~A" name)))
 483             (cname (gffi::default-alien-fname name)))
 484         (def (list name cname) 'optimized-double-float))
 485      ,@(when relative-p
 486          (let* ((rel-name (intern (format nil "REL-~A" name)))
 487                 (fast-rel-name (intern (format nil "FAST-REL-~A" name)))
 488                 (cname (gffi::default-alien-fname rel-name)))
 489            (list
 490             (def rel-name 'double-float)
 491             (def (list fast-rel-name cname) 'optimized-double-float)))))))
 492
 493
 494 (defpath arc (xc yc radius angle1 angle2))
 495 (defpath arc-negative (xc yc radius angle1 angle2))
 496 (defpath curve-to (x1 y1 x2 y2 x3 y3) t)
 497 (defpath line-to (x y) t)
 498 (defpath move-to (x y) t)
 499 (defpath rectangle (x y width height))
 500
 501 (defun circle (cr x y radius &optional negative-p)
 502   (move-to cr radius 0.0d0)
 503   (if negative-p
 504       (arc-negative cr x y radius (* pi 2) 0.0d0)
 505     (arc cr x y radius 0.0d0 (* pi 2)))
 506   (close-path cr))
 507
 508
 509 (defbinding glyph-path (cr glyphs) nil
 510   (cr context)
 511   (glyphs (vector glyph))
 512   ((length glyphs) int))
 513
 514 (defbinding text-path () nil
 515   (cr context)
 516   (text string))
 517
 518
 519
 520 ;;; Patterns
 521
 522 (defbinding (pattern-add-color-stop "cairo_pattern_add_color_stop_rgba")
 523     (pattern offset red green blue &optional (alpha 1.0)) nil
 524   (pattern pattern)
 525   (offset double-float)
 526   ((ensure-color-component red) double-float)
 527   ((ensure-color-component green) double-float)
 528   ((ensure-color-component blue) double-float)
 529   ((ensure-color-component alpha) double-float))
 530
 531 (defbinding (pattern-create "cairo_pattern_create_rgba")
 532     (red green blue &optional (alpha 1.0)) pattern
 533   ((ensure-color-component red) double-float)
 534   ((ensure-color-component green) double-float)
 535   ((ensure-color-component blue) double-float)
 536   ((ensure-color-component alpha) double-float))
 537
 538 (defbinding pattern-create-for-surface () pattern
 539   (surface surface))
 540
 541 (defbinding pattern-create-linear () pattern
 542   (x0 double-float)
 543   (y0 double-float)
 544   (x1 double-float)
 545   (y1 double-float))
 546
 547 (defbinding pattern-create-radial () pattern
 548   (cx0 double-float)
 549   (cy0 double-float)
 550   (radius0 double-float)
 551   (cx1 double-float)
 552   (cy1 double-float)
 553   (radius1 double-float))
 554
 555 (defbinding %pattern-reference () pointer
 556   (location pointer))
 557
 558 (defbinding %pattern-destroy () nil
 559   (location pointer))
 560
 561 (defbinding pattern-status () status
 562   (pattern pattern))
 563
 564
 565
 566 ;;; Transformations
 567
 568 (defbinding translate () nil
 569   (cr context)
 570   (tx double-float)
 571   (ty double-float))
 572
 573 (defbinding scale (cr sx &optional (sy sx)) nil
 574   (cr context)
 575   (sx double-float)
 576   (sy double-float))
 577
 578 (defun scale-to-device (cr &optional keep-rotation-p)
 579   (if keep-rotation-p
 580       (multiple-value-call #'scale cr (device-to-user-distance cr 1.0))
 581     (multiple-value-bind (x y)
 582         (with-context (cr)
 583           (move-to cr 0.0 0.0)
 584           (multiple-value-call #'user-to-device cr (get-current-point cr)))
 585       (identity-matrix cr)
 586       (translate cr x y))))
 587
 588 (defbinding rotate () nil
 589   (cr context)
 590   (angle double-float))
 591
 592 (defbinding transform () nil
 593   (cr context)
 594   (matrix matrix))
 595
 596 (defbinding (matrix "cairo_get_matrix") () nil
 597   (cr context)
 598   ((make-instance 'matrix) matrix :in/return))
 599
 600 (defbinding identity-matrix () nil
 601   (cr context))
 602
 603 (defbinding user-to-device () nil
 604   (cr context)
 605   (x double-float :in/out)
 606   (y double-float :in/out))
 607
 608 (defbinding user-to-device-distance (cr dx &optional (dy dx)) nil
 609   (cr context)
 610   (dx double-float :in/out)
 611   (dy double-float :in/out))
 612
 613 (defbinding device-to-user () nil
 614   (cr context)
 615   (x double-float :in/out)
 616   (y double-float :in/out))
 617
 618 (defbinding device-to-user-distance (cr dx &optional (dy dx)) nil
 619   (cr context)
 620   (dx double-float :in/out)
 621   (dy double-float :in/out))
 622
 623
 624 ;;; Text
 625
 626 (defbinding select-font-face () nil
 627   (cr context)
 628   (family string)
 629   (slant font-slant)
 630   (weight font-weight))
 631
 632 (defbinding set-font-size () nil
 633   (cr context)
 634   (size double-float))
 635
 636 (defbinding show-text () nil
 637   (cr context)
 638   (text string))
 639
 640 (defbinding show-glyphs () nil
 641   (cr context)
 642   (glyphs (vector glyph))
 643   ((length glyphs) int))
 644
 645 (defbinding font-extents () boolean
 646   (cr context))
 647
 648 (defbinding text-extents (cr text &optional (extents (make-instance 'text-extents))) nil
 649   (cr context)
 650   (text string)
 651   (extents text-extents :in/return))
 652
 653 (defbinding glyph-extents (cr glyphs &optional (extents (make-instance 'text-extents))) nil
 654   (cr context)
 655   (glyphs (vector glyph))
 656   ((length glyphs) int)
 657   (extents text-extents :in/return))
 658
 659
 660 ;;; Fonts
 661
 662 (defbinding %font-face-reference () pointer
 663   (location pointer))
 664
 665 (defbinding %font-face-destroy () nil
 666   (location pointer))
 667
 668 (defbinding font-face-status () status
 669   (font-face font-face))
 670
 671
 672
 673 ;;; Scaled Fonts
 674
 675 (defbinding %scaled-font-reference () pointer
 676   (location pointer))
 677
 678 (defbinding %scaled-font-destroy () nil
 679   (location pointer))
 680
 681 (defbinding scaled-font-status () status
 682   (scaled-font scaled-font))
 683
 684 (defbinding scaled-font-extents (scaled-font &optional (extents (make-instance 'text-extents))) nil
 685   (scaled-font scaled-font)
 686   (extents text-extents :in/return))
 687
 688 (defbinding scaled-font-glyph-extents (scaled-font glyphs &optional (extents (make-instance 'text-extents))) nil
 689   (scaled-font scaled-font)
 690   (glyphs (vector glyph))
 691   ((length glyphs) int)
 692   (extents text-extents :in/return))
 693
 694 (defbinding %scaled-font-create () pointer
 695   (font-face font-face)
 696   (font-matrix matrix)
 697   (ctm matrix)
 698   (options font-options))
 699
 700 (defmethod allocate-foreign ((scaled-font scaled-font) &key font-face font-matrix cmt options)
 701   (%scaled-font-create font-face font-matrix cmt options))
 702
 703
 704
 705 ;;; Font Options
 706
 707
 708 (defbinding %font-options-copy () nil
 709   (location pointer))
 710
 711 (defbinding %font-options-destroy () nil
 712   (location pointer))
 713
 714 (defbinding font-options-status () status
 715   (font-options font-options))
 716
 717 (defbinding %font-options-create () pointer)
 718
 719 (defmethod allocate-foreign ((font-options font-options) &rest initargs)
 720   (declare (ignore initargs))
 721   (%font-options-create))
 722
 723 (defbinding font-options-merge () nil
 724   (options1 font-options :in/return)
 725   (options2 font-options))
 726
 727 (defbinding font-options-hash () unsigned-int
 728   (options font-options))
 729
 730 (defbinding font-options-equal-p () boolean
 731   (options1 font-options)
 732   (options2 font-options))
 733
 734
 735
 736 ;;; Surfaces
 737
 738 (defmethod make-proxy-instance :around ((class surface-class) location
 739                                         &rest initargs)
 740   (let ((class (find-class (%surface-get-type location))))
 741     (apply #'call-next-method class location initargs)))
 742
 743 (defbinding %surface-get-type () surface-type
 744   (location pointer))
 745
 746 (defbinding %surface-reference () pointer
 747   (location pointer))
 748
 749 (defbinding %surface-destroy () nil
 750   (location pointer))
 751
 752 (defmethod reference-function ((class surface-class))
 753   (declare (ignore class))
 754   #'%surface-reference)
 755
 756 (defmethod unreference-function ((class surface-class))
 757   (declare (ignore class))
 758   #'%surface-destroy)
 759
 760 (defbinding %surface-set-user-data (surface key data-id) status
 761   (surface pointer)
 762   ((quark-intern key) pointer-data)
 763   (data-id pointer-data)
 764   (user-data-destroy-callback callback))
 765
 766 (defmethod (setf user-data) (data (surface surface) key)
 767   (%surface-set-user-data (foreign-location surface) key (register-user-data data))
 768   data)
 769
 770 (defbinding %surface-get-user-data () pointer-data
 771   (surface surface)
 772   (key pointer-data))
 773
 774 (defmethod user-data ((surface surface) key)
 775   (find-user-data (%surface-get-user-data surface (quark-intern key))))
 776
 777 (defbinding surface-create-similar () surface
 778   (other surface)
 779   (format surface-format )
 780   (width int)
 781   (height int))
 782
 783 (defbinding surface-finish () nil
 784   (surface surface))
 785
 786 (defbinding surface-flush () nil
 787   (surface surface))
 788
 789 (defbinding surface-get-font-options () nil
 790   (surface surface)
 791   ((make-instance 'font-options) font-options :in/return))
 792
 793 (defbinding surface-set-device-offset () nil
 794   (surface surface)
 795   (x-offset double-float)
 796   (y-offset double-float))
 797
 798 (defbinding surface-status () status
 799   (surface surface))
 800
 801 (defbinding %surface-mark-dirty () nil
 802   (surface surface))
 803
 804 (defbinding %surface-mark-dirty-rectangle () nil
 805   (surface surface)
 806   (x int)
 807   (y int)
 808   (width int)
 809   (height int))
 810
 811 (defun surface-mark-dirty (surface &optional x y width height)
 812   (if x
 813       (%surface-mark-dirty-rectangle surface x y width height)
 814     (%surface-mark-dirty surface)))
 815
 816 (defbinding surface-set-fallback-resolution () nil
 817   (surface surface)
 818   (x-pixels-per-inch double-float)
 819   (y-pixels-per-inch double-float))
 820
 821 (define-callback stream-write-func status
 822     ((stream-id pointer-data) (data pointer) (length unsigned-int))
 823   (let ((stream (find-user-data stream-id)))
 824     (typecase stream
 825       (stream
 826        (map-c-vector 'nil #'(lambda (octet) (write-byte octet stream))
 827         data '(unsigned-byte 8) length))
 828       ((or symbol function)
 829        (funcall stream
 830         (map-c-vector 'vector #'identity data '(unsigned-byte 8) length)))))
 831   :success)
 832
 833
 834 ;; Image Surface
 835
 836 ;; Should data be automatically freed when the surface is GCed?
 837 (defmethod allocate-foreign ((surface image-surface)
 838                              &key filename width height stride format data)
 839   (cond
 840    (filename (%image-surface-create-from-png filename))
 841    ((not data) (%image-surface-create format width height))
 842    (t
 843     (%image-surface-create-for-data data format width height
 844      (or
 845       stride
 846       (let ((element-size (cdr (assoc format '((:argb32 . 4) (:rgb24 . 4) (:a8 . 1) (:a1 1/8))))))
 847         (ceiling (* width element-size))))))))
 848
 849
 850 (defbinding %image-surface-create () pointer
 851   (format surface-format)
 852   (width int)
 853   (hegit int))
 854
 855 (defbinding %image-surface-create-for-data () pointer
 856   (data pointer)
 857   (format surface-format)
 858   (width int)
 859   (hegit int)
 860   (stride int))
 861
 862 (defbinding %image-surface-create-from-png () pointer
 863   (filename pathname))
 864
 865 (defbinding surface-write-to-png () status
 866   (surface surface)
 867   (filename pathname))
 868
 869
 870 ;;; PDF Surface
 871
 872 (defmethod allocate-foreign ((surface pdf-surface)
 873                              &key filename stream width height)
 874   (cond
 875    ((and filename stream)
 876     (error "Only one of the arguments :filename and :stream may be specified"))
 877    (filename (%pdf-surface-create filename width height))
 878    (stream
 879     (let* ((stream-id (register-user-data stream))
 880            (location (%pdf-surface-create-for-stream stream-id width height)))
 881       (%surface-set-user-data location 'stream stream-id)
 882       location))))
 883
 884
 885 (defbinding %pdf-surface-create () pointer
 886   (filename pathname)
 887   (width double-float)
 888   (height double-float))
 889
 890 (defbinding %pdf-surface-create-for-stream (stream width height) pointer
 891   (stream-write-func callback)
 892   (stream pointer-data)
 893   (width double-float)
 894   (height double-float))
 895
 896 (defbinding pdf-surface-set-size () nil
 897   (surface pdf-surface)
 898   (width double-float)
 899   (height double-float))
 900
 901
 902 ;;; PS Surface
 903
 904 (defmethod allocate-foreign ((surface ps-surface)
 905                              &key filename stream width height)
 906   (cond
 907    ((and filename stream)
 908     (error "Only one of the arguments :filename and :stream may be specified"))
 909    (filename (%ps-surface-create filename width height))
 910    (stream
 911     (let* ((stream-id (register-user-data stream))
 912            (location (%ps-surface-create-for-stream stream-id width height)))
 913       (%surface-set-user-data location 'stream stream-id)
 914       location))))
 915
 916 (defbinding %ps-surface-create () pointer
 917   (filename pathname)
 918   (width double-float)
 919   (height double-float))
 920
 921 (defbinding %ps-surface-create-for-stream (stream width height) pointer
 922   (stream-write-func callback)
 923   (stream pointer-data)
 924   (width double-float)
 925   (height double-float))
 926
 927 (defbinding ps-surface-set-size () nil
 928   (surface ps-surface)
 929   (width double-float)
 930   (height double-float))
 931
 932 (defbinding ps-surface-dsc-begin-setup () nil
 933   (surface ps-surface))
 934
 935 (defbinding ps-surface-dsc-begin-page-setup () nil
 936   (surface ps-surface))
 937
 938 (defbinding ps-surface-dsc-comment () nil
 939   (surface ps-surface)
 940   (comment string))
 941
 942
 943 ;;; SVG Surface
 944
 945 (defmethod allocate-foreign ((surface svg-surface)
 946                              &key filename stream width height)
 947   (cond
 948    ((and filename stream)
 949     (error "Only one of the arguments :filename and :stream may be specified"))
 950    (filename (%svg-surface-create filename width height))
 951    (stream
 952     (let* ((stream-id (register-user-data stream))
 953            (location (%svg-surface-create-for-stream stream-id width height)))
 954       (%surface-set-user-data location 'stream stream-id)
 955       location))))
 956
 957 (defbinding %svg-surface-create () pointer
 958   (filename pathname)
 959   (width double-float)
 960   (height double-float))
 961
 962 (defbinding %svg-surface-create-for-stream (stream width height) pointer
 963   (stream-write-func callback)
 964   (stream pointer-data)
 965   (width double-float)
 966   (height double-float))
 967
 968 (defbinding svg-surface-restrict-to-version () nil
 969   (surface svg-surface)
 970   (version svg-version))
 971
 972
 973
 974 ;;; Matrices
 975
 976 (defbinding matrix-init () nil
 977   (matrix matrix :in/return)
 978   (xx double-float) (yx double-float)
 979   (xy double-float) (yy double-float)
 980   (x0 double-float) (y0 double-float))
 981
 982 (defbinding matrix-init-identity (&optional (matrix (make-instance 'matrix))) nil
 983   (matrix matrix :in/return))
 984
 985 (defbinding matrix-init-translate () nil
 986   (matrix matrix :in/return)
 987   (tx double-float)
 988   (ty double-float))
 989
 990 (defbinding matrix-init-scale () nil
 991   (matrix matrix :in/return)
 992   (sx double-float)
 993   (sy double-float))
 994
 995 (defbinding matrix-init-rotate () nil
 996   (matrix matrix :in/return)
 997   (radians double-float))
 998
 999 (defbinding matrix-translate () nil
1000   (matrix matrix :in/return)
1001   (tx double-float)
1002   (ty double-float))
1003
1004 (defbinding matrix-scale () nil
1005   (matrix matrix :in/return)
1006   (sx double-float)
1007   (sy double-float))
1008
1009 (defbinding matrix-rotate () nil
1010   (matrix matrix :in/return)
1011   (radians double-float))
1012
1013 (defbinding matrix-invert () nil
1014   (matrix matrix :in/return))
1015
1016 (defbinding matrix-multiply () nil
1017   (result matrix :out)
1018   (a matrix)
1019   (b matrix))
1020
1021 (defbinding matrix-transform-distance () nil
1022   (matrix matrix :in/return)
1023   (dx double-float)
1024   (dy double-float))
1025
1026 (defbinding matrix-transform-point () nil
1027   (matrix matrix :in/return)
1028   (x double-float)
1029   (y double-float))
1030
1031
1032