belt-slot-cut-jig.scad

   1 // -*- C -*-
   2
   3 // todo
   4 //  various registration marks
   5 //   protrustions at ends at strap width and middle
   6 //   grooves on top face at 1/4,1/2,3/4 length and 1/2 width
   7
   8 crewpunch_slop = 0.3;
   9
  10 holder_min_wall = 2;
  11 holder_attach_near_wall = 3;
  12
  13 holder_attach_xsz = 5;
  14 holder_ctie_width = 4.0 + 0.5;
  15 holder_ctie_thick = 2.0 + 0.5;
  16 holder_attach_walls = 3;
  17 holder_attach_roof = 2.5;
  18
  19 jig_interval = 25;
  20 strap_width = 25;
  21 strap_thick = 3;
  22 edgewall_width = 3;
  23
  24 punch_travel = 8;
  25
  26 main_slop = 0.5;
  27
  28 jig_max_len = 130;
  29
  30 // from careful measurement
  31
  32 crewpunch_shape =
  33   [[  6, [0.6, 6.0], [1.6, 12.3] ],
  34    [  8, [1.1, 6.2], [1.9, 12.5] ],
  35    [ 10, [1.6, 6.5], [2.1, 12.8] ],
  36    [ 12, [1.8, 6.6], [2.3, 12.7] ],
  37    [ 14, [2.1, 6.8], [2.6, 13.0] ],
  38    [ 16, [2.4, 6.9], [2.7, 13.2] ]];
  39
  40 crewpunch_shaft_max_y = 7.5;
  41
  42 crewpunch_systematic_size_error = +0.36;
  43
  44 crewpunch_min_y = 4.7 - crewpunch_systematic_size_error;
  45
  46 crewpunch_smallest_shape = crewpunch_shape[0];
  47 crewpunch_biggest_shape = crewpunch_shape[len(crewpunch_shape)-1];
  48
  49 // computed
  50
  51 attach_ysz = holder_attach_walls*2 + holder_ctie_width;
  52 holder_front_all = crewpunch_shaft_max_y - crewpunch_biggest_shape[1][1]
  53   + attach_ysz;
  54
  55 holder_block_zsz = crewpunch_biggest_shape[0] - crewpunch_smallest_shape[0];
  56 holder_xsz = crewpunch_biggest_shape[2][0] + crewpunch_biggest_shape[2][1] +
  57   holder_min_wall*2;
  58 crewpunch_biggest_y =
  59   crewpunch_biggest_shape[1][0] + crewpunch_biggest_shape[1][1];
  60 holder_ysz = crewpunch_biggest_y + holder_min_wall + holder_front_all;
  61
  62 attach_offset = 0.5 * (holder_front_all - holder_attach_near_wall);
  63
  64 jig_main_zsz = holder_block_zsz + punch_travel;
  65
  66 jig_ends_extra = 2;
  67
  68 jig_iters = (jig_max_len - jig_ends_extra) / jig_interval;
  69 echo(jig_iters);
  70
  71 // objects
  72
  73 module CrewPunch(){
  74   ourslop = crewpunch_slop - crewpunch_systematic_size_error;
  75   hull(){
  76     for(layer=crewpunch_shape){
  77       translate([0,0, layer[0]]){
  78         for(xind=[0,1]) //translate([xind?0:1,0,0])
  79           for(yind=[0,1]) //translate([0,yind?0.5:0,0])
  80             mirror([xind?1:0,0,0]) mirror([0,yind?0:1,0]){
  81               translate([-0.1,-0.1,-0.1])
  82                 cube([0.1 + layer[2][xind] + ourslop,
  83                       0.1 + layer[1][yind] + ourslop,
  84                       0.2]);
  85             }
  86       }
  87     }
  88   }
  89 }
  90
  91 module PunchHolder(cutouts=true){
  92   translate([-holder_xsz/2,
  93              -holder_ysz + holder_min_wall + crewpunch_biggest_y/2,
  94              0]){
  95     difference(){
  96       translate([0,attach_offset,0])
  97         cube([holder_xsz, holder_ysz - attach_offset, holder_block_zsz]);
  98       if (cutouts)
  99         translate([crewpunch_biggest_shape[2][1] + holder_min_wall,
 100                    crewpunch_biggest_shape[1][0] + holder_front_all,
 101                    -crewpunch_smallest_shape[0]])
 102           CrewPunch();
 103     }
 104     difference(){
 105       translate([holder_xsz/2 - holder_attach_xsz/2, 0, 0])
 106         cube([holder_attach_xsz,
 107               attach_ysz,
 108               holder_block_zsz + punch_travel
 109               + holder_ctie_thick + holder_attach_roof + 1]);
 110       if (cutouts)
 111         translate([-30,
 112                    holder_attach_walls,
 113                    holder_block_zsz + punch_travel])
 114           cube([60, holder_ctie_width, holder_ctie_thick]);
 115     }
 116   }
 117 }
 118
 119 module OneJig(){
 120   difference(){
 121     translate([-(jig_interval/2 + 1),
 122                -(strap_width/2 + edgewall_width) - attach_offset,
 123                -strap_thick])
 124       cube([jig_interval + 2,
 125             strap_width + edgewall_width*2 + attach_offset,
 126             jig_main_zsz + strap_thick]);
 127     minkowski(){
 128       cube([main_slop*2, main_slop*2, 50], center=true);
 129       PunchHolder(false);
 130     }
 131     translate([-100, -strap_width/2, -10])
 132       cube([200, strap_width, 10]);
 133   }
 134 }
 135
 136 module Jig(){
 137   for (i=[0:jig_iters-1]) {
 138     translate([jig_interval * i, 0, 0])
 139       OneJig();
 140   }
 141 }
 142
 143 module Demo(){
 144   %PunchHolder();
 145   Jig();
 146 }
 147
 148 //CrewPunch();
 149 //PunchHolder();
 150 //PunchHolder(false);
 151 //OneJig();
 152 //Jig();
 153 Demo();