chiark - git - mdw - clg/blob - glib/gtype.lisp

   1 ;; Common Lisp bindings for GTK+ v2.x
   2 ;; Copyright 2000-2005 Espen S. Johnsen <espen@users.sf.net>
   3 ;;
   4 ;; Permission is hereby granted, free of charge, to any person obtaining
   5 ;; a copy of this software and associated documentation files (the
   6 ;; "Software"), to deal in the Software without restriction, including
   7 ;; without limitation the rights to use, copy, modify, merge, publish,
   8 ;; distribute, sublicense, and/or sell copies of the Software, and to
   9 ;; permit persons to whom the Software is furnished to do so, subject to
  10 ;; the following conditions:
  11 ;;
  12 ;; The above copyright notice and this permission notice shall be
  13 ;; included in all copies or substantial portions of the Software.
  14 ;;
  15 ;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  16 ;; EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 ;; MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  18 ;; IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
  19 ;; CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 ;; TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 ;; SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 ;; $Id: gtype.lisp,v 1.41 2006/02/06 18:12:19 espen Exp $
  24
  25 (in-package "GLIB")
  26
  27 (use-prefix "g")
  28
  29 ;; Initialize the glib type system
  30 (defbinding type-init () nil)
  31 (type-init)
  32
  33 (deftype type-number () '(unsigned 32))
  34
  35 (deftype gtype () 'symbol)
  36
  37 (defmethod alien-type ((type (eql 'gtype)) &rest args)
  38   (declare (ignore type args))
  39   (alien-type 'type-number))
  40
  41 (defmethod size-of ((type (eql 'gtype)) &rest args)
  42   (declare (ignore type args))
  43   (size-of 'type-number))
  44
  45 (defmethod to-alien-form (gtype (type (eql 'gtype)) &rest args)
  46   (declare (ignore type args))
  47   `(find-type-number ,gtype t))
  48
  49 (defmethod to-alien-function ((type (eql 'gtype)) &rest args)
  50   (declare (ignore type args))
  51   #'(lambda (gtype)
  52       (find-type-number gtype t)))
  53
  54 (defmethod from-alien-form (type-number (type (eql 'gtype)) &rest args)
  55   (declare (ignore type args))
  56   `(type-from-number ,type-number))
  57
  58 (defmethod from-alien-function ((type (eql 'gtype)) &rest args)
  59   (declare (ignore type args))
  60   #'(lambda (type-number)
  61       (type-from-number type-number)))
  62
  63 (defmethod writer-function ((type (eql 'gtype)) &rest args)
  64   (declare (ignore type args))
  65   (let ((writer (writer-function 'type-number)))
  66     #'(lambda (gtype location &optional (offset 0))
  67         (funcall writer (find-type-number gtype t) location offset))))
  68
  69 (defmethod reader-function ((type (eql 'gtype)) &rest args)
  70   (declare (ignore type args))
  71   (let ((reader (reader-function 'type-number)))
  72     #'(lambda (location &optional (offset 0) weak-p)
  73         (declare (ignore weak-p))
  74         (type-from-number (funcall reader location offset)))))
  75
  76
  77 (eval-when (:compile-toplevel :load-toplevel :execute)
  78   (defclass type-query (struct)
  79     ((type-number :allocation :alien :type type-number)
  80      (name :allocation :alien :type string)
  81      (class-size :allocation :alien :type unsigned-int)
  82      (instance-size :allocation :alien :type unsigned-int))
  83     (:metaclass struct-class)))
  84
  85
  86 (defbinding type-query (type) nil
  87   ((find-type-number type t) type-number)
  88   ((make-instance 'type-query) type-query :return))
  89
  90 (defun type-instance-size (type)
  91   (slot-value (type-query type) 'instance-size))
  92
  93 (defun type-class-size (type)
  94   (slot-value (type-query type) 'class-size))
  95
  96 (defbinding type-class-ref (type) pointer
  97   ((find-type-number type t) type-number))
  98
  99 (defbinding type-class-unref (type) nil
 100   ((find-type-number type t) type-number))
 101
 102 (defbinding type-class-peek (type) pointer
 103   ((find-type-number type t) type-number))
 104
 105
 106 ;;;; Mapping between lisp types and glib types
 107
 108 (defvar *registered-types* ())
 109 (defvar *registered-type-aliases* ())
 110 (defvar *lisp-type-to-type-number* (make-hash-table))
 111 (defvar *type-number-to-lisp-type* (make-hash-table))
 112
 113 (defbinding %type-from-name () type-number
 114   (name string))
 115
 116 (defun type-number-from-glib-name (name &optional (error-p t))
 117   (let ((type-number (%type-from-name name)))
 118     (cond
 119      ((not (zerop type-number)) type-number)
 120      (error-p (error "Invalid gtype name: ~A" name)))))
 121
 122 (defun register-type (type id)
 123   (pushnew (cons type id) *registered-types* :key #'car)
 124   (let ((type-number
 125          (typecase id
 126            (string (type-number-from-glib-name id))
 127            (symbol (funcall id)))))
 128        (setf (gethash type *lisp-type-to-type-number*) type-number)
 129        (setf (gethash type-number *type-number-to-lisp-type*) type)
 130        type-number))
 131
 132 (defun register-type-alias (type alias)
 133   (pushnew (cons type alias) *registered-type-aliases* :key #'car)
 134   (setf
 135    (gethash type *lisp-type-to-type-number*)
 136    (find-type-number alias t)))
 137
 138 (defun reinitialize-all-types ()
 139   (clrhash *lisp-type-to-type-number*)
 140   (clrhash *type-number-to-lisp-type*)
 141   (type-init) ; initialize the glib type system
 142   (mapc #'(lambda (type)
 143             (register-type (car type) (cdr type)))
 144         *registered-types*)
 145   (mapc #'(lambda (type)
 146             (register-type-alias (car type) (cdr type)))
 147         *registered-type-aliases*))
 148
 149 (pushnew 'reinitialize-all-types
 150   #+cmu *after-save-initializations*
 151   #+sbcl *init-hooks*)
 152
 153 #+cmu
 154 (pushnew 'system::reinitialize-global-table ; we shouldn't have to do this?
 155  *after-save-initializations*)
 156
 157
 158 (defun find-type-number (type &optional error-p)
 159   (etypecase type
 160     (integer type)
 161     (string (type-number-from-glib-name type error-p))
 162     (symbol
 163      (or
 164       (gethash type *lisp-type-to-type-number*)
 165       (and error-p (error "Type not registered: ~A" type))))
 166     (class (find-type-number (class-name type) error-p))))
 167
 168 (defun type-from-number (type-number &optional error)
 169   (multiple-value-bind (type found)
 170       (gethash type-number *type-number-to-lisp-type*)
 171     (if found
 172         type
 173       (let ((name (find-foreign-type-name type-number)))
 174         (cond
 175          ((and name (not (= (type-number-from-glib-name name nil) type-number)))
 176           ;; This is a hack because GdkEvent seems to be registered
 177           ;; multiple times
 178           (type-from-number (type-number-from-glib-name name)))
 179          ((and error name)
 180           (error "Type number not registered: ~A (~A)" type-number name))
 181          ((and error)
 182           (error "Invalid type number: ~A" type-number)))))))
 183
 184 (defbinding (find-foreign-type-name "g_type_name") (type) (copy-of string)
 185   ((find-type-number type t) type-number))
 186
 187 (defun type-number-of (object)
 188   (find-type-number (type-of object) t))
 189
 190 (eval-when (:compile-toplevel :load-toplevel :execute)
 191   (defvar *type-initializers* ())
 192   (defun %find-types-in-library (pathname prefixes ignore)
 193     (let ((process (run-program
 194                     "/usr/bin/nm" (list "--defined-only" "-D" (namestring (truename pathname)))
 195                     :output :stream :wait nil)))
 196       (unwind-protect
 197           (loop
 198            as symbol = (let ((line (read-line (process-output process) nil)))
 199                          (when line (subseq line 11)))
 200            while symbol
 201            when (and
 202                  (> (length symbol) 9)
 203                  (or
 204                   (not prefixes)
 205                   (some #'(lambda (prefix)
 206                             (and
 207                              (> (length symbol) (length prefix))
 208                              (string= prefix symbol :end2 (length prefix))))
 209                         (mklist prefixes)))
 210                  (string= "_get_type" symbol :start2 (- (length symbol) 9))
 211                  (not (member symbol ignore :test #'string=)))
 212            collect symbol)
 213         (process-close process)))))
 214
 215
 216 (defmacro init-types-in-library (filename &key prefix ignore)
 217   (let ((names (%find-types-in-library filename prefix ignore)))
 218     `(progn
 219        ,@(mapcar #'(lambda (name)
 220                      `(progn
 221                         (defbinding (,(intern name) ,name) () type-number)
 222                         (,(intern name))
 223                         (pushnew ',(intern name) *type-initializers*)))
 224                  names))))
 225
 226 (defun find-type-init-function (type-number)
 227   (loop
 228    for type-init in *type-initializers*
 229    when (= type-number (funcall type-init))
 230    do (return type-init)))
 231
 232 (defun register-type-as (type-number)
 233   (or
 234    (find-type-init-function type-number)
 235    (find-foreign-type-name type-number)
 236    (error "Unknown type-number: ~A" type-number)))
 237
 238 (defun default-type-init-name (type)
 239   (find-symbol (format nil "~A_~A_get_type"
 240                 (package-prefix *package*)
 241                 (substitute #\_ #\- (string-downcase type)))))
 242
 243
 244 (eval-when (:compile-toplevel :load-toplevel :execute)
 245   (defclass type-info (struct)
 246     ((class-size :allocation :alien :type (unsigned 16) :initarg :class-size)
 247      (base-init :allocation :alien :type pointer)
 248      (base-finalize :allocation :alien :type pointer)
 249      (class-init :allocation :alien :type pointer)
 250      (class-finalize :allocation :alien :type pointer)
 251      (class-data :allocation :alien :type pointer)
 252      (instance-size :allocation :alien :type (unsigned 16)
 253                     :initarg :instance-size)
 254      (n-preallocs :allocation :alien :type (unsigned 16))
 255      (instance-init :allocation :alien :type pointer)
 256      (value-table :allocation :alien :type pointer))
 257     (:metaclass struct-class)))
 258
 259 (defbinding %type-register-static () type-number
 260   (parent-type type-number)
 261   (name string)
 262   (info type-info)
 263   (0 unsigned-int))
 264
 265 (defun register-new-type (type parent &optional foreign-name)
 266   (let ((parent-info (type-query parent)))
 267     (with-slots ((parent-number type-number) class-size instance-size) parent-info
 268       (let ((type-number
 269              (%type-register-static
 270               parent-number
 271               (or foreign-name (default-alien-type-name type))
 272               (make-instance 'type-info :class-size class-size :instance-size instance-size))))
 273        (setf (gethash type *lisp-type-to-type-number*) type-number)
 274        (setf (gethash type-number *type-number-to-lisp-type*) type)
 275        type-number))))
 276
 277
 278
 279 ;;;; Metaclass for subclasses of ginstance
 280
 281 (eval-when (:compile-toplevel :load-toplevel :execute)
 282   (defclass ginstance-class (proxy-class)
 283     ((gtype :initarg :gtype :initform nil :reader ginstance-class-gtype))))
 284
 285
 286 (defmethod compute-foreign-size ((class ginstance-class))
 287   (type-instance-size (find-type-number (class-name class))))
 288
 289 (defmethod finalize-inheritance ((class ginstance-class))
 290   (call-next-method)
 291   (let* ((class-name (class-name class))
 292          (super (most-specific-proxy-superclass class))
 293          (gtype (or
 294                  (first (ginstance-class-gtype class))
 295                  (default-alien-type-name class-name)))
 296          (type-number
 297           (or
 298            (find-type-number class-name)
 299            (if (or (symbolp gtype) (type-number-from-glib-name gtype nil))
 300                (register-type class-name gtype)
 301              (register-new-type class-name (class-name super) gtype)))))
 302     (unless (eq (class-name super) (supertype type-number))
 303       (warn "~A is the super type for ~A in the gobject type system."
 304        (supertype type-number) class-name))))
 305
 306 (defmethod validate-superclass ((class ginstance-class) (super standard-class))
 307   (subtypep (class-name super) 'ginstance))
 308
 309
 310 ;;;; Superclass for wrapping types in the glib type system
 311
 312 (eval-when (:compile-toplevel :load-toplevel :execute)
 313   (defclass ginstance (proxy)
 314     (;(class :allocation :alien :type pointer :offset 0)
 315      )
 316     (:metaclass proxy-class)
 317     (:size #.(size-of 'pointer))))
 318
 319 (defun %type-number-of-ginstance (location)
 320   (let ((class (sap-ref-sap location 0)))
 321     (sap-ref-32 class 0)))
 322
 323 (defmethod make-proxy-instance :around ((class ginstance-class) location &rest initargs)
 324   (declare (ignore class))
 325   (let ((class (labels ((find-known-class (type-number)
 326                           (or
 327                            (find-class (type-from-number type-number) nil)
 328                            (unless (zerop type-number)
 329                              (find-known-class (type-parent type-number))))))
 330                  (find-known-class (%type-number-of-ginstance location)))))
 331     ;; Note that chancing the class argument must not alter "the
 332     ;; ordered set of applicable methods" as specified in the
 333     ;; Hyperspec
 334     (if class
 335         (apply #'call-next-method class location initargs)
 336       (error "Object at ~A has an unkown type number: ~A"
 337        location (%type-number-of-ginstance location)))))
 338
 339 (defmethod make-proxy-instance ((class ginstance-class) location &rest initargs)
 340   (declare (ignore initargs))
 341   (reference-foreign class location)
 342   ;; Since we make an explicit reference to the foreign object, we
 343   ;; always have to release it when the proxy is garbage collected
 344   ;; and therefor ignore the weak-p argument.
 345   (call-next-method class location :weak nil))
 346
 347 (defmethod invalidate-instance ((instance ginstance))
 348   (declare (ignore instance))
 349   ;; A ginstance should never be invalidated since it is ref counted
 350   nil)
 351
 352 (defmethod copy-from-alien-form (location (class ginstance-class) &rest args)
 353   (declare (ignore location class args))
 354   (error "Doing copy-from-alien on a ref. counted class is most certainly an error, but if it really is what you want you should use REFERENCE-FOREIGN on the returned instance instead."))
 355
 356 (defmethod copy-from-alien-function ((class ginstance-class) &rest args)
 357   (declare (ignore class args))
 358   (error "Doing copy-from-alien on a ref. counted class is most certainly an error, but if it really is what you want you should use REFERENCE-FOREIGN on the returned instance instead."))
 359
 360 (defmethod reader-function ((class ginstance-class) &rest args)
 361   (declare (ignore args))
 362   #'(lambda (location &optional (offset 0) weak-p)
 363       (declare (ignore weak-p))
 364       (ensure-proxy-instance class (sap-ref-sap location offset))))
 365
 366
 367 ;;;; Registering fundamental types
 368
 369 (register-type 'nil "void")
 370 (register-type 'pointer "gpointer")
 371 (register-type 'char "gchar")
 372 (register-type 'unsigned-char "guchar")
 373 (register-type 'boolean "gboolean")
 374 (register-type 'int "gint")
 375 (register-type-alias 'integer 'int)
 376 (register-type-alias 'fixnum 'int)
 377 (register-type 'unsigned-int "guint")
 378 (register-type 'long "glong")
 379 (register-type 'unsigned-long "gulong")
 380 (register-type 'single-float "gfloat")
 381 (register-type 'double-float "gdouble")
 382 (register-type 'pathname "gchararray")
 383 (register-type 'string "gchararray")
 384
 385
 386 ;;;; Introspection of type information
 387
 388 (defvar *derivable-type-info* (make-hash-table))
 389
 390 (defun register-derivable-type (type id expander &optional dependencies)
 391   (register-type type id)
 392   (let ((type-number (register-type type id)))
 393     (setf
 394      (gethash type-number *derivable-type-info*)
 395      (list expander dependencies))))
 396
 397 (defun find-type-info (type)
 398   (dolist (super (cdr (type-hierarchy type)))
 399     (let ((info (gethash super *derivable-type-info*)))
 400       (return-if info))))
 401
 402 (defun expand-type-definition (type forward-p options)
 403   (let ((expander (first (find-type-info type))))
 404     (funcall expander (find-type-number type t) forward-p options)))
 405
 406 (defbinding type-parent (type) type-number
 407   ((find-type-number type t) type-number))
 408
 409 (defun supertype (type)
 410   (type-from-number (type-parent type)))
 411
 412 (defbinding %type-interfaces (type) pointer
 413   ((find-type-number type t) type-number)
 414   (n-interfaces unsigned-int :out))
 415
 416 (defun type-interfaces (type)
 417   (multiple-value-bind (array length) (%type-interfaces type)
 418     (unwind-protect
 419         (map-c-vector 'list #'identity array 'type-number length)
 420       (deallocate-memory array))))
 421
 422 (defun implements (type)
 423   (mapcar #'type-from-number (type-interfaces type)))
 424
 425 (defun type-hierarchy (type)
 426   (let ((type-number (find-type-number type t)))
 427     (unless (= type-number 0)
 428       (cons type-number (type-hierarchy (type-parent type-number))))))
 429
 430 (defbinding (type-is-p "g_type_is_a") (type super) boolean
 431   ((find-type-number type) type-number)
 432   ((find-type-number super) type-number))
 433
 434 (defbinding %type-children () pointer
 435   (type-number type-number)
 436   (num-children unsigned-int :out))
 437
 438 (defun map-subtypes (function type &optional prefix)
 439   (let ((type-number (find-type-number type t)))
 440     (multiple-value-bind (array length) (%type-children type-number)
 441       (unwind-protect
 442           (map-c-vector
 443            'nil
 444            #'(lambda (type-number)
 445                (when (or
 446                       (not prefix)
 447                       (string-prefix-p prefix (find-foreign-type-name type-number)))
 448                  (funcall function type-number))
 449                (map-subtypes function type-number prefix))
 450            array 'type-number length)
 451         (deallocate-memory array)))))
 452
 453 (defun find-types (prefix)
 454   (let ((type-list nil))
 455     (maphash
 456      #'(lambda (type-number expander)
 457          (declare (ignore expander))
 458          (map-subtypes
 459           #'(lambda (type-number)
 460               (pushnew type-number type-list))
 461           type-number prefix))
 462      *derivable-type-info*)
 463     type-list))
 464
 465 (defun find-type-dependencies (type)
 466   (let ((list-dependencies (second (find-type-info type))))
 467     (when list-dependencies
 468       (funcall list-dependencies (find-type-number type t)))))
 469
 470 (defun %sort-types-topologicaly (types)
 471   (let ((partial-sorted
 472          (sort
 473           (mapcar
 474            #'(lambda (type)
 475                (cons type (remove-if #'(lambda (dep)
 476                                          (not (find dep types)))
 477                                      (find-type-dependencies type))))
 478            types)
 479           #'(lambda (type1 type2) (type-is-p type2 type1)) :key #'car))
 480         (sorted ()))
 481
 482     (loop
 483      as tmp = partial-sorted then (or (rest tmp) partial-sorted)
 484      while tmp
 485      do (destructuring-bind (type . dependencies) (first tmp)
 486           (cond
 487            ((every #'(lambda (dep)
 488                        (assoc dep sorted))
 489                    dependencies)
 490             (push (cons type nil) sorted) ; no forward definition needed
 491             (setq partial-sorted (delete type partial-sorted :key #'first)))
 492            ((some #'(lambda (dep)
 493                       (find type (find-type-dependencies dep)))
 494                   dependencies)
 495             (push (cons type t) sorted) ; forward definition needed
 496             (setq partial-sorted (delete type partial-sorted :key #'first))))))
 497     (nreverse sorted)))
 498
 499
 500 (defun expand-type-definitions (prefix &optional args)
 501   (flet ((type-options (type-number)
 502            (let ((name (find-foreign-type-name type-number)))
 503              (cdr (assoc name args :test #'string=)))))
 504
 505    (let ((type-list
 506           (delete-if
 507            #'(lambda (type-number)
 508                (let ((name (find-foreign-type-name type-number)))
 509                  (or
 510                   (getf (type-options type-number) :ignore)
 511                   (find-if
 512                    #'(lambda (options)
 513                        (and
 514                         (string-prefix-p (first options) name)
 515                         (getf (cdr options) :ignore-prefix)
 516                         (not (some
 517                               #'(lambda (exception)
 518                                   (string= name exception))
 519                               (getf (cdr options) :except)))))
 520                    args))))
 521            (find-types prefix))))
 522
 523      (dolist (type-number type-list)
 524        (let ((name (find-foreign-type-name type-number)))
 525          (register-type
 526           (getf (type-options type-number) :type (default-type-name name))
 527           (register-type-as type-number))))
 528
 529      (let ((sorted-type-list (%sort-types-topologicaly type-list)))
 530        `(progn
 531           ,@(mapcar
 532              #'(lambda (pair)
 533                  (destructuring-bind (type . forward-p) pair
 534                    (expand-type-definition type forward-p (type-options type))))
 535              sorted-type-list)
 536           ,@(mapcar
 537              #'(lambda (pair)
 538                  (destructuring-bind (type . forward-p) pair
 539                    (when forward-p
 540                      (expand-type-definition type nil (type-options type)))))
 541              sorted-type-list))))))
 542
 543 (defmacro define-types-by-introspection (prefix &rest args)
 544   (expand-type-definitions prefix args))
 545
 546
 547 ;;;; Initialize all non static types in GObject
 548
 549 (init-types-in-library #.(concatenate 'string (pkg-config:pkg-variable "glib-2.0" "libdir") "/libgobject-2.0.so"))