configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [207],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT([disable-static])
  46
  47 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  48 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  49
  50 # i18n stuff for the PolicyKit policy files
  51 IT_PROG_INTLTOOL([0.40.0])
  52
  53 GETTEXT_PACKAGE=systemd
  54 AC_SUBST(GETTEXT_PACKAGE)
  55
  56 AC_PROG_MKDIR_P
  57 AC_PROG_LN_S
  58 AC_PROG_SED
  59 AC_PROG_GREP
  60 AC_PROG_AWK
  61
  62 AC_PROG_CC
  63 AC_PROG_CC_C99
  64 AM_PROG_CC_C_O
  65 AC_PROG_GCC_TRADITIONAL
  66
  67 AC_PATH_PROG([M4], [m4])
  68 AC_PATH_PROG([XSLTPROC], [xsltproc])
  69
  70 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  71 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  72
  73 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  74
  75 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  76
  77 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod])
  78
  79 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec])
  80
  81 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  82 m4_ifdef([GTK_DOC_CHECK], [
  83 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  84          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
  85           enable_gtk_doc=no])
  86
  87 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  88         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  89 ])
  90
  91 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  92 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  93 ], [
  94    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  95    enable_introspection=no])
  96
  97 AC_CHECK_TOOL(OBJCOPY, objcopy)
  98 AC_CHECK_TOOL(STRINGS, strings)
  99 AC_CHECK_TOOL(GPERF, gperf)
 100 if test -z "$GPERF" ; then
 101         AC_MSG_ERROR([*** gperf not found])
 102 fi
 103
 104 # ------------------------------------------------------------------------------
 105 address_sanitizer_cflags=
 106 address_sanitizer_cppflags=
 107 address_sanitizer_ldflags=
 108 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 109 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 110             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 111             AS_IF([test -z "$with_as_cflags"],
 112                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 113             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 114             address_sanitizer_cppflags="-DVALGRIND=1"
 115             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 116       ])
 117
 118 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 119         -pipe \
 120         -Wall \
 121         -Wextra \
 122         -Wno-inline \
 123         -Wundef \
 124         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 125         -Wlogical-op \
 126         -Wsign-compare \
 127         -Wmissing-include-dirs \
 128         -Wold-style-definition \
 129         -Wpointer-arith \
 130         -Winit-self \
 131         -Wdeclaration-after-statement \
 132         -Wfloat-equal \
 133         -Wmissing-prototypes \
 134         -Wstrict-prototypes \
 135         -Wredundant-decls \
 136         -Wmissing-declarations \
 137         -Wmissing-noreturn \
 138         -Wshadow \
 139         -Wendif-labels \
 140         -Wcast-align \
 141         -Wstrict-aliasing=2 \
 142         -Wwrite-strings \
 143         -Wno-long-long \
 144         -Wno-overlength-strings \
 145         -Wno-unused-parameter \
 146         -Wno-missing-field-initializers \
 147         -Wno-unused-result \
 148         -Werror=overflow \
 149         -ffast-math \
 150         -fno-common \
 151         -fdiagnostics-show-option \
 152         -fdiagnostics-color \
 153         -fno-strict-aliasing \
 154         -fvisibility=hidden \
 155         -ffunction-sections \
 156         -fdata-sections \
 157         -fstack-protector \
 158         --param=ssp-buffer-size=4])
 159 AC_SUBST([OUR_CFLAGS], "$with_cflags $address_sanitizer_cflags")
 160
 161 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*],
 162         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 163                -Wp,-D_FORTIFY_SOURCE=2])],
 164         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 165 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $address_sanitizer_cppflags")
 166
 167 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 168         -Wl,--as-needed \
 169         -Wl,--no-undefined \
 170         -Wl,--gc-sections \
 171         -Wl,-z,relro \
 172         -Wl,-z,now])
 173 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $address_sanitizer_ldflags")
 174
 175 # ------------------------------------------------------------------------------
 176 # we use python to build the man page index, and for systemd-python
 177 have_python=no
 178 AC_ARG_WITH([python],
 179         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 180
 181 AS_IF([test "x$with_python" != "xno"], [
 182         AM_PATH_PYTHON(,, [:])
 183         AS_IF([test "$PYTHON" != :], [have_python=yes])
 184 ])
 185 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 186 AS_IF([test "x$PYTHON_BINARY" = "x"],
 187       [AS_IF([test "x$have_python" = "xyes"],
 188              [PYTHON_BINARY="$(which "$PYTHON")"],
 189              [PYTHON_BINARY=/usr/bin/python])])
 190 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 191
 192 AS_IF([test "x$have_python" != "xyes" -a "x$enable_python_devel" = "xyes"],
 193       [AC_MSG_ERROR([*** python-devel support requires --with-python])])
 194
 195 have_python_devel=no
 196 AC_ARG_ENABLE(python_devel, AS_HELP_STRING([--disable-python-devel], [Do not build python modules]))
 197 AS_IF([test "x$have_python" = "xyes" -a "x$enable_python_devel" != "xno"], [
 198       PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}],
 199             [have_python_devel=yes],
 200             [PKG_CHECK_MODULES([PYTHON_DEVEL], [python],
 201                   [have_python_devel=yes],
 202                   [have_python_devel=no])])
 203       AS_IF([test "x$have_python_devel" = xno -a "x$enable_python_devel" = xyes],
 204             [AC_MSG_ERROR([*** python-devel support requested but libraries not found])])
 205 ])
 206 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 207
 208 # ------------------------------------------------------------------------------
 209
 210 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 211 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 212 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 213
 214 # unconditionally pull-in librt with old glibc versions
 215 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 216
 217 save_LIBS="$LIBS"
 218 LIBS=
 219 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 220 CAP_LIBS="$LIBS"
 221 AC_SUBST(CAP_LIBS)
 222
 223 LIBS=
 224 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 225 RT_LIBS="$LIBS"
 226 AC_SUBST(RT_LIBS)
 227 LIBS="$save_LIBS"
 228
 229 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 230 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 231 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 232 #include <unistd.h>
 233 #include <sys/mount.h>
 234 #include <fcntl.h>]])
 235
 236 # This makes sure pkg.m4 is available.
 237 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 238
 239 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 240
 241
 242 # ------------------------------------------------------------------------------
 243 have_coverage=no
 244 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 245 if test "x$enable_coverage" = "xyes" ; then
 246         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 247         if test "x$lcov_found" = xno ; then
 248                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 249         else
 250                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 251                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 252                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 253                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 254                 else
 255                         have_coverage=yes
 256                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 257                         -fprofile-arcs \
 258                         -ftest-coverage])
 259                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 260                 fi
 261         fi
 262 fi
 263 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 264
 265 # ------------------------------------------------------------------------------
 266 have_kmod=no
 267 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 268 if test "x$enable_kmod" != "xno"; then
 269         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 270         if test "x$have_kmod" = "xyes"; then
 271                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 14 ],
 272                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 273                         AC_MSG_ERROR([*** kmod version >= 14 not found]))
 274         fi
 275         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 276                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 277         fi
 278 fi
 279 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 280
 281 # ------------------------------------------------------------------------------
 282 have_blkid=no
 283 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 284 if test "x$enable_blkid" != "xno"; then
 285         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 286                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 287         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 288                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 289         fi
 290 fi
 291 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 292
 293 # ------------------------------------------------------------------------------
 294 have_ima=yes
 295 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 296                 [case "${enableval}" in
 297                         yes) have_ima=yes ;;
 298                         no) have_ima=no ;;
 299                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 300                 esac],
 301                 [have_ima=yes])
 302
 303 if test "x${have_ima}" != xno ; then
 304         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 305 fi
 306
 307 # ------------------------------------------------------------------------------
 308 have_chkconfig=yes
 309 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 310                 [case "${enableval}" in
 311                         yes) have_chkconfig=yes ;;
 312                         no) have_chkconfig=no ;;
 313                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 314                 esac],
 315                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 316                 if test -z "$CHKCONFIG"; then
 317                         have_chkconfig=no
 318                 else
 319                         have_chkconfig=yes
 320                 fi])
 321
 322 if test "x${have_chkconfig}" != xno ; then
 323         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 324 fi
 325
 326 # ------------------------------------------------------------------------------
 327 have_selinux=no
 328 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 329 if test "x$enable_selinux" != "xno"; then
 330         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 331                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 332         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 333                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 334         fi
 335 fi
 336 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 337
 338 AC_ARG_WITH(debug-shell,
 339         AS_HELP_STRING([--with-debug-shell=PATH],
 340                 [Path to debug shell binary]),
 341         [SUSHELL="$withval"],[
 342         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 343
 344 AC_SUBST(SUSHELL)
 345
 346 AC_ARG_WITH([debug-tty],
 347         AS_HELP_STRING([--with-debug-tty=PATH],
 348                 [Specify the tty device for debug shell]),
 349         [DEBUGTTY="$withval"],
 350         [DEBUGTTY=/dev/tty9])
 351
 352 AC_SUBST(DEBUGTTY)
 353
 354 # ------------------------------------------------------------------------------
 355 have_xz=no
 356 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 357 if test "x$enable_xz" != "xno"; then
 358         PKG_CHECK_MODULES(XZ, [ liblzma ],
 359                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 360         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 361                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 362         fi
 363 fi
 364 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 365
 366 # ------------------------------------------------------------------------------
 367 AC_ARG_ENABLE([tcpwrap],
 368         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 369                 [case "${enableval}" in
 370                         yes) have_tcpwrap=yes ;;
 371                         no) have_tcpwrap=no ;;
 372                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 373                 esac],
 374                 [have_tcpwrap=auto])
 375
 376 if test "x${have_tcpwrap}" != xno ; then
 377         ACX_LIBWRAP
 378         if test "x${LIBWRAP_LIBS}" = x ; then
 379                 if test "x$have_tcpwrap" = xyes ; then
 380                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 381                 fi
 382                 have_tcpwrap=no
 383         else
 384                 have_tcpwrap=yes
 385         fi
 386 else
 387         LIBWRAP_LIBS=
 388 fi
 389 AC_SUBST(LIBWRAP_LIBS)
 390
 391 # ------------------------------------------------------------------------------
 392 AC_ARG_ENABLE([pam],
 393         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 394                 [case "${enableval}" in
 395                         yes) have_pam=yes ;;
 396                         no) have_pam=no ;;
 397                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 398                 esac],
 399                 [have_pam=auto])
 400
 401 if test "x${have_pam}" != xno ; then
 402         AC_CHECK_HEADERS(
 403                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 404                 [have_pam=yes],
 405                 [if test "x$have_pam" = xyes ; then
 406                         AC_MSG_ERROR([*** PAM headers not found.])
 407                 fi])
 408
 409         AC_CHECK_LIB(
 410                 [pam],
 411                 [pam_syslog],
 412                 [have_pam=yes],
 413                 [if test "x$have_pam" = xyes ; then
 414                         AC_MSG_ERROR([*** libpam not found.])
 415                 fi])
 416
 417         if test "x$have_pam" = xyes ; then
 418                 PAM_LIBS="-lpam -lpam_misc"
 419                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 420         else
 421                 have_pam=no
 422         fi
 423 else
 424         PAM_LIBS=
 425 fi
 426 AC_SUBST(PAM_LIBS)
 427 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 428
 429 # ------------------------------------------------------------------------------
 430 AC_ARG_ENABLE([acl],
 431         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 432                 [case "${enableval}" in
 433                         yes) have_acl=yes ;;
 434                         no) have_acl=no ;;
 435                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 436                 esac],
 437                 [have_acl=auto])
 438
 439 if test "x${have_acl}" != xno ; then
 440         AC_CHECK_HEADERS(
 441                 [sys/acl.h acl/libacl.h],
 442                 [have_acl=yes],
 443                 [if test "x$have_acl" = xyes ; then
 444                         AC_MSG_ERROR([*** ACL headers not found.])
 445                 fi])
 446
 447         AC_CHECK_LIB(
 448                 [acl],
 449                 [acl_get_file],
 450                 [have_acl=yes],
 451                 [if test "x$have_acl" = xyes ; then
 452                         AC_MSG_ERROR([*** libacl not found.])
 453                 fi])
 454
 455         if test "x$have_acl" = xyes ; then
 456                 ACL_LIBS="-lacl"
 457                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 458         else
 459                 have_acl=no
 460         fi
 461 else
 462         ACL_LIBS=
 463 fi
 464 AC_SUBST(ACL_LIBS)
 465 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 466
 467 # ------------------------------------------------------------------------------
 468 AC_ARG_ENABLE([xattr],
 469         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 470                 [case "${enableval}" in
 471                         yes) have_xattr=yes ;;
 472                         no) have_xattr=no ;;
 473                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 474                 esac],
 475                 [have_xattr=auto])
 476
 477 if test "x${have_xattr}" != xno ; then
 478         AC_CHECK_HEADERS(
 479                 [attr/xattr.h],
 480                 [have_xattr=yes],
 481                 [if test "x$have_xattr" = xyes ; then
 482                         AC_MSG_ERROR([*** XATTR headers not found.])
 483                 fi])
 484
 485         AC_CHECK_LIB(
 486                 [attr],
 487                 [fsetxattr],
 488                 [have_xattr=yes],
 489                 [if test "x$have_xattr" = xyes ; then
 490                         AC_MSG_ERROR([*** libattr not found.])
 491                 fi])
 492
 493         if test "x$have_xattr" = xyes ; then
 494                 XATTR_LIBS="-lattr"
 495                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 496         else
 497                 have_xattr=no
 498         fi
 499 else
 500         XATTR_LIBS=
 501 fi
 502 AC_SUBST(XATTR_LIBS)
 503 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 504
 505 # ------------------------------------------------------------------------------
 506 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 507                 [case "${enableval}" in
 508                         yes) have_smack=yes ;;
 509                         no) have_smack=no ;;
 510                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 511                 esac],
 512                 [have_smack=auto])
 513
 514 if test "x${have_xattr}" = xno; then
 515         if test "x${have_smack}" = xyes; then
 516                 AC_MSG_ERROR(SMACK requires xattr support)
 517         else
 518                 have_smack=no
 519         fi
 520 else
 521         if test "x${have_smack}" = xauto; then
 522                 have_smack=yes
 523         fi
 524 fi
 525
 526 if test "x${have_smack}" = xyes ; then
 527         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 528 fi
 529
 530 # ------------------------------------------------------------------------------
 531 AC_ARG_ENABLE([gcrypt],
 532         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 533                 [case "${enableval}" in
 534                         yes) have_gcrypt=yes ;;
 535                         no) have_gcrypt=no ;;
 536                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 537                 esac],
 538                 [have_gcrypt=auto])
 539
 540 if test "x${have_gcrypt}" != xno ; then
 541         AM_PATH_LIBGCRYPT(
 542                 [1.4.5],
 543                 [have_gcrypt=yes],
 544                 [if test "x$have_gcrypt" = xyes ; then
 545                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 546                 fi])
 547
 548         if test "x$have_gcrypt" = xyes ; then
 549                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 550                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 551                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 552         else
 553                 have_gcrypt=no
 554         fi
 555 else
 556         GCRYPT_LIBS=
 557         GCRYPT_CFLAGS=
 558 fi
 559 AC_SUBST(GCRYPT_LIBS)
 560 AC_SUBST(GCRYPT_CFLAGS)
 561 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 562
 563 # ------------------------------------------------------------------------------
 564 AC_ARG_ENABLE([audit],
 565         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 566                 [case "${enableval}" in
 567                         yes) have_audit=yes ;;
 568                         no) have_audit=no ;;
 569                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 570                 esac],
 571                 [have_audit=auto])
 572
 573 if test "x${have_audit}" != xno ; then
 574         AC_CHECK_HEADERS(
 575                 [libaudit.h],
 576                 [have_audit=yes],
 577                 [if test "x$have_audit" = xyes ; then
 578                         AC_MSG_ERROR([*** AUDIT headers not found.])
 579                 fi])
 580
 581         AC_CHECK_LIB(
 582                 [audit],
 583                 [audit_open],
 584                 [have_audit=yes],
 585                 [if test "x$have_audit" = xyes ; then
 586                         AC_MSG_ERROR([*** libaudit not found.])
 587                 fi])
 588
 589         if test "x$have_audit" = xyes ; then
 590                 AUDIT_LIBS="-laudit"
 591                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 592         else
 593                 have_audit=no
 594         fi
 595 else
 596         AUDIT_LIBS=
 597 fi
 598 AC_SUBST(AUDIT_LIBS)
 599
 600 # ------------------------------------------------------------------------------
 601 have_libcryptsetup=no
 602 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 603 if test "x$enable_libcryptsetup" != "xno"; then
 604         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 605                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 606         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 607                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 608         fi
 609 fi
 610 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 611
 612 # ------------------------------------------------------------------------------
 613 have_qrencode=no
 614 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 615 if test "x$enable_qrencode" != "xno"; then
 616         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 617                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 618         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 619                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 620         fi
 621 fi
 622 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 623
 624 # ------------------------------------------------------------------------------
 625 have_microhttpd=no
 626 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 627 if test "x$enable_microhttpd" != "xno"; then
 628         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 629                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 630         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 631                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 632         fi
 633 fi
 634 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 635
 636 # ------------------------------------------------------------------------------
 637 have_binfmt=no
 638 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 639 if test "x$enable_binfmt" != "xno"; then
 640         have_binfmt=yes
 641 fi
 642 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 643
 644 # ------------------------------------------------------------------------------
 645 have_vconsole=no
 646 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 647 if test "x$enable_vconsole" != "xno"; then
 648         have_vconsole=yes
 649 fi
 650 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 651
 652 # ------------------------------------------------------------------------------
 653 have_readahead=no
 654 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 655 if test "x$enable_readahead" != "xno"; then
 656         have_readahead=yes
 657 fi
 658 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 659
 660 # ------------------------------------------------------------------------------
 661 have_bootchart=no
 662 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 663 if test "x$enable_bootchart" != "xno"; then
 664         have_bootchart=yes
 665 fi
 666 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 667
 668 # ------------------------------------------------------------------------------
 669 have_quotacheck=no
 670 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 671 if test "x$enable_quotacheck" != "xno"; then
 672         have_quotacheck=yes
 673 fi
 674 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 675
 676 # ------------------------------------------------------------------------------
 677 have_tmpfiles=no
 678 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 679 if test "x$enable_tmpfiles" != "xno"; then
 680         have_tmpfiles=yes
 681 fi
 682 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 683
 684 # ------------------------------------------------------------------------------
 685 have_randomseed=no
 686 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 687 if test "x$enable_randomseed" != "xno"; then
 688         have_randomseed=yes
 689 fi
 690 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 691
 692 # ------------------------------------------------------------------------------
 693 have_backlight=no
 694 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
 695 if test "x$enable_backlight" != "xno"; then
 696         have_backlight=yes
 697 fi
 698 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
 699
 700 # ------------------------------------------------------------------------------
 701 have_logind=no
 702 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 703 if test "x$enable_logind" != "xno"; then
 704         have_logind=yes
 705 fi
 706 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 707 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 708
 709 # ------------------------------------------------------------------------------
 710 have_machined=no
 711 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
 712 if test "x$enable_machined" != "xno"; then
 713         have_machined=yes
 714 fi
 715 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
 716 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
 717
 718 # ------------------------------------------------------------------------------
 719 have_hostnamed=no
 720 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 721 if test "x$enable_hostnamed" != "xno"; then
 722         have_hostnamed=yes
 723 fi
 724 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 725
 726 # ------------------------------------------------------------------------------
 727 have_timedated=no
 728 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 729 if test "x$enable_timedated" != "xno"; then
 730         have_timedated=yes
 731 fi
 732 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 733
 734 # ------------------------------------------------------------------------------
 735 have_localed=no
 736 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 737 if test "x$enable_localed" != "xno"; then
 738         have_localed=yes
 739 fi
 740 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 741
 742 # ------------------------------------------------------------------------------
 743 have_coredump=no
 744 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 745 if test "x$enable_coredump" != "xno"; then
 746         have_coredump=yes
 747 fi
 748 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 749
 750 # ------------------------------------------------------------------------------
 751 have_polkit=no
 752 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 753 if test "x$enable_polkit" != "xno"; then
 754         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 755         have_polkit=yes
 756 fi
 757 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 758
 759 # ------------------------------------------------------------------------------
 760 have_efi=no
 761 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 762 if test "x$enable_efi" != "xno"; then
 763         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 764         have_efi=yes
 765 fi
 766 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 767
 768 # ------------------------------------------------------------------------------
 769 AC_ARG_WITH(rc-local-script-path-start,
 770         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 771                 [Path to /etc/rc.local]),
 772         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 773         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 774
 775 AC_ARG_WITH(rc-local-script-path-stop,
 776         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 777                 [Path to /usr/sbin/halt.local]),
 778         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 779         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 780
 781 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 782 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 783
 784 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 785 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 786
 787 # ------------------------------------------------------------------------------
 788 AC_ARG_WITH(kbd-loadkeys,
 789         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 790                 [Path to loadkeys]),
 791         [KBD_LOADKEYS="$withval"],
 792         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 793
 794 AC_ARG_WITH(kbd-setfont,
 795         AS_HELP_STRING([--with-kbd-setfont=PATH],
 796                 [Path to setfont]),
 797         [KBD_SETFONT="$withval"],
 798         [KBD_SETFONT="/usr/bin/setfont"])
 799
 800 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 801 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 802
 803 AC_SUBST(KBD_LOADKEYS)
 804 AC_SUBST(KBD_SETFONT)
 805
 806 AC_ARG_WITH(telinit,
 807         AS_HELP_STRING([--with-telinit=PATH],
 808                 [Path to telinit]),
 809         [TELINIT="$withval"],
 810         [TELINIT="/lib/upstart/telinit"])
 811
 812 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 813
 814 AC_SUBST(TELINIT)
 815
 816 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 817
 818 # ------------------------------------------------------------------------------
 819 have_myhostname=no
 820 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 821 if test "x$enable_myhostname" != "xno"; then
 822         AC_HEADER_STDC
 823         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h])
 824
 825         AC_C_CONST
 826         AC_TYPE_SIZE_T
 827         AC_HEADER_TIME
 828
 829         AC_FUNC_MALLOC
 830         AC_FUNC_SELECT_ARGTYPES
 831         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 832
 833         have_myhostname=yes
 834 fi
 835 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 836
 837 # ------------------------------------------------------------------------------
 838 AC_ARG_WITH(firmware-path,
 839        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 840           [Firmware search path (default="")]),
 841        [], [with_firmware_path=""])
 842 OLD_IFS=$IFS
 843 IFS=:
 844 for i in $with_firmware_path; do
 845        if test "x${FIRMWARE_PATH}" = "x"; then
 846               FIRMWARE_PATH="\\\"${i}/\\\""
 847        else
 848               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 849        fi
 850 done
 851 IFS=$OLD_IFS
 852 AC_SUBST(FIRMWARE_PATH)
 853 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
 854 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
 855
 856 # ------------------------------------------------------------------------------
 857 AC_ARG_ENABLE([gudev],
 858        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 859        [], [enable_gudev=yes])
 860 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 861 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 862 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 863
 864 # ------------------------------------------------------------------------------
 865 have_manpages=no
 866 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 867 AS_IF([test "x$enable_manpages" != xno], [
 868         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 869                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 870         ])
 871         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 872 ])
 873 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 874
 875 # ------------------------------------------------------------------------------
 876
 877 # Location of the init scripts as mandated by LSB
 878 SYSTEM_SYSVINIT_PATH=/etc/init.d
 879 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 880 M4_DEFINES=
 881
 882 AC_ARG_WITH([sysvinit-path],
 883         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 884                 [Specify the path to where the SysV init scripts are located])],
 885         [SYSTEM_SYSVINIT_PATH="$withval"],
 886         [])
 887
 888 AC_ARG_WITH([sysvrcnd-path],
 889         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 890                 [Specify the path to the base directory for the SysV rcN.d directories])],
 891         [SYSTEM_SYSVRCND_PATH="$withval"],
 892         [])
 893
 894 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 895         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 896         SYSTEM_SYSV_COMPAT="yes"
 897         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 898 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 899         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 900 else
 901         SYSTEM_SYSV_COMPAT="no"
 902 fi
 903
 904 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 905 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 906 AC_SUBST(M4_DEFINES)
 907
 908 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 909
 910 AC_ARG_WITH([tty-gid],
 911         [AS_HELP_STRING([--with-tty-gid=GID],
 912                 [Specify the numeric GID of the 'tty' group])],
 913         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 914         [])
 915
 916 AC_ARG_WITH([dbuspolicydir],
 917         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 918         [],
 919         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
 920
 921 AC_ARG_WITH([dbussessionservicedir],
 922         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 923         [],
 924         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
 925
 926 AC_ARG_WITH([dbussystemservicedir],
 927         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 928         [],
 929         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
 930
 931 AC_ARG_WITH([dbusinterfacedir],
 932         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 933         [],
 934         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
 935
 936 AC_ARG_WITH([bashcompletiondir],
 937         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 938         [],
 939         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 940                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 941         ] , [
 942                 with_bashcompletiondir=${datadir}/bash-completion/completions
 943         ])])
 944
 945 AC_ARG_WITH([zshcompletiondir],
 946         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
 947         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
 948
 949 AC_ARG_WITH([rootprefix],
 950         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 951         [], [with_rootprefix=${ac_default_prefix}])
 952
 953 AC_ARG_WITH([rootlibdir],
 954         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 955         [],
 956         [with_rootlibdir=${libdir}])
 957
 958 AC_ARG_WITH([pamlibdir],
 959         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 960         [],
 961         [with_pamlibdir=${with_rootlibdir}/security])
 962
 963 AC_ARG_WITH([pamconfdir],
 964         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
 965         [],
 966         [with_pamconfdir=${sysconfdir}/pam.d])
 967
 968 AC_ARG_ENABLE([split-usr],
 969         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 970         [],
 971         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 972                 enable_split_usr=yes
 973         ], [
 974                 enable_split_usr=no
 975         ])])
 976
 977 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 978         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 979 ])
 980
 981 # Work around intltoolize and gtk-doc problems in VPATH builds
 982 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 983                                        [Define to do gtk-doc tests])
 984 AS_IF([test "x$0" != "x./configure"], [
 985         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 986 ])
 987
 988 AC_ARG_ENABLE(tests,
 989        [AC_HELP_STRING([--disable-tests], [disable tests])],
 990        enable_tests=$enableval, enable_tests=yes)
 991 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 992
 993 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 994 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 995 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 996 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 997 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 998 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
 999 AC_SUBST([pamlibdir], [$with_pamlibdir])
