chiark - git - mdw - clg/blob - glib/gobject.lisp

   1 ;; Common Lisp bindings for GTK+ v2.0
   2 ;; Copyright (C) 2000-2001 Espen S. Johnsen <esj@stud.cs.uit.no>
   3 ;;
   4 ;; This library is free software; you can redistribute it and/or
   5 ;; modify it under the terms of the GNU Lesser General Public
   6 ;; License as published by the Free Software Foundation; either
   7 ;; version 2 of the License, or (at your option) any later version.
   8 ;;
   9 ;; This library is distributed in the hope that it will be useful,
  10 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 ;; Lesser General Public License for more details.
  13 ;;
  14 ;; You should have received a copy of the GNU Lesser General Public
  15 ;; License along with this library; if not, write to the Free Software
  16 ;; Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18 ;; $Id: gobject.lisp,v 1.32 2005-02-10 00:20:02 espen Exp $
  19
  20 (in-package "GLIB")
  21
  22
  23 ;;;; Metaclass used for subclasses of gobject
  24
  25 (eval-when (:compile-toplevel :load-toplevel :execute)
  26   (defclass gobject-class (ginstance-class)
  27     ())
  28
  29   (defmethod validate-superclass ((class gobject-class) (super standard-class))
  30 ;  (subtypep (class-name super) 'gobject)
  31     t))
  32
  33 (defclass direct-property-slot-definition (direct-virtual-slot-definition)
  34   ((pname :reader slot-definition-pname :initarg :pname)
  35    (readable :initform t :reader slot-readable-p :initarg :readable)
  36    (writable :initform t :reader slot-writable-p :initarg :writable)
  37    (construct :initform nil :initarg :construct)))
  38
  39 (defclass effective-property-slot-definition (effective-virtual-slot-definition)
  40   ((pname :reader slot-definition-pname :initarg :pname)
  41    (readable :reader slot-readable-p :initarg :readable)
  42    (writable :reader slot-writable-p :initarg :writable)
  43    (construct :initarg :construct)))
  44
  45 (defclass direct-user-data-slot-definition (direct-virtual-slot-definition)
  46   ())
  47
  48 (defclass effective-user-data-slot-definition (effective-virtual-slot-definition)
  49   ())
  50
  51
  52 (defbinding %object-ref () pointer
  53   (location pointer))
  54
  55 (defbinding %object-unref () nil
  56   (location pointer))
  57
  58 (defmethod reference-foreign ((class gobject-class) location)
  59   (declare (ignore class))
  60   (%object-ref location))
  61
  62 (defmethod unreference-foreign ((class gobject-class) location)
  63   (declare (ignore class))
  64   (%object-unref location))
  65
  66
  67 ; (defbinding object-class-install-param () nil
  68 ;   (class pointer)
  69 ;   (id unsigned-int)
  70 ;   (parameter parameter))
  71
  72 ; (defbinding object-class-find-param-spec () parameter
  73 ;   (class pointer)
  74 ;   (name string))
  75
  76 (defun signal-name-to-string (name)
  77   (substitute #\_ #\- (string-downcase (string name))))
  78
  79
  80 (defmethod direct-slot-definition-class ((class gobject-class) &rest initargs)
  81   (case (getf initargs :allocation)
  82     (:property (find-class 'direct-property-slot-definition))
  83     (:user-data (find-class 'direct-user-data-slot-definition))
  84     (t (call-next-method))))
  85
  86 (defmethod effective-slot-definition-class ((class gobject-class) &rest initargs)
  87   (case (getf initargs :allocation)
  88     (:property (find-class 'effective-property-slot-definition))
  89     (:user-data (find-class 'effective-user-data-slot-definition))
  90     (t (call-next-method))))
  91
  92 (defmethod compute-effective-slot-definition-initargs ((class gobject-class) direct-slotds)
  93   (if (typep (first direct-slotds) 'direct-property-slot-definition)
  94       (nconc
  95        (list :pname (signal-name-to-string
  96                      (most-specific-slot-value direct-slotds 'pname))
  97              :readable (most-specific-slot-value direct-slotds 'readable)
  98              :writable (most-specific-slot-value direct-slotds 'writable)
  99              :construct (most-specific-slot-value direct-slotds 'construct))
 100        (call-next-method))
 101     (call-next-method)))
 102
 103
 104 (defmethod initialize-internal-slot-functions ((slotd effective-property-slot-definition))
 105   (let* ((type (slot-definition-type slotd))
 106          (pname (slot-definition-pname slotd))
 107          (type-number (find-type-number type)))
 108     (when (and (not (slot-boundp slotd 'getter)) (slot-readable-p slotd))
 109       (setf
 110        (slot-value slotd 'getter)
 111        (let ((reader nil)) ;(reader-function type)))
 112          #'(lambda (object)
 113              (unless reader
 114                (setq reader (reader-function type)))
 115              (let ((gvalue (gvalue-new type-number)))
 116                (%object-get-property object pname gvalue)
 117                (unwind-protect
 118                  (funcall reader  gvalue +gvalue-value-offset+)
 119                  (gvalue-free gvalue t)))))))
 120
 121     (when (and (not (slot-boundp slotd 'setter)) (slot-writable-p slotd))
 122       (setf
 123        (slot-value slotd 'setter)
 124        (let ((writer nil)) ;(writer-function type)))
 125          #'(lambda (value object)
 126              (unless writer
 127                (setq writer (writer-function type)))
 128              (let ((gvalue (gvalue-new type-number)))
 129                (funcall writer value gvalue +gvalue-value-offset+)
 130                (%object-set-property object pname gvalue)
 131                (gvalue-free gvalue t)
 132                value))))))
 133
 134   (call-next-method))
 135
 136 (defmethod initialize-internal-slot-functions ((slotd effective-user-data-slot-definition))
 137   (let ((slot-name (slot-definition-name slotd)))
 138     (unless (slot-boundp slotd 'getter)
 139       (setf
 140        (slot-value slotd 'getter)
 141        #'(lambda (object)
 142            (prog1 (user-data object slot-name)))))
 143     (unless (slot-boundp slotd 'setter)
 144       (setf
 145        (slot-value slotd 'setter)
 146        #'(lambda (value object)
 147            (setf (user-data object slot-name) value))))
 148     (unless (slot-boundp slotd 'boundp)
 149       (setf
 150        (slot-value slotd 'boundp)
 151        #'(lambda (object)
 152            (user-data-p object slot-name)))))
 153   (call-next-method))
 154
 155
 156 ;;;; Super class for all classes in the GObject type hierarchy
 157
 158 (eval-when (:compile-toplevel :load-toplevel :execute)
 159   (defclass gobject (ginstance)
 160     ()
 161     (:metaclass gobject-class)
 162     (:alien-name "GObject")))
 163
 164
 165 (defun initial-add (object function initargs key pkey)
 166   (loop
 167    as (initarg value . rest) = initargs then rest
 168    do (cond
 169        ((eq initarg key) (funcall function object value))
 170        ((eq initarg pkey) (mapc #'(lambda (value)
 171                                     (funcall function object value))
 172                                 value)))
 173        while rest))
 174
 175 (defun initial-apply-add (object function initargs key pkey)
 176   (initial-add object #'(lambda (object value)
 177                           (apply function object (mklist value)))
 178                initargs key pkey))
 179
 180
 181 (defmethod initialize-instance ((object gobject) &rest initargs)
 182   (unless (slot-boundp object 'location)
 183     ;; Extract initargs which we should pass directly to the GObeject
 184     ;; constructor
 185     (let* ((slotds (class-slots (class-of object)))
 186            (args (when initargs
 187                    (loop
 188                     as (key value . rest) = initargs then rest
 189                     as slotd = (find-if
 190                                 #'(lambda (slotd)
 191                                     (member key (slot-definition-initargs slotd)))
 192                                 slotds)
 193                     when (and (typep slotd 'effective-property-slot-definition)
 194                               (slot-value slotd 'construct))
 195                     collect (progn
 196                               (remf initargs key)
 197                               (list
 198                                (slot-definition-pname slotd)
 199                                (slot-definition-type slotd)
 200                                value))
 201                     while rest))))
 202       (if args
 203           (let* ((string-size (size-of 'string))
 204                  (string-writer (writer-function 'string))
 205                  (string-destroy (destroy-function 'string))
 206                  (params (allocate-memory
 207                           (* (length args) (+ string-size +gvalue-size+)))))
 208             (loop
 209              for (pname type value) in args
 210              as tmp = params then (sap+ tmp (+ string-size +gvalue-size+))
 211              do (funcall string-writer pname tmp)
 212              (gvalue-init (sap+ tmp string-size) type value))
 213             (unwind-protect
 214                 (setf
 215                  (slot-value object 'location)
 216                  (%gobject-newv (type-number-of object) (length args) params))
 217               (loop
 218                repeat (length args)
 219                as tmp = params then (sap+ tmp (+ string-size +gvalue-size+))
 220                do (funcall string-destroy tmp)
 221                (gvalue-unset (sap+ tmp string-size)))
 222               (deallocate-memory params)))
 223         (setf
 224          (slot-value object 'location)
 225          (%gobject-new (type-number-of object))))))
 226
 227   (apply #'call-next-method object initargs))
 228
 229
 230 (defmethod instance-finalizer ((instance gobject))
 231   (let ((location (proxy-location instance)))
 232     #'(lambda ()
 233         (remove-cached-instance location)
 234         (%object-unref location))))
 235
 236
 237 (defbinding (%gobject-new "g_object_new") () pointer
 238   (type type-number)
 239   (nil null))
 240
 241 (defbinding (%gobject-newv "g_object_newv") () pointer
 242   (type type-number)
 243   (n-parameters unsigned-int)
 244   (params pointer))
 245
 246
 247
 248 ;;;; Property stuff
 249
 250 (defbinding %object-set-property () nil
 251   (object gobject)
 252   (name string)
 253   (value gvalue))
 254
 255 (defbinding %object-get-property () nil
 256   (object gobject)
 257   (name string)
 258   (value gvalue))
 259
 260 (defbinding %object-notify () nil
 261   (object gobject)
 262   (name string))
 263
 264 (defbinding object-freeze-notify () nil
 265   (object gobject))
 266
 267 (defbinding object-thaw-notify () nil
 268   (object gobject))
 269
 270
 271 ;;;; User data
 272
 273 (defbinding %object-set-qdata-full () nil
 274   (object gobject)
 275   (id quark)
 276   (data unsigned-long)
 277   (destroy-marshal pointer))
 278
 279 (defcallback user-data-destroy-func (nil (id unsigned-int))
 280   (destroy-user-data id))
 281
 282 (export 'user-data-destroy-func)
 283
 284 (defun (setf user-data) (data object key)
 285   (%object-set-qdata-full object (quark-intern key)
 286    (register-user-data data) (callback user-data-destroy-func))
 287   data)
 288
 289 ;; deprecated
 290 (defun (setf object-data) (data object key &key (test #'eq))
 291   (assert (eq test #'eq))
 292   (setf (user-data object key) data))
 293
 294 (defbinding %object-get-qdata () unsigned-long
 295   (object gobject)
 296   (id quark))
 297
 298 (defun user-data (object key)
 299   (find-user-data (%object-get-qdata object (quark-intern key))))
 300
 301 ;; deprecated
 302 (defun object-data (object key &key (test #'eq))
 303   (assert (eq test #'eq))
 304   (user-data object key))
 305
 306 (defun user-data-p (object key)
 307   (user-data-exists-p (%object-get-qdata object (quark-intern key))))
 308
 309 (defbinding %object-steal-qdata () unsigned-long
 310   (object gobject)
 311   (id quark))
 312
 313 (defun unset-user-data (object key)
 314   (destroy-user-data (%object-steal-qdata object (quark-intern key))))
 315
 316
 317 ;;;;
 318
 319 (defbinding %object-class-list-properties () pointer
 320   (class pointer)
 321   (n-properties unsigned-int :out))
 322
 323
 324 (defun %map-params (params length type inherited-p)
 325   (if inherited-p
 326       (map-c-vector 'list #'identity params 'param length)
 327     (let ((properties ()))
 328       (map-c-vector 'list
 329        #'(lambda (param)
 330            (when (eql (param-owner-type param) type)
 331              (push param properties)))
 332        params 'param length)
 333       (nreverse properties))))
 334
 335 (defun query-object-class-properties (type &optional inherited-p)
 336   (let* ((type-number (find-type-number type))
 337          (class (type-class-ref type-number)))
 338     (unwind-protect
 339          (multiple-value-bind (array length)
 340              (%object-class-list-properties class)
 341            (unless (null-pointer-p array)
 342              (unwind-protect
 343                  (%map-params array length type-number inherited-p)
 344                (deallocate-memory array))))
 345 ;      (type-class-unref type-number)
 346       )))
 347
 348
 349 (defun default-slot-name (name)
 350   (intern (substitute #\- #\_ (string-upcase (string-upcase name)))))
 351
 352 (defun default-slot-accessor (class-name slot-name type)
 353   (intern
 354    (format
 355     nil "~A-~A~A" class-name slot-name
 356     (if (eq type 'boolean) "-P" ""))))
 357
 358
 359 (defun slot-definition-from-property (class property &optional slot-name args)
 360   (with-slots (name flags value-type documentation) property
 361     (let* ((slot-name (or slot-name (default-slot-name name)))
 362            (slot-type (or (getf args :type) (type-from-number value-type) 'pointer))
 363            (accessor (default-slot-accessor class slot-name slot-type)))
 364
 365       `(,slot-name
 366         :allocation :property :pname ,name
 367
 368         ,@(cond
 369            ((find :unbound args) (list :unbound (getf args :unbound))))
 370
 371         ;; accessors
 372         ,@(cond
 373            ((and
 374              (member :writable flags) (member :readable flags)
 375              (not (member :construct-only flags)))
 376             (list :accessor accessor))
 377            ((and (member :writable flags) (not (member :construct-only flags)))
 378             (list :writer `(setf ,accessor)))
 379            ((member :readable flags)
 380             (list :reader accessor)))
 381
 382         ;; readable/writable/construct
 383         ,@(when (or (not (member :writable flags))
 384                     (member :construct-only flags))
 385             '(:writable nil))
 386         ,@(when (not (member :readable flags))
 387             '(:readable nil))
 388         ,@(when (or (member :construct flags)
 389                     (member :construct-only flags))
 390             '(:construct t))
 391
 392         ;; initargs
 393         ,@(when (or (member :construct flags)
 394                     (member :construct-only flags)
 395                     (member :writable flags))
 396             (list :initarg (intern (string slot-name) "KEYWORD")))
 397         ,@(cond
 398            ((find :initarg args) (list :initarg (getf args :initarg))))
 399
 400         :type ,slot-type
 401         :documentation ,documentation))))
 402
 403
 404 (defun slot-definitions (class properties slots)
 405   (loop
 406    for property in properties
 407    as slot = (or
 408               (find (param-name property) slots
 409                :key #'(lambda (slot) (getf (rest slot) :pname))
 410                :test #'string=)
 411               (find (param-name property) slots
 412                :key #'first :test #'string-equal))
 413    do (cond
 414        ((not slot)
 415         (push (slot-definition-from-property class property) slots))
 416        ((getf (rest slot) :merge)
 417         (setf
 418          (rest slot)
 419          (rest (slot-definition-from-property class property (first slot) (rest slot)))))))
 420   (delete-if #'(lambda (slot) (getf (rest slot) :ignore)) slots))
 421
 422
 423 (defun expand-gobject-type (type forward-p options &optional (metaclass 'gobject-class))
 424   (let ((supers (cons (supertype type) (implements type)))
 425         (class  (type-from-number type))
 426         (slots (getf options :slots)))
 427     `(defclass ,class ,supers
 428        ,(unless forward-p
 429           (slot-definitions class (query-object-class-properties type) slots))
 430       (:metaclass ,metaclass)
 431       (:alien-name ,(find-type-name type)))))
 432
 433 (defun gobject-dependencies (type)
 434   (delete-duplicates
 435    (cons
 436     (supertype type)
 437     (append
 438      (type-interfaces type)
 439      (mapcar #'param-value-type (query-object-class-properties type))))))
 440
 441
 442 (register-derivable-type 'gobject "GObject" 'expand-gobject-type 'gobject-dependencies)
 443
 444
 445 ;;; Pseudo type for gobject instances which have their reference count
 446 ;;; increased by the returning function
 447
 448 (defmethod alien-type ((type (eql 'referenced)) &rest args)
 449   (declare (ignore type args))
 450   (alien-type 'gobject))
 451
 452 (defmethod from-alien-form (form (type (eql 'referenced)) &rest args)
 453   (declare (ignore type))
 454   (destructuring-bind (type) args
 455     (if (subtypep type 'gobject)
 456         (let ((instance (make-symbol "INSTANCE")))
 457           `(let ((,instance ,(from-alien-form form type)))
 458              (when ,instance
 459                (%object-unref (proxy-location ,instance)))
 460              ,instance))
 461       (error "~A is not a subclass of GOBJECT" type))))
 462
 463 (export 'referenced)