chiark / gitweb /
gnome-ask-password-agent: require libnotify >= 0.7.0
[elogind.git] / configure.ac
1 #  This file is part of systemd.
2 #
3 #  Copyright 2010 Lennart Poettering
4 #
5 #  systemd is free software; you can redistribute it and/or modify it
6 #  under the terms of the GNU General Public License as published by
7 #  the Free Software Foundation; either version 2 of the License, or
8 #  (at your option) any later version.
9 #
10 #  systemd is distributed in the hope that it will be useful, but
11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 #  General Public License for more details.
14 #
15 #  You should have received a copy of the GNU General Public License
16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
17
18 AC_PREREQ(2.63)
19
20 AC_INIT([systemd],[37],[systemd-devel@lists.freedesktop.org])
21 AC_CONFIG_SRCDIR([src/main.c])
22 AC_CONFIG_MACRO_DIR([m4])
23 AC_CONFIG_HEADERS([config.h])
24 AC_USE_SYSTEM_EXTENSIONS
25 AC_SYS_LARGEFILE
26
27 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
28
29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
30
31 AC_CANONICAL_HOST
32 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
33 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
34        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
35       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
36
37 AM_SILENT_RULES([yes])
38
39 AC_CHECK_PROG([STOW], [stow], [yes], [no])
40
41 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
42         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
43         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
44 ])
45
46 # i18n stuff for the PolicyKit policy files
47 IT_PROG_INTLTOOL([0.40.0])
48
49 GETTEXT_PACKAGE=systemd
50 AC_SUBST(GETTEXT_PACKAGE)
51
52 AC_PROG_MKDIR_P
53 AC_PROG_LN_S
54 AC_PROG_SED
55 AC_PROG_AWK
56
57 AC_PROG_CC
58 AC_PROG_CC_C99
59 AM_PROG_CC_C_O
60 AC_PROG_GCC_TRADITIONAL
61
62 AC_CHECK_TOOL(OBJCOPY, objcopy)
63 AC_CHECK_TOOL(STRINGS, strings)
64 AC_CHECK_TOOL(GPERF, gperf)
65 if test -z "$GPERF" ; then
66         AC_MSG_ERROR([*** gperf not found])
67 fi
68
69 CC_CHECK_CFLAGS_APPEND([ \
70         -pipe \
71         -Wall \
72         -W \
73         -Wextra \
74         -Wno-inline \
75         -Wvla \
76         -Wundef \
77         -Wformat=2 \
78         -Wlogical-op \
79         -Wsign-compare \
80         -Wformat-security \
81         -Wmissing-include-dirs \
82         -Wformat-nonliteral \
83         -Wold-style-definition \
84         -Wpointer-arith \
85         -Winit-self \
86         -Wdeclaration-after-statement \
87         -Wfloat-equal \
88         -Wmissing-prototypes \
89         -Wstrict-prototypes \
90         -Wredundant-decls \
91         -Wmissing-declarations \
92         -Wmissing-noreturn \
93         -Wshadow \
94         -Wendif-labels \
95         -Wcast-align \
96         -Wstrict-aliasing=2 \
97         -Wwrite-strings \
98         -Wno-long-long \
99         -Wno-overlength-strings \
100         -Wno-unused-parameter \
101         -Wno-missing-field-initializers \
102         -Wno-unused-result \
103         -Wp,-D_FORTIFY_SOURCE=2 \
104         -ffast-math \
105         -fno-common \
106         -fdiagnostics-show-option \
107         -fno-strict-aliasing \
108         -fvisibility=hidden \
109         -ffunction-sections \
110         -fdata-sections \
111         -Wl,--as-needed \
112         -Wl,--gc-sections])
113
114 LT_PREREQ(2.2)
115 LT_INIT
116
117 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
118 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
119
120 save_LIBS="$LIBS"
121 LIBS=
122 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
123 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
124 CAP_LIBS="$LIBS"
125 LIBS="$save_LIBS"
126 AC_SUBST(CAP_LIBS)
127
128 # This makes sure pkg.m4 is available.
129 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
130
131 PKG_CHECK_MODULES(UDEV, [ libudev >= 172 ])
132 AC_SUBST(UDEV_CFLAGS)
133 AC_SUBST(UDEV_LIBS)
134
135 PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.2 ])
136 AC_SUBST(DBUS_CFLAGS)
137 AC_SUBST(DBUS_LIBS)
138
139 have_selinux=no
140 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
141 if test "x$enable_selinux" != "xno"; then
142         PKG_CHECK_MODULES(SELINUX, [ libselinux ],
143                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
144         AC_SUBST(SELINUX_CFLAGS)
145         AC_SUBST(SELINUX_LIBS)
146         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
147                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
148         fi
149 fi
150 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
151
152 have_xz=no
153 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
154 if test "x$enable_xz" != "xno"; then
155         PKG_CHECK_MODULES(XZ, [ liblzma ],
156                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
157         AC_SUBST(XZ_CFLAGS)
158         AC_SUBST(XZ_LIBS)
159         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
160                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
161         fi
162 fi
163 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
164
165 AC_ARG_ENABLE([tcpwrap],
166         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
167                 [case "${enableval}" in
168                         yes) have_tcpwrap=yes ;;
169                         no) have_tcpwrap=no ;;
170                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
171                 esac],
172                 [have_tcpwrap=auto])
173
174 if test "x${have_tcpwrap}" != xno ; then
175         ACX_LIBWRAP
176         if test "x${LIBWRAP_LIBS}" = x ; then
177                 if test "x$have_tcpwrap" = xyes ; then
178                         AC_MSG_ERROR([*** TCP wrappers support not found.])
179                 fi
180                 have_tcpwrap=no
181         else
182                 have_tcpwrap=yes
183         fi
184 else
185         LIBWRAP_LIBS=
186 fi
187 AC_SUBST(LIBWRAP_LIBS)
188
189 AC_ARG_ENABLE([pam],
190         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
191                 [case "${enableval}" in
192                         yes) have_pam=yes ;;
193                         no) have_pam=no ;;
194                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
195                 esac],
196                 [have_pam=auto])
197
198 if test "x${have_pam}" != xno ; then
199         AC_CHECK_HEADERS(
200                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
201                 [have_pam=yes],
202                 [if test "x$have_pam" = xyes ; then
203                         AC_MSG_ERROR([*** PAM headers not found.])
204                 fi])
205
206         AC_CHECK_LIB(
207                 [pam],
208                 [pam_syslog],
209                 [have_pam=yes],
210                 [if test "x$have_pam" = xyes ; then
211                         AC_MSG_ERROR([*** libpam not found.])
212                 fi])
213
214         if test "x$have_pam" = xyes ; then
215                 PAM_LIBS="-lpam -lpam_misc"
216                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
217         else
218                 have_pam=no
219         fi
220 else
221         PAM_LIBS=
222 fi
223 AC_SUBST(PAM_LIBS)
224 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
225
226 AC_ARG_ENABLE([acl],
227         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
228                 [case "${enableval}" in
229                         yes) have_acl=yes ;;
230                         no) have_acl=no ;;
231                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
232                 esac],
233                 [have_acl=auto])
234
235 if test "x${have_acl}" != xno ; then
236         AC_CHECK_HEADERS(
237                 [sys/acl.h acl/libacl.h],
238                 [have_acl=yes],
239                 [if test "x$have_acl" = xyes ; then
240                         AC_MSG_ERROR([*** ACL headers not found.])
241                 fi])
242
243         AC_CHECK_LIB(
244                 [acl],
245                 [acl_get_file],
246                 [have_acl=yes],
247                 [if test "x$have_acl" = xyes ; then
248                         AC_MSG_ERROR([*** libacl not found.])
249                 fi])
250
251         if test "x$have_acl" = xyes ; then
252                 ACL_LIBS="-lacl"
253                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
254         else
255                 have_acl=no
256         fi
257 else
258         ACL_LIBS=
259 fi
260 AC_SUBST(ACL_LIBS)
261 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
262
263 AC_ARG_ENABLE([audit],
264         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
265                 [case "${enableval}" in
266                         yes) have_audit=yes ;;
267                         no) have_audit=no ;;
268                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
269                 esac],
270                 [have_audit=auto])
271
272 if test "x${have_audit}" != xno ; then
273         AC_CHECK_HEADERS(
274                 [libaudit.h],
275                 [have_audit=yes],
276                 [if test "x$have_audit" = xyes ; then
277                         AC_MSG_ERROR([*** AUDIT headers not found.])
278                 fi])
279
280         AC_CHECK_LIB(
281                 [audit],
282                 [audit_open],
283                 [have_audit=yes],
284                 [if test "x$have_audit" = xyes ; then
285                         AC_MSG_ERROR([*** libaudit not found.])
286                 fi])
287
288         if test "x$have_audit" = xyes ; then
289                 AUDIT_LIBS="-laudit"
290                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
291         else
292                 have_audit=no
293         fi
294 else
295         AUDIT_LIBS=
296 fi
297 AC_SUBST(AUDIT_LIBS)
298
299 have_libcryptsetup=no
300 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
301 if test "x$enable_libcryptsetup" != "xno"; then
302         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup ],
303                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
304         AC_SUBST(LIBCRYPTSETUP_CFLAGS)
305         AC_SUBST(LIBCRYPTSETUP_LIBS)
306         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
307                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
308         fi
309 fi
310 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
311
312 have_binfmt=no
313 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
314 if test "x$enable_binfmt" != "xno"; then
315         have_binfmt=yes
316 fi
317 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
318
319 have_logind=no
320 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
321 if test "x$enable_logind" != "xno"; then
322         have_logind=yes
323 fi
324 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
325
326 have_hostnamed=no
327 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
328 if test "x$enable_hostnamed" != "xno"; then
329         have_hostnamed=yes
330 fi
331 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
332
333 have_timedated=no
334 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
335 if test "x$enable_timedated" != "xno"; then
336         have_timedated=yes
337 fi
338 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
339
340 have_localed=no
341 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
342 if test "x$enable_localed" != "xno"; then
343         have_localed=yes
344 fi
345 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
346
347 have_gtk=no
348 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
349 if test "x$enable_gtk" != "xno"; then
350         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 glib-2.0 > 2.26 gio-unix-2.0 gee-1.0],
351                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
352         AC_SUBST(GTK_CFLAGS)
353         AC_SUBST(GTK_LIBS)
354         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
355                 AC_MSG_ERROR([*** gtk support requested but libraries not found])
356         fi
357 fi
358 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
359
360 if test "$have_gtk" = "yes"; then
361         PKG_CHECK_MODULES(LIBNOTIFY, [ libnotify ])
362         AC_SUBST(LIBNOTIFY_CFLAGS)
363         AC_SUBST(LIBNOTIFY_LIBS)
364 fi
365
366 AM_PROG_VALAC([0.10])
367 AC_SUBST(VAPIDIR)
368 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
369
370 AC_PATH_PROG([XSLTPROC], [xsltproc])
371 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
372
373 AC_PATH_PROG([M4], [m4])
374
375 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux or other]))
376 if test "z$with_distro" = "z"; then
377         if test "$cross_compiling" = yes; then
378                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
379         else
380                 test -f "/etc/redhat-release" && with_distro="fedora"
381                 test -f "/etc/SuSE-release" && with_distro="suse"
382                 test -f "/etc/debian_version" &&  with_distro="debian"
383                 test -f "/etc/arch-release" && with_distro="arch"
384                 test -f "/etc/gentoo-release" && with_distro="gentoo"
385                 test -f "/etc/slackware-version" && with_distro="slackware"
386                 test -f "/etc/frugalware-release" && with_distro="frugalware"
387                 test -f "/etc/altlinux-release" && with_distro="altlinux"
388                 test -f "/etc/mandriva-release" && with_distro="mandriva"
389                 test -f "/etc/meego-release" && with_distro="meego"
390                 test -f "/etc/angstrom-version" && with_distro="angstrom"
391                 test -f "/etc/mageia-release" && with_distro="mageia"
392                 if test "x`lsb_release -is 2>/dev/null`" = "xUbuntu"; then
393                         with_distro="ubuntu"
394                 fi
395         fi
396         if test "z$with_distro" = "z"; then
397                 with_distro=`uname -s`
398         fi
399 fi
400 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
401 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
402
403 # Location of the init scripts as mandated by LSB
404 SYSTEM_SYSVINIT_PATH=/etc/init.d
405 SYSTEM_SYSVRCND_PATH=/etc/rc.d
406
407 M4_DEFINES=
408 have_plymouth=no
409
410 case $with_distro in
411         fedora)
412                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
413                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
414                 M4_DEFINES=-DTARGET_FEDORA=1
415                 have_plymouth=yes
416                 ;;
417         suse)
418                 SYSTEM_SYSVRCND_PATH=/etc/init.d
419                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
420                 M4_DEFINES=-DTARGET_SUSE=1
421                 have_plymouth=yes
422                 ;;
423         debian)
424                 SYSTEM_SYSVRCND_PATH=/etc
425                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
426                 M4_DEFINES=-DTARGET_DEBIAN=1
427                 ;;
428         ubuntu)
429                 SYSTEM_SYSVRCND_PATH=/etc
430                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
431                 M4_DEFINES=-DTARGET_UBUNTU=1
432                 ;;
433         arch)
434                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
435                 SYSTEM_SYSVRCND_PATH=/etc
436                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
437                 M4_DEFINES=-DTARGET_ARCH=1
438                 ;;
439         gentoo)
440                 SYSTEM_SYSVINIT_PATH=
441                 SYSTEM_SYSVRCND_PATH=
442                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
443                 M4_DEFINES=-DTARGET_GENTOO=1
444                 ;;
445         slackware)
446                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
447                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
448                 M4_DEFINES=-DTARGET_SLACKWARE=1
449                 ;;
450         frugalware)
451                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
452                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
453                 M4_DEFINES=-DTARGET_FRUGALWARE=1
454                 have_plymouth=yes
455                 ;;
456         altlinux)
457                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
458                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
459                 M4_DEFINES=-DTARGET_ALTLINUX=1
460                 have_plymouth=yes
461                 ;;
462         mandriva)
463                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
464                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
465                 M4_DEFINES=-DTARGET_MANDRIVA=1
466                 have_plymouth=yes
467                 ;;
468         meego)
469                 SYSTEM_SYSVINIT_PATH=
470                 SYSTEM_SYSVRCND_PATH=
471                 AC_DEFINE(TARGET_MEEGO, [], [Target is MeeGo])
472                 M4_DEFINES=-DTARGET_MEEGO=1
473                 ;;
474         angstrom)
475                 SYSTEM_SYSVRCND_PATH=/etc
476                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
477                 M4_DEFINES=-DTARGET_ANGSTROM=1
478                 ;;
479         mageia)
480                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
481                 AC_DEFINE(TARGET_MAGEIA, [], [Target is Mageia])
482                 M4_DISTRO_FLAG=-DTARGET_MAGEIA=1
483                 have_plymouth=yes
484                 ;;
485         other)
486                 ;;
487         *)
488                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
489                 ;;
490 esac
491
492 AC_ARG_WITH([sysvinit-path],
493         [AS_HELP_STRING([--with-sysvinit-path=PATH],
494                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
495         [SYSTEM_SYSVINIT_PATH="$withval"],
496         [])
497
498 AC_ARG_WITH([sysvrcd-path],
499         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
500                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
501         [SYSTEM_SYSVRCND_PATH="$withval"],
502         [])
503
504 AC_SUBST(SYSTEM_SYSVINIT_PATH)
505 AC_SUBST(SYSTEM_SYSVRCND_PATH)
506 AC_SUBST(M4_DEFINES)
507
508 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
509         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
510         SYSTEM_SYSV_COMPAT="yes"
511         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
512 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
513         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
514 else
515         SYSTEM_SYSV_COMPAT="no"
516 fi
517
518 AC_ARG_WITH([tty-gid],
519         [AS_HELP_STRING([--with-tty-gid=GID],
520                 [Specify the numeric GID of the 'tty' group])],
521         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
522         [])
523
524 AC_ARG_ENABLE(plymouth, AS_HELP_STRING([--enable-plymouth], [enable plymouth support]))
525 if test -n "$enable_plymouth"; then
526         have_plymouth="$enable_plymouth"
527 fi
528
529 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
530 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
531 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
532 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
533 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
534 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
535 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
536 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
537 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
538 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
539 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
540 AM_CONDITIONAL(TARGET_MEEGO, test x"$with_distro" = xmeego)
541 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
542 AM_CONDITIONAL(TARGET_MAGEIA, test x"$with_distro" = xmageia)
543
544 AM_CONDITIONAL(HAVE_PLYMOUTH, test "$have_plymouth" = "yes")
545 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
546
547 AC_ARG_WITH([dbuspolicydir],
548         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
549         [],
550         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
551
552 AC_ARG_WITH([dbussessionservicedir],
553         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
554         [],
555         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
556
557 AC_ARG_WITH([dbussystemservicedir],
558         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
559         [],
560         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
561
562 AC_ARG_WITH([dbusinterfacedir],
563         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
564         [],
565         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
566
567 AC_ARG_WITH([udevrulesdir],
568         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
569         [],
570         [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
571
572 AC_ARG_WITH([pamlibdir],
573         AS_HELP_STRING([--with-pamlibdir=DIR], [Diectory for PAM modules]),
574         [],
575         [with_pamlibdir=/lib/`$CC -print-multi-os-directory`/security])
576
577 AC_ARG_WITH([rootdir],
578         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
579         [],
580         [with_rootdir=${ac_default_prefix}])
581
582 AC_ARG_WITH([rootlibdir],
583         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
584         [],
585         [with_rootlibdir=${libdir}])
586
587 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
588 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
589 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
590 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
591 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
592 AC_SUBST([pamlibdir], [$with_pamlibdir])
593 AC_SUBST([rootdir], [$with_rootdir])
594 AC_SUBST([rootlibdir], [$with_rootlibdir])
595
596 AC_CONFIG_FILES([Makefile po/Makefile.in])
597 AC_OUTPUT
598 AC_MSG_RESULT([
599         $PACKAGE_NAME $VERSION
600
601         Distribution:            ${with_distro}
602         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
603         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
604         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
605         Gtk:                     ${have_gtk}
606         libcryptsetup:           ${have_libcryptsetup}
607         tcpwrap:                 ${have_tcpwrap}
608         PAM:                     ${have_pam}
609         AUDIT:                   ${have_audit}
610         SELinux:                 ${have_selinux}
611         XZ:                      ${have_xz}
612         ACL:                     ${have_acl}
613         binfmt:                  ${have_binfmt}
614         logind:                  ${have_logind}
615         hostnamed:               ${have_hostnamed}
616         timedated:               ${have_timedated}
617         localed:                 ${have_localed}
618         plymouth:                ${have_plymouth}
619         prefix:                  ${prefix}
620         root dir:                ${with_rootdir}
621         lib dir:                 ${libdir}
622         rootlib dir:             ${with_rootlibdir}
623         pam modules dir:         ${with_pamlibdir}
624         udev rules dir:          ${with_udevrulesdir}
625         dbus policy dir:         ${with_dbuspolicydir}
626         dbus session dir:        ${with_dbussessionservicedir}
627         dbus system dir:         ${with_dbussystemservicedir}
628         dbus interfaces dir:     ${with_dbusinterfacedir}
629 ])