fairphone4-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.86, 162.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 0;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 7.0; // actuall 8.mumble, but smaller is fine
 146 phone_rim_depth = 0.01; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 11.25;
 151
 152 // xxx this is all wrong
 153
 154 camera_pos_tl = [  7.350,  7.500 ]; // from tl corner (as seen from back)
 155 camera_edge_rad = 9.0;
 156 camera_sz = 32.92;
 157
 158 // this is disabled, FP4 doesn't have one
 159 jack_pos = [ 13.83, 8.485 ];
 160 jack_dia = 10.64 + .5; // some jack I had lying around
 161
 162 // this led stuff, is irrelevant, we have disabled it as it doesn't have one
 163 led_pos = []; // [ 13.98, 10.00 ];
 164 led_aperture = 9;
 165 led_window_ledge = 0.75; // each side
 166
 167 noisecancelmic_pos = [ 15.08, 4.35 ];   // from rhs, from top edge
 168 noisecancelmic_dia = 4.00;
 169
 170 mainmic_pos = [ 21.0, 4.35 ];   // from lhs, from top edge
 171 mainmic_dia = 4.00;
 172
 173 lhshole_pos = [ phone[1]/2, 4.35 ];
 174
 175 // fingerpushhole_dias = [];
 176 fingerpushhole_dias = [ 15, 18 ]; // this is for testing
 177
 178 lanyard_half_dia = 1.15;
 179 lanyard_entry_rel_breadth = 2;
 180 lanyard_channel_len = 8;
 181 //rearspeaker_pos_bl = [ 12.64, 18.72 ];
 182 //rearspeaker_size   = [  3.76,  7.36 ];
 183
 184 bottomspeaker_size = [ 11.35, 1.40 ] + [1,1] * 0.5;
 185 bottomspeaker_pos = [ 19.45, 4.82 ];
 186
 187 microusb_above = 1.64 - 0.25;
 188 microusb_below = 2.42;
 189 microusb_width = 12.16 + 2.0 + 1.25;
 190
 191 case_th_bottom = 2.5;
 192 case_th_lid = 3.0;
 193 case_th_side = 2.3;
 194 case_th_lip = 1.2;
 195
 196 lid_screen_gap_extra = .66;
 197
 198 case_struts_count = 6;
 199 case_struts_solid_below = 1.00;
 200 case_struts_solid_above = 0.75;
 201 case_struts_width = 0.10;
 202
 203 keeper_th_z = 0.75;
 204 keeper_th_x = 0.75;
 205 keeper_inner_width = 2.75;
 206 keeper_inner_height = 2.75;
 207 keeper_slant_slope = 2; // larger means steeper
 208
 209 keeper_gap_z_top = 0.25;
 210 keeper_gap_z_bot = 0.75;
 211 keeper_gap_x     = 0.25;
 212 keeper_gap_x_holes = 0.75;
 213
 214 keeper_side = 0; // 0 = lhs; 1 = rhs
 215
 216 case_lip = 1.25;
 217
 218 lid_gap_x = 0.25;
 219 lid_gap_z = 0.25;
 220 lid_lip = 1.75;
 221 lid_edgepart_width = 5.0;
 222 lid_buttoncover_thick = 1.3;
 223 lid_buttoncover_reinf = 0.65;
 224
 225 foldover_gap = 0.50;
 226 foldover_lever_gap = 0.50;
 227
 228 // xxx replace hinge screw with nail plan
 229
 230 // properties of the hinge fasteners
 231 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 232 hingescrew_shaft_len = 12;
 233 hingescrew_fasteners_extra_thick = 0.40;
 234 // ^ amount of thread protruding if everything was completely nominal
 235 //   and we are using two nuts
 236 hingescrew_nut_access_dia = 4.72 + 0.50;
 237 // ^ washer is 4.72 dia
 238 //   also, want to get pliers or tiny spanner in to do up locknut
 239 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 240 hingescrew_nut_thick = 1.93;
 241 hingescrew_head_th = 1.38 + 0.75;
 242 hingescrew_head_dia = 3.92;
 243
 244 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 245
 246 lever_cover_th = 0.75;
 247 hingemount_th = 2.5;
 248 hingemount_wd = 4.8725;
 249
 250 $fa = 5;
 251 $fs = 0.1;
 252
 253 button_l_fudge = 4.4;
 254 buttonishleg_default_l_is_fudge = 10;
 255
 256 hinge_base_slope = 1.5; // bigger is steeper
 257
 258 strut_min_at_end = 1.5;
 259
 260 hinge_x_gap = 0.125;
 261 hinge_x_postscrew_gap = 0.75;
 262 hinge_x_arms_gap = 0.35;
 263 hinge_r_arms_gap = 0.55;
 264 hinge_over_nut_plate = 1.0;
 265
 266 // there isn't one of these, speaker is by hinge
 267 // rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 268
 269 thumbrecess_depth = 1.3;
 270 thumbrecess_width = 16.5;
 271 thumbrecess_topcurve_r = 5.0;
 272
 273 prop_recess_under = 0.50;
 274 prop_recess_slop = 0.200; // each side
 275 prop_end_dia = 0.5;
 276 prop_main_th = 3;
 277 prop_taper_len = 6;
 278 prop_main_width = 4;
 279 prop_side_gap = 0.75; // each side
 280 prop_lidrecess_behind = 0.75;
 281 prop_caserecess_behind = 0.75;
 282 prop_caserecess_taper = 0.45; // one side only
 283 prop_prop_gap = 0.5;
 284 prop_prong_heel_slope = 0.5;
 285
 286 lid_fold_clearance_antislop = 0.5;
 287
 288 $button_leg_only = false;
 289 $suppress_forward_holes = false;
 290
 291 // ---------- calculated ----------
 292
 293 phone_total_thick = phone_edge_thick;
 294
 295 phone_width =  (phone + bumper*2)[0];
 296 phone_height = (phone + bumper*2)[1];
 297
 298 inside_br = [phone_width, -phone_height];
 299
 300 prop_prong_h = prop_main_th;
 301
 302 //echo(camera_pos_tl + bumper,
 303 //     camera_pos_br + bumper);
 304
 305 // ----- could be changed -----
 306 lid_buttoncover_gap = lid_gap_x;
 307 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 308
 309 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 310
 311 //prop_nose_len = case_th_lid - prop_recess_under;
 312 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 313 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 314
 315
 316 //lid_lip_overlap_width xxx bad name = ;
 317 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 318
 319 epp0 = [0,0];
 320 epp1 = [0, -phone_edge_thick];
 321 epp2i = epp1; // conflated for FP4
 322 epp2o = epp2i;
 323 epp3 = epp2i + [10, 0];
 324 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 325 epp4 = epp5 + [-1,0] * case_th_side;
 326
 327 kppe = [0,0];
 328 kppd = kppe + [1,0] * keeper_inner_width;
 329 kppc = kppd + [0,1] * keeper_th_z;
 330 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 331 kppf = kppe - [0,1] * keeper_inner_height;
 332 kppa = [ kppb[0], kppf[1] ];
 333
 334 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 335 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 336
 337 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 338 // exact x posn not very important; must extend past end of keeper
 339
 340 lpp15 = [ lpp14[0],
 341           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 342           + lid_screen_gap_extra ];
 343 // ^ beam theory says to maximise force before contact,
 344 //   the gap below the `beam' (the lid) must be 1/3
 345 //   the thickness (ie the lid thickness) if the beam
 346 //   is solid, or 1/2 if it has a top and bottom only.
 347 //   ours is mostly solid.
 348
 349 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 350              case_th_lip);
 351
 352 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 353 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 354
 355 case_bottom_z = epp2o[1] - case_th_bottom;
 356
 357 // button profile
 358 bppM = epp4 + [0,5];
 359 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 360 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 361 bppS = [ epp1[0], bppR[1] ];
 362 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 363 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 364 bppO = [ bppN[0], bppP[1] ];
 365 bppL = lpp10 + [5,0];
 366 bppK = [ bppL[0], bppN[1] ];
 367 bppJ = [ bppN[0], bppL[1] ];
 368 bppU = [ bppJ[0], lpp12[1] ];
 369 bppV = lpp11;
 370 bppW = lpp10;
 371
 372 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 373
 374 // notification led aperture
 375
 376 nla_r0 = led_aperture/2;
 377 nla_r1 = nla_r0 + led_window_ledge;
 378 nla_r2 = nla_r1 + multicolour_gap;
 379 nla_t =
 380   led_window_style >= 3 ? initial_layer_thick :
 381   led_window_style >= 2 ? led_window_ledge : 0;
 382
 383
 384 // hinge plan
 385 hp_rn = hingescrew_nut_access_dia/2;
 386 hp_r2_min = hp_rn + lever_cover_th;
 387 hp_rs = hingescrew_shaft_dia/2;
 388 hp_r1_min = hp_rs + hingemount_th;
 389
 390 hp_r1 = max(hp_r1_min, hp_r2_min);
 391 hp_r2 = hp_r1;
 392
 393 hppU = lpp13;
 394 hppS = epp2o + [0,-1] * case_th_bottom;
 395 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 396
 397 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 398          0.5 * (hppU + hppS)[1] ];
 399 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 400 hppB = hppT + [0,-1] * hp_k;
 401
 402 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 403 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 404 hppE = [ hppE_x, hppE_y ];
 405
 406 // hinge elevation x coords
 407
 408 hex20 = max(epp2o[0],
 409             phone_cnr_rad,
 410             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 411 hex21 = hex20 + hingemount_wd;
 412 hex22 = hex21 + hinge_x_gap;
 413 hex27 = hex20 + hingescrew_shaft_len;
 414 hex24 = hex27 + hinge_x_postscrew_gap;
 415 hex23 = hex27 - (hingescrew_nut_thick*2
 416                  + hingescrew_fasteners_extra_thick);
 417 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 418
 419 echo(hex20, hex21, hex22, hex23, hex24);
 420 //  6, 10.8725, 10.9975, 13.74, 18.75
 421 module chk(act,exp) {
 422   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 423   else echo("ok", act);
 424 }
 425 chk(hex20, 6);
 426 chk(hex21, 10.8725);
 427 chk(hex22, 10.9975);
 428 chk(hex23, 13.74);
 429 chk(hex24, 18.75);
 430
 431 lid_fold_clearance_skew =
 432   (lpp10[1] - hppB[1]) /
 433   (lpp10[0] - hppB[0]);
 434
 435 echo("SK",lid_fold_clearance_skew);
 436
 437 // thumb recess (used to be "catch" hence cpp*
 438
 439 cppA = epp4 + [thumbrecess_depth, 0];
 440 cppB = [ cppA[0], epp1[1] ];
 441
 442 // lanyard
 443
 444 ly_r = lanyard_half_dia / 2;
 445 ly_rc = ly_r * 2;
 446
 447 ly_theta = 90;
 448 ly_o = epp2i + 3 * ly_r * [0,1];
 449
 450 max_case_bottom_edge_thickness =
 451   case_th_bottom;
 452
 453 ly_q_z = -(ly_rc + ly_r);
 454 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 455
 456 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 457
 458 // prop recess in case
 459
 460 prop_x_pos = phone_width/2;
 461
 462 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 463
 464 prc_r1 = prop_end_dia/2;
 465 prc_r3 = prc_r1 + prop_recess_slop;
 466
 467 prcp2 = [ epp4[0] + prop_buildout_less,
 468           case_bottom_z ];
 469
 470 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 471
 472 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 473           epp2i[1] - prc_r3 - prop_recess_under];
 474
 475 // prop recess in lid
 476
 477 prl_r10 = prop_end_dia/2;
 478 prl_r10o = prl_r10 + prop_recess_slop;
 479
 480 prlp10 = lpp10 + [1,1] * prl_r10o
 481   + [1,0] * prop_lidrecess_behind
 482   + [0,1] * prop_recess_under;
 483
 484 // prop
 485
 486 $prpp10 = [0,0];
 487 $prpp11 = [0, prop_taper_len];
 488
 489 $prp_r10 = prl_r10;
 490
 491 // ---------- modules ----------
 492
 493 module AdhocMultiprintFrame(phase, z0, zs) {
 494   // from z0 to z0 + zs*layer
 495   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 496   xextra = extra + -epp4[0];
 497   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 498   yextra = extra + -epp4[0];
 499   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 500   p0 = [ xrange[0], yrange[0] ];
 501   p1 = [ xrange[1], yrange[1] ];
 502   echo(p0, p1);
 503   translate([0,0, z0])
 504     mirror([0,0, zs<0 ? 1 : 0])
 505     linear_extrude(height= initial_layer_thick)
 506     difference(){
 507       rectfromto(p0 - [1,1] * initial_layer_width,
 508                  p1 + [1,1] * initial_layer_width);
 509       rectfromto(p0, p1);
 510     }
 511 }
 512
 513 module KeeperProfile(slant=0){
 514   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 515   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 516 }
 517
 518 module EdgeProfile(){
 519   difference(){
 520     hull(){
 521       translate(epp3) square(case_th_bottom*2, center=true);
 522       circleat(epp2o, r=case_th_bottom);
 523       circleat(epp1, r=case_th_side);
 524       rectfromto(epp0, epp4);
 525     }
 526     polygon([ epp5 + [0,10],
 527               epp1,
 528               epp3 + [10,0] ]);
 529   }
 530 }
 531
 532 module LanyardLanyardProfile(entry=false){
 533   hull(){
 534     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 535       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 536         circle(r= lanyard_half_dia/2);
 537   }
 538 }
 539
 540 module LanyardCurveChannelProfile(){
 541   translate([0, -ly_r])
 542     LanyardLanyardProfile();
 543 }
 544
 545 module LanyardEntryChannelProfile(){
 546   LanyardLanyardProfile(true);
 547 }
 548
 549 module LanyardMainChannelProfile(){
 550   LanyardCurveChannelProfile();
 551   difference(){
 552     square(center=true, ly_r * [6, 2]);
 553     for (xs=[-1,+1])
 554       translate(ly_r * [3 * xs, -1])
 555         circle(r = ly_r);
 556   }
 557 }
 558
 559 module LanyardEntryOuterProfile(){
 560   circleat([ly_re + ly_r, 0], ly_re);
 561 }
 562
 563 module LanyardEntry(){
 564   q_z = ly_q_z;
 565   oec_y = ly_oec_y;
 566
 567   d_x = -ly_rc;
 568
 569   translate([d_x, 0, q_z]) {
 570     intersection(){
 571       rotate([90,0,0])
 572         rotate_extrude(convexity=10)
 573         rotate(90)
 574         translate([0, -q_z])
 575         LanyardCurveChannelProfile();
 576       translate([0,-10,0])
 577         cube([20,20,20]);
 578     }
 579   }
 580
 581   mirror([0,0,1])
 582     translate([0,0,-1])
 583     linear_extrude(height=20)
 584     rotate(-90)
 585     LanyardEntryChannelProfile();
 586
 587   translate([0, ly_r*2, 0])
 588     rotate([90,0,0])
 589     linear_extrude(height = ly_r*4){
 590     difference(){
 591       rectfromto([d_x, q_z], [ly_r, 0]);
 592       circleat([d_x, q_z], ly_rc);
 593     }
 594   }
 595
 596   translate([0,0,q_z]){
 597     for (my=[0,1])
 598       mirror([0,my,0]){
 599         translate([0, oec_y, 0]){
 600           difference(){
 601             translate(ly_re * [-1,0,-2])
 602               cube(ly_re * [2,1,2]);
 603             rotate_extrude(convexity=10)
 604               LanyardEntryOuterProfile();
 605           }
 606         }
 607       }
 608     difference(){
 609       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 610         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 611       for (mx=[0,1])
 612         mirror([mx,0,0])
 613           rotate([90,0,0])
 614           translate([0,0,-10])
 615           linear_extrude(height=20)
 616           LanyardEntryOuterProfile();
 617     }
 618   }
 619 }
 620
 621 module LanyardCutout(l){
 622   rotate([0,-90,0])
 623     linear_extrude(height=l)
 624     rotate(-90)
 625     LanyardMainChannelProfile();
 626
 627   for (ee=[0,1]){
 628     translate(ee * l * [-1,0])
 629       mirror([ee,0,0])
 630       LanyardEntry();
 631   }
 632 }
 633
 634 module LidEdgeProfile(){
 635   polygon([ lpp10,
 636             lpp11,
 637             lpp12,
 638             lpp13,
 639             lpp13 + [10, 0],
 640             lpp15 + [10, 0],
 641             lpp15,
 642             lpp14,
 643             ]);
 644   intersection(){
 645     circleat(lpp12, r=lp_r12);
 646     rectfromto( lpp12 + [-10,   0],
 647                 lpp12 + [+10, +10] );
 648   }
 649 }
 650
 651 module LidEdgeFoldClearanceProfile(){
 652   translate([-lid_fold_clearance_antislop, 0])
 653     polygon([ lpp10,
 654               lpp11,
 655               lpp11 + [-20,  0],
 656               lpp11 + [-20, 20],
 657               lpp11 + [+20, 20],
 658               lpp10 + [+20,  0] ]);
 659 }
 660
 661 module ButtonCoverProfile(){
 662   intersection(){
 663     polygon(concat([ bppM, bppP, bppO, bppJ ],
 664                    (enable_support && !$button_suppress_over_keeper
 665                     ? [ bppU, bppV, bppW ] : []),
 666                    [ bppL, bppK ]));
 667     hull(){
 668       EdgeProfile();
 669       LidEdgeProfile();
 670     }
 671   }
 672 }
 673
 674 module ButtonPlan(l, deep, cut){
 675   epsilon =
 676     (cut  ? 0 : lid_buttoncover_gap);
 677
 678   delta =
 679     (deep ? lid_buttoncover_overlap : 0);
 680
 681   C = [0,0]; // by definition
 682   T = [ 0, epp4[1] ];
 683   G = T + [0,10];
 684
 685   B0 = C + [0,-1] * button_cutout_depth;
 686   B1 = B0 + [0,1] * epsilon;
 687
 688   r0 = 0.5 * (T[1] - B0[1]);
 689   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 690   H = A + [0,-1] * delta;
 691
 692   D = A + [-2,0] * r0;
 693   F = D + [0,10];
 694
 695   E0 = 0.5 * (D + A);
 696   E1 = E0 + [1,0] * epsilon;
 697
 698   I0 = [ E0[0], H[1] ];
 699   I1 = [ E1[0], H[1] ];
 700
 701   hull(){
 702     for (m=[0,1]) mirror([m,0])
 703       circleat(H, r0 - epsilon);
 704   }
 705   for (m=[0,1]) mirror([m,0]) {
 706     difference(){
 707       polygon([ E1,
 708                 I1,
 709                 H,
 710                 B1,
 711                 G,
 712                 F,
 713                 D
 714                 ]);
 715       circleat(D, r0 + epsilon);
 716     }
 717   }
 718 }
 719
 720 module ButtonCoverReinf(){ ////toplevel
 721   minkowski(){
 722     rotate([90,0,0])
 723       linear_extrude(height=0.01)
 724       intersection(){
 725         ButtonCoverProfile();
 726         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 727           square([100,100]);
 728     }
 729     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 730       circle(r= lid_buttoncover_reinf);
 731       translate([-20,0]) square(40, center=true);
 732     }
 733   }
 734 }
 735
 736 module ThumbRecessCutProfile(){
 737   difference(){
 738     polygon([ cppA + [-10,0],
 739               cppB + [-10,0],
 740               cppB,
 741               cppA ]);
 742     circleat(epp1, r=case_th_side);
 743   }
 744 }
 745
 746 module Flip_rhs(yn=[0,1]) {
 747   for ($rhsflip=yn) {
 748     translate([phone_width/2, 0, 0])
 749       mirror([$rhsflip,0,0])
 750       translate([-phone_width/2, 0, 0])
 751       children();
 752   }
 753 }
 754
 755 module Flip_bot(yn=[0,1]) {
 756   for ($botflip=yn) {
 757     translate([0, -phone_height/2, 0])
 758       mirror([0, $botflip, 0])
 759       translate([0, phone_height/2, 0])
 760       children();
 761   }
 762 }
 763
 764 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 765   // sides
 766   Flip_rhs(){
 767     translate([0, -phone_cnr_rad, 0])
 768       rotate([90,0,0])
 769       linear_extrude(height = phone_height - phone_cnr_rad*2)
 770       children(0);
 771   }
 772   // corners
 773   Flip_rhs() Flip_bot() {
 774     translate([+1,-1] * phone_cnr_rad)
 775       intersection(){
 776         rotate_extrude()
 777           intersection(){
 778             mirror([1,0,0])
 779               translate([-1,0] * phone_cnr_rad)
 780               children(0);
 781             rectfromto([0,-20],[10,20]);
 782           }
 783         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 784           cube([10,10,40]);
 785       }
 786   }
 787   // top and bottom
 788   Flip_bot(){
 789     translate([ phone_width - phone_cnr_rad, 0,0 ])
 790       rotate([90,0,-90])
 791       linear_extrude(height = phone_width - phone_cnr_rad*2)
 792       children(0);
 793   }
 794   // fill
 795   translate([0,0, fill_zstart])
 796     mirror([0,0, fill_downwards])
 797     linear_extrude(height = fill_th)
 798     rectfromto([+1,-1] * phone_cnr_rad,
 799                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 800 }
 801
 802 module CaseAperture(pos, dia, $fn, topbottom=0) {
 803   theta = 180/$fn;
 804   translate([ bumper[0],
 805               -epp2i[0],
 806                0 ])
 807     rotate([0,0, 90*topbottom])
 808     translate([ pos[0] * (topbottom>0 ? -1 : +1), 0, -pos[1] ])
 809     rotate([-90, theta, 0])
 810     cylinder(r = dia/2 / cos(theta),
 811              h = 60);
 812 }
 813
 814 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 815   // y_ref_sign:
 816   //   +1  measured from top    of actual phone to top    of button
 817   //   -1  measured from bottom of actual phone to bottom of button
 818   //    0  y is centre of button in coordinate system
 819   $button_l= l;
 820   $button_suppress_over_keeper= suppress_over_keeper;
 821   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 822           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 823           y;
 824   //echo(eff_y);
 825   translate([0, eff_y, 0])
 826     children();
 827 }
 828
 829 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 830   $button_leg_only = true;
 831   SideButton(y, y_ref_sign, l) children();
 832 }
 833
 834 module Buttons(){
 835   Flip_rhs(1) SideButton(30.320, +1, 22.960  ) children(); // volume
 836   Flip_rhs(1) SideButton(64.220, +1, 14.500  ) children(); // power
 837   Flip_rhs(1) LidButtonishLeg(14, -1) children();
 838   Flip_rhs(0) LidButtonishLeg(21, -1) children();
 839   Flip_rhs(0) LidButtonishLeg(14, +1) children();
 840   // xxx need hole for whatever that hole is on lhs
 841 }
 842
 843 module Struts(x_start, z_min, th){
 844   // if th is negative, starts at z_min and works towards -ve z
 845   // and object should then be printed other way up
 846   for (i= [1 : 1 : case_struts_count]) {
 847     translate([0,
 848                0,
 849                z_min])
 850       mirror([0,0, th<0 ? 1 : 0])
 851       translate([0,
 852                  -phone_height * i / (case_struts_count+1),
 853                  case_struts_solid_below])
 854       linear_extrude(height= abs(th)
 855                      -(case_struts_solid_below+case_struts_solid_above))
 856       rectfromto([               x_start, -0.5 * case_struts_width ],
 857                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 858   }
 859 }
 860
 861 module OrdinaryRearAperture(rhs,bot, pos){
 862   Flip_rhs(rhs) Flip_bot(bot)
 863     linextr(-20, 20)
 864     mirror([0,1])
 865     translate(pos + bumper)
 866     children();
 867 }
 868
 869 module MicroUSBEtc(){
 870   Flip_bot(1){
 871     rotate([90,0,0])
 872       mirror([0,0,1])
 873       linextr(-epp2i[0], 60)
 874       translate([0.5 * phone_width, 0, 0])
 875       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 876                  [+microusb_width/2, epp0[1] + -microusb_above]);
 877   }
 878 }
 879
 880 module OrdinaryBottomEdgeApertures(){
 881   Flip_bot(1)
 882     CaseAperture(mainmic_pos, mainmic_dia, 8);
 883
 884   Flip_bot(1) Flip_rhs(1) {
 885     linextr_y_xz(-epp2i[0], 60)
 886       hull()
 887       for (x= [-1,+1]) {
 888         translate([ -bottomspeaker_pos[0], -bottomspeaker_pos[1] ] +
 889                   [ 0.5 * x * bottomspeaker_size[0] - bottomspeaker_size[1],
 890                     0 ])
 891           rotate(360/16)
 892           circle(r = bottomspeaker_size[1], $fn = 8);
 893       }
 894   }
 895 }
 896
 897 module OrdinaryRearApertures(){
 898   // rear speaker
 899   //  OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 900   //    rectfromto(-rearspeaker_gap,
 901   //           rearspeaker_size + rearspeaker_gap);
 902
 903   RearCameraAperture();
 904 }
 905
 906 module NotInTestFrameRearApertures(){
 907   // finger hole to remove phone
 908   if (len(fingerpushhole_dias))
 909     OrdinaryRearAperture(0,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 910                                 phone[1]/2 ])
 911     scale(fingerpushhole_dias)
 912     circle(r= 0.5 );
 913 }
 914
 915 module RearCameraAperture(){
 916   %Flip_rhs(1)
 917     mirror([0, 0, 1])
 918     translate([0,0,0])
 919     linear_extrude(height = 20)
 920     mirror([0, 1, 0])
 921     translate(bumper)
 922     translate(camera_pos_tl)
 923     hull(){
 924       for (xy = [ [0,0], [0,1], [1,0] ]) {
 925         translate(
 926             camera_edge_rad * [1,1] +
 927             xy * (camera_sz - camera_edge_rad * 2)
 928                   )
 929           circle(r = camera_edge_rad);
 930       }
 931     }
 932 }
 933
 934 module HingeLidProfile(){
 935   hull(){
 936     circleat(hppT, hp_r1);
 937     circleat(lpp12, lp_r12);
 938     polygon([lpp10,
 939              lpp13 + [2,0],
 940              lpp12,
 941              hppT]);
 942   }
 943 }
 944
 945 module HingeBaseProfile(){
 946   difference(){
 947     hull(){
 948       circleat(hppB, hp_r1);
 949       circleat(hppE, hp_r1);
 950       circleat(epp2o, case_th_bottom);
 951       circleat(hppB + [10,0], hp_r1);
 952     }
 953     polygon([epp5, epp1, epp3, bppL]);
 954   }
 955 }
 956
 957 module HingeLeverOuterProfile(){
 958   hull(){
 959     circleat(hppT, hp_r2);
 960     circleat(hppB, hp_r2);
 961   }
 962 }
 963
 964 module HingeLeverInnerProfile(){
 965   for (s = [-1,+1]) {
 966     c = s > 0 ? hppT : hppB;
 967     translate(c)
 968       mirror([0,0, s>0 ? 1 : 0])
 969       rotate(s<0 ? -40 : 0)
 970       hull()
 971       for (x=[-20,20])
 972         for (y=[0, s * 10])
 973           translate([x,y])
 974             circle(hp_rn);
 975   }
 976 }
 977
 978 module HingeLeverNutProfile(){
 979   for (c= [hppB, hppT]) {
 980     translate(c)
 981       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 982   }
 983 }
 984
 985 module Flip_hinge(doflip=1){
 986   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 987   translate(hinge_origin)
 988     rotate([doflip*180,0,0])
 989     translate(-hinge_origin)
 990     children();
 991 }
 992
 993 module HingePortion(x0,x1){
 994   Flip_rhs() Flip_bot(1)
 995     translate([x0,0,0])
 996     mirror([1,0,0])
 997     rotate([90,0,-90])
 998     linear_extrude(height=x1-x0)
 999     children();
1000 }
1001
1002 module ThumbRecessApply(ztop){
1003   width = thumbrecess_width;
1004   w = width + thumbrecess_topcurve_r*2 + 1;
1005   translate([phone_width/2, 0,0]){
1006     difference(){
1007       rotate([90,0,-90])
1008         linextr(-w/2, w/2)
1009         children(0);
1010       translate([0, 50, 0])
1011         rotate([90,0,0])
1012         linear_extrude(height=100){
1013         for (m=[0,1]) mirror([m,0,0]) {
1014           hull(){
1015             translate([w/2, ztop - thumbrecess_topcurve_r])
1016               circle(thumbrecess_topcurve_r);
1017             translate([w/2, -50])
1018               square(thumbrecess_topcurve_r*2, center=true);
1019           }
1020         }
1021       }
1022     }
1023   }
1024 }
1025
1026 module CaseBase(){
1027   AroundEdges(epp3[1], case_th_bottom, 1)
1028     EdgeProfile();
1029 }
1030
1031 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
1032
1033 module PropProfileAssignments(gamma){
1034   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
1035   x = prop_x(gamma);
1036   p = phone_height + prlp10[0] - hppB[0];
1037   b = p + x;
1038
1039   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1040   a = q + x;
1041   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1042   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1043
1044   $prp_theta = 90 - $prp_alpha;
1045   beta = 180 - $prp_alpha - gamma;
1046   psi = 90 - beta;
1047
1048   //echo("abc", a,b,c);
1049
1050   v1 = [ [ cos(psi), -sin(psi) ],    // x
1051          [ sin(psi),  cos(psi) ] ];  // y
1052
1053   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1054
1055   $prp_r1 = prc_r1;
1056   $prp_r11 = prop_main_th/2;
1057
1058   $prpp1 = $prpp7 + [1,0] *
1059     // this is approximate, but will do
1060     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1061   $prpp3 = $prpp1 +
1062     v1[0] * -$prp_r1 +
1063     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1064   $prpp12 = $prpp3 + v1[0] *
1065     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1066   $prp_r8 = prop_main_th;
1067   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1068   $prp_r5 = $prp_r8;
1069   $prpp5 = [ $prpp12[0] - $prp_r5,
1070             $prpp3[1] - prop_prong_h + $prp_r5 ];
1071   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1072          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1073   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1074   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1075
1076   children();
1077 }
1078
1079 module PropProfile(gamma, cut=0, rot=0){
1080   PropProfileAssignments(gamma){
1081
1082     //#circleat($prpp3,1);
1083     //#circleat($prpp12,1);
1084
1085     if (!cut) {
1086       hull(){
1087         translate($prpp8)
1088           intersection(){
1089             circle($prp_r8);
1090             polygon([[-20,-0], [20,20], [0,0]]);
1091           }
1092         rectfromto($prpp6, $prpp9);
1093         translate($prpp5) intersection(){
1094           circle($prp_r5);
1095           polygon([[-10,-10], [0,0], [10,0]]);
1096         }
1097         rectfromto($prpp12 + [0,-0.1], $prpp3);
1098       }
1099       hull(){
1100         circleat($prpp1, $prp_r1);
1101         rectfromto($prpp12 + [0,-0.1], $prpp3);
1102       }
1103     }
1104     // main shaft
1105     rotate([0,0, rot*-$prp_theta]){
1106       hull(){
1107         extra = cut ? prop_recess_slop : 0;
1108         rectfromto($prpp6, $prpp9);
1109         circleat($prpp11, $prp_r11 + extra);
1110         circleat($prpp10, $prp_r10 + extra);
1111       }
1112     }
1113   }
1114 }
1115
1116 module PropAggregateProfile(){
1117   for (angle = prop_angles)
1118     PropProfile(angle, 0,0);
1119 }
1120
1121 module Prop(){ ////toplevel
1122   hw = prop_main_width/2;
1123   linextr(-hw, +hw)
1124     PropAggregateProfile();
1125 }
1126
1127 module Case(){ ////toplevel
1128   difference(){
1129     union(){
1130       CaseBase();
1131
1132       // ledge (fixed keeper)
1133       Flip_rhs(1-keeper_side) intersection(){
1134         rotate([90, 0, 0])
1135           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1136           KeeperProfile(1);
1137
1138         // outline of the whole case, to stop it protruding
1139         translate([0,0, -25])
1140           linear_extrude(height = 50)
1141           hull()
1142           Flip_bot()
1143           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1144       }
1145
1146       // hinge
1147       HingePortion(hex20, hex21) HingeBaseProfile();
1148
1149       // buildout for prop recess
1150       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1151         linextr(case_bottom_z, epp2i[1])
1152         hull() {
1153           for (dxs = [-1,+1])
1154             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1155                        -epp2o[0] ],
1156                      r = epp2o[0] - prcp2[0]);
1157         }
1158     }
1159
1160     // slot for keeper
1161     Flip_rhs(keeper_side)
1162       translate([0, -phone_cnr_rad, 0])
1163       rotate([90, 0, 0])
1164       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1165       minkowski(){
1166         KeeperProfile();
1167         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1168                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1169       }
1170
1171     // front camera
1172     // RearCameraAperture();
1173     // now in OrdinaryRearApertures
1174
1175     // struts (invisible, because they're buried in the case)
1176     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1177
1178     Buttons(){
1179       mirror([1,0,0])
1180         rotate([90,0,90]) {
1181           if (!($button_leg_only && enable_support))
1182           intersection(){
1183             translate([0,0,-10])
1184               linear_extrude(height= 20)
1185               ButtonPlan($button_l, 0,1);
1186             if ($button_leg_only)
1187               rotate([-90,90,0])
1188                 translate([phone_width/2, -400, kppe[1]])
1189                 mirror([1-abs($rhsflip - keeper_side),0,0])
1190                 cube([400, 800, 50]);
1191             if (enable_support && !$button_suppress_over_keeper)
1192               rotate([-90,90,0])
1193               translate([-400, -400, kppd[1]])
1194                 mirror([0,0,1])
1195                 cube([800,800,100]);
1196           }
1197           translate([0,0, -bppR[0]])
1198             linear_extrude(height= 20)
1199             ButtonPlan($button_l, 1,1);
1200         }
1201
1202     }
1203
1204     // apertures along top edge
1205     if (!$suppress_forward_holes) {
1206       // CaseAperture(jack_pos, jack_dia, 8);
1207       Flip_rhs(1)
1208         CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1209       CaseAperture(lhshole_pos, noisecancelmic_dia, 8, 1);
1210     }
1211
1212     OrdinaryBottomEdgeApertures();
1213
1214     OrdinaryRearApertures();
1215     NotInTestFrameRearApertures();
1216
1217     MicroUSBEtc();
1218
1219     // gaps for the lid's hinge arms
1220     HingePortion(hex20 - hinge_x_arms_gap,
1221                  hex21 + hinge_x_arms_gap)
1222       minkowski(){
1223         HingeLidProfile();
1224         circle(r= hinge_r_arms_gap, $fn= 8);
1225       }
1226
1227     // screw holes in the hinge arms
1228     HingeScrews();
1229
1230     // thumb recess
1231     ThumbRecessApply(epp4[1])
1232       ThumbRecessCutProfile();
1233
1234     // lanyard
1235     Flip_bot(1)
1236       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1237       rotate([0, ly_theta, 0])
1238       rotate([0,0,90])
1239       LanyardCutout(lanyard_channel_len);
1240
1241     // prop recess
1242     Flip_rhs(1)
1243       translate([prop_x_pos,0,0])
1244       mirror([0,1,0])
1245       rotate([90,0,90])
1246       linextr(-prop_recess_hw, +prop_recess_hw)
1247       hull(){
1248         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1249           circleat(prcp1 + 20*d,
1250                    prc_r3);
1251       }
1252   }
1253 }
1254
1255 module LidAdhocMultiprintFrame(phase){
1256   if (led_window_style >= 3) {
1257     AdhocMultiprintFrame(phase, lpp13[1], -1);
1258   }
1259 }
1260
1261 module LidAroundEdges(){
1262   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1263     children();
1264 }
1265
1266 module Lid(){ ////toplevel
1267   skew_centre = [0, lpp11[0], lpp11[1]];
1268   difference(){
1269     union(){
1270       intersection(){
1271         LidAroundEdges()
1272           LidEdgeProfile();
1273
1274         translate(skew_centre)
1275           multmatrix([[ 1, 0, 0, 0 ],
1276                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1277                       [ 0, 0, 1, 0 ],
1278                       [ 0, 0, 0, 1 ]])
1279           translate(-skew_centre)
1280           LidAroundEdges()
1281           LidEdgeFoldClearanceProfile();
1282       }
1283
1284       // button covers
1285       Buttons(){
1286         intersection(){
1287           rotate([90,0,90])
1288             translate([0,0,-10])
1289             linear_extrude(height= 20)
1290             ButtonPlan($button_l, 1,0);
1291           union(){
1292             rotate([90,0,0])
1293               translate([0,0,-100])
1294               linear_extrude(height= 200)
1295               ButtonCoverProfile();
1296             hull()
1297               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1298                                  - lid_buttoncover_reinf))
1299                 translate([0,y,0])
1300                   ButtonCoverReinf();
1301           }
1302         }
1303       }
1304
1305       // hinge arms
1306       HingePortion(hex20, hex21) {
1307         LidEdgeProfile();
1308         HingeLidProfile();
1309       }
1310     }
1311     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1312
1313     // screw holes in the hinge arms
1314     HingeScrews();
1315
1316     // prop recess
1317     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1318       mirror([0,1,0])
1319       rotate([90,0,90])
1320       linextr(-prop_recess_hw, +prop_recess_hw)
1321       hull()
1322       for (pa = prop_angles)
1323         PropProfile(pa, 1,1);
1324
1325     // notification led aperture
1326     if (led_window_style)
1327       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1328         translate([0,0,-10])
1329           cylinder(r=nla_r0, h=20);
1330         if (led_window_style >= 2)
1331           translate([0,0, -nla_t])
1332             cylinder(r=nla_r2, height=20);
1333       }
1334
1335     }
1336
1337   LidAdhocMultiprintFrame(1);
1338 }
1339
1340 module HingeLever(){ ////toplevel
1341   difference() {
1342     // outer body, positive
1343     HingePortion(hex22, hex22 + phone_width/2)
1344       HingeLeverOuterProfile();
1345
1346     // space for the screws
1347     HingePortion(hex26, hex24)
1348       HingeLeverInnerProfile();
1349
1350     // recesses for the nuts
1351     HingePortion(hex23, hex26+1)
1352       HingeLeverNutProfile();
1353
1354     // bores for the screws
1355     HingeScrews();
1356
1357     // space for the charging cable and speaker and micc apertures
1358     hull() {
1359       for (x = [-1,+1]) {
1360         multmatrix([[ 1,0,
1361
1362                      x
1363                      * ( (hex24 + hinge_over_nut_plate) -
1364                          (phone_width/2 - microusb_width/2)
1365                         )
1366                      / ( (epp0[1] - microusb_above)
1367                          -
1368                          (hppB[1] - hp_r2) ),
1369
1370                      x * (epp0[1] - microusb_above)
1371
1372                       ],
1373                     [ 0,1,0, 0 ],
1374                     [ 0,0,1, 0 ]]) {
1375           union(){
1376             MicroUSBEtc();
1377             Flip_hinge() MicroUSBEtc();
1378           }
1379         }
1380       }
1381     }
1382   }
1383 }
1384
1385 module LidWindow(){ ////toplevel
1386   translate([led_pos[0], -led_pos[1], lpp13[1]])
1387     mirror([0,0,1])
1388     cylinder(r= nla_r1, h=nla_t);
1389   LidAdhocMultiprintFrame(0);
1390 }
1391
1392 module LidWindowPrint(){ ////toplevel
1393   rotate([0,180,0])
1394     LidWindow();
1395 }
1396
1397 module DemoLidWindowSelect(){
1398   translate([led_pos[0], led_pos[1], -100]) {
1399     translate([0, -30, 0]) cube([400, 400, 200]);
1400   }
1401 }
1402
1403 module DemoLidWindow(){ ////toplevel
1404   %Lid();
1405   LidWindow();
1406   translate([0,40,0]){
1407     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1408     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1409   }
1410 }
1411
1412 module HingeLeverPrint(){ ////toplevel
1413   rotate([-90,0,0])
1414     translate([-phone_width/2, phone_height, 0])
1415     HingeLever();
1416 }
1417
1418 module TestSelectLength(){
1419   translate([-30, -200, -20])
1420     cube([30 + 15, 250, 40]);
1421 }
1422
1423 module TestLength(){ ////toplevel
1424   intersection(){
1425     Case();
1426     TestSelectLength();
1427   }
1428 }
1429
1430 module TestLengthRight(){ ////toplevel
1431   intersection(){
1432     Case();
1433     Flip_rhs(1)
1434       TestSelectLength();
1435   }
1436 }
1437
1438 module TestSelectWidth(){
1439   translate([-30, -(phone_height - 25), -20])
1440     mirror([0, 1, 0])
1441     cube([200, 50, 40]);
1442 }
1443
1444 module TestWidth(){ ////toplevel
1445   intersection(){
1446     Case();
1447     TestSelectWidth();
1448   }
1449 }
1450
1451 module TestLidWidthPrint(){ ////toplevel
1452   rotate([0,180.0]) intersection(){
1453     Lid();
1454     TestSelectWidth();
1455   }
1456 }
1457
1458 module TestSelectRearAperture(){
1459   minkowski(){
1460     union() children();
1461     translate([20, 0,0])
1462       cube([42, 2, 1], center=true);
1463   }
1464 }
1465
1466 module TestSelectCamera(){
1467   minkowski(){
1468     TestSelectRearAperture()
1469       RearCameraAperture();
1470     cube([0.1, 50, 0.1]);
1471   }
1472 }
1473
1474 module TestSelectOrdinaryRearApertures(){
1475   TestSelectRearAperture()
1476     OrdinaryRearApertures();
1477 }
1478
1479 module TestCamera(){ ////toplevel
1480   intersection(){
1481     Case();
1482     TestSelectCamera();
1483   }
1484 }
1485
1486 module TestLidByCamera(){ ////toplevel
1487   intersection(){
1488     Lid();
1489     TestSelectCamera();
1490   }
1491 }
1492
1493 module TestLidByCameraPrint(){ ////toplevel
1494   rotate([180,0,0]) TestLidByCamera();
1495 }
1496
1497 module DemoByCamera(){ ////toplevel
1498   color("blue") TestLidByCamera();
1499   color("red")  TestCamera();
1500 }
1501
1502 module OneKeeper(){ ////toplevel
1503   translate([0, -phone_cnr_rad, 0])
1504     rotate([90, 0, 0])
1505     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1506     KeeperProfile();
1507 }
1508
1509 module OneKeeperPrint(){ ////toplevel
1510   rotate([0,180,0])
1511     OneKeeper();
1512 }
1513
1514 module LidPrint(){ ////toplevel
1515   rotate([0,180,0])
1516     Lid();
1517 }
1518
1519 module TestSelectFrame(){
1520   include = [1,-1] * (epp2i[0] + 4);
1521
1522   difference(){
1523     cube(1000, center=true);
1524     translate([0,0, -100])
1525       linear_extrude(height=200)
1526       rectfromto(include,  inside_br - include);
1527   }
1528 }
1529
1530 module TestSelectLidFrame(){
1531   TestSelectFrame();
1532   if (len(led_pos))
1533     translate([led_pos[0], -led_pos[1], -50])
1534     cylinder(r= nla_r2+3, h=100);
1535 }
1536
1537 module TestFrameCase(){ ////toplevel
1538   intersection(){
1539     Case();
1540     union(){
1541       TestSelectFrame();
1542       TestSelectCamera();
1543       TestSelectOrdinaryRearApertures();
1544     }
1545   }
1546 }
1547
1548 module TestSelectTopApertures(){
1549   translate([-100, -35, -100])
1550     cube([400, 100, 200]);
1551   LidAdhocMultiprintFrame(0);
1552   LidAdhocMultiprintFrame(1);
1553 }
1554
1555 module TestTopApertures(){ ////toplevel
1556   intersection(){
1557     Case();
1558     TestSelectFrame();
1559     TestSelectTopApertures();
1560   }
1561 }
1562
1563 module TestLidTopAperturesPrint(){ ////toplevel
1564   rotate([0,180,0]) intersection(){
1565     Lid();
1566     TestSelectLidFrame();
1567     TestSelectTopApertures();
1568   }
1569 }
1570
1571 module TestLidWindowTopAperturesPrint(){ ////toplevel
1572   rotate([0,180,0]) intersection(){
1573     LidWindow();
1574     TestSelectTopApertures();
1575   }
1576 }
1577
1578 module TestFrameLidPrint(){ ////toplevel
1579   rotate([0,180,0]) intersection(){
1580     Lid();
1581     TestSelectLidFrame();
1582   }
1583 }
1584
1585 module ButtonPlanForDemo(z, deep, cut){
1586   translate([0,0,z])
1587     ButtonPlan(8, deep, cut);
1588 }
1589
1590 module HingeScrews(){
1591   Flip_rhs() Flip_bot(1){
1592     for (c= [ hppT, hppB ])
1593       translate([ hex20,
1594                   -c[0],
1595                   c[1] ]){
1596         rotate([0,90,0])
1597           translate([0,0,-.2])
1598           cylinder( r= hingescrew_shaft_dia/2,
1599                     h = hingescrew_shaft_len+0.2 );
1600         rotate([0,-90,0])
1601           translate([0,0,+.1])
1602           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1603       }
1604   }
1605 }
1606
1607 module DemoPropAngleSelect(c){
1608   color(c) difference(){
1609     union(){ children(); }
1610     translate([ prop_x_pos, -400, -200 ])
1611       cube([ 400,800,400 ]);
1612   }
1613 }
1614
1615 module DemoPropAngle(ang){
1616   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1617   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1618
1619   translate(hL)
1620     rotate([ang/2,0,0])
1621     translate(-hL)
1622     translate(hC)
1623     rotate([ang/2,0,0])
1624     translate(-hC) {
1625       DemoPropAngleSelect("red") Case();
1626
1627       color("orange")
1628         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1629         PropProfileAssignments(ang) {
1630           echo($prpp1);
1631           rotate([-$prp_theta, 0, 0])
1632           translate([0, $prpp1[0], -$prpp1[1]])
1633           rotate([90,0,-90])
1634           Prop();
1635         }
1636     }
1637
1638   translate([0,0, -hp_k*2])
1639     DemoPropAngleSelect("blue")
1640     Lid();
1641 }
1642
1643 module DemoPropAngles(){ ////toplevel
1644   for (i=[0 : len(prop_angles)-1])
1645     translate(i * [0, -100, 100])
1646     DemoPropAngle(prop_angles[i]);
1647 }
1648
1649 module DemoHingeAngle(ang1,ang2){
1650   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1651   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1652
1653   translate(hL)
1654     rotate([ang2,0,0])
1655     translate(-hL)
1656     translate(hC)
1657     rotate([ang1,0,0])
1658     translate(-hC) {
1659       color("red") Lid();
1660     }
1661
1662   color("blue") intersection(){
1663     Case();
1664     union(){
1665       translate([bppJ[0], -400, -200])
1666         mirror([1,0,0])
1667         cube([400, 800, 400]);
1668       translate([10, -400, -200])
1669         cube([10, 800, 400]);
1670     }
1671   }
1672 }
1673
1674 module DemoHingeAngles(){ ////toplevel
1675   angles = [ 0, 4, 8, 12 ];
1676   echo("angles",angles);
1677   for (i=[0 : len(angles)-1]) {
1678     translate(i * [0, 0, 30]) {
1679       DemoHingeAngle(0,angles[i]);
1680       translate([0, 200, 0])
1681         DemoHingeAngle(angles[i],0);
1682     }
1683   }
1684 }
1685
1686 module DemoSelectAdhocLeftRight(right=0) {
1687   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1688     mirror([1-right, 0,0])
1689     cube([400, 800, 200]);
1690 }
1691
1692 module DemoLeft(){ ////toplevel
1693   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1694   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1695 }
1696
1697 module DemoFrame(){ ////toplevel
1698   color("red") render() TestFrameCase();
1699   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1700   color("black") render() HingeScrews();
1701   %render() HingeLever();
1702 }
1703
1704 module DemoLanyardCutout(){ ////toplevel
1705   LanyardCutout(25);
1706 }
1707
1708 module DemoHingedFrame(){ ///toplevel
1709   color("red") render() TestFrameCase();
1710   translate([0,0, -2*hp_k])
1711   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1712
1713   Flip_hinge(){
1714     color("orange") render() HingeLever();
1715     color("black") render() HingeScrews();
1716   }
1717 }
1718
1719 module DemoHinge(){ ////toplevel
1720   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1721     DemoFrame();
1722     translate([0,0, -hp_k*3])
1723       DemoHingedFrame();
1724   }
1725 }
1726
1727 module DemoProfiles(){ ////toplevel
1728   LidEdgeProfile();
1729   %EdgeProfile();
1730   KeeperProfile();
1731   translate([0,0,-1]) color("black") KeeperProfile(1);
1732   translate(ly_o){
1733     rotate(-ly_theta){
1734       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1735       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1736       translate([0, ly_q_z]){
1737         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1738         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1739       }
1740     }
1741   }
1742   translate([0,0,-5]) color("white") translate(epp2i)
1743     rotate(-ly_theta)
1744     rectfromto([-15, 0],
1745                [+15, -max_case_bottom_edge_thickness]);
1746
1747   translate([0,20]) {
1748     LanyardMainChannelProfile();
1749     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1750     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1751   }
1752
1753   translate([20,0]) {
1754     LidEdgeProfile();
1755     %EdgeProfile();
1756
1757     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1758
1759     color("blue") ButtonCoverProfile();
1760     color("red") {
1761       rectfromto(bppQ, demopoint_QR);
1762       rectfromto(bppR, demopoint_QR);
1763     }
1764   }
1765
1766   translate([-20,0]) {
1767     color("black") ButtonPlanForDemo(-2, 0,1);
1768     color("red" )  ButtonPlanForDemo(-4, 1,1);
1769     color("blue")  ButtonPlanForDemo(-6, 1,0);
1770   }
1771
1772   translate([0, -30]) {
1773     %LidEdgeProfile();
1774     %EdgeProfile();
1775     color("blue") HingeLidProfile();
1776     color("red")  HingeBaseProfile();
1777     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1778   }
1779
1780   for (f=[0,1]) {
1781     translate([-30, -60 + 30*f]) {
1782       translate([0,0,-4]) EdgeProfile();
1783       %translate([0,0,-10]) HingeBaseProfile();
1784       translate([0,-2] * f * hp_k) {
1785         translate([0,0,-4]) LidEdgeProfile();
1786         %translate([0,0,-10]) %HingeLidProfile();
1787       }
1788       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1789         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1790         translate([0,0,0]) color("red") difference(){
1791           HingeLeverOuterProfile();
1792           HingeLeverInnerProfile();
1793         }
1794         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1795       }
1796     }
1797   }
1798
1799   translate([20,-30]) {
1800     %EdgeProfile();
1801     %LidEdgeProfile();
1802     //translate([0,0,1]) ThumbRecessCutProfile();
1803     translate([0,0,+1]) color("red")
1804       difference(){ EdgeProfile(); ThumbRecessCutProfile(); }
1805   }
1806
1807   translate([40,-30]) {
1808     difference(){
1809       LidEdgeProfile();
1810       translate(prlp10)
1811         PropProfile(10, 1, 0);
1812     }
1813     translate(prlp10)
1814       PropProfile(15, 0);
1815   }
1816   translate([60,-30]) {
1817     PropAggregateProfile();
1818   }
1819 }
1820
1821 //EdgeProfile();
1822 //KeeperProfile();
1823 //CaseBase();
1824 //%Case();
1825 //Keeper();
1826 //LidEdgeProfile();
1827 //KeeperProfile();
1828 //DemoProfiles();
1829 //PropRecess();