configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010 Lennart Poettering
   4 #
   5 #  systemd is free software; you can redistribute it and/or modify it
   6 #  under the terms of the GNU General Public License as published by
   7 #  the Free Software Foundation; either version 2 of the License, or
   8 #  (at your option) any later version.
   9 #
  10 #  systemd is distributed in the hope that it will be useful, but
  11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 #  General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU General Public License
  16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ(2.63)
  19
  20 AC_INIT([systemd],[0],[mzflfgrzq (at) 0pointer (dot) net])
  21 AC_CONFIG_SRCDIR([main.c])
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax])
  26
  27 AC_SUBST(PACKAGE_URL, [http://git.0pointer.de/?p=systemd.git])
  28
  29 AC_CANONICAL_HOST
  30
  31 AM_SILENT_RULES([yes])
  32
  33 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  34
  35 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  36         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  37         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  38 ])
  39
  40 AC_PROG_CC
  41 AC_PROG_CC_C99
  42 AM_PROG_CC_C_O
  43 AC_PROG_GCC_TRADITIONAL
  44 AC_USE_SYSTEM_EXTENSIONS
  45
  46 CC_CHECK_CFLAGS_APPEND([-Wall -W -Wextra -pipe -Wno-long-long -Winline -Wvla -Wno-overlength-strings -Wundef -Wformat=2 -Wlogical-op -Wsign-compare -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wpointer-arith -Winit-self -Wdeclaration-after-statement -Wfloat-equal -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-declarations -Wmissing-noreturn -Wshadow -Wendif-labels -Wcast-align -Wstrict-aliasing=2 -Wwrite-strings -Wno-unused-parameter -ffast-math -Wp,-D_FORTIFY_SOURCE=2 -fno-common -fdiagnostics-show-option -Wno-missing-field-initializers])
  47
  48 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
  49 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
  50 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
  51
  52 # This makes sure pkg.m4 is available.
  53 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[pkg.m4 missing, please install pkg-config])
  54 PKG_CHECK_MODULES(UDEV, [ libudev ])
  55 AC_SUBST(UDEV_CFLAGS)
  56 AC_SUBST(UDEV_LIBS)
  57
  58 PKG_CHECK_MODULES(DBUS, [ dbus-1 ])
  59 AC_SUBST(DBUS_CFLAGS)
  60 AC_SUBST(DBUS_LIBS)
  61
  62 PKG_CHECK_MODULES(DBUSGLIB, [ dbus-glib-1 ])
  63 AC_SUBST(DBUSGLIB_CFLAGS)
  64 AC_SUBST(DBUSGLIB_LIBS)
  65
  66 PKG_CHECK_MODULES(GTK, [ gtk+-2.0 ])
  67 AC_SUBST(GTK_CFLAGS)
  68 AC_SUBST(GTK_LIBS)
  69
  70 PKG_CHECK_MODULES( CGROUP, [ libcgroup >= 0.35 ], [],
  71     [AC_CHECK_HEADER( [libcgroup.h], [], [AC_MSG_ERROR([*** libcgroup.h not found])], )
  72      save_CPPFLAGS="$CPPFLAGS"
  73      save_LIBS="$LIBS"
  74      CGROUP_LIBS=${CGROUP_LIBS:--lcgroup}
  75      LIBS="$LIBS $CGROUP_LIBS"
  76      CPPFLAGS="$CPPFLAGS $CGROUP_CFLAGS"
  77      AC_MSG_CHECKING([for libcgroup >= 0.35])
  78      AC_LINK_IFELSE(
  79          [AC_LANG_PROGRAM([[#include <libcgroup.h>]], [[ CGFLAG_DELETE_RECURSIVE; cgroup_init(); ]])],
  80          [AC_MSG_RESULT([yes])],
  81          [AC_MSG_RESULT([no]); AC_MSG_ERROR([*** systemd needs libcgroup 0.35 or newer])],
  82          [${CGROUP_LIBS}])
  83      CPPFLAGS="$save_CPPFLAGS"
  84      LIBS="$save_LIBS"
  85     ])
  86
  87 AC_SUBST(CGROUP_CFLAGS)
  88 AC_SUBST(CGROUP_LIBS)
  89
  90 AM_PROG_VALAC([0.7])
  91 AC_SUBST(VAPIDIR)
  92
  93 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, or none]))
  94 if test "z$with_distro" = "z"; then
  95         if test "$cross_compiling" = yes; then
  96                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
  97         else
  98                 AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
  99                 AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 100                 AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 101                 AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
 102         fi
 103         if test "z$with_distro" = "z"; then
 104                 with_distro=`uname -s`
 105         fi
 106 fi
 107 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 108
 109 case $with_distro in
 110         fedora)
 111                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 112                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 113                 special_dbus_service=messagebus.service
 114                 special_syslog_service=rsyslog.service
 115                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 116                 ;;
 117         suse)
 118                 SYSTEM_SYSVINIT_PATH=/etc/init.d
 119                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 120                 special_dbus_service=dbus.service
 121                 special_syslog_service=syslog.service
 122                 AC_DEFINE(TARGET_SUSE, [], [Target is OpenSUSE/SLES])
 123                 ;;
 124         debian)
 125                 SYSTEM_SYSVINIT_PATH=/etc/init.d
 126                 SYSTEM_SYSVRCND_PATH=/etc
 127                 special_dbus_service=dbus.service
 128                 special_syslog_service=sysklogd.service
 129                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian/Ubuntu])
 130                 ;;
 131         arch)
 132                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 133                 SYSTEM_SYSVRCND_PATH=/etc
 134                 special_dbus_service=dbus.service
 135                 special_syslog_service=syslog-ng.service
 136                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 137                 ;;
 138         none)
 139                 SYSTEM_SYSVINIT_PATH=/fix/the/configure/script
 140                 SYSTEM_SYSVRCND_PATH=/fix/the/configure/script
 141                 special_dbus_service=fix-the-configure-script.service
 142                 special_syslog_service=fix-the-configure-script.service
 143                 ;;
 144         *)
 145                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=none to skip this check])
 146                 ;;
 147 esac
 148
 149 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 150 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 151
 152 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 153 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 154 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 155 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 156
 157 AC_DEFINE_UNQUOTED(SPECIAL_DBUS_SERVICE, ["$special_dbus_service"], [D-Bus service name])
 158 AC_DEFINE_UNQUOTED(SPECIAL_SYSLOG_SERVICE, ["$special_syslog_service"], [syslog service name])
 159
 160 AC_OUTPUT([Makefile])
 161
 162 echo "
 163         $PACKAGE_NAME $VERSION
 164
 165         Distribution:            ${with_distro}
 166         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 167         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 168         Syslog service:          ${special_syslog_service}
 169         D-Bus service:           ${special_dbus_service}
 170 "