chiark / gitweb /
lock-inframe-bracket: wip new divide
[reprap-play.git] / lock-inframe-bracket.scad
1 // -*- C -*-
2
3 // use shell thickness 1.50
4 // use fill density 40%
5
6 include <funcs.scad>
7
8 tube_dia = 27.5 + 1.625;
9 lock_w = 42.5 + 0.5;
10 lock_d = 28.0 + 0.5;
11 main_h = 45.0;
12 backflange_d = 12;
13 backflange_hole_dy = -1;
14 lockshaft_dia = 14.35;
15
16 cliprecess_h = 16;
17 total_h = 45;
18
19 back_gap = 12.5;
20 main_th = 3.50;
21 tube_th = 4.00;
22
23 midweb_d = 3;
24 clip_th = 3.5;
25 clip_gap = 2.5;
26 clip_d = 22.0;
27
28 mountscrew_dia = 4 + 0.5;
29 clipbolt_dia = 5 + 0.6;
30
31 mountscrew_washer = 10;
32
33 backflange_th = 4.5;
34
35 $fn=50;
36
37 join_cr = 9;
38
39 tube_rear_extra_th = 1;
40
41 divide_shaft_w = 1.75;
42 divide_shaft_l = 1.5;
43 divide_head_dx = 1.75;
44 divide_head_th = 1.5;
45 divide_gap = 0.50;
46 divide_heads = 2;
47
48 divide_angle = 26;
49 divide_fudge_r = 4.75;
50 divide_around = 3.5;
51
52 backflange_angle = 20;
53
54 // calculated
55
56 lockshaft_r = [1, 1] * lockshaft_dia / 2;
57 front_th = main_th;
58
59 tube_or = tube_dia/2 + tube_th;
60 back_ohw = back_gap/2 + backflange_th;
61 backflange_ymin = tube_dia/2 + backflange_d;
62
63 lock_0y = tube_dia/2 + lock_d/2 + midweb_d;
64 lock_0x = lock_w/2 - lock_d/2;
65 lock_0 = [lock_0x,lock_0y];
66
67 lock_or = [lock_w, lock_d]/2 + [front_th,front_th];
68
69 module oval(sz){ // sz[0] > sz[1]
70   xr = sz[0];
71   yr = sz[1];
72   hull(){
73     for (sx=[-1,+1]) {
74       translate([sx * (xr-yr), 0])
75         circle(r=yr);
76     }
77   }
78 }
79
80 module JoinCircs(jr){
81   // http://mathworld.wolfram.com/Circle-CircleIntersection.html
82   R = tube_or + join_cr;
83   r = lock_or[1] + join_cr;
84   d = dist2d( [0,0], lock_0 );
85   x = (d*d - r*r + R*R) / (2*d);
86   y = sqrt( R*R - x*x );
87
88   echo(lock_0x, lock_0y, R,r, d, x,y);
89
90   for (m=[0,1]) {
91     mirror([m,0]) {
92       rotate(atan2(lock_0y, lock_0x)) {
93         translate([x,-y])
94           circle(r= jr);
95       }
96     }
97   }
98 }
99
100 module DividePlan(xl=10){
101   w = divide_shaft_w;
102   g = divide_gap;
103   l = divide_shaft_l + g;
104   t = divide_head_th + g;
105   dx = divide_head_dx;
106   for (m=[0,1]) mirror([m,0]) {
107     translate([w, 0]) square([xl, g]);
108     for (i=[0:divide_heads-1]) {
109       translate([w, i*(l + t)]) {
110         translate([0, 0]) square([g, l + g]);
111         translate([0, l]) square([divide_head_dx + g, g]);
112         translate([dx, l]) square([g, t + g]);
113         translate([0, l + t])
114           square([divide_head_dx + g, g]);
115       }
116     }
117     translate([-0.1, (l + t) * divide_heads])
118       square([w + g, g]);
119   }
120 }
121
122 module DividePlanInPlace(xl=10){
123   rotate([0,0, -divide_angle])
124     translate([ -tube_dia/2 -tube_th/2 - divide_fudge_r, 0])
125     DividePlan(xl);
126 }
127
128 module DivideHook(){ ////toplevel
129   w = tube_th/2;
130   d = divide_gap;
131
132   translate([-1,0] * (w + d + w)){
133     for (sx=[-1,+1])
134       translate([-(w + w+d) * sx, 0]) circle(r= w);
135     difference(){
136       circle(r = 3*w + d);
137       circle(r =   w + d);
138       translate([-10*w, -10*w]) square([20*w, 10*w]);
139     }
140   }
141 }
142
143 module DivideCut(){
144   w = tube_th/2;
145   d = divide_gap;
146
147   difference(){
148     offset(r=divide_gap) DivideHook();
149     DivideHook();
150     translate([-2*w,0]) mirror([0,1]) square([4*w, 4*w]);
151   }
152 }
153
154 module DivideInPlace(){
155   rotate([0,0, -divide_angle])
156     translate([ -tube_dia/2 -tube_th/2, 0])
157     children();
158 }
159
160 module MainPlan(){ ////toplevel
161   difference(){
162     union(){
163       difference(){
164         union(){
165           hull(){
166             for (t=[0, tube_rear_extra_th])
167               translate([0, -t])
168                 circle(r = tube_or);
169           }
170           rotate([0,0, backflange_angle])
171             translate([-back_ohw,0]) mirror([0,1])
172             square([back_ohw*2, backflange_ymin]);
173
174           translate([0, lock_0y]){
175             oval(lock_or);
176           }
177
178           hull(){
179             JoinCircs(0.01);
180             polygon([[0,0], lock_0, [-lock_0[0], lock_0[1]]]);
181           }
182         }
183
184         rotate([0,0, backflange_angle])
185           translate([-back_gap/2,1]) mirror([0,1])
186           square([back_gap, backflange_ymin+2]);
187
188         JoinCircs(join_cr);
189       }
190
191       hull(){
192         minkowski(){
193           DividePlanInPlace(0.1);
194           circle(divide_around);
195         }
196       }
197     }
198     translate([0, lock_0y]){
199       oval([lock_w/2, lock_d/2]);
200     }
201
202     circle(r = tube_dia/2);
203
204     DividePlanInPlace();
205   }
206 }
207
208 lockshaft_or = lockshaft_r + [clip_th,clip_th];
209 cliprecess_ymax = cliprecess_h - lockshaft_r[1];
210 clip_ymin = cliprecess_ymax - total_h;
211 clip_ogap = clip_gap + clip_th*2;
212
213 module ClipElevationPositive(){
214   hull(){
215     oval(lockshaft_or);
216     translate([0, -lockshaft_or[1] * sqrt(2)])
217       square(center=true, 0.5);
218   }
219   translate([-lockshaft_or[0], 0])
220     square([lockshaft_or[0]*2, cliprecess_ymax]);
221   translate([-clip_ogap/2, 0]) mirror([0,1]) square([clip_ogap, -clip_ymin]);
222 }
223
224 module ClipElevationNegative(){
225   hull(){
226     for (y=[0, cliprecess_ymax+1])
227       translate([0, y])
228         oval(lockshaft_r);
229   }
230   translate([-clip_gap/2, 1]) mirror([0,1]) square([clip_gap, 2-clip_ymin]);
231 }
232
233 module ClipElevation(){
234   difference(){
235     ClipElevationPositive(1);
236     ClipElevationNegative(0);
237   }
238 }
239
240 module ExtrudeClipElevation(extra=0){
241   translate([0,
242              lock_0y + lock_d/2 + clip_d + extra,
243              -clip_ymin])
244     rotate([90,0,0])
245     linear_extrude(height= clip_d + extra*2, convexity=100)
246     children(0);
247 }
248
249 module ThroughHole(r, y, z, x=-50) {
250   translate([x, y, z])
251     rotate([0, 90, 0])
252     cylinder(r=r, h=100, $fn=20);
253 }
254
255 module MountingHoleCylinders(r, x=-50){
256   for (z=[ 1/4, 3/4 ]) {
257     rotate([0,0, backflange_angle])
258       ThroughHole( r,
259                    -tube_dia/2 -0.5*backflange_d + backflange_hole_dy,
260                    total_h * z,
261                    x);
262   }
263 }
264
265 module ThroughHoles(){
266   MountingHoleCylinders(mountscrew_dia/2);
267
268   ThroughHole( clipbolt_dia/2,
269                lock_0y + lock_d/2 + clip_d/2 + front_th/2,
270                total_h - cliprecess_h - clip_th - clip_d/2 );
271 }
272
273 module MainPositive(){
274   difference(){
275     union(){
276       linear_extrude(height=total_h, convexity=100) MainPlan();
277       ExtrudeClipElevation() ClipElevationPositive();
278     }
279     ExtrudeClipElevation(1) ClipElevationNegative();
280   }
281 }
282
283 module Bracket(){ ////toplevel
284   difference(){
285     MainPositive();
286     ThroughHoles();
287   }
288 }
289
290 module TestTopEdge(){ ////toplevel
291   intersection(){
292     translate([0,0, -total_h])
293       translate([0,0, 4])
294       Bracket();
295     translate([-200,-200,0])
296       cube([400,400,100]);
297   }
298 }
299
300 module TestClipBoltHole(){ ////toplevel
301   intersection(){
302     union(){
303       translate([0, 0, -5])
304         Bracket();
305       translate([-4, lock_0y + lock_d/2 + 1, 0])
306         cube([8, 4, 1.5]);
307     }
308     translate([-200, lock_0y + lock_d/2 + 0.1])
309       cube([400, 400, total_h-20]);
310   }
311 }
312
313 module Demo(){ ////toplevel
314   Bracket();
315   color("blue") MountingHoleCylinders(mountscrew_dia/2 - 0.1);
316   color("black") MountingHoleCylinders(mountscrew_washer/2,
317                                        back_ohw + 0.25);
318 }
319
320 module DividePlanDemo(){ ////toplevel
321   DividePlan();
322 }
323
324 module DivideDemo(){ ////toplevel
325   color("black") translate([0,0,-2]) MainPlan();
326   DivideInPlace() DivideHook();
327   color("blue") translate([0,0,2]) DivideInPlace() DivideCut();
328 }
329
330 //MainPlan();
331 //ClipElevationPositive();
332 //ClipElevation();
333 //MainPositive();
334 //%ThroughHoles();
335 //TestTopEdge();
336 //TestClipBoltHole();
337
338 //Bracket();
339