digispark-with-cable.scad

   1 // -*- C -*-
   2 //
   3 // Print (fine detail settings):
   4 //
   5 //   * Bottom
   6 //   * MiddlePrint
   7 //   * CoverPrint
   8
   9 include <utils.scad>
  10
  11 usb_w = 12.01 + 0.19;
  12 usb_wall_w = 0.51;
  13 usb_tongue_d = 8.97 - 0.2;
  14 usb_tongue_w_slop = +0.5;
  15 usb_wall_h = 4.54 - 2.04;
  16 usb_ceil_th = 0.425;
  17
  18 wall_th = 1.5; // XXXX rename wall_th
  19
  20 board_l = 17.56 + 0.2;
  21 board_w = 19.14 + 0.2;
  22 board_th = 1.92 + 0.1;
  23
  24 sw_to_edge = board_w/2 + 0.1;
  25
  26 front_wall_th = 0.75;
  27 // egress_w = 8.0;
  28
  29 wall_y_min = -board_l - wall_th;
  30 ceil_y_min = wall_y_min - 5;;
  31
  32 small_walls = [
  33                [ [0, 0], [-sw_to_edge, -1.0] ],
  34                [ [sw_to_edge-4.5, -4.5], [sw_to_edge, -5.7] ],
  35 //             [ [3.0, -11.72],              [sw_to_edge, -13.38] ],
  36                [ [-sw_to_edge+3.85, -14.90], [sw_to_edge, -13.38] ],
  37                ];
  38 chip_cutout = [[ -sw_to_edge + 4.20,    -3.75 ],
  39                [ -sw_to_edge + 11.95,  -11.90 ]];
  40
  41 strain_w = 3.5 + 0.5;
  42 strain_t = 1.5 + 0.5;
  43 strain_pitch_across = 5;
  44 strain_pitch_along = 10;
  45 strain_groove_d = 2;
  46 strain_groove_w = 4.5;
  47
  48 cover_strap_c_d_y = 5.5; // from front of board
  49 cover_registration_sz_y = 2;
  50 cover_registration_sz_z = 3;
  51 midbot_registraton_sz_x = 3;
  52
  53 cable_space_z = 6;
  54 cable_dia = 6;
  55 bottom_floor_th = 1.5;
  56
  57 fit_gap_z = 0.5;
  58 fit_gap_y = 0.25;
  59 side_x_gap = 0.5;
  60
  61 cover_ceil_th = 0.9;
  62
  63 cover_strap_sz_x = wall_th * 3.5;
  64
  65 // calculated
  66
  67 strap_w = strain_w;
  68 cover_strap_cutout_z = wall_th;
  69
  70 middle_top_z = usb_wall_h;
  71 middle_base_z = -board_th;
  72 bottom_base_z = middle_base_z - cable_space_z - bottom_floor_th;;
  73
  74 front_y_max = front_wall_th;
  75 main_y_min = -board_l - wall_th;
  76
  77 strain_0_y_c = main_y_min - strain_w/2;
  78 strain_1_y_c = strain_0_y_c - strain_pitch_along;
  79 total_y_min = strain_1_y_c - strain_w/2 - wall_th;
  80
  81 bottom_wall_top_z = (middle_top_z + middle_base_z) * 0.5 - fit_gap_z/2;
  82 cover_wall_bot_z  = (middle_top_z + middle_base_z) * 0.5 + fit_gap_z/2;
  83 cover_top_z  = middle_top_z + cover_ceil_th;
  84
  85 middle_side_wall_x = +board_w/2 + wall_th;
  86 total_side_wall_x = middle_side_wall_x + wall_th + side_x_gap;
  87
  88 cover_registration_c_dy = -cover_strap_c_d_y - strap_w/2
  89   - wall_th - cover_registration_sz_y/2;
  90
  91 midbot_registration_sz_y = cover_registration_sz_y;
  92 midbot_registration_sz_z = cover_registration_sz_z;
  93 midbot_registration_y_min = total_y_min + wall_th*2;
  94 midbot_registration_y_max = midbot_registration_y_min
  95   + midbot_registration_sz_y;
  96 midbot_registration_y_around_max = midbot_registration_y_max
  97   + wall_th*2;
  98 midbot_registration_bottom_x = board_w/2 - midbot_registraton_sz_x;
  99
 100 midbot_strap_c_y = 0.5 * (strain_0_y_c + strain_1_y_c);
 101
 102 module BothSides(){
 103   for (m=[0,1]) {
 104     mirror([m,0,0]) {
 105       children();
 106     }
 107   }
 108 }
 109
 110 module NormalStrapCutouts(y_c, z, rot){
 111   BothSides(){
 112     translate([ -total_side_wall_x, y_c, z ])
 113       rotate([0, rot, 0])
 114       cube([ wall_th,
 115              strap_w,
 116              10 ],
 117            center=true);
 118   }
 119 }
 120 module BottomStrapCutouts(y_c){
 121   NormalStrapCutouts(y_c, bottom_base_z, -45);
 122 }
 123 module CoverStrapCutouts(){
 124   BothSides(){
 125     translate([ -total_side_wall_x, -cover_strap_c_d_y, cover_top_z ])
 126       cube([ cover_strap_sz_x*2,
 127              strap_w,
 128              cover_strap_cutout_z*2 ],
 129            center=true);
 130   }
 131 }
 132
 133 module FrontWallsPlan(slop) {
 134   BothSides(){
 135     rectfromto([ -board_w/2 - wall_th,    0             ],
 136                [ -usb_w/2 - slop,         front_wall_th ]);
 137   }
 138 }
 139 module MiddleSmallWallsPlan() {
 140   for (m=[0,1]) {
 141     mirror([m,0]) {
 142       rectfromto([ -usb_w/2,              -0.01        ],
 143                  [ -usb_w/2 + usb_wall_w, usb_tongue_d ]);
 144     }
 145   }
 146   FrontWallsPlan(0);
 147   for (w=small_walls) {
 148     rectfromto(w[0], w[1]);
 149   }
 150 }
 151 module MiddleCeilPlan() {
 152   difference(){
 153     BothSides(){
 154       rectfromto([ -usb_w/2,              -0.01        ],
 155                  [ 0.1,                   usb_tongue_d ]);
 156       rectfromto([ -board_w/2 - wall_th, 0            ],
 157                  [ 0.1,                  ceil_y_min   ]);
 158     }
 159     rectfromto(chip_cutout[0], chip_cutout[1]);
 160   }
 161 }
 162 module MiddleMainWallsPlan() {
 163   BothSides(){
 164     rectfromto([ -board_w/2 - wall_th, 0          ],
 165                [ -board_w/2,           wall_y_min ]);
 166   }
 167   FrontWallsPlan(usb_tongue_w_slop);
 168   rectfromto([ -board_w/2 - wall_th + 0, -      board_l   ],
 169              [ +board_w/2 + wall_th,            total_y_min ]);
 170 }
 171
 172 module RegistrationsMinkowski(){
 173   minkowski(){
 174     cube([ 1, fit_gap_y*2, fit_gap_z*2 ], center=true);
 175     children();
 176   }
 177 }
 178 module CoverRegistrations(){
 179   linextr_y_xz(cover_registration_c_dy - strap_w/2,
 180                cover_registration_c_dy + strap_w/2) {
 181     difference(){
 182       rectfromto([ -total_side_wall_x,
 183                           cover_wall_bot_z - cover_registration_sz_z  ],
 184                  [ +total_side_wall_x, cover_top_z ]);
 185       hull(){
 186         MiddleElevationForCutout();
 187         translate([0, -20]) MiddleElevationForCutout();
 188       }
 189     }
 190   }
 191 }
 192 module MidBotRegistrations(){
 193   linextr_y_xz(midbot_registration_y_min,
 194                midbot_registration_y_max) {
 195     BothSides(){
 196       rectfromto([ midbot_registration_bottom_x, middle_base_z + 0.1 ],
 197                  [ middle_side_wall_x, middle_base_z
 198                         - midbot_registration_sz_z ]);
 199     }
 200   }
 201 }
 202
 203 module Middle(){ ////toplevel
 204   difference(){
 205     union(){
 206       linextr(0, usb_wall_h)
 207         MiddleSmallWallsPlan();
 208       linextr(usb_wall_h - usb_ceil_th, usb_wall_h)
 209         MiddleCeilPlan();
 210       linextr(-board_th, usb_wall_h)
 211         MiddleMainWallsPlan();
 212       BothSides()
 213         linextr(cover_wall_bot_z, middle_top_z)
 214         rectfromto([ -(board_w/2 + 0.1),  total_y_min             ],
 215                    [ -total_side_wall_x,  main_y_min - fit_gap_y  ]);
 216       MidBotRegistrations();
 217     }
 218
 219     for (y_c = [strain_0_y_c, strain_1_y_c]) {
 220       for (x_c = [-1,+1] * strain_pitch_across/2) {
 221         translate([x_c, y_c, 0])
 222           linextr(-20, 20)
 223           square([ strain_t, strain_w ], center=true);
 224       }
 225     }
 226     linextr_y_xz(total_y_min-1, main_y_min)
 227       translate([0, middle_base_z])
 228       scale([1, strain_groove_d/strain_groove_w])
 229       circle(strain_groove_w/2, $fn = 8);
 230     NormalStrapCutouts(midbot_strap_c_y,
 231                        middle_top_z, 45);
 232   }
 233 }
 234 module MiddlePrint(){ ////toplevel
 235   rotate([180,0,0]) Middle();
 236 }
 237
 238 module MiddleElevationForCutout(){
 239     rectfromto([ -(middle_side_wall_x + side_x_gap),
 240                     middle_base_z - fit_gap_z ],
 241                [ +(middle_side_wall_x + side_x_gap), middle_top_z  ]);
 242 }
 243 module BottomMainElevation(){
 244   difference(){
 245     rectfromto([ -total_side_wall_x, bottom_base_z        ],
 246                [ +total_side_wall_x, bottom_wall_top_z    ]);
 247
 248     MiddleElevationForCutout();
 249   }
 250 }
 251 module Bottom(){ ////toplevel
 252   difference(){
 253     union(){
 254       linextr_y_xz(total_y_min, front_y_max)
 255         BottomMainElevation();
 256     }
 257
 258     linextr_y_xz(midbot_registration_y_around_max,
 259                  front_y_max - wall_th)
 260       rectfromto([ -board_w/2, bottom_base_z + bottom_floor_th ],
 261                  [ +board_w/2, 20         ]);
 262
 263     linextr_y_xz(total_y_min + wall_th,
 264                  front_y_max - wall_th)
 265       rectfromto([ -midbot_registration_bottom_x,
 266                      bottom_base_z + bottom_floor_th ],
 267                  [ +midbot_registration_bottom_x, 20         ]);
 268
 269     linextr_y_xz(total_y_min - 1,
 270                  total_y_min + wall_th + 1){
 271       translate([ 0, middle_base_z ]){
 272         hull(){
 273           translate([ 0, -cable_dia/2 ])
 274             circle(r = cable_dia/2, $fa = 10, $fs = 1);
 275           square([ cable_dia, 0.1 ], center=true);
 276         }
 277       }
 278     }
 279     RegistrationsMinkowski()
 280       CoverRegistrations();
 281     RegistrationsMinkowski()
 282       MidBotRegistrations();
 283     BottomStrapCutouts(-cover_strap_c_d_y);
 284     BottomStrapCutouts(midbot_strap_c_y);
 285   }
 286 }
 287
 288 module CoverMainElevation(){
 289   difference(){
 290     rectfromto([ -total_side_wall_x, cover_wall_bot_z        ],
 291                [ +total_side_wall_x, cover_top_z    ]);
 292
 293     MiddleElevationForCutout();
 294   }
 295 }
 296 module Cover(){ ////toplevel
 297   difference(){
 298     union(){
 299       linextr_y_xz(main_y_min, front_y_max)
 300         CoverMainElevation();
 301       CoverRegistrations();
 302     }
 303     CoverStrapCutouts();
 304   }
 305 }
 306 module CoverPrint(){ ////toplevel
 307   rotate([180,0,0]) Cover();
 308 }
 309
 310 module BottomDemo(){ ////toplevel
 311   translate([0, 0, -0.25]) Bottom();
 312   %Middle();
 313   translate([0, 0, +0.25]) Cover();
 314 }