chiark / gitweb /
bus-proxy: also consider ENOTCONN a clean termination condition
[elogind.git] / shell-completion / zsh / _systemd-run
1 #compdef systemd-run
2
3 __systemctl() {
4         local -a _modes
5         _modes=("--user" "--system")
6         systemctl ${words:*_modes} --full --no-legend --no-pager "$@" 2>/dev/null
7 }
8
9 __get_slices () {
10         __systemctl list-units --all -t slice \
11         | { while read -r a b; do echo $a; done; };
12 }
13
14 __slices () {
15         local -a _slices
16         _slices=(${(fo)"$(__get_slices)"})
17         typeset -U _slices
18         _describe 'slices' _slices
19 }
20
21 _arguments \
22         {-h,--help}'[Show help message]' \
23         '--version[Show package version]' \
24         '--user[Run as user unit]' \
25         {-H+,--host=}'[Operate on remote host]:[user@]host:_sd_hosts_or_user_at_host' \
26         {-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
27         '--scope[Run this as scope rather than service]' \
28         '--unit=[Run under the specified unit name]:unit name' \
29         {-p+,--property=}'[Set unit property]:NAME=VALUE' \
30         '--description=[Description for unit]:description' \
31         '--slice=[Run in the specified slice]:slices:__slices' \
32         {-r,--remain-after-exit}'[Leave service around until explicitly stopped]' \
33         '--send-sighup[Send SIGHUP when terminating]' \
34         '--service-type=[Service type]:type:(simple forking oneshot dbus notify idle)' \
35         '--uid=[Run as system user]:user:_users' \
36         '--gid=[Run as system group]:group:_groups' \
37         '--nice=[Nice level]:nice level' \
38         '--setenv=[Set environment]:NAME=VALUE' \
39         '--on-active=[Run after SEC seconds]:SEC' \
40         '--on-boot=[Run after SEC seconds from machine was booted up]:SEC' \
41         '--on-statup=[Run after SEC seconds from systemd was first started]:SEC' \
42         '--on-unit-active=[Run after SEC seconds from the last activation]:SEC' \
43         '--on-unit-inactive=[Run after SEC seconds from the last deactivation]:SEC' \
44         '--on-calendar=[Realtime timer]:SPEC' \
45         '--timer-property=[Set timer unit property]:NAME=VALUE' \
46         '*::command:_command'