trackpump-mutlihead-clip.scad

   1 // -*- C -*-
   2
   3 pump_main_dia = 38;
   4 pump_side_width = 5;
   5 pump_side_thick = 4;
   6 pump_shaft_dia = 14;
   7 baseplate = 3;
   8
   9 pump_protr_flat = 3;
  10 pump_protr_slope = 0.9;
  11
  12 hose_inner_dia = 20;
  13 hose_aperture = 11;
  14 hose_side_width = 5;
  15 hose_base_offset = 30;
  16
  17 hose_side_thick = 6;
  18 hose_side_stalk_width = 6;
  19
  20 pump_protr_protr = 3;
  21 pump_side_height = 20;
  22
  23 // calculated
  24 pump_protr_slheight = pump_protr_protr / pump_protr_slope;
  25
  26 pump_side_outer_rad = pump_side_width + pump_main_dia/2;
  27
  28 baseplate_width_rad =
  29   sqrt( pow(pump_side_outer_rad, 2)
  30         -pow( pump_main_dia/2 - pump_protr_protr, 2) );
  31
  32 xm = baseplate + pump_main_dia/2;
  33
  34 pump_side_total_height =
  35   pump_side_thick + pump_side_height + pump_protr_slheight + pump_protr_flat;
  36
  37 $fa=5;
  38
  39 module PumpSidePlan() {
  40   or = pump_side_outer_rad;
  41   difference(){
  42     union(){
  43       intersection(){
  44         translate([-xm, 0]) circle(r=or);
  45 //      translate([-(xm+or), -or]) square([xm+or, or*2]);
  46       }
  47     }
  48     translate([-xm-or, 0])
  49       square(center=true, [pump_side_width*4, pump_shaft_dia]);
  50   }
  51 }
  52
  53 module PumpSideElevation(){
  54   x3 = 0;
  55   x2 = x3 - baseplate;
  56   x1 = x2 - pump_main_dia;
  57   x0 = x1 - pump_side_width;
  58   x2a = x2 - pump_protr_protr;
  59   x4 = x2 + pump_side_width;
  60
  61   z0 = 0;
  62   z1 = z0 - pump_side_thick;
  63   z2 = z1 - pump_side_height;
  64   z2a = z2 - pump_protr_slheight;
  65   z2b = z2a - pump_protr_flat;
  66
  67   arcx = x2-x1;
  68   arcy = z1-z2;
  69
  70   translate([x0,z1]) square([x1-x0, z0-z1]);
  71
  72   difference(){
  73     translate([x1,z2]) square([x3-x1, z0-z2]);
  74     translate([x1,z2]) scale([1,arcy/arcx]) circle(r=arcx);
  75   }
  76
  77   translate([x2,z2a]) square([x4-x2, z0-z2a]);
  78
  79   hull(){
  80     translate([x2,z2a]) square([x4-x2, z2-z2a]);
  81     translate([x2a,z2b]) square([x3-x2a, z2a-z2b]);
  82   }
  83 }
  84
  85 module PumpSide(){
  86   br = baseplate_width_rad;
  87   brs =
  88     sqrt( pow(pump_side_outer_rad, 2)
  89           -pow(pump_main_dia/2 + baseplate, 2) );
  90   echo(brs);
  91
  92   difference(){
  93     intersection(){
  94       translate([0,100,0])
  95         rotate([90,0,0])
  96         linear_extrude(height=200)
  97         PumpSideElevation();
  98       union(){
  99         translate([0,0,-100])
 100           linear_extrude(height=200)
 101           PumpSidePlan();
 102         // baseplate
 103         hull(){
 104           mirror([0,0,1])
 105             translate([-xm, -brs, 0])
 106             cube([pump_main_dia/2 + pump_side_width,
 107                   brs*2,
 108                   1]);
 109           translate([-xm, -br, -pump_side_total_height])
 110             cube([xm,
 111                   br*2,
 112                   pump_protr_flat]);
 113         }
 114       }
 115     }
 116     translate([-(baseplate + pump_main_dia/2), 0,
 117                 -(pump_side_thick + pump_side_height)])
 118       cylinder(r=pump_main_dia/2, h=200);
 119   }
 120 }
 121
 122 module HoseSidePlan(){
 123   ro = hose_inner_dia/2 + hose_side_width;
 124   ri = (hose_inner_dia/2);
 125   st = hose_side_stalk_width/2;
 126
 127   apx = sqrt( ri*ri - (hose_aperture*hose_aperture)/4 );
 128   apsq = hose_base_offset + apx - hose_aperture/2;
 129   echo(apx,apsq);
 130
 131   difference(){
 132     union(){
 133       translate([-1, -st]) square([hose_base_offset+1, st*2]);
 134       translate([hose_base_offset, 0]) circle(r= ro);
 135     }
 136     translate([hose_base_offset, 0]) circle(r= hose_inner_dia/2);
 137     translate([apsq, 0])
 138       rotate(-45)
 139       square([50,50]);
 140   }
 141
 142   //%translate([hose_base_offset + apx, 0]) square([50,50]);
 143   //%square(center=true, [100, hose_aperture]);
 144 }
 145
 146 module HoseSide(){
 147   mirror([0,0,1])
 148     linear_extrude(height=hose_side_thick)
 149     HoseSidePlan();
 150 }
 151
 152 module Clip(){
 153   PumpSide();
 154   HoseSide();
 155 }
 156
 157 module ClipPrint(){
 158   rotate([180,0,0])
 159     Clip();
 160 }
 161
 162 //PumpSidePlan();
 163 //PumpSide();
 164 //HoseSide();
 165 //Clip();
 166 ClipPrint();