fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172 lanyard_entry_rel_breadth = 2;
 173 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 174 rearspeaker_size   = [  3.76,  7.36 ];
 175
 176 microusb_above = 3.27 - 0.25;
 177 microusb_below = 0.0;
 178 microusb_width = 16.12 + 1.25;
 179
 180 case_th_bottom = 2.5;
 181 case_th_lid = 3.0;
 182 case_th_side = 2.3;
 183 case_th_lip = 1.2;
 184
 185 lid_screen_gap_extra = .66;
 186
 187 case_struts_count = 6;
 188 case_struts_solid_below = 1.00;
 189 case_struts_solid_above = 0.75;
 190 case_struts_width = 0.10;
 191
 192 keeper_th_z = 0.75;
 193 keeper_th_x = 0.75;
 194 keeper_inner_width = 2.75;
 195 keeper_inner_height = 2.75;
 196 keeper_slant_slope = 2; // larger means steeper
 197
 198 keeper_gap_z_top = 0.25;
 199 keeper_gap_z_bot = 0.75;
 200 keeper_gap_x     = 0.25;
 201 keeper_gap_x_holes = 0.75;
 202
 203 keeper_side = 0; // 0 = lhs; 1 = rhs
 204
 205 case_lip = 1.25;
 206
 207 lid_gap_x = 0.25;
 208 lid_gap_z = 0.25;
 209 lid_lip = 1.75;
 210 lid_edgepart_width = 5.0;
 211 lid_buttoncover_thick = 1.3;
 212
 213 catch_slop = 0.50;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 254
 255 catch_len = 7.5;
 256 catch_width = 15;
 257 catch_thickness = 1.0;
 258 catch_side_gap = 0.75; // each side
 259
 260 catch_depth = 0.75;
 261 catch_height = 0.35;
 262 catch_finger_height = 1.5;
 263 catch_finger_depth = 2.5;
 264
 265 catch_topcurve_r = 5.0;
 266
 267 prop_recess_under = 0.50;
 268 prop_recess_slop = 0.200; // each side
 269 prop_end_dia = 0.5;
 270 prop_main_th = 3;
 271 prop_taper_len = 6;
 272 prop_main_width = 4;
 273 prop_side_gap = 0.75; // each side
 274 prop_lidrecess_behind = 0.75;
 275 prop_caserecess_behind = 0.75;
 276 prop_caserecess_taper = 0.45; // one side only
 277 prop_prop_gap = 0.5;
 278 prop_prong_heel_slope = 0.5;
 279
 280 lid_fold_clearance_antislop = 0.5;
 281
 282 // ---------- calculated ----------
 283
 284 phone_width =  (phone + bumper*2)[0];
 285 phone_height = (phone + bumper*2)[1];
 286
 287 inside_br = [phone_width, -phone_height];
 288
 289 prop_prong_h = prop_main_th;
 290
 291 //echo(camera_pos_tl + bumper,
 292 //     camera_pos_br + bumper);
 293
 294 // ----- could be changed -----
 295 lid_buttoncover_gap = lid_gap_x;
 296 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 297
 298 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 299
 300 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 301
 302 //prop_nose_len = case_th_lid - prop_recess_under;
 303 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 304 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 305
 306
 307 //lid_lip_overlap_width xxx bad name = ;
 308 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 309
 310 epp0 = [0,0];
 311 epp1 = [0, -phone_edge_thick];
 312 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 313 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 314 epp3 = epp2i + [10, 0];
 315 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 316 epp4 = epp5 + [-1,0] * case_th_side;
 317
 318 kppe = [0,0];
 319 kppd = kppe + [1,0] * keeper_inner_width;
 320 kppc = kppd + [0,1] * keeper_th_z;
 321 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 322 kppf = kppe - [0,1] * keeper_inner_height;
 323 kppa = [ kppb[0], kppf[1] ];
 324
 325 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 326 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 327
 328 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 329 // exact x posn not very important; must extend past end of keeper
 330
 331 lpp15 = [ lpp14[0],
 332           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 333           + lid_screen_gap_extra ];
 334 // ^ beam theory says to maximise force before contact,
 335 //   the gap below the `beam' (the lid) must be 1/3
 336 //   the thickness (ie the lid thickness) if the beam
 337 //   is solid, or 1/2 if it has a top and bottom only.
 338 //   ours is mostly solid.
 339
 340 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 341              case_th_lip);
 342
 343 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 344 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 345
 346 case_bottom_z = epp2o[1] - case_th_bottom;
 347
 348 // button profile
 349 bppM = epp4 + [0,5];
 350 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 351 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 352 bppS = [ epp1[0], bppR[1] ];
 353 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 354 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 355 bppO = [ bppN[0], bppP[1] ];
 356 bppL = lpp10 + [5,0];
 357 bppK = [ bppL[0], bppN[1] ];
 358 bppJ = [ bppN[0], bppL[1] ];
 359 bppU = [ bppJ[0], lpp12[1] ];
 360 bppV = lpp11;
 361 bppW = lpp10;
 362
 363 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 364
 365 // notification led aperture
 366
 367 nla_r0 = led_aperture/2;
 368 nla_r1 = nla_r0 + led_window_ledge;
 369 nla_r2 = nla_r1 + multicolour_gap;
 370 nla_t =
 371   led_window_style >= 3 ? initial_layer_thick :
 372   led_window_style >= 2 ? led_window_ledge : 0;
 373
 374
 375 // hinge plan
 376 hp_rn = hingescrew_nut_access_dia/2;
 377 hp_r2_min = hp_rn + lever_cover_th;
 378 hp_rs = hingescrew_shaft_dia/2;
 379 hp_r1_min = hp_rs + hingemount_th;
 380
 381 hp_r1 = max(hp_r1_min, hp_r2_min);
 382 hp_r2 = hp_r1;
 383
 384 hppU = lpp13;
 385 hppS = epp2o + [0,-1] * case_th_bottom;
 386 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 387
 388 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 389          0.5 * (hppU + hppS)[1] ];
 390 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 391 hppB = hppT + [0,-1] * hp_k;
 392
 393 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 394 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 395 hppE = [ hppE_x, hppE_y ];
 396
 397 // hinge elevation x coords
 398
 399 hex20 = max(epp2o[0],
 400             phone_cnr_rad,
 401             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 402 hex21 = hex20 + hingemount_wd;
 403 hex22 = hex21 + hinge_x_gap;
 404 hex27 = hex20 + hingescrew_shaft_len;
 405 hex24 = hex27 + hinge_x_postscrew_gap;
 406 hex23 = hex27 - (hingescrew_nut_thick*2
 407                  + hingescrew_fasteners_extra_thick);
 408 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 409
 410 echo(hex20, hex21, hex22, hex23, hex24);
 411 //  6, 10.8725, 10.9975, 13.74, 18.75
 412 module chk(act,exp) {
 413   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 414   else echo("ok", act);
 415 }
 416 chk(hex20, 6);
 417 chk(hex21, 10.8725);
 418 chk(hex22, 10.9975);
 419 chk(hex23, 13.74);
 420 chk(hex24, 18.75);
 421
 422 lid_fold_clearance_skew =
 423   (lpp10[1] - hppB[1]) /
 424   (lpp10[0] - hppB[0]);
 425
 426 echo("SK",lid_fold_clearance_skew);
 427
 428 // catch
 429
 430 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 431 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 432 cppB = [ epp0[0], cppA[1] ];
 433 cppP = [ epp4[0], cppJ[1] ];
 434
 435 cppS = cppJ + [0,-1] * catch_len;
 436 cppD = [ cppA[0], cppS[1] + catch_slop ];
 437 cppC = [ cppB[0], cppD[1] ];
 438 cppT = cppS + [1,0] * catch_depth;
 439 cppU = cppT + [0,-1] * catch_height;
 440 cppV = [ cppS[0], cppU[1] - catch_depth ];
 441
 442 cppR = 0.5*(cppP + cppJ);
 443
 444 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 445 cppQ = [ cppR[0],
 446          cppV[1] - (catch_finger_height - cp_rQ) ];
 447 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 448
 449 // lanyard
 450
 451 ly_r = lanyard_half_dia / 2;
 452 ly_rc = ly_r * 2;
 453 ly_re = 10; // xxx
 454
 455 // prop recess in case
 456
 457 prop_x_pos = phone_width/2;
 458
 459 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 460
 461 prc_r1 = prop_end_dia/2;
 462 prc_r3 = prc_r1 + prop_recess_slop;
 463
 464 prcp2 = [ epp4[0] + prop_buildout_less,
 465           case_bottom_z ];
 466
 467 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 468
 469 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 470           epp2i[1] - prc_r3 - prop_recess_under];
 471
 472 // prop recess in lid
 473
 474 prl_r10 = prop_end_dia/2;
 475 prl_r10o = prl_r10 + prop_recess_slop;
 476
 477 prlp10 = lpp10 + [1,1] * prl_r10o
 478   + [1,0] * prop_lidrecess_behind
 479   + [0,1] * prop_recess_under;
 480
 481 // prop
 482
 483 $prpp10 = [0,0];
 484 $prpp11 = [0, prop_taper_len];
 485
 486 $prp_r10 = prl_r10;
 487
 488 // ---------- modules ----------
 489
 490 module AdhocMultiprintFrame(phase, z0, zs) {
 491   // from z0 to z0 + zs*layer
 492   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 493   xextra = extra + -epp4[0];
 494   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 495   yextra = extra + -epp4[0];
 496   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 497   p0 = [ xrange[0], yrange[0] ];
 498   p1 = [ xrange[1], yrange[1] ];
 499   echo(p0, p1);
 500   translate([0,0, z0])
 501     mirror([0,0, zs<0 ? 1 : 0])
 502     linear_extrude(height= initial_layer_thick)
 503     difference(){
 504       rectfromto(p0 - [1,1] * initial_layer_width,
 505                  p1 + [1,1] * initial_layer_width);
 506       rectfromto(p0, p1);
 507     }
 508 }
 509
 510 module KeeperProfile(slant=0){
 511   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 512   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 513 }
 514
 515 module EdgeProfile(){
 516   difference(){
 517     hull(){
 518       translate(epp3) square(case_th_bottom*2, center=true);
 519       circleat(epp2o, r=case_th_bottom);
 520       circleat(epp1, r=case_th_side);
 521       rectfromto(epp0, epp4);
 522     }
 523     polygon([ epp5 + [0,10],
 524               epp1,
 525               epp2i,
 526               epp3 + [10,0] ]);
 527   }
 528 }
 529
 530 module LanyardLanyardProfile(entry=false){
 531   hull(){
 532     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 533       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 534         circle(r= lanyard_half_dia/2);
 535   }
 536 }
 537
 538 module LanyardCurveChannelProfile(){
 539   translate([0, -ly_r])
 540     LanyardLanyardProfile();
 541 }
 542
 543 module LanyardEntryChannelProfile(){
 544   LanyardLanyardProfile(true);
 545 }
 546
 547 module LanyardMainChannelProfile(){
 548   LanyardCurveChannelProfile();
 549   difference(){
 550     square(center=true, ly_r * [6, 2]);
 551     for (xs=[-1,+1])
 552       translate(ly_r * [3 * xs, -1])
 553         circle(r = ly_r);
 554   }
 555 }
 556
 557 module LanyardEntry(){
 558   q_z = -(ly_rc + ly_r);
 559   d_x = -ly_rc;
 560
 561   oec_y = lanyard_entry_rel_breadth * ly_r;
 562
 563   translate([d_x, 0, q_z]) {
 564     intersection(){
 565       rotate([90,0,0])
 566         rotate_extrude(convexity=10)
 567         rotate(90)
 568         translate([0, -q_z])
 569         LanyardCurveChannelProfile();
 570       translate([0,-10,0])
 571         cube([20,20,20]);
 572     }
 573   }
 574
 575   mirror([0,0,1])
 576     translate([0,0,-1])
 577     linear_extrude(height=20)
 578     rotate(-90)
 579     LanyardEntryChannelProfile();
 580
 581   translate([0, ly_r*2, 0])
 582     rotate([90,0,0])
 583     linear_extrude(height = ly_r*4){
 584     difference(){
 585       rectfromto([d_x, q_z], [ly_r, 0]);
 586       circleat([d_x, q_z], ly_rc);
 587     }
 588   }
 589
 590   translate([0,0,q_z]){
 591     for (my=[0,1])
 592       mirror([0,my,0]){
 593         translate([0, oec_y, 0]){
 594           difference(){
 595             translate(ly_re * [-1,0,-1])
 596               cube(ly_re * [2,1,1]);
 597             rotate_extrude(convexity=10)
 598               circleat([ly_re + ly_r, 0], ly_re);
 599           }
 600         }
 601       }
 602   }
 603 }
 604
 605 module LanyardCutout(l){
 606   rotate([0,-90,0])
 607     linear_extrude(height=l)
 608     rotate(-90)
 609     LanyardMainChannelProfile();
 610
 611   for (ee=[0,1]){
 612     translate(ee * l * [-1,0])
 613       mirror([ee,0,0])
 614       LanyardEntry();
 615   }
 616 }
 617
 618 module LidEdgeProfile(){
 619   polygon([ lpp10,
 620             lpp11,
 621             lpp12,
 622             lpp13,
 623             lpp13 + [10, 0],
 624             lpp15 + [10, 0],
 625             lpp15,
 626             lpp14,
 627             ]);
 628   intersection(){
 629     circleat(lpp12, r=lp_r12);
 630     rectfromto( lpp12 + [-10,   0],
 631                 lpp12 + [+10, +10] );
 632   }
 633 }
 634
 635 module LidEdgeFoldClearanceProfile(){
 636   translate([-lid_fold_clearance_antislop, 0])
 637     polygon([ lpp10,
 638               lpp11,
 639               lpp11 + [-20,  0],
 640               lpp11 + [-20, 20],
 641               lpp11 + [+20, 20],
 642               lpp10 + [+20,  0] ]);
 643 }
 644
 645 module ButtonCoverProfile(){
 646   intersection(){
 647     polygon(concat([ bppM, bppP, bppO, bppJ ],
 648                    (enable_support && !$button_suppress_over_keeper
 649                     ? [ bppU, bppV, bppW ] : []),
 650                    [ bppL, bppK ]));
 651     hull(){
 652       EdgeProfile();
 653       LidEdgeProfile();
 654     }
 655   }
 656 }
 657
 658 module ButtonPlan(l, deep, cut){
 659   epsilon =
 660     (cut  ? 0 : lid_buttoncover_gap);
 661
 662   delta =
 663     (deep ? lid_buttoncover_overlap : 0);
 664
 665   C = [0,0]; // by definition
 666   T = [ 0, epp4[1] ];
 667   G = T + [0,10];
 668
 669   B0 = C + [0,-1] * button_cutout_depth;
 670   B1 = B0 + [0,1] * epsilon;
 671
 672   r0 = 0.5 * (T[1] - B0[1]);
 673   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 674   H = A + [0,-1] * delta;
 675
 676   D = A + [-2,0] * r0;
 677   F = D + [0,10];
 678
 679   E0 = 0.5 * (D + A);
 680   E1 = E0 + [1,0] * epsilon;
 681
 682   I0 = [ E0[0], H[1] ];
 683   I1 = [ E1[0], H[1] ];
 684
 685   hull(){
 686     for (m=[0,1]) mirror([m,0])
 687       circleat(H, r0 - epsilon);
 688   }
 689   for (m=[0,1]) mirror([m,0]) {
 690     difference(){
 691       polygon([ E1,
 692                 I1,
 693                 H,
 694                 B1,
 695                 G,
 696                 F,
 697                 D
 698                 ]);
 699       circleat(D, r0 + epsilon);
 700     }
 701   }
 702 }
 703
 704 module CatchCatchProfile(){
 705   hull(){
 706     for (c=[ cppR, cppQ ])
 707       circleat(c, cp_rQ);
 708   }
 709   hull(){
 710     circleat(lpp12, lp_r12);
 711     circleat(lpp12 + [5,0], lp_r12);
 712     rectfromto(cppP, cppP + [5,0.1]);
 713   }
 714   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 715 }
 716
 717 module CatchCutProfile(){
 718   polygon([ cppB,
 719             cppA,
 720             cppD,
 721             cppF,
 722             cppF + [0,-10],
 723             cppF + [-10,-10],
 724             lpp12 + [-10,0],
 725             lpp12 + [10,0]
 726             ]);
 727 }
 728
 729 module Flip_rhs(yn=[0,1]) {
 730   for ($rhsflip=yn) {
 731     translate([phone_width/2, 0, 0])
 732       mirror([$rhsflip,0,0])
 733       translate([-phone_width/2, 0, 0])
 734       children();
 735   }
 736 }
 737
 738 module Flip_bot(yn=[0,1]) {
 739   for ($botflip=yn) {
 740     translate([0, -phone_height/2, 0])
 741       mirror([0, $botflip, 0])
 742       translate([0, phone_height/2, 0])
 743       children();
 744   }
 745 }
 746
 747 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 748   // sides
 749   Flip_rhs(){
 750     translate([0, -phone_cnr_rad, 0])
 751       rotate([90,0,0])
 752       linear_extrude(height = phone_height - phone_cnr_rad*2)
 753       children(0);
 754   }
 755   // corners
 756   Flip_rhs() Flip_bot() {
 757     translate([+1,-1] * phone_cnr_rad)
 758       intersection(){
 759         rotate_extrude()
 760           intersection(){
 761             mirror([1,0,0])
 762               translate([-1,0] * phone_cnr_rad)
 763               children(0);
 764             rectfromto([0,-20],[10,20]);
 765           }
 766         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 767           cube([10,10,40]);
 768       }
 769   }
 770   // top and bottom
 771   Flip_bot(){
 772     translate([ phone_width - phone_cnr_rad, 0,0 ])
 773       rotate([90,0,-90])
 774       linear_extrude(height = phone_width - phone_cnr_rad*2)
 775       children(0);
 776   }
 777   // fill
 778   translate([0,0, fill_zstart])
 779     mirror([0,0, fill_downwards])
 780     linear_extrude(height = fill_th)
 781     rectfromto([+1,-1] * phone_cnr_rad,
 782                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 783 }
 784
 785 module CaseAperture(pos, dia, $fn) {
 786   theta = 180/$fn;
 787   translate([ pos[0] + bumper[0],
 788               -epp2i[0],
 789               -pos[1] ])
 790     rotate([-90, theta, 0])
 791     cylinder(r = dia/2 / cos(theta),
 792              h = 60);
 793 }
 794
 795 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 796   // y_ref_sign:
 797   //   +1  measured from top    of actual phone to top    of button
 798   //   -1  measured from bottom of actual phone to bottom of button
 799   //    0  y is centre of button in coordinate system
 800   $button_l= l;
 801   $button_suppress_over_keeper= suppress_over_keeper;
 802   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 803           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 804           y;
 805   //echo(eff_y);
 806   translate([0, eff_y, 0])
 807     children();
 808 }
 809
 810 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 811   $button_leg_only = true;
 812   SideButton(y, y_ref_sign, l) children();
 813 }
 814
 815 module Buttons(){
 816   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 817   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 818   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 819   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 820 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 821 }
 822
 823 module Struts(x_start, z_min, th){
 824   // if th is negative, starts at z_min and works towards -ve z
 825   // and object should then be printed other way up
 826   for (i= [1 : 1 : case_struts_count]) {
 827     translate([0,
 828                0,
 829                z_min])
 830       mirror([0,0, th<0 ? 1 : 0])
 831       translate([0,
 832                  -phone_height * i / (case_struts_count+1),
 833                  case_struts_solid_below])
 834       linear_extrude(height= abs(th)
 835                      -(case_struts_solid_below+case_struts_solid_above))
 836       rectfromto([               x_start, -0.5 * case_struts_width ],
 837                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 838   }
 839 }
 840
 841 module OrdinaryRearAperture(rhs,bot, pos){
 842   Flip_rhs(rhs) Flip_bot(bot)
 843     linextr(-20, 20)
 844     mirror([0,1])
 845     translate(pos + bumper)
 846     children();
 847 }
 848
 849 module MicroUSB(){
 850   Flip_bot(1){
 851     rotate([90,0,0])
 852       mirror([0,0,1])
 853       linextr(-epp2i[0], 60)
 854       translate([0.5 * phone_width, 0, 0])
 855       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 856                  [+microusb_width/2, epp0[1] + -microusb_above]);
 857   }
 858 }
 859
 860 module OrdinaryRearApertures(){
 861   // rear speaker
 862   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 863     rectfromto(-rearspeaker_gap,
 864                rearspeaker_size + rearspeaker_gap);
 865
 866   // finger hole to remove phone
 867   if (len(fingerpushhole_dias))
 868     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 869                                 phone[1]/2 ])
 870     scale(fingerpushhole_dias)
 871     circle(r= 0.5 );
 872 }
 873
 874 module RearCameraAperture(){
 875   Flip_rhs(1)
 876     mirror([0, 0, 1])
 877     linear_extrude(height = 20)
 878     mirror([0, 1, 0])
 879     translate(bumper)
 880     rectfromto(camera_pos_tl, camera_pos_br);
 881 }
 882
 883 module HingeLidProfile(){
 884   hull(){
 885     circleat(hppT, hp_r1);
 886     circleat(lpp12, lp_r12);
 887     polygon([lpp10,
 888              lpp13 + [2,0],
 889              lpp12,
 890              hppT]);
 891   }
 892 }
 893
 894 module HingeBaseProfile(){
 895   difference(){
 896     hull(){
 897       circleat(hppB, hp_r1);
 898       circleat(hppE, hp_r1);
 899       circleat(epp2o, case_th_bottom);
 900       circleat(hppB + [10,0], hp_r1);
 901     }
 902     polygon([epp5, epp1, epp2i, epp3, bppL]);
 903   }
 904 }
 905
 906 module HingeLeverOuterProfile(){
 907   hull(){
 908     circleat(hppT, hp_r2);
 909     circleat(hppB, hp_r2);
 910   }
 911 }
 912
 913 module HingeLeverInnerProfile(){
 914   for (s = [-1,+1]) {
 915     c = s > 0 ? hppT : hppB;
 916     translate(c)
 917       mirror([0,0,s>0])
 918       rotate(s<0 ? -40 : 0)
 919       hull()
 920       for (x=[-20,20])
 921         for (y=[0, s * 10])
 922           translate([x,y])
 923             circle(hp_rn);
 924   }
 925 }
 926
 927 module HingeLeverNutProfile(){
 928   for (c= [hppB, hppT]) {
 929     translate(c)
 930       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 931   }
 932 }
 933
 934 module Flip_hinge(doflip=1){
 935   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 936   translate(hinge_origin)
 937     rotate([doflip*180,0,0])
 938     translate(-hinge_origin)
 939     children();
 940 }
 941
 942 module HingePortion(x0,x1){
 943   Flip_rhs() Flip_bot(1)
 944     translate([x0,0,0])
 945     mirror([1,0,0])
 946     rotate([90,0,-90])
 947     linear_extrude(height=x1-x0)
 948     children();
 949 }
 950
 951 module CatchPortion(xwidth, ztop){
 952   width = catch_width + xwidth;
 953   w = width + catch_topcurve_r*2 + 1;
 954   translate([phone_width/2, 0,0]){
 955     difference(){
 956       rotate([90,0,-90])
 957         linextr(-w/2, w/2)
 958         children(0);
 959       translate([0, 50, 0])
 960         rotate([90,0,0])
 961         linear_extrude(height=100){
 962         for (m=[0,1]) mirror([m,0,0]) {
 963           hull(){
 964             translate([w/2, ztop - catch_topcurve_r])
 965               circle(catch_topcurve_r);
 966             translate([w/2, -50])
 967               square(catch_topcurve_r*2, center=true);
 968           }
 969         }
 970       }
 971     }
 972   }
 973 }
 974
 975 module CaseBase(){
 976   AroundEdges(epp3[1], case_th_bottom, 1)
 977     EdgeProfile();
 978 }
 979
 980 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 981
 982 module PropProfileAssignments(gamma){
 983   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 984   x = prop_x(gamma);
 985   p = phone_height + prlp10[0] - hppB[0];
 986   b = p + x;
 987
 988   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 989   a = q + x;
 990   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 991   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 992
 993   $prp_theta = 90 - $prp_alpha;
 994   beta = 180 - $prp_alpha - gamma;
 995   psi = 90 - beta;
 996
 997   //echo("abc", a,b,c);
 998
 999   v1 = [ [ cos(psi), -sin(psi) ],    // x
1000          [ sin(psi),  cos(psi) ] ];  // y
1001
1002   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1003
1004   $prp_r1 = prc_r1;
1005   $prp_r11 = prop_main_th/2;
1006
1007   $prpp1 = $prpp7 + [1,0] *
1008     // this is approximate, but will do
1009     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1010   $prpp3 = $prpp1 +
1011     v1[0] * -$prp_r1 +
1012     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1013   $prpp12 = $prpp3 + v1[0] *
1014     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1015   $prp_r8 = prop_main_th;
1016   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1017   $prp_r5 = $prp_r8;
1018   $prpp5 = [ $prpp12[0] - $prp_r5,
1019             $prpp3[1] - prop_prong_h + $prp_r5 ];
1020   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1021          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1022   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1023   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1024
1025   children();
1026 }
1027
1028 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
1029   PropProfileAssignments(gamma){
1030
1031     //#circleat($prpp3,1);
1032     //#circleat($prpp12,1);
1033
1034     if (!cut) {
1035       hull(){
1036         translate($prpp8)
1037           intersection(){
1038             circle($prp_r8);
1039             polygon([[-20,-0], [20,20], [0,0]]);
1040           }
1041         rectfromto($prpp6, $prpp9);
1042         translate($prpp5) intersection(){
1043           circle($prp_r5);
1044           polygon([[-10,-10], [0,0], [10,0]]);
1045         }
1046         rectfromto($prpp12 + [0,-0.1], $prpp3);
1047       }
1048       hull(){
1049         circleat($prpp1, $prp_r1);
1050         rectfromto($prpp12 + [0,-0.1], $prpp3);
1051       }
1052     }
1053     // main shaft
1054     rotate([0,0, rot*-$prp_theta]){
1055       hull(){
1056         extra = cut ? prop_recess_slop : 0;
1057         rectfromto($prpp6, $prpp9);
1058         circleat($prpp11, $prp_r11 + extra);
1059         circleat($prpp10, $prp_r10 + extra);
1060       }
1061     }
1062   }
1063 }
1064
1065 module PropAggregateProfile(){
1066   for (angle = prop_angles)
1067     PropProfile(angle, 0,0);
1068 }
1069
1070 module Prop(){ ////toplevel
1071   hw = prop_main_width/2;
1072   linextr(-hw, +hw)
1073     PropAggregateProfile();
1074 }
1075
1076 module Case(){ ////toplevel
1077   difference(){
1078     union(){
1079       CaseBase();
1080
1081       // ledge (fixed keeper)
1082       Flip_rhs(1-keeper_side) intersection(){
1083         rotate([90, 0, 0])
1084           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1085           KeeperProfile(1);
1086
1087         // outline of the whole case, to stop it protruding
1088         translate([0,0, -25])
1089           linear_extrude(height = 50)
1090           hull()
1091           Flip_bot()
1092           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1093       }
1094
1095       // hinge
1096       HingePortion(hex20, hex21) HingeBaseProfile();
1097
1098       // buildout for prop recess
1099       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1100         linextr(case_bottom_z, epp2i[1])
1101         hull() {
1102           for (dxs = [-1,+1])
1103             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1104                        -epp2o[0] ],
1105                      r = epp2o[0] - prcp2[0]);
1106         }
1107     }
1108
1109     // slot for keeper
1110     Flip_rhs(keeper_side)
1111       translate([0, -phone_cnr_rad, 0])
1112       rotate([90, 0, 0])
1113       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1114       minkowski(){
1115         KeeperProfile();
1116         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1117                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1118       }
1119
1120     // front camera
1121     RearCameraAperture();
1122
1123     // struts (invisible, because they're buried in the case)
1124     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1125
1126     Buttons(){
1127       mirror([1,0,0])
1128         rotate([90,0,90]) {
1129           if (!($button_leg_only && enable_support))
1130           intersection(){
1131             translate([0,0,-10])
1132               linear_extrude(height= 20)
1133               ButtonPlan($button_l, 0,1);
1134             if ($button_leg_only)
1135               rotate([-90,90,0])
1136                 translate([phone_width/2, -400, kppe[1]])
1137                 mirror([1-abs($rhsflip - keeper_side),0,0])
1138                 cube([400, 800, 50]);
1139             if (enable_support && !$button_suppress_over_keeper)
1140               rotate([-90,90,0])
1141               translate([-400, -400, kppd[1]])
1142                 mirror([0,0,1])
1143                 cube([800,800,100]);
1144           }
1145           translate([0,0, -bppR[0]])
1146             linear_extrude(height= 20)
1147             ButtonPlan($button_l, 1,1);
1148         }
1149
1150     }
1151
1152     // apertures along top edge
1153     CaseAperture(jack_pos, jack_dia, 8);
1154     Flip_rhs(1)
1155       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1156
1157     OrdinaryRearApertures();
1158
1159     MicroUSB();
1160
1161     // gaps for the lid's hinge arms
1162     HingePortion(hex20 - hinge_x_arms_gap,
1163                  hex21 + hinge_x_arms_gap)
1164       minkowski(){
1165         HingeLidProfile();
1166         circle(r= hinge_r_arms_gap, $fn= 8);
1167       }
1168
1169     // screw holes in the hinge arms
1170     HingeScrews();
1171
1172     // catch striker
1173     CatchPortion(catch_side_gap*2, epp4[1])
1174       CatchCutProfile();
1175
1176     // prop recess
1177     Flip_rhs(1)
1178       translate([prop_x_pos,0,0])
1179       mirror([0,1,0])
1180       rotate([90,0,90])
1181       linextr(-prop_recess_hw, +prop_recess_hw)
1182       hull(){
1183         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1184           circleat(prcp1 + 20*d,
1185                    prc_r3);
1186       }
1187   }
1188 }
1189
1190 module LidAdhocMultiprintFrame(phase){
1191   if (led_window_style >= 3) {
1192     AdhocMultiprintFrame(phase, lpp13[1], -1);
1193   }
1194 }
1195
1196 module LidAroundEdges(){
1197   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1198     children();
1199 }
1200
1201 module Lid(){ ////toplevel
1202   skew_centre = [0, lpp11[0], lpp11[1]];
1203   difference(){
1204     union(){
1205       intersection(){
1206         LidAroundEdges()
1207           LidEdgeProfile();
1208
1209         translate(skew_centre)
1210           multmatrix([[ 1, 0, 0, 0 ],
1211                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1212                       [ 0, 0, 1, 0 ],
1213                       [ 0, 0, 0, 1 ]])
1214           translate(-skew_centre)
1215           LidAroundEdges()
1216           LidEdgeFoldClearanceProfile();
1217       }
1218
1219       // button covers
1220       Buttons(){
1221         intersection(){
1222           rotate([90,0,90])
1223             translate([0,0,-10])
1224             linear_extrude(height= 20)
1225             ButtonPlan($button_l, 1,0);
1226           rotate([90,0,0])
1227              translate([0,0,-100])
1228             linear_extrude(height= 200)
1229             ButtonCoverProfile();
1230         }
1231       }
1232
1233       // hinge arms
1234       HingePortion(hex20, hex21) {
1235         LidEdgeProfile();
1236         HingeLidProfile();
1237       }
1238
1239       // catch
1240       CatchPortion(0, lpp12[1])
1241         CatchCatchProfile();
1242     }
1243     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1244
1245     // screw holes in the hinge arms
1246     HingeScrews();
1247
1248     // prop recess
1249     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1250       mirror([0,1,0])
1251       rotate([90,0,90])
1252       linextr(-prop_recess_hw, +prop_recess_hw)
1253       hull()
1254       for (pa = prop_angles)
1255         PropProfile(pa, 1,1);
1256
1257     // notification led aperture
1258     if (led_window_style)
1259       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1260         translate([0,0,-10])
1261           cylinder(r=nla_r0, h=20);
1262         if (led_window_style >= 2)
1263           translate([0,0, -nla_t])
1264             cylinder(r=nla_r2, height=20);
1265       }
1266
1267     }
1268
1269   LidAdhocMultiprintFrame(1);
1270 }
1271
1272 module HingeLever(){ ////toplevel
1273   difference() {
1274     // outer body, positive
1275     HingePortion(hex22, hex22 + phone_width/2)
1276       HingeLeverOuterProfile();
1277
1278     // space for the screws
1279     HingePortion(hex26, hex24)
1280       HingeLeverInnerProfile();
1281
1282     // recesses for the nuts
1283     HingePortion(hex23, hex26+1)
1284       HingeLeverNutProfile();
1285
1286     // bores for the screws
1287     HingeScrews();
1288
1289     // space for the charging cable
1290     MicroUSB();
1291     Flip_hinge() MicroUSB();
1292   }
1293 }
1294
1295 module LidWindow(){ ////toplevel
1296   translate([led_pos[0], -led_pos[1], lpp13[1]])
1297     mirror([0,0,1])
1298     cylinder(r= nla_r1, h=nla_t);
1299   LidAdhocMultiprintFrame(0);
1300 }
1301
1302 module LidWindowPrint(){ ////toplevel
1303   rotate([0,180,0])
1304     LidWindow();
1305 }
1306
1307 module DemoLidWindowSelect(){
1308   translate([led_pos[0], led_pos[1], -100]) {
1309     translate([0, -30, 0]) cube([400, 400, 200]);
1310   }
1311 }
1312
1313 module DemoLidWindow(){ ////toplevel
1314   %Lid();
1315   LidWindow();
1316   translate([0,40,0]){
1317     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1318     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1319   }
1320 }
1321
1322 module HingeLeverPrint(){ ////toplevel
1323   rotate([-90,0,0])
1324     translate([-phone_width/2, phone_height, 0])
1325     HingeLever();
1326 }
1327
1328 module TestSelectLength(){
1329   translate([-30, -200, -20])
1330     cube([30 + 15, 250, 40]);
1331 }
1332
1333 module TestLength(){ ////toplevel
1334   intersection(){
1335     Case();
1336     TestSelectLength();
1337   }
1338 }
1339
1340 module TestLengthRight(){ ////toplevel
1341   intersection(){
1342     Case();
1343     Flip_rhs(1)
1344       TestSelectLength();
1345   }
1346 }
1347
1348 module TestSelectWidth(){
1349   translate([-30, -(phone_height - 25), -20])
1350     mirror([0, 1, 0])
1351     cube([200, 50, 40]);
1352 }
1353
1354 module TestWidth(){ ////toplevel
1355   intersection(){
1356     Case();
1357     TestSelectWidth();
1358   }
1359 }
1360
1361 module TestLidWidthPrint(){ ////toplevel
1362   rotate([0,180.0]) intersection(){
1363     Lid();
1364     TestSelectWidth();
1365   }
1366 }
1367
1368 module TestSelectRearAperture(){
1369   minkowski(){
1370     union() children();
1371     translate([20, 0,0])
1372       cube([42, 2, 1], center=true);
1373   }
1374 }
1375
1376 module TestSelectCamera(){
1377   minkowski(){
1378     TestSelectRearAperture()
1379       RearCameraAperture();
1380     cube([0.1, 50, 0.1]);
1381   }
1382 }
1383
1384 module TestSelectOrdinaryRearApertures(){
1385   TestSelectRearAperture()
1386     OrdinaryRearApertures();
1387 }
1388
1389 module TestCamera(){ ////toplevel
1390   intersection(){
1391     Case();
1392     TestSelectCamera();
1393   }
1394 }
1395
1396 module TestLidByCamera(){ ////toplevel
1397   intersection(){
1398     Lid();
1399     TestSelectCamera();
1400   }
1401 }
1402
1403 module TestLidByCameraPrint(){ ////toplevel
1404   rotate([180,0,0]) TestLidByCamera();
1405 }
1406
1407 module DemoByCamera(){ ////toplevel
1408   color("blue") TestLidByCamera();
1409   color("red")  TestCamera();
1410 }
1411
1412 module OneKeeper(){ ////toplevel
1413   translate([0, -phone_cnr_rad, 0])
1414     rotate([90, 0, 0])
1415     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1416     KeeperProfile();
1417 }
1418
1419 module OneKeeperPrint(){ ////toplevel
1420   rotate([0,180,0])
1421     OneKeeper();
1422 }
1423
1424 module LidPrint(){ ////toplevel
1425   rotate([0,180,0])
1426     Lid();
1427 }
1428
1429 module TestSelectFrame(){
1430   include = [1,-1] * (epp2i[0] + 4);
1431
1432   difference(){
1433     cube(1000, center=true);
1434     translate([0,0, -100])
1435       linear_extrude(height=200)
1436       rectfromto(include,  inside_br - include);
1437   }
1438 }
1439
1440 module TestSelectLidFrame(){
1441   TestSelectFrame();
1442   translate([led_pos[0], -led_pos[1], -50])
1443     cylinder(r= nla_r2+3, h=100);
1444 }
1445
1446 module TestFrameCase(){ ////toplevel
1447   intersection(){
1448     Case();
1449     union(){
1450       TestSelectFrame();
1451       TestSelectCamera();
1452       TestSelectOrdinaryRearApertures();
1453     }
1454   }
1455 }
1456
1457 module TestSelectTopApertures(){
1458   translate([-100, -35, -100])
1459     cube([400, 100, 200]);
1460   LidAdhocMultiprintFrame(0);
1461   LidAdhocMultiprintFrame(1);
1462 }
1463
1464 module TestTopApertures(){ ////toplevel
1465   intersection(){
1466     Case();
1467     TestSelectFrame();
1468     TestSelectTopApertures();
1469   }
1470 }
1471
1472 module TestLidTopAperturesPrint(){ ////toplevel
1473   rotate([0,180,0]) intersection(){
1474     Lid();
1475     TestSelectLidFrame();
1476     TestSelectTopApertures();
1477   }
1478 }
1479
1480 module TestLidWindowTopAperturesPrint(){ ////toplevel
1481   rotate([0,180,0]) intersection(){
1482     LidWindow();
1483     TestSelectTopApertures();
1484   }
1485 }
1486
1487 module TestFrameLidPrint(){ ////toplevel
1488   rotate([0,180,0]) intersection(){
1489     Lid();
1490     TestSelectLidFrame();
1491   }
1492 }
1493
1494 module ButtonPlanForDemo(z, deep, cut){
1495   translate([0,0,z])
1496     ButtonPlan(8, deep, cut);
1497 }
1498
1499 module HingeScrews(){
1500   Flip_rhs() Flip_bot(1){
1501     for (c= [ hppT, hppB ])
1502       translate([ hex20,
1503                   -c[0],
1504                   c[1] ]){
1505         rotate([0,90,0])
1506           translate([0,0,-.2])
1507           cylinder( r= hingescrew_shaft_dia/2,
1508                     h = hingescrew_shaft_len+0.2 );
1509         rotate([0,-90,0])
1510           translate([0,0,+.1])
1511           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1512       }
1513   }
1514 }
1515
1516 module DemoPropAngleSelect(c){
1517   color(c) difference(){
1518     union(){ children(); }
1519     translate([ prop_x_pos, -400, -200 ])
1520       cube([ 400,800,400 ]);
1521   }
1522 }
1523
1524 module DemoPropAngle(ang){
1525   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1526   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1527
1528   translate(hL)
1529     rotate([ang/2,0,0])
1530     translate(-hL)
1531     translate(hC)
1532     rotate([ang/2,0,0])
1533     translate(-hC) {
1534       DemoPropAngleSelect("red") Case();
1535
1536       color("orange")
1537         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1538         PropProfileAssignments(ang) {
1539           echo($prpp1);
1540           rotate([-$prp_theta, 0, 0])
1541           translate([0, $prpp1[0], -$prpp1[1]])
1542           rotate([90,0,-90])
1543           Prop();
1544         }
1545     }
1546
1547   translate([0,0, -hp_k*2])
1548     DemoPropAngleSelect("blue")
1549     Lid();
1550 }
1551
1552 module DemoPropAngles(){ ////toplevel
1553   for (i=[0 : len(prop_angles)-1])
1554     translate(i * [0, -100, 100])
1555     DemoPropAngle(prop_angles[i]);
1556 }
1557
1558 module DemoHingeAngle(ang1,ang2){
1559   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1560   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1561
1562   translate(hL)
1563     rotate([ang2,0,0])
1564     translate(-hL)
1565     translate(hC)
1566     rotate([ang1,0,0])
1567     translate(-hC) {
1568       color("red") Lid();
1569     }
1570
1571   color("blue") intersection(){
1572     Case();
1573     union(){
1574       translate([bppJ[0], -400, -200])
1575         mirror([1,0,0])
1576         cube([400, 800, 400]);
1577       translate([10, -400, -200])
1578         cube([10, 800, 400]);
1579     }
1580   }
1581 }
1582
1583 module DemoHingeAngles(){ ////toplevel
1584   angles = [ 0, 4, 8, 12 ];
1585   echo("angles",angles);
1586   for (i=[0 : len(angles)-1]) {
1587     translate(i * [0, 0, 30]) {
1588       DemoHingeAngle(0,angles[i]);
1589       translate([0, 200, 0])
1590         DemoHingeAngle(angles[i],0);
1591     }
1592   }
1593 }
1594
1595 module DemoSelectAdhocLeftRight(right=0) {
1596   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1597     mirror([1-right, 0,0])
1598     cube([400, 800, 200]);
1599 }
1600
1601 module DemoLeft(){ ////toplevel
1602   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1603   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1604 }
1605
1606 module DemoFrame(){ ////toplevel
1607   color("red") TestFrameCase();
1608   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1609   color("black") HingeScrews();
1610   %HingeLever();
1611 }
1612
1613 module DemoLanyardCutout(){ ////toplevel
1614   LanyardCutout(25);
1615 }
1616
1617 module DemoHingedFrame(){ ///toplevel
1618   color("red") TestFrameCase();
1619   translate([0,0, -2*hp_k])
1620   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1621
1622   Flip_hinge(){
1623     color("orange") HingeLever();
1624     color("black") HingeScrews();
1625   }
1626 }
1627
1628 module DemoHinge(){ ////toplevel
1629   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1630     DemoFrame();
1631     translate([0,0, -hp_k*3])
1632       DemoHingedFrame();
1633   }
1634 }
1635
1636 module DemoProfiles(){ ////toplevel
1637   LidEdgeProfile();
1638   %EdgeProfile();
1639   KeeperProfile();
1640   translate([0,0,-1]) color("black") KeeperProfile(1);
1641   color("purple") translate(epp2i)
1642     rotate(atan2vector(epp2i - epp1)) {
1643     translate(lanyard_half_dia * 0.5 * [-3,-1])
1644       LanyardLanyardProfile();
1645     translate(lanyard_half_dia * 0.5 * [-3,+1])
1646       translate([0,-1] * case_th_side)
1647       LanyardLanyardProfile(true);
1648   }
1649
1650   translate([0,20]) {
1651     LanyardMainChannelProfile();
1652     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1653     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1654   }
1655
1656   translate([20,0]) {
1657     LidEdgeProfile();
1658     %EdgeProfile();
1659
1660     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1661
1662     color("blue") ButtonCoverProfile();
1663     color("red") {
1664       rectfromto(bppQ, demopoint_QR);
1665       rectfromto(bppR, demopoint_QR);
1666     }
1667   }
1668
1669   translate([-20,0]) {
1670     color("black") ButtonPlanForDemo(-2, 0,1);
1671     color("red" )  ButtonPlanForDemo(-4, 1,1);
1672     color("blue")  ButtonPlanForDemo(-6, 1,0);
1673   }
1674
1675   translate([0, -30]) {
1676     %LidEdgeProfile();
1677     %EdgeProfile();
1678     color("blue") HingeLidProfile();
1679     color("red")  HingeBaseProfile();
1680     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1681   }
1682
1683   for (f=[0,1]) {
1684     translate([-30, -60 + 30*f]) {
1685       translate([0,0,-4]) EdgeProfile();
1686       %translate([0,0,-10]) HingeBaseProfile();
1687       translate([0,-2] * f * hp_k) {
1688         translate([0,0,-4]) LidEdgeProfile();
1689         %translate([0,0,-10]) %HingeLidProfile();
1690       }
1691       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1692         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1693         translate([0,0,0]) color("red") difference(){
1694           HingeLeverOuterProfile();
1695           HingeLeverInnerProfile();
1696         }
1697         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1698       }
1699     }
1700   }
1701
1702   translate([20,-30]) {
1703     %EdgeProfile();
1704     %LidEdgeProfile();
1705     //translate([0,0,1]) CatchCutProfile();
1706     color("blue") CatchCatchProfile();
1707     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1708   }
1709
1710   translate([40,-30]) {
1711     difference(){
1712       LidEdgeProfile();
1713       translate(prlp10)
1714         PropProfile(10, 1, 0);
1715     }
1716     translate(prlp10)
1717       PropProfile(15, 0);
1718   }
1719   translate([60,-30]) {
1720     PropAggregateProfile();
1721   }
1722 }
1723
1724 //EdgeProfile();
1725 //KeeperProfile();
1726 //CaseBase();
1727 //%Case();
1728 //Keeper();
1729 //LidEdgeProfile();
1730 //KeeperProfile();
1731 //DemoProfiles();
1732 //PropRecess();