digispark-with-cable.scad

   1 // -*- C -*-
   2
   3 include <utils.scad>
   4
   5 //tongue_w = 11.92 + 0.4;
   6
   7 usb_w = 12.01 + 0.19;
   8 usb_wall_w = 0.51;
   9 usb_tongue_d = 8.97 - 0.2;
  10 usb_tongue_w_slop = +0.5;
  11 usb_wall_h = 4.54 - 2.04;
  12 usb_ceil_th = 0.425;
  13
  14 side_wall_th = 1.5;
  15
  16 board_l = 17.56 + 0.2;
  17 board_w = 19.14 + 0.2;
  18 board_th = 1.92 + 0.1;
  19
  20 sw_to_edge = board_w/2 + 0.1;
  21
  22 front_wall_th = 0.75;
  23 // egress_w = 8.0;
  24
  25 wall_y_min = -board_l - side_wall_th; // XXXX remove
  26 main_y_min = -board_l - side_wall_th;
  27 ceil_y_min = wall_y_min - 5;;
  28
  29 small_walls = [
  30                [ [0, 0], [-sw_to_edge, -1.0] ],
  31                [ [sw_to_edge-4.5, -4.5], [sw_to_edge, -5.7] ],
  32 //             [ [3.0, -11.72],              [sw_to_edge, -13.38] ],
  33                [ [-sw_to_edge+3.85, -14.90], [sw_to_edge, -13.38] ],
  34                ];
  35 chip_cutout = [[ -sw_to_edge + 4.20,    -3.75 ],
  36                [ -sw_to_edge + 11.95,  -11.90 ]];
  37
  38 strain_w = 2.0 + 0.5;
  39 strain_t = 1.0 + 0.5;
  40 strain_pitch_across = 5;
  41 strain_pitch_along = 10;
  42 strain_groove_d = 2;
  43 strain_groove_w = 3;
  44
  45 cable_space_z = 6;
  46 bottom_floor_th = 1.5;
  47
  48 fit_gap_z = 0.5;
  49 side_x_gap = 0.5;
  50
  51 // calculated
  52
  53 top_top_z = usb_wall_h;
  54 top_base_z = -board_th;
  55 bottom_base_z = top_base_z - cable_space_z - bottom_floor_th;;
  56
  57 front_y_max = front_wall_th;
  58
  59 strain_0_y_c = main_y_min - strain_w/2;
  60 strain_1_y_c = strain_0_y_c - strain_pitch_along;
  61 total_y_min = strain_1_y_c - strain_w/2 - side_wall_th;
  62
  63 bottom_wall_top_z = (top_top_z + top_base_z) * 0.5 - fit_gap_z/2;
  64 cover_wall_top_z  = (top_top_z + top_base_z) * 0.5 + fit_gap_z/2;
  65
  66 top_side_wall_x = +board_w/2 + side_wall_th;
  67 total_side_wall_x = top_side_wall_x + side_wall_th + side_x_gap;
  68
  69 module BothSides(){
  70   for (m=[0,1]) {
  71     mirror([m,0]) {
  72       children();
  73     }
  74   }
  75 }
  76 module FrontWallsPlan(slop) {
  77   BothSides(){
  78     rectfromto([ -board_w/2 - side_wall_th,    0             ],
  79                [ -usb_w/2 - slop,              front_wall_th ]);
  80   }
  81 }
  82 module TopSmallWallsPlan() {
  83   for (m=[0,1]) {
  84     mirror([m,0]) {
  85       rectfromto([ -usb_w/2,              -0.01        ],
  86                  [ -usb_w/2 + usb_wall_w, usb_tongue_d ]);
  87     }
  88   }
  89   FrontWallsPlan(0);
  90   for (w=small_walls) {
  91     rectfromto(w[0], w[1]);
  92   }
  93 }
  94 module TopCeilPlan() {
  95   difference(){
  96     BothSides(){
  97       rectfromto([ -usb_w/2,              -0.01        ],
  98                  [ 0.1,                   usb_tongue_d ]);
  99       rectfromto([ -board_w/2 - side_wall_th, 0            ],
 100                  [ 0.1,                       ceil_y_min   ]);
 101     }
 102     rectfromto(chip_cutout[0], chip_cutout[1]);
 103   }
 104 }
 105 module TopMainWallsPlan() {
 106   BothSides(){
 107     rectfromto([ -board_w/2 - side_wall_th, 0          ],
 108                [ -board_w/2,                wall_y_min ]);
 109   }
 110   FrontWallsPlan(usb_tongue_w_slop);
 111   rectfromto([ -board_w/2 - side_wall_th + 0, -      board_l   ],
 112              [ +board_w/2 + side_wall_th,            total_y_min ]);
 113 }
 114
 115 module Top(){ ////toplevel
 116   difference(){
 117     union(){
 118       linextr(0, usb_wall_h)
 119         TopSmallWallsPlan();
 120       linextr(usb_wall_h - usb_ceil_th, usb_wall_h)
 121         TopCeilPlan();
 122       linextr(-board_th, usb_wall_h)
 123         TopMainWallsPlan();
 124     }
 125
 126     for (y_c = [strain_0_y_c, strain_1_y_c]) {
 127       for (x_c = [-1,+1] * strain_pitch_across/2) {
 128         translate([x_c, y_c, 0])
 129           linextr(-20, 20)
 130           square([ strain_t, strain_w ], center=true);
 131       }
 132     }
 133     linextr_y_xz(total_y_min-1, main_y_min)
 134       translate([0, top_base_z])
 135       scale([1, strain_groove_d/strain_groove_w])
 136       circle(strain_groove_w/2, $fn = 8);
 137   }
 138 }
 139
 140 module BottomMainElevation(){ ////toplevel
 141   difference(){
 142     rectfromto([ -total_side_wall_x, bottom_base_z        ],
 143                [ +total_side_wall_x, bottom_wall_top_z    ]);
 144
 145     rectfromto([ -(top_side_wall_x + side_x_gap), top_base_z ],
 146                [ +(top_side_wall_x + side_x_gap), 20         ]);
 147     rectfromto([ -board_w/2, bottom_base_z + bottom_floor_th ],
 148                [ +board_w/2, 20         ]);
 149   }
 150 }
 151 module Bottom(){ ////toplevel
 152   linextr_y_xz(total_y_min, front_y_max)
 153     BottomMainElevation();
 154 }
 155
 156 module BottomDemo(){ ////toplevel
 157   Bottom();
 158   translate([0, 0, 0.25]) %Top();
 159 }