lock-inframe-bracket.scad

   1 // -*- C -*-
   2
   3 // use shell thickness 1.50
   4 // use fill density 40%
   5
   6 include <funcs.scad>
   7
   8 tube_dia = 27.5 + 1.625;
   9 lock_w = 42.5 + 0.5;
  10 lock_d = 28.0 + 0.5;
  11 main_h = 45.0;
  12 backflange_d = 12;
  13 backflange_hole_dy = -1;
  14 lockshaft_dia = 14.35;
  15
  16 cliprecess_h = 16;
  17 total_h = 45;
  18
  19 back_gap = 12.5;
  20 main_th = 3.50;
  21 tube_th = 4.00;
  22
  23 midweb_d = 3;
  24 clip_th = 3.5;
  25 clip_gap = 2.5;
  26 clip_d = 22.0;
  27
  28 mountscrew_dia = 4 + 0.5;
  29 clipbolt_dia = 5 + 0.6;
  30
  31 mountscrew_washer = 10;
  32
  33 backflange_th = 4.5;
  34
  35 $fn=50;
  36
  37 join_cr = 9;
  38
  39 tube_rear_extra_th = 1;
  40
  41 divide_shaft_w = 1.75;
  42 divide_shaft_l = 1.5;
  43 divide_head_dx = 1.75;
  44 divide_head_th = 1.5;
  45 divide_gap = 0.50;
  46 divide_heads = 2;
  47
  48 divide_angle = 26;
  49 divide_fudge_r = 4.75;
  50 divide_around = 3.5;
  51
  52 backflange_angle = 20;
  53
  54 // calculated
  55
  56 lockshaft_r = [1, 1] * lockshaft_dia / 2;
  57 front_th = main_th;
  58
  59 tube_or = tube_dia/2 + tube_th;
  60 back_ohw = back_gap/2 + backflange_th;
  61 backflange_ymin = tube_dia/2 + backflange_d;
  62
  63 lock_0y = tube_dia/2 + lock_d/2 + midweb_d;
  64 lock_0x = lock_w/2 - lock_d/2;
  65 lock_0 = [lock_0x,lock_0y];
  66
  67 lock_or = [lock_w, lock_d]/2 + [front_th,front_th];
  68
  69 module oval(sz){ // sz[0] > sz[1]
  70   xr = sz[0];
  71   yr = sz[1];
  72   hull(){
  73     for (sx=[-1,+1]) {
  74       translate([sx * (xr-yr), 0])
  75         circle(r=yr);
  76     }
  77   }
  78 }
  79
  80 module JoinCircs(jr){
  81   // http://mathworld.wolfram.com/Circle-CircleIntersection.html
  82   R = tube_or + join_cr;
  83   r = lock_or[1] + join_cr;
  84   d = dist2d( [0,0], lock_0 );
  85   x = (d*d - r*r + R*R) / (2*d);
  86   y = sqrt( R*R - x*x );
  87
  88   echo(lock_0x, lock_0y, R,r, d, x,y);
  89
  90   for (m=[0,1]) {
  91     mirror([m,0]) {
  92       rotate(atan2(lock_0y, lock_0x)) {
  93         translate([x,-y])
  94           circle(r= jr);
  95       }
  96     }
  97   }
  98 }
  99
 100 module DividePlan(xl=10){
 101   w = divide_shaft_w;
 102   g = divide_gap;
 103   l = divide_shaft_l + g;
 104   t = divide_head_th + g;
 105   dx = divide_head_dx;
 106   for (m=[0,1]) mirror([m,0]) {
 107     translate([w, 0]) square([xl, g]);
 108     for (i=[0:divide_heads-1]) {
 109       translate([w, i*(l + t)]) {
 110         translate([0, 0]) square([g, l + g]);
 111         translate([0, l]) square([divide_head_dx + g, g]);
 112         translate([dx, l]) square([g, t + g]);
 113         translate([0, l + t])
 114           square([divide_head_dx + g, g]);
 115       }
 116     }
 117     translate([-0.1, (l + t) * divide_heads])
 118       square([w + g, g]);
 119   }
 120 }
 121
 122 module DividePlanInPlace(xl=10){
 123   rotate([0,0, -divide_angle])
 124     translate([ -tube_dia/2 -tube_th/2 - divide_fudge_r, 0])
 125     DividePlan(xl);
 126 }
 127
 128 module MainPlan(){
 129   difference(){
 130     union(){
 131       difference(){
 132         union(){
 133           hull(){
 134             for (t=[0, tube_rear_extra_th])
 135               translate([0, -t])
 136                 circle(r = tube_or);
 137           }
 138           rotate([0,0, backflange_angle])
 139             translate([-back_ohw,0]) mirror([0,1])
 140             square([back_ohw*2, backflange_ymin]);
 141
 142           translate([0, lock_0y]){
 143             oval(lock_or);
 144           }
 145
 146           hull(){
 147             JoinCircs(0.01);
 148             polygon([[0,0], lock_0, [-lock_0[0], lock_0[1]]]);
 149           }
 150         }
 151
 152         rotate([0,0, backflange_angle])
 153           translate([-back_gap/2,1]) mirror([0,1])
 154           square([back_gap, backflange_ymin+2]);
 155
 156         JoinCircs(join_cr);
 157       }
 158
 159       hull(){
 160         minkowski(){
 161           DividePlanInPlace(0.1);
 162           circle(divide_around);
 163         }
 164       }
 165     }
 166     translate([0, lock_0y]){
 167       oval([lock_w/2, lock_d/2]);
 168     }
 169
 170     circle(r = tube_dia/2);
 171
 172     DividePlanInPlace();
 173   }
 174 }
 175
 176 lockshaft_or = lockshaft_r + [clip_th,clip_th];
 177 cliprecess_ymax = cliprecess_h - lockshaft_r[1];
 178 clip_ymin = cliprecess_ymax - total_h;
 179 clip_ogap = clip_gap + clip_th*2;
 180
 181 module ClipElevationPositive(){
 182   hull(){
 183     oval(lockshaft_or);
 184     translate([0, -lockshaft_or[1] * sqrt(2)])
 185       square(center=true, 0.5);
 186   }
 187   translate([-lockshaft_or[0], 0])
 188     square([lockshaft_or[0]*2, cliprecess_ymax]);
 189   translate([-clip_ogap/2, 0]) mirror([0,1]) square([clip_ogap, -clip_ymin]);
 190 }
 191
 192 module ClipElevationNegative(){
 193   hull(){
 194     for (y=[0, cliprecess_ymax+1])
 195       translate([0, y])
 196         oval(lockshaft_r);
 197   }
 198   translate([-clip_gap/2, 1]) mirror([0,1]) square([clip_gap, 2-clip_ymin]);
 199 }
 200
 201 module ClipElevation(){
 202   difference(){
 203     ClipElevationPositive(1);
 204     ClipElevationNegative(0);
 205   }
 206 }
 207
 208 module ExtrudeClipElevation(extra=0){
 209   translate([0,
 210              lock_0y + lock_d/2 + clip_d + extra,
 211              -clip_ymin])
 212     rotate([90,0,0])
 213     linear_extrude(height= clip_d + extra*2, convexity=100)
 214     children(0);
 215 }
 216
 217 module ThroughHole(r, y, z, x=-50) {
 218   translate([x, y, z])
 219     rotate([0, 90, 0])
 220     cylinder(r=r, h=100, $fn=20);
 221 }
 222
 223 module MountingHoleCylinders(r, x=-50){
 224   for (z=[ 1/4, 3/4 ]) {
 225     rotate([0,0, backflange_angle])
 226       ThroughHole( r,
 227                    -tube_dia/2 -0.5*backflange_d + backflange_hole_dy,
 228                    total_h * z,
 229                    x);
 230   }
 231 }
 232
 233 module ThroughHoles(){
 234   MountingHoleCylinders(mountscrew_dia/2);
 235
 236   ThroughHole( clipbolt_dia/2,
 237                lock_0y + lock_d/2 + clip_d/2 + front_th/2,
 238                total_h - cliprecess_h - clip_th - clip_d/2 );
 239 }
 240
 241 module MainPositive(){
 242   difference(){
 243     union(){
 244       linear_extrude(height=total_h, convexity=100) MainPlan();
 245       ExtrudeClipElevation() ClipElevationPositive();
 246     }
 247     ExtrudeClipElevation(1) ClipElevationNegative();
 248   }
 249 }
 250
 251 module Bracket(){ ////toplevel
 252   difference(){
 253     MainPositive();
 254     ThroughHoles();
 255   }
 256 }
 257
 258 module TestTopEdge(){ ////toplevel
 259   intersection(){
 260     translate([0,0, -total_h])
 261       translate([0,0, 4])
 262       Bracket();
 263     translate([-200,-200,0])
 264       cube([400,400,100]);
 265   }
 266 }
 267
 268 module TestClipBoltHole(){ ////toplevel
 269   intersection(){
 270     union(){
 271       translate([0, 0, -5])
 272         Bracket();
 273       translate([-4, lock_0y + lock_d/2 + 1, 0])
 274         cube([8, 4, 1.5]);
 275     }
 276     translate([-200, lock_0y + lock_d/2 + 0.1])
 277       cube([400, 400, total_h-20]);
 278   }
 279 }
 280
 281 module Demo(){ ////toplevel
 282   Bracket();
 283   color("blue") MountingHoleCylinders(mountscrew_dia/2 - 0.1);
 284   color("black") MountingHoleCylinders(mountscrew_washer/2,
 285                                        back_ohw + 0.25);
 286 }
 287
 288 //MainPlan();
 289 //ClipElevationPositive();
 290 //ClipElevation();
 291 //MainPositive();
 292 //%ThroughHoles();
 293 //TestTopEdge();
 294 //TestClipBoltHole();
 295 //DividePlan();
 296
 297 //Bracket();
 298