poster-tube-lid.scad

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4
   5 coarse = false;
   6
   7 main_dia = 71.2 + 0.50 - 2.26;
   8 top_thick_middle = 4;
   9 top_thick_by_oring = 3.0;
  10 top_middle_dr = 11;
  11
  12 main_cnr = 6.0;
  13
  14 min_wall = 3;
  15
  16 rivet_posn = 6.0 + 0.30;
  17 rivet_thick = 1.67;
  18 rivet_width = 4.15 + 1.0;
  19 rivet_tall = 5.51 + 1.49;
  20
  21 over_rivet_wall = 1.0;
  22 side_rivet_gap = 1.5;
  23 inside_rivet_gap = 1.5;
  24
  25 bayo_interf = 0.30;
  26 bayo_behind = 3.5;
  27 bayo_interf_width = 2.0;
  28 bayo_interf_slope = 0.5;
  29
  30 oring_thick = 5.0;
  31 oring_bore = 62.0;
  32
  33 oring_upper_embed_angle = 80;
  34 oring_compress = 0.1; // proportion
  35 oring_compress_more = 0.2;
  36
  37 oring_rm_beside = 8;
  38 oring_rm_scale = 2.0;
  39 oring_rm_angle = 20;
  40
  41 side_taper = 1.0;
  42
  43 bayo_gap = 6.0;
  44
  45 bayo_entry = bayo_behind/3;
  46
  47 bayo_slice_size = coarse ? 5 : 1;
  48
  49 brace_hole_width = 1.0;
  50 brace_above_below = 1.2;
  51 brace_end_shorter = 0.3;
  52
  53 jig_thick = 1.4;
  54 jig_hole_dia = 3.0;
  55 jig_rim = 5;
  56 jig_mark = 5;
  57
  58 strap_hoop_thick = 6;
  59 strap_hoop_inside = 10;
  60 strap_hoop_strlen = 10;
  61 strap_hoop_elevation = 45;
  62
  63 sm_inner_circum = 218 - 1.90 - 1.00 - 0.50;
  64 sm_main_thick = 2.0;
  65 sm_main_width = 20;
  66
  67 sm_bolt_dia = 3.5 + 0.1;
  68 sm_bolt_shaft = 21.9;
  69 sm_bolt_head_dia = 6.94 + 1.0;
  70 sm_bolt_head_thick = 2.14;
  71 sm_bolt_nut_width = 5.89 + 0.25;
  72 sm_bolt_nut_thick = 3.68;
  73 sm_bolt_tighten_allow = 2.0;
  74
  75 sm_bolt_y_clear = 0.75;
  76 sm_bolt_y_over = 0.5;
  77
  78 sm_closure_cnr = 3.0;
  79
  80 catch_stalk_h = 4.5;
  81 catch_stalk_len = 50;
  82 catch_tip_th = 4;
  83 catch_head_th = 3;
  84
  85 catch_pin_slop = 0.25; // each side, and above
  86 catch_pin_slop_x_extra = 0.0; // only on one side
  87 catch_stalk_above_gap = 1.5;
  88 catch_stalk_eff_bend_rad = catch_stalk_len * 0.75;
  89
  90 catch_strap_width = 12;
  91 catch_stalk_base_width = 15;
  92
  93 catch_knob_dia = 6;
  94 catch_knob_above_gap = 5;
  95 catch_knob_height = 3.0;
  96
  97 catch_stalk_below_gap = 1.0;
  98 catch_stalk_beside_gap = 2.0;
  99
 100 // calculated
 101
 102 TAU = PI*2;
 103
 104 bayo_entry_x = bayo_entry;
 105 bayo_entry_z = bayo_entry;
 106 bayo_inramp_x = bayo_entry;
 107 bayo_inramp_z = bayo_entry;
 108
 109 oring_mid_dia = oring_bore + oring_thick;
 110 oring_outer_dia = oring_mid_dia + oring_thick;
 111
 112 oring_oblate = (1 - oring_compress);
 113
 114 oring_y_rad = oring_thick/2 * oring_oblate;
 115 oring_x_rad = oring_thick/2 / oring_oblate;
 116
 117 by_oring_z = oring_y_rad * (1 + cos(oring_upper_embed_angle));
 118
 119 side_height = rivet_posn + bayo_behind + rivet_thick/2;
 120 side_thick = rivet_tall + over_rivet_wall;
 121
 122 top_z = top_thick_by_oring + oring_y_rad + by_oring_z;
 123
 124 middle_bot_z = top_z - top_thick_middle;
 125
 126 bayo_entry = bayo_behind / 3.0;
 127 bayo_top_z = bayo_behind + bayo_gap;
 128
 129 bayo_nom_rad = main_dia/2 + side_thick;
 130 bayo_real_rad = main_dia/2 + rivet_tall;
 131
 132 rivet_entry_width = rivet_width + side_rivet_gap;
 133
 134 jig_mark_rad = jig_mark + main_dia/2 + jig_thick;
 135
 136 handling_dia = oring_bore + oring_thick*2 + min_wall*2;
 137 handling_angle = 45;
 138
 139 sm_inner_rad = (sm_inner_circum + sm_bolt_tighten_allow/2) / TAU;
 140 sm_outer_rad = sm_inner_rad + sm_main_thick;
 141
 142 smc_pos = [ 0, sm_inner_rad, 0 ];
 143
 144 smc_bolt_nut_dia = sm_bolt_nut_width / cos(30);
 145 smc_bolt_nut_eff_thick = sm_bolt_nut_thick + sm_bolt_tighten_allow;
 146
 147 smc_bolt_y = sm_bolt_dia/2 + sm_bolt_y_clear;
 148 smc_max_y = smc_bolt_y + sm_bolt_y_over
 149   + max(sm_bolt_head_dia/2, smc_bolt_nut_dia/2);
 150 smc_cnr_c_x = sm_bolt_shaft/2 - sm_closure_cnr
 151   + sm_bolt_head_thick/2 + smc_bolt_nut_eff_thick/2;
 152
 153 catch_cr = catch_knob_dia/2 + catch_stalk_beside_gap;
 154 catch_strap_thick = sm_main_thick;
 155
 156 echo("R ", sm_inner_rad, bayo_real_rad, bayo_nom_rad);
 157
 158 $fs= coarse ? 2.5 : 0.5;
 159 $fa= coarse ? 5 : 1;
 160
 161 include <poster-tube-lid-parametric.scad>
 162
 163 // bayonet definition
 164
 165 bayo_a = [ bayo_entry_x, 0 ];
 166 bayo_p = [ 0, bayo_entry_z ];
 167 bayo_n = [ 0, bayo_behind-bayo_inramp_z ];
 168 bayo_m = [ bayo_inramp_x, bayo_behind ];
 169 bayo_l = bayo_m + bayo_interf * [ 1/bayo_interf_slope,  1 ];
 170 bayo_k = bayo_l + [ bayo_interf_width, 0 ];
 171 bayo_j = bayo_k + bayo_interf * [ 1/bayo_interf_slope, -1 ];
 172 bayo_i = bayo_j + [ rivet_width + inside_rivet_gap, 0 ];
 173 bayo_h = [ bayo_i[0], bayo_behind + bayo_gap + bayo_interf ];
 174 bayo_g = [ bayo_m[0] - rivet_width, bayo_h[1] ];
 175
 176 bayo_e = [-bayo_p[0], bayo_p[1]] - [rivet_entry_width,0];
 177 bayo_d = [-bayo_a[0], bayo_a[1]] - [rivet_entry_width,0];
 178 bayo_c = bayo_d + [0,-5];
 179 bayo_b = bayo_a + [0,-5];
 180
 181 bayo_f = [ bayo_e[0], bayo_g[1] + (bayo_e[0] - bayo_g[0]) ];
 182
 183 bayo_polygon = [ bayo_a,
 184                  bayo_b,
 185                  bayo_c,
 186                  bayo_d,
 187                  bayo_e,
 188                  bayo_f,
 189                  bayo_g,
 190                  bayo_h,
 191                  bayo_i,
 192                  bayo_j,
 193                  bayo_k,
 194                  bayo_l,
 195                  bayo_m,
 196                  bayo_n,
 197                  bayo_p ];
 198
 199 echo(bayo_polygon);
 200
 201 // CATCH
 202
 203 cppxC = 0.41 * sm_inner_rad * TAU;
 204
 205 // catch pin
 206
 207 cpp_adj = (bayo_n[0] - bayo_f[0]) * (1 - sm_inner_rad / bayo_nom_rad);
 208 // radius scaling due to nom and actual radius difference in
 209 // bayo entry construction
 210
 211 cppa = bayo_f + [1,-1] * catch_pin_slop + [1,0] * cpp_adj;
 212 cppb = bayo_g + [1,-1] * catch_pin_slop + [1,0] * cpp_adj;
 213 cppd = [ bayo_n[0]
 214          - catch_pin_slop - catch_pin_slop_x_extra,
 215          -catch_stalk_above_gap ];
 216 cppi = [ cppa[0], cppd[1] ];
 217 cppc = [ cppd[0], cppb[1] ];
 218 cpph = cppd + [0,-1] * catch_stalk_h;
 219 cppe = cppd + [0,-1] * (catch_knob_above_gap + catch_knob_dia/2);
 220 cppf = [ cppa[0], cppe[1] ];
 221 cppg = [ cppa[0], cpph[1] ];
 222 cppB = 0.5 * (cppf + cppe);
 223
 224 echo("RR", sm_inner_rad / bayo_nom_rad);
 225
 226 // catch assembly depression below pin
 227
 228 cppy6 = cppB[1] - (catch_knob_dia/2
 229                    + (cppc[1] - cppd[1])
 230                    + catch_stalk_below_gap);
 231 cpp7 = [ cppB[0], cppy6 + catch_cr ];
 232 cpp11 = cpp7 + [1,0] * catch_cr;
 233 cppy9 = cppy6 + catch_strap_width * 1/3;
 234 cpp9 = [ cpp7[0] + catch_cr * 2, cppy9 ];
 235 cpp8 = cpp9 + [0,-1] * catch_cr;
 236 cpp10 = cpp8 + [-1,0] * catch_cr;
 237 cppC = [ cppxC, cpp9[1] ];
 238 cppD = cppC + [0,-1] * catch_strap_width;
 239
 240 // catch assembly stalk and so on
 241
 242 catch_cr3 = catch_cr + catch_stalk_h;
 243
 244 cppF = [ cppg[0] - catch_stalk_eff_bend_rad, cppd[1] ];
 245 cpp4 = [ cppg[0] - catch_stalk_len, cpph[1] ] + [1,-1] * catch_cr;
 246 cpp5 = [ cpp4[0], cppC[1] + catch_cr ];
 247 cpp2 = cpp5 + [-1,0] * (catch_cr * 2 + catch_stalk_base_width);
 248 cpp2r = cpp2 + [1,0] * catch_cr;
 249 cpp2d = cpp2 + [0,-1] * catch_cr;
 250 cpp3 = [ cpp2[0] + catch_cr + catch_cr3, cppd[1] - catch_cr3 ];
 251 cppA = [ -cppxC, cpp9[1] ];
 252 cppE = [ cppA[0], cppD[1] ];
 253
 254 catch_assembly_dy = -cppy9 + catch_strap_width;
 255
 256
 257 module MainProfile(){
 258   main_cnr_pos = [ side_thick, top_z ] - [1,1]*main_cnr;
 259   difference(){
 260     union(){
 261       translate(main_cnr_pos){
 262         intersection(){
 263           difference(){
 264             circle(r = main_cnr);
 265             circle(r = main_cnr * 0.5);
 266           }
 267           square([10,10]);
 268         }
 269       }
 270       polygon([[ -top_middle_dr,        middle_bot_z      ],
 271                [ -top_middle_dr,        top_z             ],
 272                [ main_cnr_pos[0],       top_z             ],
 273                [ side_thick,            main_cnr_pos[1]   ],
 274                [ side_thick,            -side_height      ],
 275                [ side_taper,            -side_height      ],
 276                [ 0,                     -rivet_posn       ],
 277                [ 0,                     by_oring_z        ],
 278                [ -oring_x_rad,          by_oring_z        ],
 279                ],
 280               convexity=10);
 281     }
 282     translate([ oring_mid_dia/2 - main_dia/2, 0 ])
 283       hull(){
 284       translate([ 0, oring_y_rad ])
 285         scale([ 1/oring_oblate * (oring_compress_more+1) , oring_oblate ])
 286         circle(oring_thick/2);
 287       translate([ 0, oring_y_rad*2 - oring_thick/2 ])
 288         circle(oring_thick/2);
 289     }
 290   }
 291 }
 292
 293 module StrapHoopProfile(){
 294   circle(r = strap_hoop_thick/2);
 295 }
 296
 297 module StrapHoop(){ ////toplevel
 298   bigrad = strap_hoop_inside/2 + strap_hoop_thick/2;
 299   extralen = strap_hoop_thick * 5;
 300
 301   intersection(){
 302     rotate([strap_hoop_elevation, 0,0]){
 303       for (x= [ -1, +1 ] * bigrad) {
 304         translate([x, -extralen, 0])
 305           rotate([-90,0,0])
 306           linear_extrude(height= extralen + strap_hoop_strlen + 0.1,
 307                          convexity=10)
 308           StrapHoopProfile();
 309       }
 310       translate([0, strap_hoop_strlen, 0]){
 311         intersection(){
 312           rotate_extrude(convexity=10)
 313             translate([bigrad, 0,0])
 314             StrapHoopProfile();
 315           translate([0,50,0])
 316             cube([100,100,100], center=true);
 317         }
 318       }
 319     }
 320     translate([0, 50, 0])
 321       cube(100, center=true);
 322   }
 323 }
 324
 325 module RotateProjectSlice(offset, slice_size, nom_rad, real_rad){
 326   // nom_rad > real_rad
 327   rotate([0,0, atan2(offset, nom_rad) ]){
 328     intersection(){
 329       translate([-offset, -10, 0])
 330         rotate([90,0,0])
 331         linear_extrude(height= nom_rad*2)
 332         children(0);
 333       translate([0,0, -25])
 334         cylinder(h=50, r= real_rad);
 335       translate([0,0, -25])
 336         linear_extrude(height= 50)
 337         polygon([ [ 0,0 ],
 338                   [ -slice_size, -real_rad*2 ],
 339                   [ +slice_size, -real_rad*2 ] ]);
 340     }
 341   }
 342 }
 343
 344 module RotateProject(x_min, x_max, slice_size, nom_rad, real_rad){
 345   offs = [ for (i=[ x_min :
 346                     slice_size :
 347                     x_max + slice_size ]) i ];
 348   echo (offs);
 349   for (off=offs)
 350     RotateProjectSlice(off, slice_size, nom_rad, real_rad)
 351     children(0);
 352 }
 353
 354 module BayonetCutout(){
 355   RotateProject(bayo_c[0], bayo_i[0], bayo_slice_size,
 356                 bayo_nom_rad,
 357                 bayo_real_rad)
 358     translate([-0.5 * (bayo_a[0] + bayo_d[0]), 0])
 359     polygon(bayo_polygon, convexity=10);
 360 }
 361
 362 module ProfilesDemo(){ ////toplevel
 363   translate([-10,0]) MainProfile();
 364   translate([+10, -side_height]) polygon(bayo_polygon, convexity=10);
 365 }
 366
 367 module LimitForHandling(){ ////toplevel
 368   hull() for (r=[0,180])
 369     rotate([0,0,r]) {
 370       for (rs=[-1,+1]) {
 371         for (xd=[0,1]) {
 372           rotate([0,0, rs * handling_angle/2]) {
 373             translate([rs * xd * main_dia/2 * tan(handling_angle/2),
 374                        main_dia/2 + side_thick - main_cnr,
 375                        top_z - main_cnr]) {
 376               mirror([0,0,1])
 377                 cylinder(r= main_cnr, h=50);
 378               sphere(main_cnr);
 379             }
 380           }
 381         }
 382       }
 383     }
 384   hull() rotate_extrude(){
 385     translate([ handling_dia/2 - main_cnr, top_z - main_cnr ]) {
 386       circle(r = main_cnr);
 387       mirror([0,1]) square([ main_cnr, 50 ]);
 388     }
 389   }
 390   //cylinder(r= handling_dia/2, h=20);
 391 }
 392
 393 module Cover(){ ////toplevel
 394   render() difference(){
 395     intersection(){
 396       union(){
 397         rotate_extrude(convexity=10)
 398           translate([main_dia/2, 0])
 399           MainProfile();
 400         translate([0,0, middle_bot_z])
 401           cylinder(h= top_thick_middle, r = main_dia/2 - top_middle_dr + 1);
 402       }
 403       LimitForHandling();
 404     }
 405     for (r=[0,180]){
 406       rotate([0,0, r])
 407         translate([0,0, -side_height])
 408         BayonetCutout();
 409       rotate([0,0, r + asin((-oring_rm_beside) / (main_dia/2))])
 410         translate([0,
 411                    oring_mid_dia/2 + oring_thick/4 * oring_rm_scale,
 412                    oring_y_rad * 1.5])
 413         rotate([-oring_rm_angle, 0, 0])
 414         mirror([0,0,1])
 415         cylinder(r = oring_thick/4 * oring_rm_scale, h=20);
 416     }
 417     for (r=[0 : 60 : 179]) {
 418       rotate([0,0, r]) {
 419         height = top_thick_middle - brace_above_below*2;
 420         translate([0,0, middle_bot_z + brace_above_below + height/2 ])
 421         cube(center=true, [ oring_bore - brace_end_shorter,
 422                             brace_hole_width, height ]);
 423       }
 424     }
 425   }
 426   for (r=[0,180])
 427     rotate([0,0,r])
 428       translate([-implheadcup_large_dia * .5 - implheadcup_thick/2,
 429                  -implheadcup_large_dia * .0,
 430                  middle_bot_z + 0.1])
 431       ImplHeadCup();
 432 //  translate(strap_hoop_thick * [-0.5, 0, +1])
 433 //    translate([handling_dia/2, 0, -side_height])
 434 //    rotate([0,180,0]) rotate([0,0,90])
 435 //    StrapHoop();
 436 }
 437
 438 module SavingHole(){
 439   translate([0,0, -10])
 440     cylinder(r= main_dia/2 - jig_rim, h=20);
 441 }
 442
 443 module Jig(){ ////toplevel
 444   difference(){
 445     union(){
 446       translate([0,0, -side_height]){
 447         cylinder(r= main_dia/2 + jig_thick, h= side_height + jig_thick);
 448       }
 449       translate([-jig_mark_rad, 0, jig_thick - jig_mark])
 450         cube([jig_mark_rad*2, jig_mark, jig_mark]);
 451     }
 452     translate([0,0, -side_height-1])
 453       cylinder(r= main_dia/2, h= side_height + 1);
 454     SavingHole();
 455     translate([0,0, -rivet_posn])
 456       rotate([90, 0,0])
 457       translate([0,0, -100])
 458       cylinder(r= jig_hole_dia/2, h = 200);
 459   }
 460 }
 461
 462 module CoverTest2(){ ////toplevel
 463   difference(){
 464     Cover();
 465     SavingHole();
 466   }
 467 }
 468
 469 module CoverTest1(){ ////toplevel
 470   difference(){
 471     CoverTest2();
 472     difference(){
 473       for (r= [ 40, 147 ]){
 474         rotate([0,0, r]){
 475           translate([0,0, -10]) {
 476             cube([ main_dia*3, main_dia * .53, 18], center=true);
 477           }
 478         }
 479       }
 480 //      translate([ 50, 0, 0 ])
 481 //      cube([ 100,
 482 //             strap_hoop_inside + strap_hoop_thick*2 + 1,
 483 //             100 ],
 484 //           center=true);
 485     }
 486   }
 487 }
 488
 489 module ImplHeadCupTest(){ ////toplevel
 490   for (r=[0,180])
 491     rotate([0,0,r])
 492       translate([-17,0,0])
 493       ImplHeadCup();
 494 }
 495
 496 module SomeStrap(width){
 497   // children(0) is to add, (1) subtract
 498   difference(){
 499     union(){
 500       cylinder(r=sm_outer_rad, h=width);
 501       StrapMountProtrusion(smc_cnr_c_x + sm_closure_cnr,
 502                            smc_max_y,
 503                            sm_closure_cnr,
 504                            width);
 505       children(0);
 506     }
 507     translate([0,0,-1])
 508       cylinder(r=sm_inner_rad, h=width+2);
 509     translate(smc_pos)
 510       StrapMountBolt(10, width);
 511     translate(smc_pos)
 512       cube([ sm_bolt_tighten_allow, 40,100 ], center=true);
 513     children(1);
 514   }
 515 }
 516
 517 module StrapMountBolt(l_delta, strap_width){ ///toplevel
 518   // positioned relative to smc_pos
 519   translate([(smc_bolt_nut_eff_thick - sm_bolt_head_thick)/2,
 520              smc_bolt_y,
 521              strap_width/2]){
 522     translate([ -sm_bolt_shaft/2-1, 0,0 ]){
 523       rotate([0,90,0]) cylinder(r= sm_bolt_dia/2, h= sm_bolt_shaft+2);
 524     }
 525     translate([ -sm_bolt_shaft/2, 0,0 ])
 526       rotate([0,-90,0])
 527       cylinder($fn=6, r=smc_bolt_nut_dia/2,
 528                h=smc_bolt_nut_eff_thick + l_delta);
 529     translate([ sm_bolt_shaft/2, 0,0 ])
 530       rotate([0,90,0])
 531       cylinder(r=sm_bolt_head_dia/2, h=sm_bolt_head_thick + l_delta);
 532   }
 533 }
 534
 535 module StrapMountProtrusion(half_x, max_y, cnr, width){
 536   translate(smc_pos){
 537     linear_extrude(height=width, convexity=10){
 538       hull(){
 539         for (m = [0,1]) mirror([m,0,0]) {
 540           translate([-(half_x - cnr), max_y - cnr])
 541             circle(r=cnr);
 542           translate([-half_x, -sm_inner_rad])
 543             square([1,1]);
 544         }
 545       }
 546     }
 547   }
 548 }
 549
 550 module StrapMount(){ ////toplevel
 551   SomeStrap(sm_main_width){
 552     rotate([0,0,180]){
 553       StrapMountProtrusion(strap_hoop_inside/2 + strap_hoop_thick,
 554                            strap_hoop_thick,
 555                            sm_closure_cnr);
 556       translate(smc_pos +
 557                 [0,0, sm_main_width] +
 558                 strap_hoop_thick * [ 0, 0.5, -1.0 ])
 559         StrapHoop();
 560     }
 561     union(){ };
 562   }
 563 }
 564
 565 module CatchAssemblyCoreProfile(){
 566   difference(){
 567     union(){
 568       hull(){
 569         translate(cpp3) circle(r= catch_cr3);
 570         polygon([ cpp3,
 571                   cpp2r,
 572                   cpp5,
 573                   cpph,
 574                   cppd
 575                   ]);
 576       }
 577       polygon([cppD,
 578                cppC,
 579                cpp9,
 580                cpp10,
 581                cpp11,
 582                cpp4,
 583                cpp2r,
 584                cpp2d,
 585                cppA,
 586                cppE
 587                ]);
 588       translate(cpp8) circle(r= catch_cr);
 589     }
 590     hull(){
 591       translate(cpp4) circle(r= catch_cr);
 592       translate(cpp5) circle(r= catch_cr);
 593       translate(cpp7) circle(r= catch_cr);
 594       polygon([cpp4,
 595                cppg,
 596                cpph,
 597                cpp10,
 598                cpp11,
 599                ]);
 600     }
 601     translate(cpp2) circle(r= catch_cr);
 602   }
 603   // if cpp11 is above cpp10, the subtracted hull above
 604   // can go down too far.  Ensure we do not cut off below cppy6.
 605   polygon([ cppE,
 606             cppD,
 607             cpp9,
 608             [ cpp9[0],            cppy6 ],
 609             [ cpp7[0] - catch_cr, cppy6 ],
 610             cpp2d
 611             ]);
 612 }
 613
 614 module CatchTipProfile(dy){
 615   ddy = [0,dy];
 616   intersection(){
 617     translate(cppF){
 618       difference(){
 619         circle(r = dist2d(cppF, cppd));
 620         //circle(r = dist2d(cppF, cppa));
 621       }
 622     }
 623     polygon([ cppa,
 624               cppi + ddy,
 625               cppd + ddy,
 626               cppc,
 627               cppb ]);
 628   }
 629 }
 630
 631 module CatchHeadProfile(){
 632   polygon([ cppd,
 633             cppd,
 634             cppi,
 635             cppf,
 636             cppe,
 637             cpph ]);
 638 }
 639
 640
 641 module CatchCore(){ /////toplevel
 642   linear_extrude(height=catch_strap_thick, convexity=10)
 643     CatchAssemblyCoreProfile();
 644
 645   hull(){
 646     linear_extrude(height=catch_head_th, convexity=10)
 647       CatchTipProfile(0);
 648     linear_extrude(height=catch_tip_th, convexity=10)
 649       CatchTipProfile(catch_tip_th - catch_head_th);
 650   }
 651
 652   linear_extrude(height=catch_head_th, convexity=10)
 653     CatchHeadProfile();
 654
 655   translate(concat(cppB,[0])) hull(){
 656     translate([0,0, catch_knob_height + catch_head_th - catch_knob_dia/2])
 657       sphere(r = catch_knob_dia/2);
 658     cylinder(r = catch_knob_dia/2, h = 0.1);
 659   }
 660 }
 661
 662 module CatchPreDistort(){ /////toplevel
 663   scale(100 / sm_inner_rad)
 664     rotate([90,0,0])
 665     CatchCore();
 666 }
 667
 668 module CatchAssembly(){ /////toplevel
 669   rotate([0,0, -(cppe[0] + cppB[0] + catch_pin_slop) / sm_inner_rad * 360/TAU])
 670     translate([0,0, catch_assembly_dy])
 671     scale(sm_inner_rad / 100)
 672     import(str("poster-tube-lid,CatchPostDistort-fa",
 673                (coarse ? 20 : 3),
 674                ".stl"),
 675            convexity=20);
 676
 677   SomeStrap(catch_strap_width){
 678     union(){ }
 679     union(){
 680       translate([-200, -200, -200])
 681         cube([400, 200, 400]);
 682     }
 683   }
 684 }
 685
 686 module CatchDemo(){ /////toplevel
 687   color("blue") translate([0,0,
 688                            -catch_assembly_dy
 689              ])
 690     CatchAssembly();
 691   translate([0,0,+side_height
 692              ])
 693     Cover();
 694 }
 695
 696 module CatchDemoS(){ /////toplevel
 697   color("blue") translate([0,0,
 698              -catch_assembly_dy
 699              ])
 700     CatchAssembly();
 701   intersection(){
 702     translate([0,0,+side_height
 703                ])
 704       Cover();
 705     mirror([0,1,0]) translate([-250,33,0]) cube([500,500,500]);
 706   }
 707   color("black")
 708     translate([0,-33,0])
 709     cube([6.15, 2,2], center=true);
 710 }
 711
 712 module CatchPinProfileDemo(){ /////toplevel
 713   echo("G ",
 714        cpp2[0] - cpp1[0],
 715        bayo_n[0] - bayo_e[0]);
 716   color("blue") translate([0,0,
 717                            +1,
 718              ]) {
 719     CatchAssemblyCoreProfile();
 720     CatchHeadProfile();
 721   }
 722   polygon(bayo_polygon, convexity=10);
 723 }
 724
 725 //ProfilesDemo();
 726 //BayonetCutout();
 727 //MainProfile();
 728 //Cover();
 729 //Jig();
 730 //CoverTest();