filamentspool.scad

   1 // -*- C -*-
   2
   3 // filamentspool.scad
   4 // 3D design for filament spools to hold coils as supplied by Faberdashery
   5 //
   6
   7 //
   8 // Copyright 2012,2013,2016 Ian Jackson
   9 //
  10 // This work is free software: you can redistribute it and/or modify
  11 // it under the terms of the GNU General Public License as published by
  12 // the Free Software Foundation, either version 3 of the License, or
  13 // (at your option) any later version.
  14 //
  15 // This work is distributed in the hope that it will be useful,
  16 // but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 // GNU General Public License for more details.
  19 //
  20 // You should have received a copy of the GNU General Public License
  21 // along with this work.  If not, see <http://www.gnu.org/licenses/>
  22 //
  23
  24 //
  25 // Each spool is a hub with 3 or 4 arms.  Each arm has a cup for
  26 // holding the filament.  The effective diameter can be adjusted by
  27 // setting the cup into a different seat in the arm.  The cups are
  28 // held on with simple clips, so the filement coil can easily be
  29 // removed and replaced.
  30 //
  31 // This file (and its includes) can generate:
  32 //
  33 // ===== Heavy duty 4-armed spool for 3mm x 100m coil =====
  34 //
  35 // A heavy duty 4-armed spool suitable for holding a 100m
  36 // Faberdashery coil on the spool arm of a Lulzbot TAZ-5.
  37 //
  38 //     Set
  39 //           fdia=2.85
  40 //           lightduty=false
  41 //     And print following parts
  42 //            Hub
  43 //            ArmEnd x 4
  44 //            FilamentCup x 4  (or FilamentCupPair x 2)
  45 //            CupSecuringClip x 4
  46 //
  47 //     You will also need  4 x M4 machine screws and nuts.
  48 //
  49 //     This is the default.
  50 //
  51 // ===== Light duty 3-armed spool for 3mm x <=30m coil =====
  52 //
  53 // A light duty 3-armed spool suitable for up to around 30m
  54 // of Faberdashery 2.85mm PLA.
  55 //
  56 //     Set
  57 //           fdia=2.85
  58 //           lightduty=true
  59 //     (or look in filamentspool-lt.scad).
  60 //
  61 //     And print following parts
  62 //           Hub
  63 //           ArmEnd x 3
  64 //           FilamentCup x 3  (or FilamentCup + FilamentCupPair)
  65 //           CupSecuringClip x 3
  66 //           TowerDoveClipPin x 6
  67 //
  68 //     When assembling, insert one TowerDoveClipPin from each side,
  69 //     joining each ArmEnd to the Hub with two TowerDoveClipPins.
  70 //     Modest force with pliers is good to seat them properly.
  71 //
  72 //     (note that the light duty and heavy duty CupSecuringClips
  73 //      are slightly different)
  74 //
  75 // ===== Notes regarding both the above spools =====
  76 //
  77 // When mounting either spool on the TAZ-5 spool arm, put the `pointy'
  78 // end of the hub towards the printer - ie, put put the spool on
  79 // `backwards'.  This ensures that the spool's arms will clear the
  80 // printer framework.
  81 //
  82 // For the above, I generally used the Cura `Standard' PLA profile.
  83 //
  84 // ===== TAZ-5 feed tube adjustment kit =====
  85 //
  86 // With a TAZ-5 I recommend using this kit to improve the feed
  87 // reliability:
  88 //
  89 //       Set
  90 //           fdia=2.85
  91 //     And print following parts
  92 //           FilamentGuideSpacer (ideally, at `high detail')
  93 //           FilamentGuideArmPrint (optional; `high detail' or `standard')
  94 //
  95 //     And possibly also
  96 //           t-nut_jig_0.2.stl
  97 //     from Aleph Objects - look here:
  98 //           http://download.lulzbot.com/TAZ/accessories/tool_heads/version_2/Dual_Extruder_v2/production_parts/stl/
  99 //
 100 // The spacer clips onto the filament guide tube holder arm, on the
 101 // inside, with the pointy flanged end towards the filament guide
 102 // tube.  It stops the filament guide tube angle (and so the
 103 // filament's natural pickup location) changing as the print head moves.
 104 //
 105 // The FilamentGuideArm[Print] is a replacement for the arm supplied
 106 // with your TAZ-5.  It's longer, so that the filament pickup point is
 107 // closer to the middle of the coil.  Use the t-nut_jig to stop the
 108 // T-nuts in the aluminium channel from annoyingly sliding down to the
 109 // bottom while you swap out the arm.
 110 //
 111 // (Faberdashery coils, and therefore both the above spools, have a
 112 // larger diameter than the flat-walled spools often supplied by other
 113 // vendors.  And the spools above have individual arms rather than a
 114 // continuous disc.  If the filament `unhooks' from the arm, it can
 115 // pull taught around the hub and stop feeding properly.)
 116 //
 117 // ===== Spool storage arm, for mounting on walls =====
 118 //
 119 // A storage arm suitable for screwing to walls, bookshelves,
 120 // etc. (requires non-countersunk M4 screws); will hold two heavy duty
 121 // spools each with a 100m coil.
 122 //
 123 //     Set
 124 //           fdia=2.85
 125 //           lightduty=false
 126 //     (or look in filamentspool-sm.scad).
 127 //
 128 //     And print one of these, according to taste
 129 //            StorageArmLeft
 130 //            StorageArmRight
 131 //
 132 //     NB that the `light duty' version of this is shorter and
 133 //     will only take two `light duty' spools.
 134 //
 135 // For the above, I used the Cura `High detail' PLA profile because
 136 // I wanted it pretty, but the `Standard' profile should do fine.
 137 //
 138 // ===== Spools for 1.75mm filament =====
 139 //
 140 // Spool (in many parts) for handing 1.75mm filament, printable
 141 // on, and with parts for mounting on, a Reprappro Huxley.
 142
 143
 144 fdia=2.85; // or 1.75
 145 lightduty=false; // or true
 146
 147
 148 slop=0.5;
 149 bigslop=slop*2;
 150
 151 function selsz(sm,lt,lg) = fdia < 2 ? sm : lightduty ? lt : lg;
 152 function usedove() = selsz(true,true,false);
 153
 154 num_arms = selsz(3,3,4);
 155
 156 channelslop=selsz(slop,0.75,slop);
 157
 158 exteffrad = 70;
 159 hubeffrad = selsz(30, 82, 40);
 160 hubbigrad = selsz(20, 38, 38);
 161 hublwidth = selsz(3, 2.5, 4);
 162 hubstemwidth = 2;
 163 hublthick = 10;
 164 hubaxlerad = selsz(5, 28/2, 28/2);
 165 totalheightfromtower = 240;
 166 axletowerfudgebend = 0;
 167 axleaxlefudgebend = 3;
 168 axlepadlen = 1.0;
 169
 170 armend_length = 120;
 171
 172 prongthick=selsz(5,4,5);
 173 prongwidth=selsz(5,4,5);
 174 prongribwidth=3;
 175 prongribheight=selsz(0,0,4);
 176 ratchetstep=15;
 177 ratchettooth=3;
 178 ratchettoothheight=5;
 179 ratchettoothsmoothr=1;
 180 ratchettoothslope=0.75;
 181 overlap=0.5;
 182 cupwidth=selsz(40,25,50);
 183 cupheight=selsz(55,25,55);
 184
 185 cupstrong_dx=selsz(0,0,-10);
 186
 187 propxshift = -6;
 188
 189 doveclipheight = 10;
 190
 191 teethh=3;
 192 teethgapx=4+fdia;
 193
 194 prongstalkxwidth=3;
 195
 196 stalklength=selsz(35,25,55);
 197 overclipcupgap=5;
 198 overclipdepth=15;
 199 overcliproundr=2.0;
 200 overclipthick=1.0;
 201 overclipcupnextgap=selsz(20,15,20);
 202
 203 hubaxlelen = selsz(25, 62.5, 77.5);
 204 echo(hubaxlelen);
 205
 206 overclipsmaller=-2.5;
 207 overclipbigger=0.0;
 208
 209 wingspoke=2.5;
 210 wingsize=6;
 211 wingthick=3;
 212
 213 armendwallthick=selsz(2.5, 1.8, 2.5);
 214 armendbasethick=selsz(1.2, 1.2, 1.2);
 215
 216 numbers_relief = 0.7;
 217 numbers_tick_len = 8;
 218 numbers_tick_width = 0.75;
 219 numbers_tick_linespc = 1.0;
 220 numbers_height_allow = 8;
 221
 222 axlehorizoffset = 12.5;
 223 axlevertheight = 100;
 224 towercliph = 16;
 225 towerclipcount = 3;
 226 towerpillarw = 5;
 227
 228 axlepinrad = 2;
 229 axlepintabrad = 5;
 230
 231 washerthick = 1.2;
 232 washerthinthick = 0.8;
 233 washerverythinthick = 0.4;
 234 washerrad = hubaxlerad + 7.5;
 235 frictionwasherarmwidth = 3;
 236 frictionwasherextrapush = 1.0;
 237
 238 ratchetpawl=ratchetstep-ratchettooth-bigslop*2;
 239
 240 nondove_armhole_x = 32;
 241 nondove_armhole_hole = 4 + 0.8;
 242 nondove_armhole_support = 7;
 243 nondove_armhole_wall = 3.2;
 244 nondove_armhole_slop = 0.5;
 245 nondove_armhole_slop_x = 0.5;
 246
 247 nondove_armbase = nondove_armhole_x + nondove_armhole_hole/2 +
 248   nondove_armhole_support;
 249 echo(nondove_armbase);
 250
 251 include <doveclip.scad>
 252 include <cliphook.scad>
 253 include <filamentteeth.scad>
 254 include <axlepin.scad>
 255 include <commitid.scad>
 256
 257 hub_clip_baseextend = (hubeffrad - DoveClip_depth()
 258                        - hubbigrad + hublwidth);
 259
 260 real_exteffrad = selsz(exteffrad + hub_clip_baseextend,
 261                        hubeffrad + DoveClip_depth(),
 262                        hubeffrad + nondove_armbase);
 263
 264 channelwidth = prongthick + channelslop;
 265 channeldepth = prongwidth + ratchettoothheight;
 266 totalwidth = armendwallthick*2 + channelwidth;
 267 totalheight = channeldepth + armendbasethick;
 268 stalkwidth = prongwidth + prongstalkxwidth;
 269
 270 tau = PI*2;
 271
 272 module ArmEnd(length=armend_length){ ////toplevel
 273   if (usedove()) {
 274     translate([ratchettoothsmoothr, channelwidth/2, -armendbasethick]) {
 275       rotate([0,0,-90])
 276         DoveClipPairBase(h=doveclipheight);
 277     }
 278   } else {
 279     difference(){
 280       translate([1, -armendwallthick, -armendbasethick])
 281         mirror([1,0,0])
 282         cube([nondove_armbase+1, totalwidth, totalheight]);
 283       translate([-nondove_armbase + nondove_armhole_x,
 284                  -armendwallthick + totalwidth/2,
 285                  -armendbasethick -1])
 286         cylinder(r= nondove_armhole_hole/2, h=totalheight+2, $fn=10);
 287       translate([-nondove_armbase, -armendwallthick, -armendbasethick])
 288         rotate([90,0,0])
 289         Commitid_BestCount([nondove_armbase, totalwidth]);
 290     }
 291   }
 292
 293   for (otherside=[0,1]) {
 294     for (circum = [300:100:1500]) {
 295       assign(rad = circum / tau)
 296         assign(fn = str("filamentspool-number-n",circum,".dxf"))
 297         assign(rotateoffset = [0, totalwidth/2, 0])
 298         assign(xlen = rad - real_exteffrad) {
 299         if (xlen >= numbers_tick_width/2
 300             + (otherside ? numbers_height_allow : 0) &&
 301             xlen <= length - (otherside ? 0 : numbers_height_allow))
 302           translate([xlen, -armendwallthick,
 303                      -armendbasethick + (totalheight - numbers_tick_len)/2])
 304           translate(rotateoffset)
 305           rotate([0,0, otherside*180])
 306           translate(-rotateoffset){
 307             translate([-numbers_tick_width/2, -1, 0])
 308               cube([numbers_tick_width, numbers_relief+1, numbers_tick_len]);
 309             translate([numbers_tick_width/2 + numbers_tick_linespc,
 310                        1,
 311                        numbers_tick_len])
 312               rotate([90,0,0])
 313               rotate([0,0,-90])
 314               linear_extrude(height= numbers_relief+1)
 315               //    scale(templatescale)
 316               import(file=fn, convexity=100);
 317           }
 318       }
 319     }
 320   }
 321
 322   difference(){
 323     translate([0, -armendwallthick, -armendbasethick])
 324       cube([length, totalwidth, totalheight]);
 325     translate([-1, 0, 0])
 326       cube([length+1 - ratchettooth, channelwidth, channeldepth+1]);
 327     translate([-1, 0, ratchettoothheight])
 328       cube([length+2, channelwidth, channeldepth+1]);
 329
 330     if (usedove()){
 331       translate([0,0, -armendbasethick])
 332         Commitid_BestCount_M([length/3, totalwidth]);
 333     }
 334   }
 335   for (dx = [0 : ratchetstep : length - ratchetstep]) translate([dx,0,0]) {
 336     translate([ratchettoothsmoothr+0.5, armendwallthick/2, 0]) minkowski(){
 337       rotate([90,0,0])
 338         cylinder($fn=20, r=ratchettoothsmoothr, h=armendwallthick);
 339       multmatrix([      [       1, 0, ratchettoothslope, 0      ],
 340                         [       0,      1,      0,      0       ],
 341                         [       0,      0,      1,      0       ],
 342                         [       0,      0,      0,      1       ]])
 343         cube([ratchettooth - ratchettoothsmoothr*2,
 344               channelwidth, ratchettoothheight - ratchettoothsmoothr]);
 345     }
 346   }
 347 }
 348
 349 module FilamentCupHandle(){
 350   pawlusewidth = ratchetpawl-ratchettoothsmoothr*2;
 351   mirror([0,1,0]) {
 352     cube([stalklength, stalkwidth, prongthick]);
 353     translate([stalklength, stalkwidth/2, 0])
 354       cylinder(r=stalkwidth/2, h=prongthick, $fn=20);
 355     translate([ratchettoothsmoothr, stalkwidth, 0]) {
 356       minkowski(){
 357         cylinder($fn=20,r=ratchettoothsmoothr, h=1);
 358         multmatrix([    [       1, -ratchettoothslope, 0, 0     ],
 359                         [       0,      1,      0,      0       ],
 360                         [       0,      0,      1,      0       ],
 361                         [       0,      0,      0,      1       ]])
 362           cube([pawlusewidth,
 363                 ratchettoothheight - ratchettoothsmoothr,
 364                 prongthick - 1]);
 365       }
 366     }
 367   }
 368 }
 369
 370 module FilamentCupCup(){
 371   for (my=[0,1]) mirror([0,my,0]) {
 372     translate([0, cupwidth/2, 0])
 373       cube([cupheight + prongwidth, prongwidth, prongthick]);
 374   }
 375 }
 376
 377 module FilamentCup() { ////toplevel
 378   FilamentCupHandle();
 379
 380   gapy = prongwidth;
 381   dy = cupwidth/2 + gapy + overclipcupgap;
 382   baselen = dy+cupwidth/2;
 383
 384   translate([0, dy, 0])
 385     FilamentCupCup();
 386   cube([prongwidth, baselen+1, prongthick]);
 387
 388   translate([cupstrong_dx, prongwidth, 0]) {
 389     cube([prongwidth, baselen-prongwidth, prongthick]);
 390     for (y = [0, .33, .67, 1])
 391       translate([0, (baselen - prongwidth) * y, 0])
 392         cube([-cupstrong_dx + 1, prongwidth, prongthick]);
 393   }
 394   if (cupstrong_dx != 0) {
 395     rotate([0,0,45])
 396       translate([-prongwidth*.55, -prongwidth*2.1, 0])
 397       cube([prongwidth*(2.65), prongwidth*4.2, prongthick]);
 398   }
 399
 400   translate([0, -0.2, 0])
 401     cube([prongribwidth, baselen, prongthick + prongribheight]);
 402
 403   if (prongribheight > 0) {
 404     translate([-prongwidth, baselen, 0])
 405       cube([cupheight/2, prongwidth + prongribheight, prongribwidth]);
 406   }
 407
 408   midrad = cupwidth/2 + prongwidth/2;
 409
 410   propshift = stalklength - overclipdepth - prongthick + propxshift;
 411   proptaken = propshift;
 412   echo(midrad, propshift, proptaken);
 413
 414   translate([propshift, -1, 0]) {
 415     // something is wrong with the y calculation
 416     cube([prongwidth,
 417           gapy+2,
 418           prongthick]);
 419   }
 420   for (y = [overclipcupgap, overclipcupgap+overclipcupnextgap]) {
 421     translate([cupstrong_dx, y + prongwidth, 0])
 422       rotate([0,0, 102 + fdia])
 423       FilamentTeeth(fdia=fdia, h=teethh);
 424   }
 425   for (x = [-0.3, -1.3]) {
 426     translate([cupheight + overclipcupnextgap*x, baselen + prongwidth, 0])
 427       rotate([0,0, 12 + fdia])
 428       FilamentTeeth(fdia=fdia, h=teethh);
 429   }
 430 }
 431
 432 module CupSecuringClipSolid(w,d,h1,h2){
 433   rotate([0,-90,0]) translate([0,-h1/2,-w/2]) linear_extrude(height=w) {
 434     polygon(points=[[0,0], [d,0], [d,h2], [0,h1]]);
 435   }
 436 }
 437
 438 module CupSecuringClipSolidSmooth(xrad=0, xdepth=0){
 439   hbase = totalheight + prongstalkxwidth - overcliproundr*2;
 440   minkowski(){
 441     CupSecuringClipSolid(w=totalwidth,
 442                          d=overclipdepth + xdepth,
 443                          h1=hbase - overclipsmaller,
 444                          h2=hbase + overclipbigger);
 445     cylinder($fn=20, h=0.01, r=overcliproundr+xrad);
 446   }
 447 }
 448
 449 module CupSecuringClip(){ ////toplevel
 450   wingswidth = wingspoke*2 + overclipthick*2 + overcliproundr*2 + totalwidth;
 451   difference(){
 452     union(){
 453       CupSecuringClipSolidSmooth(xrad=overclipthick, xdepth=0);
 454       translate([-wingswidth/2, -wingsize/2, 0])
 455         cube([wingswidth, wingsize, wingthick]);
 456       translate([-wingsize/2, -wingswidth/2, 0])
 457         cube([wingsize, wingswidth, wingthick]);
 458     }
 459     translate([0,0,-0.1])
 460       CupSecuringClipSolidSmooth(xrad=0, xdepth=0.2);
 461   }
 462 }
 463
 464 module ArmDoveClipPin(){ ////toplevel
 465   DoveClipPin(h=doveclipheight);
 466 }
 467
 468 module TowerDoveClipPin(){ ////toplevel
 469   DoveClipPin(h=towercliph/2);
 470 }
 471
 472 module Hub(){ ////toplevel
 473   axlerad = hubaxlerad + slop;
 474   xmin = axlerad+hublwidth/2;
 475   xmax = hubbigrad-hublwidth/2;
 476   hole = hubeffrad - hubbigrad - DoveClip_depth() - hublwidth*2;
 477   holewidth = DoveClipPairSane_width() - hubstemwidth*2;
 478   nondove_allwidth = nondove_armhole_wall*2 + totalwidth;
 479   difference(){
 480     union(){
 481       difference(){
 482         cylinder($fn=60, h=hublthick, r=hubbigrad);
 483         translate([0,0,-1])
 484           cylinder($fn=30, h=hublthick+2, r=(hubbigrad-hublwidth));
 485       }
 486       cylinder(h=hubaxlelen, r=axlerad+hublwidth);
 487       for (ang=[0 : 360/num_arms : 359])
 488         rotate([0,0,ang]) {
 489           if (usedove()){
 490             difference() {
 491               translate([hubeffrad,0,0])
 492                 DoveClipPairSane(h=doveclipheight,
 493                                  baseextend = hub_clip_baseextend);
 494               if (hole>hublwidth && holewidth > 2) {
 495                 translate([hubbigrad + hublwidth, -holewidth/2, -1])
 496                   cube([hole, holewidth, hublthick+2]);
 497               }
 498             }
 499           } else {
 500             difference(){
 501               translate([0,
 502                          -nondove_allwidth/2,
 503                          0])
 504                 cube([hubeffrad + nondove_armhole_x
 505                       + nondove_armhole_hole/2 + nondove_armhole_support,
 506                       nondove_allwidth,
 507                       nondove_armhole_wall + totalheight]);
 508               translate([hubeffrad - nondove_armhole_slop_x,
 509                          -nondove_allwidth/2
 510                          + nondove_armhole_wall - nondove_armhole_slop,
 511                          nondove_armhole_wall])
 512                 cube([nondove_armhole_x + 50,
 513                       totalwidth + nondove_armhole_slop*2,
 514                       totalheight + 1]);
 515               translate([hubeffrad + nondove_armhole_x, 0, -20])
 516                 cylinder(r= nondove_armhole_hole/2, h=50, $fn=10);
 517             }
 518           }
 519         }
 520       for (ang = [0 : 180/num_arms : 359])
 521         rotate([0,0,ang]) rotate([90,0,0]) {
 522           translate([0,0,-hublwidth/2])
 523             linear_extrude(height=hublwidth)
 524             polygon([[xmin,0.05], [xmax,0.05],
 525                      [xmax,hublthick-0.2], [xmin, hubaxlelen-0.2]]);
 526         }
 527     }
 528     translate([0,0,-1]) cylinder($fn=60, h=hubaxlelen+2, r=axlerad);
 529
 530     rotate([0,0, selsz(0,0,45)])
 531       translate([axlerad+hublwidth,
 532                  -hublwidth/2,
 533                  0])
 534       rotate([90,0,0])
 535       Commitid_BestCount([(hubbigrad-hublwidth) - (axlerad+hublwidth),
 536                           hublthick +
 537                           hublwidth/2 * hubaxlelen/(hubbigrad-axlerad),
 538                           ]);
 539   }
 540 }
 541
 542 module ArmExtender(){ ////toplevel
 543   DoveClipExtender(length=exteffrad-hubeffrad,
 544                    ha=doveclipheight,
 545                    hb=doveclipheight);
 546 }
 547
 548 module FsAxlePin(){ ////toplevel
 549   AxlePin(hubaxlerad, washerrad*2, axlepinrad, axlepintabrad, slop);
 550 }
 551
 552 module Axle(){ ////toplevel
 553   pillarswidth = DoveClipPairSane_width(towerclipcount);
 554
 555   rotate([0,0, -( axleaxlefudgebend + atan(slop/hubaxlelen) ) ])
 556   translate([-axlehorizoffset, -axlevertheight, 0]) {
 557     rotate([0,0,-axletowerfudgebend])
 558     rotate([0,0,-90])
 559       DoveClipPairSane(h=towercliph, count=towerclipcount, baseextend=3);
 560     translate([0, DoveClip_depth(), 0])
 561     rotate([0,0,90])
 562       ExtenderPillars(axlevertheight - DoveClip_depth(),
 563                       pillarswidth, towercliph,
 564                       pillarw=towerpillarw);
 565   }
 566
 567   axleclearlen = hubaxlelen + slop*4 + washerthick*2 + axlepadlen;
 568   axlerad = hubaxlerad-slop;
 569   bump = axlerad * 0.2;
 570   shift = axlerad-bump;
 571   joinbelowallow = 3;
 572
 573   intersection(){
 574     translate([0, 0, shift]) {
 575       difference() {
 576         union(){
 577           translate([-1, 0, 0])
 578             rotate([0,90,0])
 579             cylinder($fn=60,
 580                      r = axlerad,
 581                      h = 1 + axleclearlen + axlepinrad*2 + 2);
 582           mirror([1,0,0]) rotate([0,90,0])
 583             cylinder(r = axlerad*1.75, h = 3);
 584           intersection(){
 585             mirror([1,0,0])
 586               translate([axlehorizoffset - pillarswidth/2, 0, 0])
 587               rotate([0,90,0])
 588               cylinder($fn=60,
 589                        r = towercliph - shift,
 590                        h = pillarswidth);
 591             translate([-50, -joinbelowallow, -50])
 592               cube([100, joinbelowallow+50, 100]);
 593           }
 594         }
 595         rotate([90,0,0])
 596         translate([axleclearlen + axlepinrad/2, 0, -25])
 597           cylinder(r = axlepinrad + slop, h=50);
 598       }
 599     }
 600     translate([-50,-50,0]) cube([100,100,100]);
 601   }
 602 }
 603
 604 module washer(thick){
 605   Washer(hubaxlerad, washerrad, thick, slop);
 606 }
 607
 608 module AxleWasher(){ ////toplevel
 609   washer(thick=washerthick);
 610 }
 611
 612 module AxleThinWasher(){ ////toplevel
 613   washer(thick=washerthinthick);
 614 }
 615
 616 module AxleVeryThinWasher(){ ////toplevel
 617   washer(thick=washerverythinthick);
 618 }
 619
 620 module AxleFrictionWasher(){ ////toplevel
 621   difference(){
 622     cylinder(h=washerthick, r=washerrad);
 623     translate([0,0,-1]) cylinder(h=washerthick+2, r=hubaxlerad+slop);
 624   }
 625   frarmr = hubbigrad;
 626   frarmw = frictionwasherarmwidth;
 627   frarmpawlr = hublwidth;
 628   frarmpawlpush = slop*4 + frictionwasherextrapush;
 629   for (ang=[0,180]) rotate([0,0,ang]) {
 630     translate([washerrad-1, -frarmw/2, 0])
 631       cube([frarmr - washerrad + 1, frarmw, washerthick]);
 632     intersection(){
 633       translate([frarmr - frarmpawlr, -50, 0])
 634         cube([frarmpawlr, 100, 50]);
 635       rotate([0,90,0])
 636         cylinder(h = 50, r = frarmpawlpush, $fn=36);
 637     }
 638   }
 639 }
 640
 641 module TowerExtender(){ ////toplevel
 642   l = totalheightfromtower - axlevertheight;
 643   echo("TowerExtender",l);
 644   DoveClipExtender(length = l,
 645                    ha = towercliph, hb = towercliph,
 646                    counta = towerclipcount, countb = towerclipcount,
 647                    pillarw = towerpillarw);
 648 }
 649
 650 module FilamentCupPair(){ ////toplevel
 651   FilamentCup();
 652   translate([cupheight + prongthick*3,
 653              cupwidth/2*1.7,
 654              0])
 655     rotate([0,0,180]) FilamentCup();
 656 }
 657
 658 //----- storarm -----
 659
 660 storarm_hooklen = 8;
 661 storarm_hookheight = 5;
 662 storarm_thick = 10;
 663 storarm_axleslop = 4;
 664
 665 storarm_base_w = 30;
 666 storarm_base_h = 100;
 667 storarm_base_d = 15;
 668 storarm_base_mind = 2;
 669
 670 storarm_cope_hubaxle_mk1 = true;
 671
 672 storarm_screw_hole = 4;
 673 storarm_screw_hole_slop = 0.5;
 674 storarm_besides_hole = 4;
 675
 676 storarm_under_hole = 5;
 677 storarm_screw_hole_head = 8.8;
 678 storarm_screw_hole_head_slop = 1.5;
 679
 680 // calculated
 681
 682 storarm_axlerad = hubaxlerad - storarm_axleslop;
 683 storarm_mainlen = hubaxlelen*2 + storarm_axleslop
 684   + (storarm_cope_hubaxle_mk1 ? 10 : 0);
 685 storarm_totlen = storarm_mainlen + storarm_hooklen;
 686
 687 storarm_mid_off_y = storarm_axlerad;
 688
 689 storarm_base_off_y = storarm_mid_off_y + storarm_base_h/2;
 690
 691 module StorageArmDiagPartSide(xmin, xmax){
 692   xsz = xmax-xmin;
 693   yuse = storarm_thick/2;
 694
 695   intersection(){
 696     translate([xmin-1, -storarm_axlerad, storarm_thick/2])
 697       rotate([0,90,0])
 698       cylinder(r=storarm_axlerad, h=xsz+2, $fn=60);
 699     translate([xmin, -yuse, 0])
 700       cube([xsz, yuse, storarm_thick]);
 701   }
 702 }
 703
 704 module StorageArmDiagPart(xmin, xmax, shear, adjbot){
 705   hull(){
 706     StorageArmDiagPartSide(xmin,xmax);
 707
 708     multmatrix([[1,0,0,0],
 709                 [shear,1,0,0],
 710                 [0,0,1,0],
 711                 [0,0,0,1]])
 712       translate([0, -storarm_axlerad*2 + adjbot, 0])
 713       mirror([0,1,0])
 714       StorageArmDiagPartSide(xmin,xmax);
 715   }
 716 }
 717
 718 module StorageArmBaseTemplate(){
 719   square([storarm_base_w, storarm_base_h]);
 720 }
 721
 722 module StorageArmAtMountingHoles(){
 723   bes = storarm_besides_hole + storarm_screw_hole;
 724
 725   x0 = bes;
 726   x1 = storarm_base_w-bes;
 727   y1 = storarm_base_h - bes;
 728   y0 = bes;
 729
 730   for (pos=[ [x0, y1],
 731              [x1, y1],
 732              [x1, y0] ]) {
 733     rotate([0,90,0])
 734       translate([pos[0] - storarm_base_w,
 735                  pos[1] - storarm_base_off_y, -storarm_base_d])
 736       children();
 737   }
 738 }
 739
 740 module StorageArmRight(){ ////toplevel
 741   shear = storarm_hookheight / (storarm_mainlen/2);
 742
 743   StorageArmDiagPart(-1, storarm_mainlen/2+1, shear, 0);
 744   StorageArmDiagPart(storarm_mainlen/2-1, storarm_mainlen+1, shear/2,
 745                      storarm_hookheight/2);
 746
 747   translate([0, storarm_hookheight, 0])
 748     StorageArmDiagPart(storarm_mainlen, storarm_totlen,
 749                        shear/2, -storarm_hookheight/2);
 750
 751   difference(){
 752     union(){
 753       hull(){
 754         translate([-storarm_base_d, -storarm_base_off_y, storarm_base_w])
 755           rotate([0,90,0])
 756           linear_extrude(height=storarm_base_mind)
 757           StorageArmBaseTemplate();
 758         StorageArmDiagPart(-1, 0, shear, 0);
 759       }
 760       StorageArmAtMountingHoles(){
 761         cylinder(r= storarm_screw_hole_head/2,
 762                  h=10);
 763       }
 764     }
 765     StorageArmAtMountingHoles(){
 766       translate([0,0,-1])
 767         cylinder(r= (storarm_screw_hole + storarm_screw_hole_slop)/2 ,
 768                  h=20);
 769       translate([0,0,storarm_under_hole])
 770         cylinder(r= (storarm_screw_hole_head + storarm_screw_hole_head_slop)/2,
 771                  h=20);
 772     }
 773   }
 774 }
 775
 776 module StorageArmLeft(){ ////toplevel
 777   mirror([1,0,0]) StorageArmRight();
 778 }
 779
 780 module StorArmHoleTest(){ ////toplevel
 781   sz = storarm_screw_hole_head + storarm_besides_hole*2;
 782   intersection(){
 783     StorageArmRight();
 784     translate([-50, -storarm_base_off_y, -1])
 785       cube([100, sz, sz+1]);
 786   }
 787 }
 788
 789
 790 //----- filament guide spacer -----
 791
 792 guide_armdia = 15.0;
 793 guide_armwidth = 10.2;
 794 guide_armcorelen = 25.0;
 795 guide_clipcirclethick = 10.0;
 796
 797 guidefilclip_outerdia = 22.8;
 798
 799 guidespacer_armslop = 0.75;
 800 guidespacer_armlenslop = 1.05;
 801
 802 guidespacer_prongprotrude = 4;
 803 guidespacer_thick = 1.6;
 804
 805 // calculated
 806
 807 guidespacer_armdia = guide_armdia + guidespacer_armslop;
 808 guidespacer_armwidth = guide_armwidth + guidespacer_armslop;
 809 guidespacer_len = guide_armcorelen - guide_clipcirclethick
 810   + guidespacer_armlenslop;
 811
 812 guidespacer_wingheight = (guidefilclip_outerdia - guidespacer_armdia)/2;
 813
 814 module FilamentGuideArmTemplate(extra=0){
 815   intersection(){
 816     circle(r= (guidespacer_armdia/2) + extra);
 817     square(center=true, [guidespacer_armwidth+extra*2,
 818                          guidespacer_armdia + extra*2 + 10]);
 819   }
 820 }
 821
 822 module FilamentGuideSpacerInnerTemplate(){
 823   FilamentGuideArmTemplate();
 824   translate([0, -guidespacer_armdia/2])
 825     square(center=true, [guidespacer_armwidth - guidespacer_prongprotrude,
 826                          guidespacer_armdia]);
 827 }
 828
 829 module FilamentGuideSpacer(){ ////toplevel
 830   difference(){
 831     union(){
 832       linear_extrude(height= guidespacer_len)
 833         FilamentGuideArmTemplate(extra= guidespacer_thick);
 834       for (angle=[26, 60]) {
 835         for (m=[0,1]) {
 836           mirror([m,0,0]) {
 837             rotate([0,0,angle]) {
 838               hull(){
 839                 for (t=[[0, guidespacer_wingheight],
 840                         [guidespacer_len-1, -guidespacer_wingheight]])
 841                   translate([0,0, t[0] + 0.5])
 842                     cube([guidespacer_thick, guidespacer_armdia + t[1]*2,
 843                       1],
 844                          center=true);
 845               }
 846             }
 847           }
 848         }
 849       }
 850     }
 851     translate([0,0,-1])
 852       linear_extrude(height= guidespacer_len+5)
 853       FilamentGuideSpacerInnerTemplate();
 854   }
 855 }
 856
 857
 858 //----- replacement filament guide arm for TAZ-5 -----
 859
 860 guidearm_armslop = 0.25;
 861 guidearm_armlenslop = 0.25;
 862
 863 guidearm_hookprotr = 3;
 864 guidearm_hookprotrflat = 1;
 865 guidearm_hookslope = 0.3;
 866
 867 guidearm_totallen = 60;
 868
 869 guidearm_screwplatesz = 12;
 870 guidearm_screwplateth = 4;
 871 guidearm_screwplatewd = 15;
 872 guidearm_screwhole = 5 + 0.5;
 873
 874 guidearm_bendlen = 40;
 875 guidearm_bendslot = 4.5;
 876
 877 guidearm_stopthick = 4;
 878 guidearm_protrslop = 1.0;
 879
 880 // calculated
 881
 882 guidearm_armdia = guide_armdia - guidearm_armslop;
 883 guidearm_armwidth = guide_armwidth - guidearm_armslop;
 884 guidearm_armcorelen = guide_armcorelen + guidearm_armlenslop;
 885
 886 guidearm_base_z0 = -(guidearm_totallen - guidearm_armcorelen);
 887
 888 guidearm_realbendlen = min(guidearm_bendlen,
 889                            guidearm_totallen - guidearm_screwplateth - 0.1);
 890 guidearm_slopelen = guidearm_hookprotr/guidearm_hookslope;
 891
 892 module FilamentGuideArmStop(h){
 893   for (ts=[-1,+1]) {
 894     translate([ts * guidearm_hookprotr, 0,0])
 895       cylinder(r=guidearm_armdia/2, h, $fn=80);
 896   }
 897 }
 898
 899 module FilamentGuideArmShaftPositive(){
 900   r = guidearm_armdia/2;
 901
 902   translate([0,0, guidearm_base_z0+1])
 903     cylinder(r=r, h= guidearm_totallen, $fn=80);
 904   translate([0,0, guidearm_armcorelen]){
 905     hull(){
 906       FilamentGuideArmStop(guidearm_hookprotrflat);
 907       translate([0,0, guidearm_slopelen])
 908         cylinder(r=r, h=guidearm_hookprotrflat, $fn=80);
 909     }
 910   }
 911   mirror([0,0,1])
 912     FilamentGuideArmStop(guidearm_stopthick);
 913 }
 914
 915 module FilamentGuideArmBase(){
 916   translate([0,
 917              (guidearm_screwplatewd - guidearm_armwidth)/2,
 918              guidearm_base_z0]){
 919     difference(){
 920       translate([0,0, guidearm_screwplateth/2])
 921         cube(center=true,
 922              [guidearm_armdia + guidearm_screwplatesz*2,
 923               guidearm_screwplatewd,
 924               guidearm_screwplateth]);
 925       for (ts=[-1,+1]) {
 926         translate([ts * (guidearm_armdia/2 + guidearm_screwplatesz/2),
 927                    0,
 928                    -20])
 929           cylinder(r= guidearm_screwhole/2, h=40, $fn=20);
 930       }
 931     }
 932   }
 933 }
 934
 935 module FilamentGuideArm(){ ///toplevel
 936   intersection(){
 937     difference(){
 938       FilamentGuideArmShaftPositive();
 939       translate([-guidearm_bendslot/2,
 940                  -50,
 941                  -guidearm_realbendlen + guidearm_armcorelen])
 942         cube([guidearm_bendslot,
 943               100,
 944               guidearm_realbendlen + 100]);
 945       hull(){
 946         for (zx=[ [ 0, guidearm_bendslot ],
 947                   [ guidearm_armcorelen + guidearm_slopelen,
 948                     guidearm_hookprotr*2 + guidearm_protrslop ]
 949                   ]) {
 950           translate([-zx[1]/2, -50, zx[0]])
 951           cube([zx[1], 100, 1]);
 952         }
 953       }
 954     }
 955     cube(center=true,
 956          [guidearm_armdia*2,
 957           guidearm_armwidth,
 958           guidearm_totallen*3]);
 959   }
 960   FilamentGuideArmBase();
 961 }
 962
 963 module FilamentGuideArmPrint(){ ////toplevel
 964   rotate([90,0,0])
 965     FilamentGuideArm();
 966 }
 967
 968 module Demo(){ ////toplevel
 969   translate([-real_exteffrad,-20,0]) Hub();
 970   ArmEnd();
 971   translate([ratchettooth*2, 30, 0]) FilamentCup();
 972   if (selsz(true,false,false)) {
 973     translate([-exteffrad + hubeffrad - hub_clip_baseextend, -10, 0])
 974       ArmExtender();
 975   }
 976 }
 977
 978 //ArmEnd();
 979 //FilamentCup();
 980 //FilamentCupPair();
 981 //CupSecuringClip();
 982 //Hub();
 983 //ArmExtender();
 984 //Axle();
 985 //AxleWasher();
 986 //AxlePin();
 987 //AxleFrictionWasher();
 988 //StorageArmLeft();
 989 //StorArmHoleTest();
 990 //FilamentGuideSpacer();
 991 //FilamentGuideArm();
 992 //FilamentGuideArmPrint();
 993 //Demo();