fairphone4-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. <deleted>
  13 //
  14 //  3. use "make" to generate the necessary files:
  15 //
  16 //     make -j8 fairphone-case.auto.scads `for f in   \
  17 //        HingePrint        \
  18 //        LidPrint          \
  19 //        OneKeeperPrint    \
  20 //        Case              \
  21 //     ; do echo fairphone-case,$f.auto.stl; done`
  22 //
  23 //  4. Print them.  Case and OneKeeperPrint should probably be
  24 //     the same colour.
  25 //
  26 //  5. Assemble the hinge.  After placing the parts in the appropirate
  27 //     relative placement:
  28 //
  29 //        Use long bit of wire to ensure holes are lined up and proper
  30 //        Cut four short bits of wire, using above as a guage
  31 //
  32 //        Push two short bits into two holes on same side
  33 //        Use long bit of wire to ensure properly in holes
  34 //        Keep that side up so they don't fall out!
  35 //
  36 //        For each of the two holes
  37 //          Use 20-30cm hunk of 2.85mm PLA
  38 //          Use gas flame to melt end until it catches fire (!)
  39 //          Remove from flame, wave to extinguish, and quickly:
  40 //          Dab end onto where hole is
  41 //          As it congeals, use sidecutters to cut off by hole
  42 //
  43 //        Repeat for two holes on other side
  44 //        When cool, file down rough edges
  45 //
  46 //  6. In use:
  47 //
  48 //      - To put the phone in, drop its RH side into the RH side of
  49 //        the case.  Then feed the keeper through the small hole.
  50 //        Feed it right through.
  51 //
  52 //      - The optional prop can be used to prop the phone up (in
  53 //        portrait orientation only right now).  See
  54 //            openscad fairphone-case,DemoPropAngles.auto.scad
  55 //
  56 // Other phones
  57 //
  58 //  It might well be possible to adapt this file for other phones.
  59 //  If you do, let me know how you get on.
  60 //
  61 //
  62 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  63 //
  64 //   Copyright (C) 2018-2022 Ian Jackson.
  65 //
  66 //    This program for generating a 3D model is free software: you can
  67 //    redistribute it and/or modify it under the terms of the GNU
  68 //    General Public License as published by the Free Software
  69 //    Foundation, either version 3 of the License, or (at your option)
  70 //    any later version.
  71 //
  72 //    This program is distributed in the hope that it will be useful,
  73 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
  74 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  75 //    GNU General Public License for more details.
  76 //
  77 //    You should have received a copy of the GNU General Public
  78 //    License along with this program.  If not, see
  79 //    <http://www.gnu.org/licenses/>.
  80 //
  81 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
  82 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
  83 //  this case will meet your needs.
  84
  85 include <utils.scad>
  86 include <funcs.scad>
  87
  88 phone = [ 75.86, 162.0 ];
  89
  90 prop_buildout_less = 3;
  91
  92 prop_angles = [ 15, 30, 45, 60 ];
  93
  94 bumper = [ 0.250, -0.025 ];
  95 // ^ One side.  Overall size is increased by twice this.
  96 // If no bumpers, is the gap around the phone.
  97
  98 enable_support = 1;
  99
 100 led_window_style = 0;
 101 // 0: no window
 102 // 1: simply an opening
 103 // 2: opening with separate cover model, for printing in clear (two colour)
 104 // 3: like 2 but one-layer window for ad-hoc multi-colour
 105
 106 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 107 initial_layer_width = 0.750; // ^ needed for mode 3 only
 108 multicolour_gap = 0.15; // each side
 109
 110 phone_cnr_rad = 7.0; // actuall 8.mumble, but smaller is fine
 111 phone_rim_depth = 0.01; // includes allowance for a screen protector
 112
 113 button_cutout_depth = 9;
 114
 115 phone_edge_thick = 11.25;
 116
 117 camera_pos_tl = [  5.600,  5.750 ]; // from tl corner (as seen from back)
 118 camera_edge_rad = 9.750 + 0.700;
 119 camera_sz = 32.920 + .750 + 1.000;
 120
 121 // this is disabled, FP4 doesn't have one
 122 jack_pos = [ 13.83, 8.485 ];
 123 jack_dia = 10.64 + .5; // some jack I had lying around
 124
 125 // this led stuff, is irrelevant, we have disabled it as it doesn't have one
 126 led_pos = []; // [ 13.98, 10.00 ];
 127 led_aperture = 9;
 128 led_window_ledge = 0.75; // each side
 129
 130 noisecancelmic_pos = [ 15.08 + .720, 4.35 ];   // from rhs, from top edge
 131 noisecancelmic_dia = 4.00;
 132
 133 mainmic_pos = [ 21.0, 4.65 ];   // from lhs, from top edge
 134 mainmic_dia = 4.00;
 135
 136 lhshole_pos = [ phone[1]/2 + 0.40, 4.35 ];
 137
 138 fingerpushhole_dias = [];
 139 //fingerpushhole_dias = [ 15, 18 ]; // this is for testing
 140
 141 lanyard_half_dia = 1.15;
 142 lanyard_entry_rel_breadth = 2;
 143 lanyard_channel_len = 8;
 144 //rearspeaker_pos_bl = [ 12.64, 18.72 ];
 145 //rearspeaker_size   = [  3.76,  7.36 ];
 146
 147 bottomspeaker_size = [ 11.35, 1.90 ] + [1,1] * 0.5;
 148 bottomspeaker_pos = [ 17.55, 5.17 ]; // from rhs, from top
 149
 150 microusb_above = 1.64 - 0.25;
 151 microusb_below = 2.42;
 152 microusb_width = 12.16 + 2.0 + 1.25;
 153
 154 case_th_bottom = 2.5;
 155 case_th_lid = 3.0;
 156 case_th_side = 2.3;
 157 case_th_lip = 1.2;
 158
 159 lid_screen_gap_extra = .66;
 160
 161 case_struts_count = 6;
 162 case_struts_solid_below = 1.00;
 163 case_struts_solid_above = 0.75;
 164 case_struts_width = 0.10;
 165
 166 keeper_th_z = 0.75;
 167 keeper_th_x = 0.75;
 168 keeper_inner_width = 2.75;
 169 keeper_inner_height = 2.75;
 170 keeper_slant_slope = 2; // larger means steeper
 171
 172 keeper_gap_z_top = 0.25;
 173 keeper_gap_z_bot = 0.75;
 174 keeper_gap_x     = 0.25;
 175 keeper_gap_x_holes = 0.75;
 176 keeper_fatter = 0.45;
 177 keeper_fatter_hole = 1.20;
 178
 179 keeper_side = 0; // 0 = lhs; 1 = rhs
 180
 181 case_lip = 1.25;
 182
 183 lid_gap_x = 0.25;
 184 lid_gap_z = 0.25;
 185 lid_lip = 1.75;
 186 lid_edgepart_width = 5.0;
 187 lid_buttoncover_thick = 1.3;
 188 lid_buttoncover_reinf = 0.65;
 189
 190 foldover_gap = 0.50;
 191 foldover_lever_gap = 0.50;
 192
 193 // properties of the hinge fasteners
 194 hingescrew_shaft_dia = 1.600 + 0.45; // beading wire
 195 hingescrew_shaft_len = 10;
 196 hingescrew_fasteners_extra_thick = 0.40;
 197 // ^ amount of thread protruding if everything was completely nominal
 198 //   and we are using two nuts
 199 hingescrew_nut_access_dia = 4.72 + 0.50;
 200 // ^ washer is 4.72 dia
 201 //   also, want to get pliers or tiny spanner in to do up locknut
 202 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 203 hingescrew_nut_thick = 1.93;
 204 hingescrew_head_th = 1.38 + 0.75;
 205 hingescrew_head_dia = 3.92;
 206
 207 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 208
 209 lever_cover_th = 0.75;
 210 hingemount_th = 2.5;
 211 hingemount_wd = 4.8725;
 212
 213 $fa = 5;
 214 $fs = 0.1;
 215
 216 button_l_fudge = 4.4;
 217 buttonishleg_default_l_is_fudge = 10;
 218
 219 hinge_base_slope = 1.5; // bigger is steeper
 220
 221 strut_min_at_end = 1.5;
 222
 223 hinge_x_gap = 0.125;
 224 hinge_x_postscrew_gap = 0.75;
 225 hinge_x_arms_gap = 0.35;
 226 hinge_r_arms_gap = 0.55;
 227 hinge_over_nut_plate = -0.50; // bodge apropos slope
 228
 229 // there isn't one of these, speaker is by hinge
 230 // rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 231
 232 thumbrecess_depth = 1.3;
 233 thumbrecess_width = 16.5;
 234 thumbrecess_topcurve_r = 5.0;
 235
 236 prop_recess_under = 0.50;
 237 prop_recess_slop = 0.200; // each side
 238 prop_end_dia = 0.5;
 239 prop_main_th = 3;
 240 prop_taper_len = 6;
 241 prop_main_width = 4;
 242 prop_side_gap = 0.75; // each side
 243 prop_lidrecess_behind = 0.75;
 244 prop_caserecess_behind = 0.75;
 245 prop_caserecess_taper = 0.45; // one side only
 246 prop_prop_gap = 0.5;
 247 prop_prong_heel_slope = 0.5;
 248
 249 lid_fold_clearance_antislop = 0.5;
 250
 251 $button_leg_only = false;
 252 $suppress_forward_holes = false;
 253 $suppress_hinge = false;
 254
 255 // ---------- calculated ----------
 256
 257 phone_total_thick = phone_edge_thick;
 258
 259 phone_width =  (phone + bumper*2)[0];
 260 phone_height = (phone + bumper*2)[1];
 261
 262 inside_br = [phone_width, -phone_height];
 263
 264 prop_prong_h = prop_main_th;
 265
 266 //echo(camera_pos_tl + bumper,
 267 //     camera_pos_br + bumper);
 268
 269 // ----- could be changed -----
 270 lid_buttoncover_gap = lid_gap_x;
 271 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 272
 273 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 274
 275 //prop_nose_len = case_th_lid - prop_recess_under;
 276 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 277 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 278
 279
 280 epp0 = [0,0];
 281 epp1 = [0, -phone_edge_thick];
 282 epp2i = epp1; // conflated for FP4
 283 epp2o = epp2i;
 284 epp3 = epp2i + [10, 0];
 285 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 286 epp4 = epp5 + [-1,0] * case_th_side;
 287
 288 kppe = [0,0];
 289 kppd = kppe + [1,0] * keeper_inner_width;
 290 kppc = kppd + [0,1] * keeper_th_z;
 291 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 292 kppf = kppe - [0,1] * keeper_inner_height;
 293 kppa = [ kppb[0], kppf[1] ];
 294
 295 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 296 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 297
 298 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 299 // exact x posn not very important; must extend past end of keeper
 300
 301 lpp15 = [ lpp14[0],
 302           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 303           + lid_screen_gap_extra ];
 304 // ^ beam theory says to maximise force before contact,
 305 //   the gap below the `beam' (the lid) must be 1/3
 306 //   the thickness (ie the lid thickness) if the beam
 307 //   is solid, or 1/2 if it has a top and bottom only.
 308 //   ours is mostly solid.
 309
 310 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 311              case_th_lip);
 312
 313 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 314 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 315
 316 case_bottom_z = epp2o[1] - case_th_bottom;
 317
 318 // button profile
 319 bppM = epp4 + [0,5];
 320 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 321 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 322 bppS = [ epp1[0], bppR[1] ];
 323 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 324 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 325 bppO = [ bppN[0], bppP[1] ];
 326 bppL = lpp10 + [5,0];
 327 bppK = [ bppL[0], bppN[1] ];
 328 bppJ = [ bppN[0], bppL[1] ];
 329 bppU = [ bppJ[0], lpp12[1] ];
 330 bppV = lpp11;
 331 bppW = lpp10;
 332
 333 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 334
 335 // notification led aperture
 336
 337 nla_r0 = led_aperture/2;
 338 nla_r1 = nla_r0 + led_window_ledge;
 339 nla_r2 = nla_r1 + multicolour_gap;
 340 nla_t =
 341   led_window_style >= 3 ? initial_layer_thick :
 342   led_window_style >= 2 ? led_window_ledge : 0;
 343
 344
 345 // hinge plan
 346 hp_rn = hingescrew_nut_access_dia/2;
 347 hp_r2_min = hp_rn + lever_cover_th;
 348 hp_rs = hingescrew_shaft_dia/2;
 349 hp_r1_min = hp_rs + hingemount_th;
 350
 351 hp_r1 = max(hp_r1_min, hp_r2_min);
 352 hp_r2 = hp_r1;
 353
 354 hppU = lpp13;
 355 hppS = epp2o + [0,-1] * case_th_bottom;
 356 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 357
 358 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 359          0.5 * (hppU + hppS)[1] ];
 360 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 361 hppB = hppT + [0,-1] * hp_k;
 362
 363 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 364 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 365 hppE = [ hppE_x, hppE_y ];
 366
 367 // hinge elevation x coords
 368
 369 hex20 = max(epp2o[0],
 370             phone_cnr_rad,
 371             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 372 hex21 = hex20 + hingemount_wd;
 373 hex22 = hex21 + hinge_x_gap;
 374 hex27 = hex20 + hingescrew_shaft_len;
 375 hex24 = hex27 + hinge_x_postscrew_gap;
 376 hex23 = hex27 - (hingescrew_nut_thick*2
 377                  + hingescrew_fasteners_extra_thick);
 378 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 379
 380 //echo(hex20, hex21, hex22, hex23, hex24);
 381 ////  6, 10.8725, 10.9975, 13.74, 18.75
 382 //module chk(act,exp) {
 383 //  if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 384 //  else echo("ok", act);
 385 //}
 386 //chk(hex20, 6);
 387 //chk(hex21, 10.8725);
 388 //chk(hex22, 10.9975);
 389 //chk(hex23, 13.74);
 390 //chk(hex24, 18.75);
 391
 392 lid_fold_clearance_skew =
 393   (lpp10[1] - hppB[1]) /
 394   (lpp10[0] - hppB[0]);
 395
 396 echo("SK",lid_fold_clearance_skew);
 397
 398 // thumb recess (used to be "catch" hence cpp*
 399
 400 cppA = epp4 + [thumbrecess_depth, 0];
 401 cppB = [ cppA[0], epp1[1] ];
 402
 403 // lanyard
 404
 405 ly_r = lanyard_half_dia / 2;
 406 ly_rc = ly_r * 2;
 407
 408 ly_theta = 90;
 409 ly_o = epp2i + 3 * ly_r * [0,1];
 410
 411 max_case_bottom_edge_thickness =
 412   case_th_bottom;
 413
 414 ly_q_z = -(ly_rc + ly_r);
 415 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 416
 417 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 418
 419 // prop recess in case
 420
 421 prop_x_pos = phone_width/2;
 422
 423 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 424
 425 prc_r1 = prop_end_dia/2;
 426 prc_r3 = prc_r1 + prop_recess_slop;
 427
 428 prcp2 = [ epp4[0] + prop_buildout_less,
 429           case_bottom_z ];
 430
 431 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 432
 433 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 434           epp2i[1] - prc_r3 - prop_recess_under];
 435
 436 // prop recess in lid
 437
 438 prl_r10 = prop_end_dia/2;
 439 prl_r10o = prl_r10 + prop_recess_slop;
 440
 441 prlp10 = lpp10 + [1,1] * prl_r10o
 442   + [1,0] * prop_lidrecess_behind
 443   + [0,1] * prop_recess_under;
 444
 445 // prop
 446
 447 $prpp10 = [0,0];
 448 $prpp11 = [0, prop_taper_len];
 449
 450 $prp_r10 = prl_r10;
 451
 452 // ---------- modules ----------
 453
 454 module AdhocMultiprintFrame(phase, z0, zs) {
 455   // from z0 to z0 + zs*layer
 456   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 457   xextra = extra + -epp4[0];
 458   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 459   yextra = extra + -epp4[0];
 460   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 461   p0 = [ xrange[0], yrange[0] ];
 462   p1 = [ xrange[1], yrange[1] ];
 463   echo(p0, p1);
 464   translate([0,0, z0])
 465     mirror([0,0, zs<0 ? 1 : 0])
 466     linear_extrude(height= initial_layer_thick)
 467     difference(){
 468       rectfromto(p0 - [1,1] * initial_layer_width,
 469                  p1 + [1,1] * initial_layer_width);
 470       rectfromto(p0, p1);
 471     }
 472 }
 473
 474 module KeeperProfile(fatter, slant=0){
 475   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 476   polygon([use_e + [+1,-1] * fatter,
 477            kppd  + [ 0,-1] * fatter,
 478            kppc,
 479            kppb,
 480            kppa,
 481            kppf  + [+1, 0] * fatter
 482            ]);
 483 }
 484
 485 module EdgeProfile(){
 486   difference(){
 487     hull(){
 488       translate(epp3) square(case_th_bottom*2, center=true);
 489       circleat(epp2o, r=case_th_bottom);
 490       circleat(epp1, r=case_th_side);
 491       rectfromto(epp0, epp4);
 492     }
 493     polygon([ epp5 + [0,10],
 494               epp1,
 495               epp3 + [10,0] ]);
 496   }
 497 }
 498
 499 module LanyardLanyardProfile(entry=false){
 500   hull(){
 501     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 502       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 503         circle(r= lanyard_half_dia/2);
 504   }
 505 }
 506
 507 module LanyardCurveChannelProfile(){
 508   translate([0, -ly_r])
 509     LanyardLanyardProfile();
 510 }
 511
 512 module LanyardEntryChannelProfile(){
 513   LanyardLanyardProfile(true);
 514 }
 515
 516 module LanyardMainChannelProfile(){
 517   LanyardCurveChannelProfile();
 518   difference(){
 519     square(center=true, ly_r * [6, 2]);
 520     for (xs=[-1,+1])
 521       translate(ly_r * [3 * xs, -1])
 522         circle(r = ly_r);
 523   }
 524 }
 525
 526 module LanyardEntryOuterProfile(){
 527   circleat([ly_re + ly_r, 0], ly_re);
 528 }
 529
 530 module LanyardEntry(){
 531   q_z = ly_q_z;
 532   oec_y = ly_oec_y;
 533
 534   d_x = -ly_rc;
 535
 536   translate([d_x, 0, q_z]) {
 537     intersection(){
 538       rotate([90,0,0])
 539         rotate_extrude(convexity=10)
 540         rotate(90)
 541         translate([0, -q_z])
 542         LanyardCurveChannelProfile();
 543       translate([0,-10,0])
 544         cube([20,20,20]);
 545     }
 546   }
 547
 548   mirror([0,0,1])
 549     translate([0,0,-1])
 550     linear_extrude(height=20)
 551     rotate(-90)
 552     LanyardEntryChannelProfile();
 553
 554   translate([0, ly_r*2, 0])
 555     rotate([90,0,0])
 556     linear_extrude(height = ly_r*4){
 557     difference(){
 558       rectfromto([d_x, q_z], [ly_r, 0]);
 559       circleat([d_x, q_z], ly_rc);
 560     }
 561   }
 562
 563   translate([0,0,q_z]){
 564     for (my=[0,1])
 565       mirror([0,my,0]){
 566         translate([0, oec_y, 0]){
 567           difference(){
 568             translate(ly_re * [-1,0,-2])
 569               cube(ly_re * [2,1,2]);
 570             rotate_extrude(convexity=10)
 571               LanyardEntryOuterProfile();
 572           }
 573         }
 574       }
 575     difference(){
 576       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 577         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 578       for (mx=[0,1])
 579         mirror([mx,0,0])
 580           rotate([90,0,0])
 581           translate([0,0,-10])
 582           linear_extrude(height=20)
 583           LanyardEntryOuterProfile();
 584     }
 585   }
 586 }
 587
 588 module LanyardCutout(l){
 589   rotate([0,-90,0])
 590     linear_extrude(height=l)
 591     rotate(-90)
 592     LanyardMainChannelProfile();
 593
 594   for (ee=[0,1]){
 595     translate(ee * l * [-1,0])
 596       mirror([ee,0,0])
 597       LanyardEntry();
 598   }
 599 }
 600
 601 module LidEdgeProfile(){
 602   polygon([ lpp10,
 603             lpp11,
 604             lpp12,
 605             lpp13,
 606             lpp13 + [10, 0],
 607             lpp15 + [10, 0],
 608             lpp15,
 609             lpp14,
 610             ]);
 611   intersection(){
 612     circleat(lpp12, r=lp_r12);
 613     rectfromto( lpp12 + [-10,   0],
 614                 lpp12 + [+10, +10] );
 615   }
 616 }
 617
 618 module LidEdgeFoldClearanceProfile(){
 619   translate([-lid_fold_clearance_antislop, 0])
 620     polygon([ lpp10,
 621               lpp11,
 622               lpp11 + [-20,  0],
 623               lpp11 + [-20, 20],
 624               lpp11 + [+20, 20],
 625               lpp10 + [+20,  0] ]);
 626 }
 627
 628 module ButtonCoverProfile(){
 629   intersection(){
 630     polygon(concat([ bppM, bppP, bppO, bppJ ],
 631                    (enable_support && !$button_suppress_over_keeper
 632                     ? [ bppU, bppV, bppW ] : []),
 633                    [ bppL, bppK ]));
 634     hull(){
 635       EdgeProfile();
 636       LidEdgeProfile();
 637     }
 638   }
 639 }
 640
 641 module ButtonPlan(l, deep, cut){
 642   epsilon =
 643     (cut  ? 0 : lid_buttoncover_gap);
 644
 645   delta =
 646     (deep ? lid_buttoncover_overlap : 0);
 647
 648   C = [0,0]; // by definition
 649   T = [ 0, epp4[1] ];
 650   G = T + [0,10];
 651
 652   B0 = C + [0,-1] * button_cutout_depth;
 653   B1 = B0 + [0,1] * epsilon;
 654
 655   r0 = 0.5 * (T[1] - B0[1]);
 656   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 657   H = A + [0,-1] * delta;
 658
 659   D = A + [-2,0] * r0;
 660   F = D + [0,10];
 661
 662   E0 = 0.5 * (D + A);
 663   E1 = E0 + [1,0] * epsilon;
 664
 665   I0 = [ E0[0], H[1] ];
 666   I1 = [ E1[0], H[1] ];
 667
 668   hull(){
 669     for (m=[0,1]) mirror([m,0])
 670       circleat(H, r0 - epsilon);
 671   }
 672   for (m=[0,1]) mirror([m,0]) {
 673     difference(){
 674       polygon([ E1,
 675                 I1,
 676                 H,
 677                 B1,
 678                 G,
 679                 F,
 680                 D
 681                 ]);
 682       circleat(D, r0 + epsilon);
 683     }
 684   }
 685 }
 686
 687 module ButtonCoverReinf(){ ////toplevel
 688   minkowski(){
 689     rotate([90,0,0])
 690       linear_extrude(height=0.01)
 691       intersection(){
 692         ButtonCoverProfile();
 693         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 694           square([100,100]);
 695     }
 696     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 697       circle(r= lid_buttoncover_reinf);
 698       translate([-20,0]) square(40, center=true);
 699     }
 700   }
 701 }
 702
 703 module ThumbRecessCutProfile(){
 704   difference(){
 705     polygon([ cppA + [-10,0],
 706               cppB + [-10,0],
 707               cppB,
 708               cppA ]);
 709     circleat(epp1, r=case_th_side);
 710   }
 711 }
 712
 713 module Flip_rhs(yn=[0,1]) {
 714   for ($rhsflip=yn) {
 715     translate([phone_width/2, 0, 0])
 716       mirror([$rhsflip,0,0])
 717       translate([-phone_width/2, 0, 0])
 718       children();
 719   }
 720 }
 721
 722 module Flip_bot(yn=[0,1]) {
 723   for ($botflip=yn) {
 724     translate([0, -phone_height/2, 0])
 725       mirror([0, $botflip, 0])
 726       translate([0, phone_height/2, 0])
 727       children();
 728   }
 729 }
 730
 731 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 732   // sides
 733   Flip_rhs(){
 734     translate([0, -phone_cnr_rad, 0])
 735       rotate([90,0,0])
 736       linear_extrude(height = phone_height - phone_cnr_rad*2)
 737       children(0);
 738   }
 739   // corners
 740   Flip_rhs() Flip_bot() {
 741     translate([+1,-1] * phone_cnr_rad)
 742       intersection(){
 743         rotate_extrude()
 744           intersection(){
 745             mirror([1,0,0])
 746               translate([-1,0] * phone_cnr_rad)
 747               children(0);
 748             rectfromto([0,-20],[10,20]);
 749           }
 750         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 751           cube([10,10,40]);
 752       }
 753   }
 754   // top and bottom
 755   Flip_bot(){
 756     translate([ phone_width - phone_cnr_rad, 0,0 ])
 757       rotate([90,0,-90])
 758       linear_extrude(height = phone_width - phone_cnr_rad*2)
 759       children(0);
 760   }
 761   // fill
 762   translate([0,0, fill_zstart])
 763     mirror([0,0, fill_downwards])
 764     linear_extrude(height = fill_th)
 765     rectfromto([+1,-1] * phone_cnr_rad,
 766                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 767 }
 768
 769 module CaseAperture(pos, dia, $fn, topbottom=0) {
 770   theta = 180/$fn;
 771   translate([ bumper[0],
 772               -epp2i[0],
 773                0 ])
 774     rotate([0,0, 90*topbottom])
 775     translate([ pos[0] * (topbottom>0 ? -1 : +1), 0, -pos[1] ])
 776     rotate([-90, theta, 0])
 777     cylinder(r = dia/2 / cos(theta),
 778              h = 60);
 779 }
 780
 781 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 782   // y_ref_sign:
 783   //   +1  measured from top    of actual phone to top    of button
 784   //   -1  measured from bottom of actual phone to bottom of button
 785   //    0  y is centre of button in coordinate system
 786   $button_l= l;
 787   $button_suppress_over_keeper= suppress_over_keeper;
 788   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 789           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 790           y;
 791   //echo(eff_y);
 792   translate([0, eff_y, 0])
 793     children();
 794 }
 795
 796 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 797   $button_leg_only = true;
 798   SideButton(y, y_ref_sign, l) children();
 799 }
 800
 801 module Buttons(){
 802   Flip_rhs(1) SideButton(30.320, +1, 22.960  ) children(); // volume
 803   Flip_rhs(1) SideButton(64.220, +1, 14.500  ) children(); // power
 804   Flip_rhs(1) LidButtonishLeg(14, -1) children();
 805   Flip_rhs(0) LidButtonishLeg(21, -1) children();
 806   Flip_rhs(0) LidButtonishLeg(21, +1) children();
 807 }
 808
 809 module Struts(x_start, z_min, th){
 810   // if th is negative, starts at z_min and works towards -ve z
 811   // and object should then be printed other way up
 812   for (i= [1 : 1 : case_struts_count]) {
 813     translate([0,
 814                0,
 815                z_min])
 816       mirror([0,0, th<0 ? 1 : 0])
 817       translate([0,
 818                  -phone_height * i / (case_struts_count+1),
 819                  case_struts_solid_below])
 820       linear_extrude(height= abs(th)
 821                      -(case_struts_solid_below+case_struts_solid_above))
 822       rectfromto([               x_start, -0.5 * case_struts_width ],
 823                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 824   }
 825 }
 826
 827 module OrdinaryRearAperture(rhs,bot, pos){
 828   Flip_rhs(rhs) Flip_bot(bot)
 829     linextr(-20, 20)
 830     mirror([0,1])
 831     translate(pos + bumper)
 832     children();
 833 }
 834
 835 module MicroUSBEtc(){
 836   Flip_bot(1){
 837     rotate([90,0,0])
 838       mirror([0,0,1])
 839       linextr(-epp2i[0], 60)
 840       translate([0.5 * phone_width, 0, 0])
 841       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 842                  [+microusb_width/2, epp0[1] + -microusb_above]);
 843   }
 844 }
 845
 846 module OrdinaryBottomEdgeApertures(){
 847   Flip_bot(1)
 848     CaseAperture(mainmic_pos, mainmic_dia, 8);
 849
 850   Flip_bot(1) Flip_rhs(1) {
 851     linextr_y_xz(-epp2i[0], 60)
 852       hull()
 853       for (x= [-1,+1]) {
 854         translate([ -bottomspeaker_pos[0], -bottomspeaker_pos[1] ] +
 855                   [ 0.5 * x * bottomspeaker_size[0] - bottomspeaker_size[1],
 856                     0 ])
 857           rotate(360/16)
 858           circle(r = bottomspeaker_size[1], $fn = 8);
 859       }
 860   }
 861 }
 862
 863 module OrdinaryRearApertures(){
 864   // rear speaker
 865   //  OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 866   //    rectfromto(-rearspeaker_gap,
 867   //           rearspeaker_size + rearspeaker_gap);
 868 }
 869
 870 module NotInTestFrameRearApertures(){
 871   // finger hole to remove phone
 872   if (len(fingerpushhole_dias))
 873     OrdinaryRearAperture(0,0, [ fingerpushhole_dias[0] + epp2i[0],
 874                                 phone[1]/2 ])
 875     scale(fingerpushhole_dias)
 876     circle(r= 0.5 );
 877 }
 878
 879 module RearCameraAperture(){
 880   Flip_rhs(1)
 881     mirror([0, 0, 1])
 882     translate([0,0,0])
 883     hull() // there is some kind of bug if hull() is done in 2D here!
 884     linear_extrude(height = 20)
 885     mirror([0, 1, 0])
 886     translate(bumper)
 887     translate(camera_pos_tl)
 888     for (xy = [ [0,0], [0,1], [1,0] ]) {
 889       translate(
 890           camera_edge_rad * [1,1] +
 891           xy * (camera_sz - camera_edge_rad * 2)
 892                 )
 893         circle(r = camera_edge_rad);
 894     }
 895 }
 896
 897 module HingeLidProfile(){
 898   hull(){
 899     circleat(hppT, hp_r1);
 900     circleat(lpp12, lp_r12);
 901     polygon([lpp10,
 902              lpp13 + [2,0],
 903              lpp12,
 904              hppT]);
 905   }
 906 }
 907
 908 module HingeBaseProfile(){
 909   difference(){
 910     hull(){
 911       circleat(hppB, hp_r1);
 912       circleat(hppE, hp_r1);
 913       circleat(epp2o, case_th_bottom);
 914       circleat(hppB + [10,0], hp_r1);
 915     }
 916     polygon([epp5, epp1, epp3, bppL]);
 917   }
 918 }
 919
 920 module HingeLeverOuterProfile(){
 921   hull(){
 922     circleat(hppT, hp_r2);
 923     circleat(hppB, hp_r2);
 924   }
 925 }
 926
 927 module HingeLeverInnerProfile(){
 928   for (s = [-1,+1]) {
 929     c = s > 0 ? hppT : hppB;
 930     translate(c)
 931       mirror([0,0, s>0 ? 1 : 0])
 932       rotate(s<0 ? -40 : 0)
 933       hull()
 934       for (x=[-20,20])
 935         for (y=[0, s * 10])
 936           translate([x,y])
 937             circle(hp_rn);
 938   }
 939 }
 940
 941 module HingeLeverNutProfile(){
 942   for (c= [hppB, hppT]) {
 943     translate(c)
 944       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 945   }
 946 }
 947
 948 module Flip_hinge(doflip=1){
 949   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 950   translate(hinge_origin)
 951     rotate([doflip*180,0,0])
 952     translate(-hinge_origin)
 953     children();
 954 }
 955
 956 module HingePortion(x0,x1){
 957   Flip_rhs() Flip_bot(1)
 958     translate([x0,0,0])
 959     mirror([1,0,0])
 960     rotate([90,0,-90])
 961     linear_extrude(height=x1-x0)
 962     children();
 963 }
 964
 965 module ThumbRecessApply(ztop){
 966   width = thumbrecess_width;
 967   w = width + thumbrecess_topcurve_r*2 + 1;
 968   translate([phone_width/2, 0,0]){
 969     difference(){
 970       rotate([90,0,-90])
 971         linextr(-w/2, w/2)
 972         children(0);
 973       translate([0, 50, 0])
 974         rotate([90,0,0])
 975         linear_extrude(height=100){
 976         for (m=[0,1]) mirror([m,0,0]) {
 977           hull(){
 978             translate([w/2, ztop - thumbrecess_topcurve_r])
 979               circle(thumbrecess_topcurve_r);
 980             translate([w/2, -50])
 981               square(thumbrecess_topcurve_r*2, center=true);
 982           }
 983         }
 984       }
 985     }
 986   }
 987 }
 988
 989 module CaseBase(){
 990   AroundEdges(epp3[1], case_th_bottom, 1)
 991     EdgeProfile();
 992 }
 993
 994 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 995
 996 module PropProfileAssignments(gamma){
 997   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 998   x = prop_x(gamma);
 999   p = phone_height + prlp10[0] - hppB[0];
1000   b = p + x;
1001
1002   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1003   a = q + x;
1004   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1005   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1006
1007   $prp_theta = 90 - $prp_alpha;
1008   beta = 180 - $prp_alpha - gamma;
1009   psi = 90 - beta;
1010
1011   //echo("abc", a,b,c);
1012
1013   v1 = [ [ cos(psi), -sin(psi) ],    // x
1014          [ sin(psi),  cos(psi) ] ];  // y
1015
1016   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1017
1018   $prp_r1 = prc_r1;
1019   $prp_r11 = prop_main_th/2;
1020
1021   $prpp1 = $prpp7 + [1,0] *
1022     // this is approximate, but will do
1023     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1024   $prpp3 = $prpp1 +
1025     v1[0] * -$prp_r1 +
1026     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1027   $prpp12 = $prpp3 + v1[0] *
1028     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1029   $prp_r8 = prop_main_th;
1030   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1031   $prp_r5 = $prp_r8;
1032   $prpp5 = [ $prpp12[0] - $prp_r5,
1033             $prpp3[1] - prop_prong_h + $prp_r5 ];
1034   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1035          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1036   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1037   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1038
1039   children();
1040 }
1041
1042 module PropProfile(gamma, cut=0, rot=0){
1043   PropProfileAssignments(gamma){
1044
1045     //#circleat($prpp3,1);
1046     //#circleat($prpp12,1);
1047
1048     if (!cut) {
1049       hull(){
1050         translate($prpp8)
1051           intersection(){
1052             circle($prp_r8);
1053             polygon([[-20,-0], [20,20], [0,0]]);
1054           }
1055         rectfromto($prpp6, $prpp9);
1056         translate($prpp5) intersection(){
1057           circle($prp_r5);
1058           polygon([[-10,-10], [0,0], [10,0]]);
1059         }
1060         rectfromto($prpp12 + [0,-0.1], $prpp3);
1061       }
1062       hull(){
1063         circleat($prpp1, $prp_r1);
1064         rectfromto($prpp12 + [0,-0.1], $prpp3);
1065       }
1066     }
1067     // main shaft
1068     rotate([0,0, rot*-$prp_theta]){
1069       hull(){
1070         extra = cut ? prop_recess_slop : 0;
1071         rectfromto($prpp6, $prpp9);
1072         circleat($prpp11, $prp_r11 + extra);
1073         circleat($prpp10, $prp_r10 + extra);
1074       }
1075     }
1076   }
1077 }
1078
1079 module PropAggregateProfile(){
1080   for (angle = prop_angles)
1081     PropProfile(angle, 0,0);
1082 }
1083
1084 module Prop(){ ////toplevel
1085   hw = prop_main_width/2;
1086   linextr(-hw, +hw)
1087     PropAggregateProfile();
1088 }
1089
1090 module Case(){ ////toplevel
1091   difference(){
1092     union(){
1093       CaseBase();
1094
1095       // ledge (fixed keeper)
1096       Flip_rhs(1-keeper_side) intersection(){
1097         rotate([90, 0, 0])
1098           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1099           KeeperProfile(fatter=0, slant=1);
1100
1101         // outline of the whole case, to stop it protruding
1102         translate([0,0, -25])
1103           linear_extrude(height = 50)
1104           hull()
1105           Flip_bot()
1106           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1107       }
1108
1109       // hinge
1110       if (!$suppress_hinge)
1111         HingePortion(hex20, hex21) HingeBaseProfile();
1112
1113       // buildout for prop recess
1114       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1115         linextr(case_bottom_z, epp2i[1])
1116         hull() {
1117           for (dxs = [-1,+1])
1118             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1119                        -epp2o[0] ],
1120                      r = epp2o[0] - prcp2[0]);
1121         }
1122     }
1123
1124     // slot for keeper
1125     Flip_rhs(keeper_side)
1126       translate([0, -phone_cnr_rad, 0])
1127       rotate([90, 0, 0])
1128       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1129       minkowski(){
1130         KeeperProfile(fatter=keeper_fatter_hole);
1131         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1132                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1133       }
1134
1135     // front camera
1136     RearCameraAperture();
1137
1138     // struts (invisible, because they're buried in the case)
1139     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1140
1141     Buttons(){
1142       mirror([1,0,0])
1143         rotate([90,0,90]) {
1144           if (!($button_leg_only && enable_support))
1145           intersection(){
1146             translate([0,0,-10])
1147               linear_extrude(height= 20)
1148               ButtonPlan($button_l, 0,1);
1149             if ($button_leg_only)
1150               rotate([-90,90,0])
1151                 translate([phone_width/2, -400, kppe[1]])
1152                 mirror([1-abs($rhsflip - keeper_side),0,0])
1153                 cube([400, 800, 50]);
1154             if (enable_support && !$button_suppress_over_keeper)
1155               rotate([-90,90,0])
1156               translate([-400, -400, kppd[1]])
1157                 mirror([0,0,1])
1158                 cube([800,800,100]);
1159           }
1160           translate([0,0, -bppR[0]])
1161             linear_extrude(height= 20)
1162             ButtonPlan($button_l, 1,1);
1163         }
1164
1165     }
1166
1167     // apertures along top edge
1168     if (!$suppress_forward_holes) {
1169       // CaseAperture(jack_pos, jack_dia, 8);
1170       Flip_rhs(1)
1171         CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1172     }
1173     CaseAperture(lhshole_pos, noisecancelmic_dia, 8, 1);
1174
1175     OrdinaryBottomEdgeApertures();
1176
1177     OrdinaryRearApertures();
1178     NotInTestFrameRearApertures();
1179
1180     MicroUSBEtc();
1181
1182     // gaps for the lid's hinge arms
1183     if (!$suppress_hinge) {
1184       HingePortion(hex20 - hinge_x_arms_gap,
1185                    hex21 + hinge_x_arms_gap)
1186         minkowski(){
1187         HingeLidProfile();
1188         circle(r= hinge_r_arms_gap, $fn= 8);
1189       }
1190
1191       // screw holes in the hinge arms
1192       HingeScrews();
1193     }
1194
1195     // thumb recess
1196     ThumbRecessApply(epp4[1])
1197       ThumbRecessCutProfile();
1198
1199     // lanyard
1200     Flip_bot(1)
1201       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1202       rotate([0, ly_theta, 0])
1203       rotate([0,0,90])
1204       LanyardCutout(lanyard_channel_len);
1205
1206     // prop recess
1207     Flip_rhs(1)
1208       translate([prop_x_pos,0,0])
1209       mirror([0,1,0])
1210       rotate([90,0,90])
1211       linextr(-prop_recess_hw, +prop_recess_hw)
1212       hull(){
1213         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1214           circleat(prcp1 + 20*d,
1215                    prc_r3);
1216       }
1217   }
1218 }
1219
1220 module LidAdhocMultiprintFrame(phase){
1221   if (led_window_style >= 3) {
1222     AdhocMultiprintFrame(phase, lpp13[1], -1);
1223   }
1224 }
1225
1226 module LidAroundEdges(){
1227   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1228     children();
1229 }
1230
1231 module Lid(){ ////toplevel
1232   skew_centre = [0, lpp11[0], lpp11[1]];
1233   difference(){
1234     union(){
1235       intersection(){
1236         LidAroundEdges()
1237           LidEdgeProfile();
1238
1239         translate(skew_centre)
1240           multmatrix([[ 1, 0, 0, 0 ],
1241                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1242                       [ 0, 0, 1, 0 ],
1243                       [ 0, 0, 0, 1 ]])
1244           translate(-skew_centre)
1245           LidAroundEdges()
1246           LidEdgeFoldClearanceProfile();
1247       }
1248
1249       // button covers
1250       Buttons(){
1251         intersection(){
1252           rotate([90,0,90])
1253             translate([0,0,-10])
1254             linear_extrude(height= 20)
1255             ButtonPlan($button_l, 1,0);
1256           union(){
1257             rotate([90,0,0])
1258               translate([0,0,-100])
1259               linear_extrude(height= 200)
1260               ButtonCoverProfile();
1261             hull()
1262               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1263                                  - lid_buttoncover_reinf))
1264                 translate([0,y,0])
1265                   ButtonCoverReinf();
1266           }
1267         }
1268       }
1269
1270       // hinge arms
1271       HingePortion(hex20, hex21) {
1272         LidEdgeProfile();
1273         HingeLidProfile();
1274       }
1275     }
1276     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1277
1278     // screw holes in the hinge arms
1279     HingeScrews();
1280
1281     // prop recess
1282     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1283       mirror([0,1,0])
1284       rotate([90,0,90])
1285       linextr(-prop_recess_hw, +prop_recess_hw)
1286       hull()
1287       for (pa = prop_angles)
1288         PropProfile(pa, 1,1);
1289
1290     // notification led aperture
1291     if (led_window_style)
1292       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1293         translate([0,0,-10])
1294           cylinder(r=nla_r0, h=20);
1295         if (led_window_style >= 2)
1296           translate([0,0, -nla_t])
1297             cylinder(r=nla_r2, height=20);
1298       }
1299
1300     }
1301
1302   LidAdhocMultiprintFrame(1);
1303 }
1304
1305 module HingeLever(){ ////toplevel
1306   difference() {
1307     // outer body, positive
1308     HingePortion(hex22, hex22 + phone_width/2)
1309       HingeLeverOuterProfile();
1310
1311     // space for the screws
1312 //    HingePortion(hex26, hex24)
1313 //      HingeLeverInnerProfile();
1314
1315     // recesses for the nuts
1316 //    HingePortion(hex23, hex26+1)
1317 //      HingeLeverNutProfile();
1318
1319     // bores for the screws
1320     HingeScrews();
1321
1322     // space for the charging cable and speaker and micc apertures
1323     hull() {
1324       for (x = [-1,+1]) {
1325         multmatrix([[ 1,0,
1326
1327                      x
1328                      * ( (hex24 + hinge_over_nut_plate) -
1329                          (phone_width/2 - microusb_width/2)
1330                         )
1331                      / ( (epp0[1] - microusb_above)
1332                          -
1333                          (hppB[1] - hp_r2) ),
1334
1335                      x * (epp0[1] - microusb_above)
1336
1337                       ],
1338                     [ 0,1,0, 0 ],
1339                     [ 0,0,1, 0 ]]) {
1340           union(){
1341             MicroUSBEtc();
1342             Flip_hinge() MicroUSBEtc();
1343           }
1344         }
1345       }
1346     }
1347   }
1348 }
1349
1350 module LidWindow(){ ////toplevel
1351   translate([led_pos[0], -led_pos[1], lpp13[1]])
1352     mirror([0,0,1])
1353     cylinder(r= nla_r1, h=nla_t);
1354   LidAdhocMultiprintFrame(0);
1355 }
1356
1357 module LidWindowPrint(){ ////toplevel
1358   rotate([0,180,0])
1359     LidWindow();
1360 }
1361
1362 module DemoLidWindowSelect(){
1363   translate([led_pos[0], led_pos[1], -100]) {
1364     translate([0, -30, 0]) cube([400, 400, 200]);
1365   }
1366 }
1367
1368 module DemoLidWindow(){ ////toplevel
1369   %Lid();
1370   LidWindow();
1371   translate([0,40,0]){
1372     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1373     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1374   }
1375 }
1376
1377 module HingeLeverPrint(){ ////toplevel
1378   rotate([-90,0,0])
1379     translate([-phone_width/2, phone_height, 0])
1380     HingeLever();
1381 }
1382
1383 module TestSelectLength(){
1384   translate([-30, -200, -20])
1385     cube([30 + 15, 250, 40]);
1386 }
1387
1388 module TestLength(){ ////toplevel
1389   intersection(){
1390     Case();
1391     TestSelectLength();
1392   }
1393 }
1394
1395 module TestLengthRight(){ ////toplevel
1396   intersection(){
1397     Case();
1398     Flip_rhs(1)
1399       TestSelectLength();
1400   }
1401 }
1402
1403 module TestSelectWidth(){
1404   translate([-30, -(phone_height - 25), -20])
1405     mirror([0, 1, 0])
1406     cube([200, 50, 40]);
1407 }
1408
1409 module TestWidth(){ ////toplevel
1410   intersection(){
1411     Case();
1412     TestSelectWidth();
1413   }
1414 }
1415
1416 module TestLidWidthPrint(){ ////toplevel
1417   rotate([0,180.0]) intersection(){
1418     Lid();
1419     TestSelectWidth();
1420   }
1421 }
1422
1423 module TestSelectRearAperture(){
1424   minkowski(){
1425     union() children();
1426     translate([20, 0,0])
1427       cube([42, 2, 1], center=true);
1428   }
1429 }
1430
1431 module TestSelectCamera(){
1432   minkowski(){
1433     TestSelectRearAperture()
1434       RearCameraAperture();
1435     cube([0.1, 50, 0.1]);
1436   }
1437 }
1438
1439 module TestSelectOrdinaryRearApertures(){
1440   TestSelectRearAperture()
1441     OrdinaryRearApertures();
1442 }
1443
1444 module TestCamera(){ ////toplevel
1445   intersection(){
1446     Case();
1447     TestSelectCamera();
1448   }
1449 }
1450
1451 module TestLidByCamera(){ ////toplevel
1452   intersection(){
1453     Lid();
1454     TestSelectCamera();
1455   }
1456 }
1457
1458 module TestLidByCameraPrint(){ ////toplevel
1459   rotate([180,0,0]) TestLidByCamera();
1460 }
1461
1462 module DemoByCamera(){ ////toplevel
1463   color("blue") TestLidByCamera();
1464   color("red")  TestCamera();
1465 }
1466
1467 module OneKeeper(){ ////toplevel
1468   translate([0, -phone_cnr_rad, 0])
1469     rotate([90, 0, 0])
1470     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1471     KeeperProfile(fatter=keeper_fatter);
1472 }
1473
1474 module OneKeeperPrint(){ ////toplevel
1475   rotate([0,180,0])
1476     OneKeeper();
1477 }
1478
1479 module LidPrint(){ ////toplevel
1480   rotate([0,180,0])
1481     Lid();
1482 }
1483
1484 module TestSelectFrame(){
1485   include = [1,-1] * (epp2i[0] + 4);
1486
1487   difference(){
1488     cube(1000, center=true);
1489     translate([0,0, -100])
1490       linear_extrude(height=200)
1491       rectfromto(include,  inside_br - include);
1492   }
1493
1494   for (i= [1,2]) {
1495     translate([ 0, -phone[1] * i/3, 0 ])
1496       cube(center=true, [1000, 4, 100]);
1497   }
1498 }
1499
1500 module TestSelectLidFrame(){
1501   TestSelectFrame();
1502   if (len(led_pos))
1503     translate([led_pos[0], -led_pos[1], -50])
1504     cylinder(r= nla_r2+3, h=100);
1505 }
1506
1507 module TestFrameCase(){ ////toplevel
1508   intersection(){
1509     Case();
1510     union(){
1511       TestSelectFrame();
1512       TestSelectCamera();
1513       TestSelectOrdinaryRearApertures();
1514     }
1515   }
1516 }
1517
1518 module TestSelectTopApertures(){
1519   translate([-100, -35, -100])
1520     cube([400, 100, 200]);
1521   LidAdhocMultiprintFrame(0);
1522   LidAdhocMultiprintFrame(1);
1523 }
1524
1525 module TestTopApertures(){ ////toplevel
1526   intersection(){
1527     Case();
1528     TestSelectFrame();
1529     TestSelectTopApertures();
1530   }
1531 }
1532
1533 module TestLidTopAperturesPrint(){ ////toplevel
1534   rotate([0,180,0]) intersection(){
1535     Lid();
1536     TestSelectLidFrame();
1537     TestSelectTopApertures();
1538   }
1539 }
1540
1541 module TestLidWindowTopAperturesPrint(){ ////toplevel
1542   rotate([0,180,0]) intersection(){
1543     LidWindow();
1544     TestSelectTopApertures();
1545   }
1546 }
1547
1548 module TestFrameLidPrint(){ ////toplevel
1549   rotate([0,180,0]) intersection(){
1550     Lid();
1551     TestSelectLidFrame();
1552   }
1553 }
1554
1555 module ButtonPlanForDemo(z, deep, cut){
1556   translate([0,0,z])
1557     ButtonPlan(8, deep, cut);
1558 }
1559
1560 module HingeScrews(){
1561   Flip_rhs() Flip_bot(1){
1562     for (c= [ hppT, hppB ])
1563       translate([ hex20,
1564                   -c[0],
1565                   c[1] ]){
1566         rotate([0,90,0])
1567           translate([0,0,-.2])
1568           cylinder( r= hingescrew_shaft_dia/2,
1569                     h = hingescrew_shaft_len+0.2 );
1570         rotate([0,-90,0])
1571           translate([0,0,+.1])
1572           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1573       }
1574   }
1575 }
1576
1577 module DemoPropAngleSelect(c){
1578   color(c) difference(){
1579     union(){ children(); }
1580     translate([ prop_x_pos, -400, -200 ])
1581       cube([ 400,800,400 ]);
1582   }
1583 }
1584
1585 module DemoPropAngle(ang){
1586   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1587   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1588
1589   translate(hL)
1590     rotate([ang/2,0,0])
1591     translate(-hL)
1592     translate(hC)
1593     rotate([ang/2,0,0])
1594     translate(-hC) {
1595       DemoPropAngleSelect("red") Case();
1596
1597       color("orange")
1598         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1599         PropProfileAssignments(ang) {
1600           echo($prpp1);
1601           rotate([-$prp_theta, 0, 0])
1602           translate([0, $prpp1[0], -$prpp1[1]])
1603           rotate([90,0,-90])
1604           Prop();
1605         }
1606     }
1607
1608   translate([0,0, -hp_k*2])
1609     DemoPropAngleSelect("blue")
1610     Lid();
1611 }
1612
1613 module DemoPropAngles(){ ////toplevel
1614   for (i=[0 : len(prop_angles)-1])
1615     translate(i * [0, -100, 100])
1616     DemoPropAngle(prop_angles[i]);
1617 }
1618
1619 module DemoHingeAngle(ang1,ang2){
1620   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1621   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1622
1623   translate(hL)
1624     rotate([ang2,0,0])
1625     translate(-hL)
1626     translate(hC)
1627     rotate([ang1,0,0])
1628     translate(-hC) {
1629       color("red") Lid();
1630     }
1631
1632   color("blue") intersection(){
1633     Case();
1634     union(){
1635       translate([bppJ[0], -400, -200])
1636         mirror([1,0,0])
1637         cube([400, 800, 400]);
1638       translate([10, -400, -200])
1639         cube([10, 800, 400]);
1640     }
1641   }
1642 }
1643
1644 module DemoHingeAngles(){ ////toplevel
1645   angles = [ 0, 4, 8, 12 ];
1646   echo("angles",angles);
1647   for (i=[0 : len(angles)-1]) {
1648     translate(i * [0, 0, 30]) {
1649       DemoHingeAngle(0,angles[i]);
1650       translate([0, 200, 0])
1651         DemoHingeAngle(angles[i],0);
1652     }
1653   }
1654 }
1655
1656 module DemoSelectAdhocLeftRight(right=0) {
1657   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1658     mirror([1-right, 0,0])
1659     cube([400, 800, 200]);
1660 }
1661
1662 module DemoLeft(){ ////toplevel
1663   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1664   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1665 }
1666
1667 module DemoFrame(){ ////toplevel
1668   color("red") render() TestFrameCase();
1669   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1670   color("black") render() HingeScrews();
1671   %render() HingeLever();
1672 }
1673
1674 module DemoLanyardCutout(){ ////toplevel
1675   LanyardCutout(25);
1676 }
1677
1678 module DemoHingedFrame(){ ///toplevel
1679   color("red") render() TestFrameCase();
1680   translate([0,0, -2*hp_k])
1681   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1682
1683   Flip_hinge(){
1684     color("orange") render() HingeLever();
1685     color("black") render() HingeScrews();
1686   }
1687 }
1688
1689 module DemoHinge(){ ////toplevel
1690   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1691     DemoFrame();
1692     translate([0,0, -hp_k*3])
1693       DemoHingedFrame();
1694   }
1695 }
1696
1697 module DemoProfiles(){ ////toplevel
1698   LidEdgeProfile();
1699   %EdgeProfile();
1700   KeeperProfile();
1701   translate([0,0,-1]) color("black") KeeperProfile(1);
1702   translate(ly_o){
1703     rotate(-ly_theta){
1704       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1705       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1706       translate([0, ly_q_z]){
1707         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1708         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1709       }
1710     }
1711   }
1712   translate([0,0,-5]) color("white") translate(epp2i)
1713     rotate(-ly_theta)
1714     rectfromto([-15, 0],
1715                [+15, -max_case_bottom_edge_thickness]);
1716
1717   translate([0,20]) {
1718     LanyardMainChannelProfile();
1719     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1720     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1721   }
1722
1723   translate([20,0]) {
1724     LidEdgeProfile();
1725     %EdgeProfile();
1726
1727     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1728
1729     color("blue") ButtonCoverProfile();
1730     color("red") {
1731       rectfromto(bppQ, demopoint_QR);
1732       rectfromto(bppR, demopoint_QR);
1733     }
1734   }
1735
1736   translate([-20,0]) {
1737     color("black") ButtonPlanForDemo(-2, 0,1);
1738     color("red" )  ButtonPlanForDemo(-4, 1,1);
1739     color("blue")  ButtonPlanForDemo(-6, 1,0);
1740   }
1741
1742   translate([0, -30]) {
1743     %LidEdgeProfile();
1744     %EdgeProfile();
1745     color("blue") HingeLidProfile();
1746     color("red")  HingeBaseProfile();
1747     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1748   }
1749
1750   for (f=[0,1]) {
1751     translate([-30, -60 + 30*f]) {
1752       translate([0,0,-4]) EdgeProfile();
1753       %translate([0,0,-10]) HingeBaseProfile();
1754       translate([0,-2] * f * hp_k) {
1755         translate([0,0,-4]) LidEdgeProfile();
1756         %translate([0,0,-10]) %HingeLidProfile();
1757       }
1758       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1759         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1760         translate([0,0,0]) color("red") difference(){
1761           HingeLeverOuterProfile();
1762           HingeLeverInnerProfile();
1763         }
1764         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1765       }
1766     }
1767   }
1768
1769   translate([20,-30]) {
1770     %EdgeProfile();
1771     %LidEdgeProfile();
1772     //translate([0,0,1]) ThumbRecessCutProfile();
1773     translate([0,0,+1]) color("red")
1774       difference(){ EdgeProfile(); ThumbRecessCutProfile(); }
1775   }
1776
1777   translate([40,-30]) {
1778     difference(){
1779       LidEdgeProfile();
1780       translate(prlp10)
1781         PropProfile(10, 1, 0);
1782     }
1783     translate(prlp10)
1784       PropProfile(15, 0);
1785   }
1786   translate([60,-30]) {
1787     PropAggregateProfile();
1788   }
1789 }
1790
1791 //EdgeProfile();
1792 //KeeperProfile();
1793 //CaseBase();
1794 //%Case();
1795 //Keeper();
1796 //LidEdgeProfile();
1797 //KeeperProfile();
1798 //DemoProfiles();
1799 //PropRecess();