fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172 lanyard_entry_rel_breadth = 2;
 173 lanyard_channel_len = 15;
 174 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 175 rearspeaker_size   = [  3.76,  7.36 ];
 176
 177 microusb_above = 3.27 - 0.25;
 178 microusb_below = 0.0;
 179 microusb_width = 16.12 + 1.25;
 180
 181 case_th_bottom = 2.5;
 182 case_th_lid = 3.0;
 183 case_th_side = 2.3;
 184 case_th_lip = 1.2;
 185
 186 lid_screen_gap_extra = .66;
 187
 188 case_struts_count = 6;
 189 case_struts_solid_below = 1.00;
 190 case_struts_solid_above = 0.75;
 191 case_struts_width = 0.10;
 192
 193 keeper_th_z = 0.75;
 194 keeper_th_x = 0.75;
 195 keeper_inner_width = 2.75;
 196 keeper_inner_height = 2.75;
 197 keeper_slant_slope = 2; // larger means steeper
 198
 199 keeper_gap_z_top = 0.25;
 200 keeper_gap_z_bot = 0.75;
 201 keeper_gap_x     = 0.25;
 202 keeper_gap_x_holes = 0.75;
 203
 204 keeper_side = 0; // 0 = lhs; 1 = rhs
 205
 206 case_lip = 1.25;
 207
 208 lid_gap_x = 0.25;
 209 lid_gap_z = 0.25;
 210 lid_lip = 1.75;
 211 lid_edgepart_width = 5.0;
 212 lid_buttoncover_thick = 1.3;
 213 lid_buttoncover_reinf = 0.65;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 254
 255 thumbrecess_depth = 1.3;
 256 thumbrecess_width = 16.5;
 257 thumbrecess_topcurve_r = 5.0;
 258
 259 prop_recess_under = 0.50;
 260 prop_recess_slop = 0.200; // each side
 261 prop_end_dia = 0.5;
 262 prop_main_th = 3;
 263 prop_taper_len = 6;
 264 prop_main_width = 4;
 265 prop_side_gap = 0.75; // each side
 266 prop_lidrecess_behind = 0.75;
 267 prop_caserecess_behind = 0.75;
 268 prop_caserecess_taper = 0.45; // one side only
 269 prop_prop_gap = 0.5;
 270 prop_prong_heel_slope = 0.5;
 271
 272 lid_fold_clearance_antislop = 0.5;
 273
 274 $button_leg_only = false;
 275 // ---------- calculated ----------
 276
 277 phone_width =  (phone + bumper*2)[0];
 278 phone_height = (phone + bumper*2)[1];
 279
 280 inside_br = [phone_width, -phone_height];
 281
 282 prop_prong_h = prop_main_th;
 283
 284 //echo(camera_pos_tl + bumper,
 285 //     camera_pos_br + bumper);
 286
 287 // ----- could be changed -----
 288 lid_buttoncover_gap = lid_gap_x;
 289 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 290
 291 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 292
 293 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 294
 295 //prop_nose_len = case_th_lid - prop_recess_under;
 296 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 297 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 298
 299
 300 //lid_lip_overlap_width xxx bad name = ;
 301 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 302
 303 epp0 = [0,0];
 304 epp1 = [0, -phone_edge_thick];
 305 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 306 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 307 epp3 = epp2i + [10, 0];
 308 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 309 epp4 = epp5 + [-1,0] * case_th_side;
 310
 311 kppe = [0,0];
 312 kppd = kppe + [1,0] * keeper_inner_width;
 313 kppc = kppd + [0,1] * keeper_th_z;
 314 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 315 kppf = kppe - [0,1] * keeper_inner_height;
 316 kppa = [ kppb[0], kppf[1] ];
 317
 318 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 319 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 320
 321 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 322 // exact x posn not very important; must extend past end of keeper
 323
 324 lpp15 = [ lpp14[0],
 325           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 326           + lid_screen_gap_extra ];
 327 // ^ beam theory says to maximise force before contact,
 328 //   the gap below the `beam' (the lid) must be 1/3
 329 //   the thickness (ie the lid thickness) if the beam
 330 //   is solid, or 1/2 if it has a top and bottom only.
 331 //   ours is mostly solid.
 332
 333 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 334              case_th_lip);
 335
 336 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 337 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 338
 339 case_bottom_z = epp2o[1] - case_th_bottom;
 340
 341 // button profile
 342 bppM = epp4 + [0,5];
 343 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 344 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 345 bppS = [ epp1[0], bppR[1] ];
 346 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 347 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 348 bppO = [ bppN[0], bppP[1] ];
 349 bppL = lpp10 + [5,0];
 350 bppK = [ bppL[0], bppN[1] ];
 351 bppJ = [ bppN[0], bppL[1] ];
 352 bppU = [ bppJ[0], lpp12[1] ];
 353 bppV = lpp11;
 354 bppW = lpp10;
 355
 356 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 357
 358 // notification led aperture
 359
 360 nla_r0 = led_aperture/2;
 361 nla_r1 = nla_r0 + led_window_ledge;
 362 nla_r2 = nla_r1 + multicolour_gap;
 363 nla_t =
 364   led_window_style >= 3 ? initial_layer_thick :
 365   led_window_style >= 2 ? led_window_ledge : 0;
 366
 367
 368 // hinge plan
 369 hp_rn = hingescrew_nut_access_dia/2;
 370 hp_r2_min = hp_rn + lever_cover_th;
 371 hp_rs = hingescrew_shaft_dia/2;
 372 hp_r1_min = hp_rs + hingemount_th;
 373
 374 hp_r1 = max(hp_r1_min, hp_r2_min);
 375 hp_r2 = hp_r1;
 376
 377 hppU = lpp13;
 378 hppS = epp2o + [0,-1] * case_th_bottom;
 379 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 380
 381 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 382          0.5 * (hppU + hppS)[1] ];
 383 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 384 hppB = hppT + [0,-1] * hp_k;
 385
 386 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 387 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 388 hppE = [ hppE_x, hppE_y ];
 389
 390 // hinge elevation x coords
 391
 392 hex20 = max(epp2o[0],
 393             phone_cnr_rad,
 394             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 395 hex21 = hex20 + hingemount_wd;
 396 hex22 = hex21 + hinge_x_gap;
 397 hex27 = hex20 + hingescrew_shaft_len;
 398 hex24 = hex27 + hinge_x_postscrew_gap;
 399 hex23 = hex27 - (hingescrew_nut_thick*2
 400                  + hingescrew_fasteners_extra_thick);
 401 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 402
 403 echo(hex20, hex21, hex22, hex23, hex24);
 404 //  6, 10.8725, 10.9975, 13.74, 18.75
 405 module chk(act,exp) {
 406   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 407   else echo("ok", act);
 408 }
 409 chk(hex20, 6);
 410 chk(hex21, 10.8725);
 411 chk(hex22, 10.9975);
 412 chk(hex23, 13.74);
 413 chk(hex24, 18.75);
 414
 415 lid_fold_clearance_skew =
 416   (lpp10[1] - hppB[1]) /
 417   (lpp10[0] - hppB[0]);
 418
 419 echo("SK",lid_fold_clearance_skew);
 420
 421 // thumb recess (used to be "catch" hence cpp*
 422
 423 cppA = epp4 + [thumbrecess_depth, 0];
 424 cppB = [ cppA[0], epp1[1] ];
 425
 426 // lanyard
 427
 428 ly_r = lanyard_half_dia / 2;
 429 ly_rc = ly_r * 2;
 430
 431 ly_theta = -atan2vector(epp2i - epp1);
 432 ly_o = epp2i + 3 * ly_r * unitvector2d(epp1 - epp2i);
 433
 434 max_case_bottom_edge_thickness =
 435   case_th_bottom
 436   + sin(ly_theta) * (epp2i-epp2o)[0];
 437
 438 ly_q_z = -(ly_rc + ly_r);
 439 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 440
 441 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 442
 443 // prop recess in case
 444
 445 prop_x_pos = phone_width/2;
 446
 447 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 448
 449 prc_r1 = prop_end_dia/2;
 450 prc_r3 = prc_r1 + prop_recess_slop;
 451
 452 prcp2 = [ epp4[0] + prop_buildout_less,
 453           case_bottom_z ];
 454
 455 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 456
 457 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 458           epp2i[1] - prc_r3 - prop_recess_under];
 459
 460 // prop recess in lid
 461
 462 prl_r10 = prop_end_dia/2;
 463 prl_r10o = prl_r10 + prop_recess_slop;
 464
 465 prlp10 = lpp10 + [1,1] * prl_r10o
 466   + [1,0] * prop_lidrecess_behind
 467   + [0,1] * prop_recess_under;
 468
 469 // prop
 470
 471 $prpp10 = [0,0];
 472 $prpp11 = [0, prop_taper_len];
 473
 474 $prp_r10 = prl_r10;
 475
 476 // ---------- modules ----------
 477
 478 module AdhocMultiprintFrame(phase, z0, zs) {
 479   // from z0 to z0 + zs*layer
 480   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 481   xextra = extra + -epp4[0];
 482   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 483   yextra = extra + -epp4[0];
 484   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 485   p0 = [ xrange[0], yrange[0] ];
 486   p1 = [ xrange[1], yrange[1] ];
 487   echo(p0, p1);
 488   translate([0,0, z0])
 489     mirror([0,0, zs<0 ? 1 : 0])
 490     linear_extrude(height= initial_layer_thick)
 491     difference(){
 492       rectfromto(p0 - [1,1] * initial_layer_width,
 493                  p1 + [1,1] * initial_layer_width);
 494       rectfromto(p0, p1);
 495     }
 496 }
 497
 498 module KeeperProfile(slant=0){
 499   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 500   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 501 }
 502
 503 module EdgeProfile(){
 504   difference(){
 505     hull(){
 506       translate(epp3) square(case_th_bottom*2, center=true);
 507       circleat(epp2o, r=case_th_bottom);
 508       circleat(epp1, r=case_th_side);
 509       rectfromto(epp0, epp4);
 510     }
 511     polygon([ epp5 + [0,10],
 512               epp1,
 513               epp2i,
 514               epp3 + [10,0] ]);
 515   }
 516 }
 517
 518 module LanyardLanyardProfile(entry=false){
 519   hull(){
 520     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 521       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 522         circle(r= lanyard_half_dia/2);
 523   }
 524 }
 525
 526 module LanyardCurveChannelProfile(){
 527   translate([0, -ly_r])
 528     LanyardLanyardProfile();
 529 }
 530
 531 module LanyardEntryChannelProfile(){
 532   LanyardLanyardProfile(true);
 533 }
 534
 535 module LanyardMainChannelProfile(){
 536   LanyardCurveChannelProfile();
 537   difference(){
 538     square(center=true, ly_r * [6, 2]);
 539     for (xs=[-1,+1])
 540       translate(ly_r * [3 * xs, -1])
 541         circle(r = ly_r);
 542   }
 543 }
 544
 545 module LanyardEntryOuterProfile(){
 546   circleat([ly_re + ly_r, 0], ly_re);
 547 }
 548
 549 module LanyardEntry(){
 550   q_z = ly_q_z;
 551   oec_y = ly_oec_y;
 552
 553   d_x = -ly_rc;
 554
 555   translate([d_x, 0, q_z]) {
 556     intersection(){
 557       rotate([90,0,0])
 558         rotate_extrude(convexity=10)
 559         rotate(90)
 560         translate([0, -q_z])
 561         LanyardCurveChannelProfile();
 562       translate([0,-10,0])
 563         cube([20,20,20]);
 564     }
 565   }
 566
 567   mirror([0,0,1])
 568     translate([0,0,-1])
 569     linear_extrude(height=20)
 570     rotate(-90)
 571     LanyardEntryChannelProfile();
 572
 573   translate([0, ly_r*2, 0])
 574     rotate([90,0,0])
 575     linear_extrude(height = ly_r*4){
 576     difference(){
 577       rectfromto([d_x, q_z], [ly_r, 0]);
 578       circleat([d_x, q_z], ly_rc);
 579     }
 580   }
 581
 582   translate([0,0,q_z]){
 583     for (my=[0,1])
 584       mirror([0,my,0]){
 585         translate([0, oec_y, 0]){
 586           difference(){
 587             translate(ly_re * [-1,0,-2])
 588               cube(ly_re * [2,1,2]);
 589             rotate_extrude(convexity=10)
 590               LanyardEntryOuterProfile();
 591           }
 592         }
 593       }
 594     difference(){
 595       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 596         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 597       for (mx=[0,1])
 598         mirror([mx,0,0])
 599           rotate([90,0,0])
 600           translate([0,0,-10])
 601           linear_extrude(height=20)
 602           LanyardEntryOuterProfile();
 603     }
 604   }
 605 }
 606
 607 module LanyardCutout(l){
 608   rotate([0,-90,0])
 609     linear_extrude(height=l)
 610     rotate(-90)
 611     LanyardMainChannelProfile();
 612
 613   for (ee=[0,1]){
 614     translate(ee * l * [-1,0])
 615       mirror([ee,0,0])
 616       LanyardEntry();
 617   }
 618 }
 619
 620 module LidEdgeProfile(){
 621   polygon([ lpp10,
 622             lpp11,
 623             lpp12,
 624             lpp13,
 625             lpp13 + [10, 0],
 626             lpp15 + [10, 0],
 627             lpp15,
 628             lpp14,
 629             ]);
 630   intersection(){
 631     circleat(lpp12, r=lp_r12);
 632     rectfromto( lpp12 + [-10,   0],
 633                 lpp12 + [+10, +10] );
 634   }
 635 }
 636
 637 module LidEdgeFoldClearanceProfile(){
 638   translate([-lid_fold_clearance_antislop, 0])
 639     polygon([ lpp10,
 640               lpp11,
 641               lpp11 + [-20,  0],
 642               lpp11 + [-20, 20],
 643               lpp11 + [+20, 20],
 644               lpp10 + [+20,  0] ]);
 645 }
 646
 647 module ButtonCoverProfile(){
 648   intersection(){
 649     polygon(concat([ bppM, bppP, bppO, bppJ ],
 650                    (enable_support && !$button_suppress_over_keeper
 651                     ? [ bppU, bppV, bppW ] : []),
 652                    [ bppL, bppK ]));
 653     hull(){
 654       EdgeProfile();
 655       LidEdgeProfile();
 656     }
 657   }
 658 }
 659
 660 module ButtonPlan(l, deep, cut){
 661   epsilon =
 662     (cut  ? 0 : lid_buttoncover_gap);
 663
 664   delta =
 665     (deep ? lid_buttoncover_overlap : 0);
 666
 667   C = [0,0]; // by definition
 668   T = [ 0, epp4[1] ];
 669   G = T + [0,10];
 670
 671   B0 = C + [0,-1] * button_cutout_depth;
 672   B1 = B0 + [0,1] * epsilon;
 673
 674   r0 = 0.5 * (T[1] - B0[1]);
 675   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 676   H = A + [0,-1] * delta;
 677
 678   D = A + [-2,0] * r0;
 679   F = D + [0,10];
 680
 681   E0 = 0.5 * (D + A);
 682   E1 = E0 + [1,0] * epsilon;
 683
 684   I0 = [ E0[0], H[1] ];
 685   I1 = [ E1[0], H[1] ];
 686
 687   hull(){
 688     for (m=[0,1]) mirror([m,0])
 689       circleat(H, r0 - epsilon);
 690   }
 691   for (m=[0,1]) mirror([m,0]) {
 692     difference(){
 693       polygon([ E1,
 694                 I1,
 695                 H,
 696                 B1,
 697                 G,
 698                 F,
 699                 D
 700                 ]);
 701       circleat(D, r0 + epsilon);
 702     }
 703   }
 704 }
 705
 706 module ButtonCoverReinf(){ ////toplevel
 707   minkowski(){
 708     rotate([90,0,0])
 709       linear_extrude(height=0.01)
 710       intersection(){
 711         ButtonCoverProfile();
 712         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 713           square([100,100]);
 714     }
 715     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 716       circle(r= lid_buttoncover_reinf);
 717       translate([-20,0]) square(40, center=true);
 718     }
 719   }
 720 }
 721
 722 module ThumbRecessCutProfile(){
 723   difference(){
 724     polygon([ cppA + [-10,0],
 725               cppB + [-10,0],
 726               cppB,
 727               cppA ]);
 728     circleat(epp1, r=case_th_side);
 729   }
 730 }
 731
 732 module Flip_rhs(yn=[0,1]) {
 733   for ($rhsflip=yn) {
 734     translate([phone_width/2, 0, 0])
 735       mirror([$rhsflip,0,0])
 736       translate([-phone_width/2, 0, 0])
 737       children();
 738   }
 739 }
 740
 741 module Flip_bot(yn=[0,1]) {
 742   for ($botflip=yn) {
 743     translate([0, -phone_height/2, 0])
 744       mirror([0, $botflip, 0])
 745       translate([0, phone_height/2, 0])
 746       children();
 747   }
 748 }
 749
 750 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 751   // sides
 752   Flip_rhs(){
 753     translate([0, -phone_cnr_rad, 0])
 754       rotate([90,0,0])
 755       linear_extrude(height = phone_height - phone_cnr_rad*2)
 756       children(0);
 757   }
 758   // corners
 759   Flip_rhs() Flip_bot() {
 760     translate([+1,-1] * phone_cnr_rad)
 761       intersection(){
 762         rotate_extrude()
 763           intersection(){
 764             mirror([1,0,0])
 765               translate([-1,0] * phone_cnr_rad)
 766               children(0);
 767             rectfromto([0,-20],[10,20]);
 768           }
 769         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 770           cube([10,10,40]);
 771       }
 772   }
 773   // top and bottom
 774   Flip_bot(){
 775     translate([ phone_width - phone_cnr_rad, 0,0 ])
 776       rotate([90,0,-90])
 777       linear_extrude(height = phone_width - phone_cnr_rad*2)
 778       children(0);
 779   }
 780   // fill
 781   translate([0,0, fill_zstart])
 782     mirror([0,0, fill_downwards])
 783     linear_extrude(height = fill_th)
 784     rectfromto([+1,-1] * phone_cnr_rad,
 785                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 786 }
 787
 788 module CaseAperture(pos, dia, $fn) {
 789   theta = 180/$fn;
 790   translate([ pos[0] + bumper[0],
 791               -epp2i[0],
 792               -pos[1] ])
 793     rotate([-90, theta, 0])
 794     cylinder(r = dia/2 / cos(theta),
 795              h = 60);
 796 }
 797
 798 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 799   // y_ref_sign:
 800   //   +1  measured from top    of actual phone to top    of button
 801   //   -1  measured from bottom of actual phone to bottom of button
 802   //    0  y is centre of button in coordinate system
 803   $button_l= l;
 804   $button_suppress_over_keeper= suppress_over_keeper;
 805   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 806           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 807           y;
 808   //echo(eff_y);
 809   translate([0, eff_y, 0])
 810     children();
 811 }
 812
 813 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 814   $button_leg_only = true;
 815   SideButton(y, y_ref_sign, l) children();
 816 }
 817
 818 module Buttons(){
 819   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 820   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 821   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 822   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 823 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 824 }
 825
 826 module Struts(x_start, z_min, th){
 827   // if th is negative, starts at z_min and works towards -ve z
 828   // and object should then be printed other way up
 829   for (i= [1 : 1 : case_struts_count]) {
 830     translate([0,
 831                0,
 832                z_min])
 833       mirror([0,0, th<0 ? 1 : 0])
 834       translate([0,
 835                  -phone_height * i / (case_struts_count+1),
 836                  case_struts_solid_below])
 837       linear_extrude(height= abs(th)
 838                      -(case_struts_solid_below+case_struts_solid_above))
 839       rectfromto([               x_start, -0.5 * case_struts_width ],
 840                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 841   }
 842 }
 843
 844 module OrdinaryRearAperture(rhs,bot, pos){
 845   Flip_rhs(rhs) Flip_bot(bot)
 846     linextr(-20, 20)
 847     mirror([0,1])
 848     translate(pos + bumper)
 849     children();
 850 }
 851
 852 module MicroUSB(){
 853   Flip_bot(1){
 854     rotate([90,0,0])
 855       mirror([0,0,1])
 856       linextr(-epp2i[0], 60)
 857       translate([0.5 * phone_width, 0, 0])
 858       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 859                  [+microusb_width/2, epp0[1] + -microusb_above]);
 860   }
 861 }
 862
 863 module OrdinaryRearApertures(){
 864   // rear speaker
 865   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 866     rectfromto(-rearspeaker_gap,
 867                rearspeaker_size + rearspeaker_gap);
 868
 869   // finger hole to remove phone
 870   if (len(fingerpushhole_dias))
 871     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 872                                 phone[1]/2 ])
 873     scale(fingerpushhole_dias)
 874     circle(r= 0.5 );
 875 }
 876
 877 module RearCameraAperture(){
 878   Flip_rhs(1)
 879     mirror([0, 0, 1])
 880     linear_extrude(height = 20)
 881     mirror([0, 1, 0])
 882     translate(bumper)
 883     rectfromto(camera_pos_tl, camera_pos_br);
 884 }
 885
 886 module HingeLidProfile(){
 887   hull(){
 888     circleat(hppT, hp_r1);
 889     circleat(lpp12, lp_r12);
 890     polygon([lpp10,
 891              lpp13 + [2,0],
 892              lpp12,
 893              hppT]);
 894   }
 895 }
 896
 897 module HingeBaseProfile(){
 898   difference(){
 899     hull(){
 900       circleat(hppB, hp_r1);
 901       circleat(hppE, hp_r1);
 902       circleat(epp2o, case_th_bottom);
 903       circleat(hppB + [10,0], hp_r1);
 904     }
 905     polygon([epp5, epp1, epp2i, epp3, bppL]);
 906   }
 907 }
 908
 909 module HingeLeverOuterProfile(){
 910   hull(){
 911     circleat(hppT, hp_r2);
 912     circleat(hppB, hp_r2);
 913   }
 914 }
 915
 916 module HingeLeverInnerProfile(){
 917   for (s = [-1,+1]) {
 918     c = s > 0 ? hppT : hppB;
 919     translate(c)
 920       mirror([0,0,s>0])
 921       rotate(s<0 ? -40 : 0)
 922       hull()
 923       for (x=[-20,20])
 924         for (y=[0, s * 10])
 925           translate([x,y])
 926             circle(hp_rn);
 927   }
 928 }
 929
 930 module HingeLeverNutProfile(){
 931   for (c= [hppB, hppT]) {
 932     translate(c)
 933       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 934   }
 935 }
 936
 937 module Flip_hinge(doflip=1){
 938   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 939   translate(hinge_origin)
 940     rotate([doflip*180,0,0])
 941     translate(-hinge_origin)
 942     children();
 943 }
 944
 945 module HingePortion(x0,x1){
 946   Flip_rhs() Flip_bot(1)
 947     translate([x0,0,0])
 948     mirror([1,0,0])
 949     rotate([90,0,-90])
 950     linear_extrude(height=x1-x0)
 951     children();
 952 }
 953
 954 module ThumbRecessApply(ztop){
 955   width = thumbrecess_width;
 956   w = width + thumbrecess_topcurve_r*2 + 1;
 957   translate([phone_width/2, 0,0]){
 958     difference(){
 959       rotate([90,0,-90])
 960         linextr(-w/2, w/2)
 961         children(0);
 962       translate([0, 50, 0])
 963         rotate([90,0,0])
 964         linear_extrude(height=100){
 965         for (m=[0,1]) mirror([m,0,0]) {
 966           hull(){
 967             translate([w/2, ztop - thumbrecess_topcurve_r])
 968               circle(thumbrecess_topcurve_r);
 969             translate([w/2, -50])
 970               square(thumbrecess_topcurve_r*2, center=true);
 971           }
 972         }
 973       }
 974     }
 975   }
 976 }
 977
 978 module CaseBase(){
 979   AroundEdges(epp3[1], case_th_bottom, 1)
 980     EdgeProfile();
 981 }
 982
 983 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 984
 985 module PropProfileAssignments(gamma){
 986   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 987   x = prop_x(gamma);
 988   p = phone_height + prlp10[0] - hppB[0];
 989   b = p + x;
 990
 991   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 992   a = q + x;
 993   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 994   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 995
 996   $prp_theta = 90 - $prp_alpha;
 997   beta = 180 - $prp_alpha - gamma;
 998   psi = 90 - beta;
 999
1000   //echo("abc", a,b,c);
1001
1002   v1 = [ [ cos(psi), -sin(psi) ],    // x
1003          [ sin(psi),  cos(psi) ] ];  // y
1004
1005   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1006
1007   $prp_r1 = prc_r1;
1008   $prp_r11 = prop_main_th/2;
1009
1010   $prpp1 = $prpp7 + [1,0] *
1011     // this is approximate, but will do
1012     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1013   $prpp3 = $prpp1 +
1014     v1[0] * -$prp_r1 +
1015     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1016   $prpp12 = $prpp3 + v1[0] *
1017     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1018   $prp_r8 = prop_main_th;
1019   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1020   $prp_r5 = $prp_r8;
1021   $prpp5 = [ $prpp12[0] - $prp_r5,
1022             $prpp3[1] - prop_prong_h + $prp_r5 ];
1023   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1024          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1025   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1026   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1027
1028   children();
1029 }
1030
1031 module PropProfile(gamma, cut=0, rot=0){
1032   PropProfileAssignments(gamma){
1033
1034     //#circleat($prpp3,1);
1035     //#circleat($prpp12,1);
1036
1037     if (!cut) {
1038       hull(){
1039         translate($prpp8)
1040           intersection(){
1041             circle($prp_r8);
1042             polygon([[-20,-0], [20,20], [0,0]]);
1043           }
1044         rectfromto($prpp6, $prpp9);
1045         translate($prpp5) intersection(){
1046           circle($prp_r5);
1047           polygon([[-10,-10], [0,0], [10,0]]);
1048         }
1049         rectfromto($prpp12 + [0,-0.1], $prpp3);
1050       }
1051       hull(){
1052         circleat($prpp1, $prp_r1);
1053         rectfromto($prpp12 + [0,-0.1], $prpp3);
1054       }
1055     }
1056     // main shaft
1057     rotate([0,0, rot*-$prp_theta]){
1058       hull(){
1059         extra = cut ? prop_recess_slop : 0;
1060         rectfromto($prpp6, $prpp9);
1061         circleat($prpp11, $prp_r11 + extra);
1062         circleat($prpp10, $prp_r10 + extra);
1063       }
1064     }
1065   }
1066 }
1067
1068 module PropAggregateProfile(){
1069   for (angle = prop_angles)
1070     PropProfile(angle, 0,0);
1071 }
1072
1073 module Prop(){ ////toplevel
1074   hw = prop_main_width/2;
1075   linextr(-hw, +hw)
1076     PropAggregateProfile();
1077 }
1078
1079 module Case(){ ////toplevel
1080   difference(){
1081     union(){
1082       CaseBase();
1083
1084       // ledge (fixed keeper)
1085       Flip_rhs(1-keeper_side) intersection(){
1086         rotate([90, 0, 0])
1087           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1088           KeeperProfile(1);
1089
1090         // outline of the whole case, to stop it protruding
1091         translate([0,0, -25])
1092           linear_extrude(height = 50)
1093           hull()
1094           Flip_bot()
1095           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1096       }
1097
1098       // hinge
1099       HingePortion(hex20, hex21) HingeBaseProfile();
1100
1101       // buildout for prop recess
1102       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1103         linextr(case_bottom_z, epp2i[1])
1104         hull() {
1105           for (dxs = [-1,+1])
1106             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1107                        -epp2o[0] ],
1108                      r = epp2o[0] - prcp2[0]);
1109         }
1110     }
1111
1112     // slot for keeper
1113     Flip_rhs(keeper_side)
1114       translate([0, -phone_cnr_rad, 0])
1115       rotate([90, 0, 0])
1116       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1117       minkowski(){
1118         KeeperProfile();
1119         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1120                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1121       }
1122
1123     // front camera
1124     RearCameraAperture();
1125
1126     // struts (invisible, because they're buried in the case)
1127     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1128
1129     Buttons(){
1130       mirror([1,0,0])
1131         rotate([90,0,90]) {
1132           if (!($button_leg_only && enable_support))
1133           intersection(){
1134             translate([0,0,-10])
1135               linear_extrude(height= 20)
1136               ButtonPlan($button_l, 0,1);
1137             if ($button_leg_only)
1138               rotate([-90,90,0])
1139                 translate([phone_width/2, -400, kppe[1]])
1140                 mirror([1-abs($rhsflip - keeper_side),0,0])
1141                 cube([400, 800, 50]);
1142             if (enable_support && !$button_suppress_over_keeper)
1143               rotate([-90,90,0])
1144               translate([-400, -400, kppd[1]])
1145                 mirror([0,0,1])
1146                 cube([800,800,100]);
1147           }
1148           translate([0,0, -bppR[0]])
1149             linear_extrude(height= 20)
1150             ButtonPlan($button_l, 1,1);
1151         }
1152
1153     }
1154
1155     // apertures along top edge
1156     CaseAperture(jack_pos, jack_dia, 8);
1157     Flip_rhs(1)
1158       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1159
1160     OrdinaryRearApertures();
1161
1162     MicroUSB();
1163
1164     // gaps for the lid's hinge arms
1165     HingePortion(hex20 - hinge_x_arms_gap,
1166                  hex21 + hinge_x_arms_gap)
1167       minkowski(){
1168         HingeLidProfile();
1169         circle(r= hinge_r_arms_gap, $fn= 8);
1170       }
1171
1172     // screw holes in the hinge arms
1173     HingeScrews();
1174
1175     // thumb recess
1176     ThumbRecessApply(epp4[1])
1177       ThumbRecessCutProfile();
1178
1179     // lanyard
1180     Flip_bot(1)
1181       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1182       rotate([0, ly_theta, 0])
1183       rotate([0,0,90])
1184       LanyardCutout(lanyard_channel_len);
1185
1186     // prop recess
1187     Flip_rhs(1)
1188       translate([prop_x_pos,0,0])
1189       mirror([0,1,0])
1190       rotate([90,0,90])
1191       linextr(-prop_recess_hw, +prop_recess_hw)
1192       hull(){
1193         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1194           circleat(prcp1 + 20*d,
1195                    prc_r3);
1196       }
1197   }
1198 }
1199
1200 module LidAdhocMultiprintFrame(phase){
1201   if (led_window_style >= 3) {
1202     AdhocMultiprintFrame(phase, lpp13[1], -1);
1203   }
1204 }
1205
1206 module LidAroundEdges(){
1207   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1208     children();
1209 }
1210
1211 module Lid(){ ////toplevel
1212   skew_centre = [0, lpp11[0], lpp11[1]];
1213   difference(){
1214     union(){
1215       intersection(){
1216         LidAroundEdges()
1217           LidEdgeProfile();
1218
1219         translate(skew_centre)
1220           multmatrix([[ 1, 0, 0, 0 ],
1221                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1222                       [ 0, 0, 1, 0 ],
1223                       [ 0, 0, 0, 1 ]])
1224           translate(-skew_centre)
1225           LidAroundEdges()
1226           LidEdgeFoldClearanceProfile();
1227       }
1228
1229       // button covers
1230       Buttons(){
1231         intersection(){
1232           rotate([90,0,90])
1233             translate([0,0,-10])
1234             linear_extrude(height= 20)
1235             ButtonPlan($button_l, 1,0);
1236           union(){
1237             rotate([90,0,0])
1238               translate([0,0,-100])
1239               linear_extrude(height= 200)
1240               ButtonCoverProfile();
1241             hull()
1242               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1243                                  - lid_buttoncover_reinf))
1244                 translate([0,y,0])
1245                   ButtonCoverReinf();
1246           }
1247         }
1248       }
1249
1250       // hinge arms
1251       HingePortion(hex20, hex21) {
1252         LidEdgeProfile();
1253         HingeLidProfile();
1254       }
1255     }
1256     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1257
1258     // screw holes in the hinge arms
1259     HingeScrews();
1260
1261     // prop recess
1262     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1263       mirror([0,1,0])
1264       rotate([90,0,90])
1265       linextr(-prop_recess_hw, +prop_recess_hw)
1266       hull()
1267       for (pa = prop_angles)
1268         PropProfile(pa, 1,1);
1269
1270     // notification led aperture
1271     if (led_window_style)
1272       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1273         translate([0,0,-10])
1274           cylinder(r=nla_r0, h=20);
1275         if (led_window_style >= 2)
1276           translate([0,0, -nla_t])
1277             cylinder(r=nla_r2, height=20);
1278       }
1279
1280     }
1281
1282   LidAdhocMultiprintFrame(1);
1283 }
1284
1285 module HingeLever(){ ////toplevel
1286   difference() {
1287     // outer body, positive
1288     HingePortion(hex22, hex22 + phone_width/2)
1289       HingeLeverOuterProfile();
1290
1291     // space for the screws
1292     HingePortion(hex26, hex24)
1293       HingeLeverInnerProfile();
1294
1295     // recesses for the nuts
1296     HingePortion(hex23, hex26+1)
1297       HingeLeverNutProfile();
1298
1299     // bores for the screws
1300     HingeScrews();
1301
1302     // space for the charging cable
1303     MicroUSB();
1304     Flip_hinge() MicroUSB();
1305   }
1306 }
1307
1308 module LidWindow(){ ////toplevel
1309   translate([led_pos[0], -led_pos[1], lpp13[1]])
1310     mirror([0,0,1])
1311     cylinder(r= nla_r1, h=nla_t);
1312   LidAdhocMultiprintFrame(0);
1313 }
1314
1315 module LidWindowPrint(){ ////toplevel
1316   rotate([0,180,0])
1317     LidWindow();
1318 }
1319
1320 module DemoLidWindowSelect(){
1321   translate([led_pos[0], led_pos[1], -100]) {
1322     translate([0, -30, 0]) cube([400, 400, 200]);
1323   }
1324 }
1325
1326 module DemoLidWindow(){ ////toplevel
1327   %Lid();
1328   LidWindow();
1329   translate([0,40,0]){
1330     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1331     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1332   }
1333 }
1334
1335 module HingeLeverPrint(){ ////toplevel
1336   rotate([-90,0,0])
1337     translate([-phone_width/2, phone_height, 0])
1338     HingeLever();
1339 }
1340
1341 module TestSelectLength(){
1342   translate([-30, -200, -20])
1343     cube([30 + 15, 250, 40]);
1344 }
1345
1346 module TestLength(){ ////toplevel
1347   intersection(){
1348     Case();
1349     TestSelectLength();
1350   }
1351 }
1352
1353 module TestLengthRight(){ ////toplevel
1354   intersection(){
1355     Case();
1356     Flip_rhs(1)
1357       TestSelectLength();
1358   }
1359 }
1360
1361 module TestSelectWidth(){
1362   translate([-30, -(phone_height - 25), -20])
1363     mirror([0, 1, 0])
1364     cube([200, 50, 40]);
1365 }
1366
1367 module TestWidth(){ ////toplevel
1368   intersection(){
1369     Case();
1370     TestSelectWidth();
1371   }
1372 }
1373
1374 module TestLidWidthPrint(){ ////toplevel
1375   rotate([0,180.0]) intersection(){
1376     Lid();
1377     TestSelectWidth();
1378   }
1379 }
1380
1381 module TestSelectRearAperture(){
1382   minkowski(){
1383     union() children();
1384     translate([20, 0,0])
1385       cube([42, 2, 1], center=true);
1386   }
1387 }
1388
1389 module TestSelectCamera(){
1390   minkowski(){
1391     TestSelectRearAperture()
1392       RearCameraAperture();
1393     cube([0.1, 50, 0.1]);
1394   }
1395 }
1396
1397 module TestSelectOrdinaryRearApertures(){
1398   TestSelectRearAperture()
1399     OrdinaryRearApertures();
1400 }
1401
1402 module TestCamera(){ ////toplevel
1403   intersection(){
1404     Case();
1405     TestSelectCamera();
1406   }
1407 }
1408
1409 module TestLidByCamera(){ ////toplevel
1410   intersection(){
1411     Lid();
1412     TestSelectCamera();
1413   }
1414 }
1415
1416 module TestLidByCameraPrint(){ ////toplevel
1417   rotate([180,0,0]) TestLidByCamera();
1418 }
1419
1420 module DemoByCamera(){ ////toplevel
1421   color("blue") TestLidByCamera();
1422   color("red")  TestCamera();
1423 }
1424
1425 module OneKeeper(){ ////toplevel
1426   translate([0, -phone_cnr_rad, 0])
1427     rotate([90, 0, 0])
1428     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1429     KeeperProfile();
1430 }
1431
1432 module OneKeeperPrint(){ ////toplevel
1433   rotate([0,180,0])
1434     OneKeeper();
1435 }
1436
1437 module LidPrint(){ ////toplevel
1438   rotate([0,180,0])
1439     Lid();
1440 }
1441
1442 module TestSelectFrame(){
1443   include = [1,-1] * (epp2i[0] + 4);
1444
1445   difference(){
1446     cube(1000, center=true);
1447     translate([0,0, -100])
1448       linear_extrude(height=200)
1449       rectfromto(include,  inside_br - include);
1450   }
1451 }
1452
1453 module TestSelectLidFrame(){
1454   TestSelectFrame();
1455   translate([led_pos[0], -led_pos[1], -50])
1456     cylinder(r= nla_r2+3, h=100);
1457 }
1458
1459 module TestFrameCase(){ ////toplevel
1460   intersection(){
1461     Case();
1462     union(){
1463       TestSelectFrame();
1464       TestSelectCamera();
1465       TestSelectOrdinaryRearApertures();
1466     }
1467   }
1468 }
1469
1470 module TestSelectTopApertures(){
1471   translate([-100, -35, -100])
1472     cube([400, 100, 200]);
1473   LidAdhocMultiprintFrame(0);
1474   LidAdhocMultiprintFrame(1);
1475 }
1476
1477 module TestTopApertures(){ ////toplevel
1478   intersection(){
1479     Case();
1480     TestSelectFrame();
1481     TestSelectTopApertures();
1482   }
1483 }
1484
1485 module TestLidTopAperturesPrint(){ ////toplevel
1486   rotate([0,180,0]) intersection(){
1487     Lid();
1488     TestSelectLidFrame();
1489     TestSelectTopApertures();
1490   }
1491 }
1492
1493 module TestLidWindowTopAperturesPrint(){ ////toplevel
1494   rotate([0,180,0]) intersection(){
1495     LidWindow();
1496     TestSelectTopApertures();
1497   }
1498 }
1499
1500 module TestFrameLidPrint(){ ////toplevel
1501   rotate([0,180,0]) intersection(){
1502     Lid();
1503     TestSelectLidFrame();
1504   }
1505 }
1506
1507 module ButtonPlanForDemo(z, deep, cut){
1508   translate([0,0,z])
1509     ButtonPlan(8, deep, cut);
1510 }
1511
1512 module HingeScrews(){
1513   Flip_rhs() Flip_bot(1){
1514     for (c= [ hppT, hppB ])
1515       translate([ hex20,
1516                   -c[0],
1517                   c[1] ]){
1518         rotate([0,90,0])
1519           translate([0,0,-.2])
1520           cylinder( r= hingescrew_shaft_dia/2,
1521                     h = hingescrew_shaft_len+0.2 );
1522         rotate([0,-90,0])
1523           translate([0,0,+.1])
1524           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1525       }
1526   }
1527 }
1528
1529 module DemoPropAngleSelect(c){
1530   color(c) difference(){
1531     union(){ children(); }
1532     translate([ prop_x_pos, -400, -200 ])
1533       cube([ 400,800,400 ]);
1534   }
1535 }
1536
1537 module DemoPropAngle(ang){
1538   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1539   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1540
1541   translate(hL)
1542     rotate([ang/2,0,0])
1543     translate(-hL)
1544     translate(hC)
1545     rotate([ang/2,0,0])
1546     translate(-hC) {
1547       DemoPropAngleSelect("red") Case();
1548
1549       color("orange")
1550         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1551         PropProfileAssignments(ang) {
1552           echo($prpp1);
1553           rotate([-$prp_theta, 0, 0])
1554           translate([0, $prpp1[0], -$prpp1[1]])
1555           rotate([90,0,-90])
1556           Prop();
1557         }
1558     }
1559
1560   translate([0,0, -hp_k*2])
1561     DemoPropAngleSelect("blue")
1562     Lid();
1563 }
1564
1565 module DemoPropAngles(){ ////toplevel
1566   for (i=[0 : len(prop_angles)-1])
1567     translate(i * [0, -100, 100])
1568     DemoPropAngle(prop_angles[i]);
1569 }
1570
1571 module DemoHingeAngle(ang1,ang2){
1572   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1573   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1574
1575   translate(hL)
1576     rotate([ang2,0,0])
1577     translate(-hL)
1578     translate(hC)
1579     rotate([ang1,0,0])
1580     translate(-hC) {
1581       color("red") Lid();
1582     }
1583
1584   color("blue") intersection(){
1585     Case();
1586     union(){
1587       translate([bppJ[0], -400, -200])
1588         mirror([1,0,0])
1589         cube([400, 800, 400]);
1590       translate([10, -400, -200])
1591         cube([10, 800, 400]);
1592     }
1593   }
1594 }
1595
1596 module DemoHingeAngles(){ ////toplevel
1597   angles = [ 0, 4, 8, 12 ];
1598   echo("angles",angles);
1599   for (i=[0 : len(angles)-1]) {
1600     translate(i * [0, 0, 30]) {
1601       DemoHingeAngle(0,angles[i]);
1602       translate([0, 200, 0])
1603         DemoHingeAngle(angles[i],0);
1604     }
1605   }
1606 }
1607
1608 module DemoSelectAdhocLeftRight(right=0) {
1609   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1610     mirror([1-right, 0,0])
1611     cube([400, 800, 200]);
1612 }
1613
1614 module DemoLeft(){ ////toplevel
1615   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1616   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1617 }
1618
1619 module DemoFrame(){ ////toplevel
1620   color("red") TestFrameCase();
1621   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1622   color("black") HingeScrews();
1623   %HingeLever();
1624 }
1625
1626 module DemoLanyardCutout(){ ////toplevel
1627   LanyardCutout(25);
1628 }
1629
1630 module DemoHingedFrame(){ ///toplevel
1631   color("red") TestFrameCase();
1632   translate([0,0, -2*hp_k])
1633   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1634
1635   Flip_hinge(){
1636     color("orange") HingeLever();
1637     color("black") HingeScrews();
1638   }
1639 }
1640
1641 module DemoHinge(){ ////toplevel
1642   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1643     DemoFrame();
1644     translate([0,0, -hp_k*3])
1645       DemoHingedFrame();
1646   }
1647 }
1648
1649 module DemoProfiles(){ ////toplevel
1650   LidEdgeProfile();
1651   %EdgeProfile();
1652   KeeperProfile();
1653   translate([0,0,-1]) color("black") KeeperProfile(1);
1654   translate(ly_o){
1655     rotate(-ly_theta){
1656       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1657       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1658       translate([0, ly_q_z]){
1659         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1660         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1661       }
1662     }
1663   }
1664   translate([0,0,-5]) color("white") translate(epp2i)
1665     rotate(-ly_theta)
1666     rectfromto([-15, 0],
1667                [+15, -max_case_bottom_edge_thickness]);
1668
1669   translate([0,20]) {
1670     LanyardMainChannelProfile();
1671     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1672     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1673   }
1674
1675   translate([20,0]) {
1676     LidEdgeProfile();
1677     %EdgeProfile();
1678
1679     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1680
1681     color("blue") ButtonCoverProfile();
1682     color("red") {
1683       rectfromto(bppQ, demopoint_QR);
1684       rectfromto(bppR, demopoint_QR);
1685     }
1686   }
1687
1688   translate([-20,0]) {
1689     color("black") ButtonPlanForDemo(-2, 0,1);
1690     color("red" )  ButtonPlanForDemo(-4, 1,1);
1691     color("blue")  ButtonPlanForDemo(-6, 1,0);
1692   }
1693
1694   translate([0, -30]) {
1695     %LidEdgeProfile();
1696     %EdgeProfile();
1697     color("blue") HingeLidProfile();
1698     color("red")  HingeBaseProfile();
1699     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1700   }
1701
1702   for (f=[0,1]) {
1703     translate([-30, -60 + 30*f]) {
1704       translate([0,0,-4]) EdgeProfile();
1705       %translate([0,0,-10]) HingeBaseProfile();
1706       translate([0,-2] * f * hp_k) {
1707         translate([0,0,-4]) LidEdgeProfile();
1708         %translate([0,0,-10]) %HingeLidProfile();
1709       }
1710       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1711         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1712         translate([0,0,0]) color("red") difference(){
1713           HingeLeverOuterProfile();
1714           HingeLeverInnerProfile();
1715         }
1716         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1717       }
1718     }
1719   }
1720
1721   translate([20,-30]) {
1722     %EdgeProfile();
1723     %LidEdgeProfile();
1724     //translate([0,0,1]) ThumbRecessCutProfile();
1725     translate([0,0,+1]) color("red")
1726       difference(){ EdgeProfile(); ThumbRecessCutProfile(); }
1727   }
1728
1729   translate([40,-30]) {
1730     difference(){
1731       LidEdgeProfile();
1732       translate(prlp10)
1733         PropProfile(10, 1, 0);
1734     }
1735     translate(prlp10)
1736       PropProfile(15, 0);
1737   }
1738   translate([60,-30]) {
1739     PropAggregateProfile();
1740   }
1741 }
1742
1743 //EdgeProfile();
1744 //KeeperProfile();
1745 //CaseBase();
1746 //%Case();
1747 //Keeper();
1748 //LidEdgeProfile();
1749 //KeeperProfile();
1750 //DemoProfiles();
1751 //PropRecess();