1000 AC_SUBST([pamconfdir], [$with_pamconfdir])
1001 AC_SUBST([rootprefix], [$with_rootprefix])
1002 AC_SUBST([rootlibdir], [$with_rootlibdir])
1003
1004 AC_CONFIG_FILES([
1005         Makefile po/Makefile.in
1006         docs/libudev/Makefile
1007         docs/libudev/version.xml
1008         docs/gudev/Makefile
1009         docs/gudev/version.xml
1010 ])
1011
1012 AC_OUTPUT
1013 AC_MSG_RESULT([
1014         $PACKAGE_NAME $VERSION
1015
1016         libcryptsetup:           ${have_libcryptsetup}
1017         tcpwrap:                 ${have_tcpwrap}
1018         PAM:                     ${have_pam}
1019         AUDIT:                   ${have_audit}
1020         IMA:                     ${have_ima}
1021         SELinux:                 ${have_selinux}
1022         SMACK:                   ${have_smack}
1023         XZ:                      ${have_xz}
1024         ACL:                     ${have_acl}
1025         XATTR:                   ${have_xattr}
1026         GCRYPT:                  ${have_gcrypt}
1027         QRENCODE:                ${have_qrencode}
1028         MICROHTTPD:              ${have_microhttpd}
1029         CHKCONFIG:               ${have_chkconfig}
1030         binfmt:                  ${have_binfmt}
1031         vconsole:                ${have_vconsole}
1032         readahead:               ${have_readahead}
1033         bootchart:               ${have_bootchart}
1034         quotacheck:              ${have_quotacheck}
1035         tmpfiles:                ${have_tmpfiles}
1036         randomseed:              ${have_randomseed}
1037         backlight:               ${have_backlight}
1038         logind:                  ${have_logind}
1039         machined:                ${have_machined}
1040         hostnamed:               ${have_hostnamed}
1041         timedated:               ${have_timedated}
1042         localed:                 ${have_localed}
1043         coredump:                ${have_coredump}
1044         polkit:                  ${have_polkit}
1045         efi:                     ${have_efi}
1046         kmod:                    ${have_kmod}
1047         blkid:                   ${have_blkid}
1048         nss-myhostname:          ${have_myhostname}
1049         gudev:                   ${enable_gudev}
1050         gintrospection:          ${enable_introspection}
1051         Python:                  ${have_python}
1052         Python Headers:          ${have_python_devel}
1053         man pages:               ${have_manpages}
1054         gtk-doc:                 ${enable_gtk_doc}
1055         test coverage:           ${have_coverage}
1056         Split /usr:              ${enable_split_usr}
1057         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1058
1059         prefix:                  ${prefix}
1060         rootprefix:              ${with_rootprefix}
1061         sysconf dir:             ${sysconfdir}
1062         datarootdir:             ${datarootdir}
1063         includedir:              ${includedir}
1064         include_prefix:          ${INCLUDE_PREFIX}
1065         lib dir:                 ${libdir}
1066         rootlib dir:             ${with_rootlibdir}
1067         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1068         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1069         Build Python:            ${PYTHON}
1070         Installation Python:     ${PYTHON_BINARY}
1071         firmware path:           ${FIRMWARE_PATH}
1072         PAM modules dir:         ${with_pamlibdir}
1073         PAM configuration dir:   ${with_pamconfdir}
1074         D-Bus policy dir:        ${with_dbuspolicydir}
1075         D-Bus session dir:       ${with_dbussessionservicedir}
1076         D-Bus system dir:        ${with_dbussystemservicedir}
1077         D-Bus interfaces dir:    ${with_dbusinterfacedir}
1078         Bash completions dir:    ${with_bashcompletiondir}
1079         Zsh completions dir:     ${with_zshcompletiondir}
1080         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1081         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1082         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1083
1084         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1085         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1086         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1087         PYTHON_CFLAGS:           ${PYTHON_DEVEL_CFLAGS}
1088         PYTHON_LIBS:             ${PYTHON_DEVEL_LIBS}
1089 ])