configure.ac

   1
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [194],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT
  46
  47 # i18n stuff for the PolicyKit policy files
  48 IT_PROG_INTLTOOL([0.40.0])
  49
  50 GETTEXT_PACKAGE=systemd
  51 AC_SUBST(GETTEXT_PACKAGE)
  52
  53 AC_PROG_MKDIR_P
  54 AC_PROG_LN_S
  55 AC_PROG_SED
  56 AC_PROG_GREP
  57 AC_PROG_AWK
  58
  59 AC_PROG_CC
  60 AC_PROG_CC_C99
  61 AM_PROG_CC_C_O
  62 AC_PROG_GCC_TRADITIONAL
  63
  64 AC_PATH_PROG([M4], [m4])
  65 AC_PATH_PROG([XSLTPROC], [xsltproc])
  66
  67 AC_PATH_PROG([QUOTAON], [quotaon], [/sbin/quotaon])
  68 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/sbin/quotacheck])
  69
  70 AC_PATH_PROG([SETCAP], [setcap], [/sbin/setcap])
  71
  72 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  73 m4_ifdef([GTK_DOC_CHECK], [
  74 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])
  75 ], [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
  76
  77 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  78         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  79 ])
  80
  81 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  82 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  83 ], [AM_CONDITIONAL([HAVE_INTROSPECTION], [false])])
  84
  85 AC_PATH_TOOL(OBJCOPY, objcopy)
  86 AC_PATH_TOOL(STRINGS, strings)
  87 AC_PATH_TOOL(GPERF, gperf)
  88 if test -z "$GPERF" ; then
  89         AC_MSG_ERROR([*** gperf not found])
  90 fi
  91
  92 # we use python to build the man page index, and for systemd-python
  93 have_python=no
  94 have_python_devel=no
  95 AM_PATH_PYTHON(,, [:])
  96 if test "$PYTHON" != : ; then
  97         have_python=yes
  98         AC_PATH_PROG([PYTHON_CONFIG], python-config)
  99
 100         if test -n "$PYTHON_CONFIG" ; then
 101                 have_python_devel=yes
 102                 PYTHON_CFLAGS="`$PYTHON_CONFIG --cflags`"
 103                 PYTHON_LIBS="`$PYTHON_CONFIG --libs`"
 104                 AC_SUBST(PYTHON_CFLAGS)
 105                 AC_SUBST(PYTHON_LIBS)
 106         fi
 107 fi
 108 AM_CONDITIONAL([HAVE_PYTHON], [test "$have_python" = "yes"])
 109 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 110
 111 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 112         -pipe \
 113         -Wall \
 114         -Wextra \
 115         -Wno-inline \
 116         -Wundef \
 117         -Wformat=2 \
 118         -Wlogical-op \
 119         -Wsign-compare \
 120         -Wformat-security \
 121         -Wmissing-include-dirs \
 122         -Wformat-nonliteral \
 123         -Wold-style-definition \
 124         -Wpointer-arith \
 125         -Winit-self \
 126         -Wdeclaration-after-statement \
 127         -Wfloat-equal \
 128         -Wmissing-prototypes \
 129         -Wstrict-prototypes \
 130         -Wredundant-decls \
 131         -Wmissing-declarations \
 132         -Wmissing-noreturn \
 133         -Wshadow \
 134         -Wendif-labels \
 135         -Wcast-align \
 136         -Wstrict-aliasing=2 \
 137         -Wwrite-strings \
 138         -Wno-long-long \
 139         -Wno-overlength-strings \
 140         -Wno-unused-parameter \
 141         -Wno-missing-field-initializers \
 142         -Wno-unused-result \
 143         -Werror=overflow \
 144         -ffast-math \
 145         -fno-common \
 146         -fdiagnostics-show-option \
 147         -fno-strict-aliasing \
 148         -fvisibility=hidden \
 149         -ffunction-sections \
 150         -fdata-sections \
 151         -fstack-protector \
 152         --param=ssp-buffer-size=4])
 153 AC_SUBST([OUR_CFLAGS], $with_cflags)
 154
 155 CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 156         -Wp,-D_FORTIFY_SOURCE=2])
 157 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 158
 159 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 160         -Wl,--as-needed \
 161         -Wl,--gc-sections \
 162         -Wl,-z,relro \
 163         -Wl,-z,now])
 164 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 165
 166 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 167 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 168
 169 save_LIBS="$LIBS"
 170 LIBS=
 171 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 172 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 173 CAP_LIBS="$LIBS"
 174 LIBS="$save_LIBS"
 175 AC_SUBST(CAP_LIBS)
 176
 177 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 178 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 179 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 180 #include <unistd.h>
 181 #include <sys/mount.h>
 182 #include <fcntl.h>]])
 183
 184 # This makes sure pkg.m4 is available.
 185 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 186
 187 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 188 PKG_CHECK_MODULES(KMOD, [libkmod >= 5])
 189 PKG_CHECK_MODULES(BLKID,[blkid >= 2.20])
 190
 191 # ------------------------------------------------------------------------------
 192 have_ima=yes
 193 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 194                 [case "${enableval}" in
 195                         yes) have_ima=yes ;;
 196                         no) have_ima=no ;;
 197                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 198                 esac],
 199                 [have_ima=yes])
 200
 201 if test "x${have_ima}" != xno ; then
 202         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 203 fi
 204
 205 # ------------------------------------------------------------------------------
 206 have_selinux=no
 207 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 208 if test "x$enable_selinux" != "xno"; then
 209         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 210                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 211         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 212                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 213         fi
 214 fi
 215 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 216 if test "x${have_selinux}" != xno ; then
 217         sushell=/sbin/sushell
 218 else
 219         sushell=/bin/bash
 220 fi
 221 AC_SUBST(sushell)
 222
 223 # ------------------------------------------------------------------------------
 224 have_xz=no
 225 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 226 if test "x$enable_xz" != "xno"; then
 227         PKG_CHECK_MODULES(XZ, [ liblzma ],
 228                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 229         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 230                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 231         fi
 232 fi
 233 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 234
 235 # ------------------------------------------------------------------------------
 236 AC_ARG_ENABLE([tcpwrap],
 237         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 238                 [case "${enableval}" in
 239                         yes) have_tcpwrap=yes ;;
 240                         no) have_tcpwrap=no ;;
 241                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 242                 esac],
 243                 [have_tcpwrap=auto])
 244
 245 if test "x${have_tcpwrap}" != xno ; then
 246         ACX_LIBWRAP
 247         if test "x${LIBWRAP_LIBS}" = x ; then
 248                 if test "x$have_tcpwrap" = xyes ; then
 249                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 250                 fi
 251                 have_tcpwrap=no
 252         else
 253                 have_tcpwrap=yes
 254         fi
 255 else
 256         LIBWRAP_LIBS=
 257 fi
 258 AC_SUBST(LIBWRAP_LIBS)
 259
 260 # ------------------------------------------------------------------------------
 261 AC_ARG_ENABLE([pam],
 262         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 263                 [case "${enableval}" in
 264                         yes) have_pam=yes ;;
 265                         no) have_pam=no ;;
 266                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 267                 esac],
 268                 [have_pam=auto])
 269
 270 if test "x${have_pam}" != xno ; then
 271         AC_CHECK_HEADERS(
 272                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 273                 [have_pam=yes],
 274                 [if test "x$have_pam" = xyes ; then
 275                         AC_MSG_ERROR([*** PAM headers not found.])
 276                 fi])
 277
 278         AC_CHECK_LIB(
 279                 [pam],
 280                 [pam_syslog],
 281                 [have_pam=yes],
 282                 [if test "x$have_pam" = xyes ; then
 283                         AC_MSG_ERROR([*** libpam not found.])
 284                 fi])
 285
 286         if test "x$have_pam" = xyes ; then
 287                 PAM_LIBS="-lpam -lpam_misc"
 288                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 289         else
 290                 have_pam=no
 291         fi
 292 else
 293         PAM_LIBS=
 294 fi
 295 AC_SUBST(PAM_LIBS)
 296 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 297
 298 # ------------------------------------------------------------------------------
 299 AC_ARG_ENABLE([acl],
 300         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 301                 [case "${enableval}" in
 302                         yes) have_acl=yes ;;
 303                         no) have_acl=no ;;
 304                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 305                 esac],
 306                 [have_acl=auto])
 307
 308 if test "x${have_acl}" != xno ; then
 309         AC_CHECK_HEADERS(
 310                 [sys/acl.h acl/libacl.h],
 311                 [have_acl=yes],
 312                 [if test "x$have_acl" = xyes ; then
 313                         AC_MSG_ERROR([*** ACL headers not found.])
 314                 fi])
 315
 316         AC_CHECK_LIB(
 317                 [acl],
 318                 [acl_get_file],
 319                 [have_acl=yes],
 320                 [if test "x$have_acl" = xyes ; then
 321                         AC_MSG_ERROR([*** libacl not found.])
 322                 fi])
 323
 324         if test "x$have_acl" = xyes ; then
 325                 ACL_LIBS="-lacl"
 326                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 327         else
 328                 have_acl=no
 329         fi
 330 else
 331         ACL_LIBS=
 332 fi
 333 AC_SUBST(ACL_LIBS)
 334 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 335
 336 # ------------------------------------------------------------------------------
 337 AC_ARG_ENABLE([gcrypt],
 338         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 339                 [case "${enableval}" in
 340                         yes) have_gcrypt=yes ;;
 341                         no) have_gcrypt=no ;;
 342                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 343                 esac],
 344                 [have_gcrypt=auto])
 345
 346 if test "x${have_gcrypt}" != xno ; then
 347         AM_PATH_LIBGCRYPT(
 348                 [1.4.5],
 349                 [have_gcrypt=yes],
 350                 [if test "x$have_gcrypt" = xyes ; then
 351                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 352                 fi])
 353
 354         if test "x$have_gcrypt" = xyes ; then
 355                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 356                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 357                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 358         else
 359                 have_gcrypt=no
 360         fi
 361 else
 362         GCRYPT_LIBS=
 363         GCRYPT_CFLAGS=
 364 fi
 365 AC_SUBST(GCRYPT_LIBS)
 366 AC_SUBST(GCRYPT_CFLAGS)
 367 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 368
 369 # ------------------------------------------------------------------------------
 370 AC_ARG_ENABLE([audit],
 371         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 372                 [case "${enableval}" in
 373                         yes) have_audit=yes ;;
 374                         no) have_audit=no ;;
 375                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 376                 esac],
 377                 [have_audit=auto])
 378
 379 if test "x${have_audit}" != xno ; then
 380         AC_CHECK_HEADERS(
 381                 [libaudit.h],
 382                 [have_audit=yes],
 383                 [if test "x$have_audit" = xyes ; then
 384                         AC_MSG_ERROR([*** AUDIT headers not found.])
 385                 fi])
 386
 387         AC_CHECK_LIB(
 388                 [audit],
 389                 [audit_open],
 390                 [have_audit=yes],
 391                 [if test "x$have_audit" = xyes ; then
 392                         AC_MSG_ERROR([*** libaudit not found.])
 393                 fi])
 394
 395         if test "x$have_audit" = xyes ; then
 396                 AUDIT_LIBS="-laudit"
 397                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 398         else
 399                 have_audit=no
 400         fi
 401 else
 402         AUDIT_LIBS=
 403 fi
 404 AC_SUBST(AUDIT_LIBS)
 405
 406 # ------------------------------------------------------------------------------
 407 have_libcryptsetup=no
 408 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 409 if test "x$enable_libcryptsetup" != "xno"; then
 410         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
 411                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 412         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 413                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 414         fi
 415 fi
 416 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 417
 418 # ------------------------------------------------------------------------------
 419 have_qrencode=no
 420 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 421 if test "x$enable_qrencode" != "xno"; then
 422         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 423                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 424         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 425                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 426         fi
 427 fi
 428 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 429
 430 # ------------------------------------------------------------------------------
 431 have_microhttpd=no
 432 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 433 if test "x$enable_microhttpd" != "xno"; then
 434         PKG_CHECK_MODULES(MICROHTTPD, [ libmicrohttpd ],
 435                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 436         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 437                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 438         fi
 439 fi
 440 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 441
 442 # ------------------------------------------------------------------------------
 443 have_binfmt=no
 444 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 445 if test "x$enable_binfmt" != "xno"; then
 446         have_binfmt=yes
 447 fi
 448 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 449
 450 # ------------------------------------------------------------------------------
 451 have_vconsole=no
 452 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 453 if test "x$enable_vconsole" != "xno"; then
 454         have_vconsole=yes
 455 fi
 456 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 457
 458 # ------------------------------------------------------------------------------
 459 have_readahead=no
 460 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 461 if test "x$enable_readahead" != "xno"; then
 462         have_readahead=yes
 463 fi
 464 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 465
 466 # ------------------------------------------------------------------------------
 467 have_quotacheck=no
 468 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 469 if test "x$enable_quotacheck" != "xno"; then
 470         have_quotacheck=yes
 471 fi
 472 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 473
 474 # ------------------------------------------------------------------------------
 475 have_randomseed=no
 476 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 477 if test "x$enable_randomseed" != "xno"; then
 478         have_randomseed=yes
 479 fi
 480 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 481
 482 # ------------------------------------------------------------------------------
 483 have_logind=no
 484 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 485 if test "x$enable_logind" != "xno"; then
 486         have_logind=yes
 487 fi
 488 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 489 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 490
 491 # ------------------------------------------------------------------------------
 492 have_hostnamed=no
 493 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 494 if test "x$enable_hostnamed" != "xno"; then
 495         have_hostnamed=yes
 496 fi
 497 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 498
 499 # ------------------------------------------------------------------------------
 500 have_timedated=no
 501 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 502 if test "x$enable_timedated" != "xno"; then
 503         have_timedated=yes
 504 fi
 505 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 506
 507 # ------------------------------------------------------------------------------
 508 have_localed=no
 509 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 510 if test "x$enable_localed" != "xno"; then
 511         have_localed=yes
 512 fi
 513 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 514
 515 # ------------------------------------------------------------------------------
 516 have_coredump=no
 517 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 518 if test "x$enable_coredump" != "xno"; then
 519         have_coredump=yes
 520 fi
 521 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 522
 523 # ------------------------------------------------------------------------------
 524 AC_ARG_WITH(usb-ids-path,
 525         [AS_HELP_STRING([--with-usb-ids-path=DIR], [Path to usb.ids file])],
 526         [USB_DATABASE=${withval}],
 527         [if test -n "$usbids" ; then
 528                 USB_DATABASE="$usbids"
 529         else
 530                 PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
 531                 AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])
 532         fi])
 533 AC_MSG_CHECKING([for USB database location])
 534 AC_MSG_RESULT([$USB_DATABASE])
 535 AC_SUBST(USB_DATABASE)
 536
 537 AC_ARG_WITH(pci-ids-path,
 538         [AS_HELP_STRING([--with-pci-ids-path=DIR], [Path to pci.ids file])],
 539         [PCI_DATABASE=${withval}],
 540         [if test -n "$pciids" ; then
 541                 PCI_DATABASE="$pciids"
 542         else
 543                 PKG_CHECK_MODULES(LIBPCI, libpci >= 3)
 544                 AC_SUBST([PCI_DATABASE], [$($PKG_CONFIG --variable=idsdir libpci)/pci.ids])
 545         fi])
 546 AC_MSG_CHECKING([for PCI database location])
 547 AC_MSG_RESULT([$PCI_DATABASE])
 548 AC_SUBST(PCI_DATABASE)
 549
 550 # ------------------------------------------------------------------------------
 551 AC_ARG_WITH(firmware-path,
 552        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 553           [Firmware search path (default=ROOTPREFIX/lib/firmware/updates:ROOTPREFIX/lib/firmware)]),
 554        [], [with_firmware_path="$rootprefix/lib/firmware/updates:$rootprefix/lib/firmware"])
 555 OLD_IFS=$IFS
 556 IFS=:
 557 for i in $with_firmware_path; do
 558        if test "x${FIRMWARE_PATH}" = "x"; then
 559               FIRMWARE_PATH="\\\"${i}/\\\""
 560        else
 561               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 562        fi
 563 done
 564 IFS=$OLD_IFS
 565 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
 566
 567 # ------------------------------------------------------------------------------
 568 AC_ARG_ENABLE([gudev],
 569        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 570        [], [enable_gudev=yes])
 571 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0]) ])
 572 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 573
 574 # ------------------------------------------------------------------------------
 575 AC_ARG_ENABLE([keymap],
 576        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 577        [], [enable_keymap=yes])
 578 AS_IF([test "x$enable_keymap" = "xyes"], [
 579        AC_PATH_PROG([GPERF], [gperf])
 580        if test -z "$GPERF"; then
 581               AC_MSG_ERROR([gperf is needed])
 582        fi
 583
 584        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 585        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 586 ])
 587 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 588
 589 # ------------------------------------------------------------------------------
 590 have_manpages=no
 591 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 592 AS_IF([test "x$enable_manpages" != xno], [
 593         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 594                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 595         ])
 596         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 597 ])
 598 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 599
 600 # ------------------------------------------------------------------------------
 601
 602 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux, mandriva, mageia, angstrom or other]))
 603 if test "z$with_distro" = "z"; then
 604         if test "$cross_compiling" = yes; then
 605                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 606         else
 607                 with_distro=$($GREP '^ID=' /etc/os-release 2>/dev/null | $SED 's/ID=//');
 608         fi
 609         if test "z$with_distro" = "z"; then
 610                 with_distro=other
 611         fi
 612 fi
 613 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 614 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 615
 616 # Location of the init scripts as mandated by LSB
 617 SYSTEM_SYSVINIT_PATH=/etc/init.d
 618 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 619
 620 M4_DEFINES=
 621
 622 case $with_distro in
 623         fedora)
 624                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 625                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 626                 M4_DEFINES=-DTARGET_FEDORA=1
 627                 ;;
 628         opensuse|suse)
 629                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 630                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 631                 M4_DEFINES=-DTARGET_SUSE=1
 632                 ;;
 633         debian)
 634                 SYSTEM_SYSVRCND_PATH=/etc
 635                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 636                 M4_DEFINES=-DTARGET_DEBIAN=1
 637                 ;;
 638         ubuntu)
 639                 SYSTEM_SYSVRCND_PATH=/etc
 640                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 641                 M4_DEFINES=-DTARGET_UBUNTU=1
 642                 ;;
 643         arch)
 644                 SYSTEM_SYSVINIT_PATH=
 645                 SYSTEM_SYSVRCND_PATH=
 646                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 647                 M4_DEFINES=-DTARGET_ARCH=1
 648                 ;;
 649         gentoo)
 650                 SYSTEM_SYSVINIT_PATH=
 651                 SYSTEM_SYSVRCND_PATH=
 652                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 653                 M4_DEFINES=-DTARGET_GENTOO=1
 654                 ;;
 655         slackware)
 656                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 657                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 658                 M4_DEFINES=-DTARGET_SLACKWARE=1
 659                 ;;
 660         frugalware)
 661                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 662                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 663                 M4_DEFINES=-DTARGET_FRUGALWARE=1
 664                 ;;
 665         altlinux)
 666                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 667                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 668                 M4_DEFINES=-DTARGET_ALTLINUX=1
 669                 ;;
 670         mandriva)
 671                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 672                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 673                 M4_DEFINES=-DTARGET_MANDRIVA=1
 674                 ;;
 675         angstrom)
 676                 SYSTEM_SYSVRCND_PATH=/etc
 677                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 678                 M4_DEFINES=-DTARGET_ANGSTROM=1
 679                 ;;
 680         mageia)
 681                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 682                 AC_DEFINE(TARGET_MAGEIA, [], [Target is Mageia])
 683                 M4_DEFINES=-DTARGET_MAGEIA=1
 684                 ;;
 685         other)
 686                 ;;
 687         *)
 688                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 689                 ;;
 690 esac
 691
 692 AC_ARG_WITH([sysvinit-path],
 693         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 694                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 695         [SYSTEM_SYSVINIT_PATH="$withval"],
 696         [])
 697
 698 AC_ARG_WITH([sysvrcd-path],
 699         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 700                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 701         [SYSTEM_SYSVRCND_PATH="$withval"],
 702         [])
 703
 704 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 705 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 706 AC_SUBST(M4_DEFINES)
 707
 708 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 709         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 710         SYSTEM_SYSV_COMPAT="yes"
 711         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 712 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 713         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 714 else
 715         SYSTEM_SYSV_COMPAT="no"
 716 fi
 717
 718 AC_ARG_WITH([tty-gid],
 719         [AS_HELP_STRING([--with-tty-gid=GID],
 720                 [Specify the numeric GID of the 'tty' group])],
 721         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 722         [])
 723
 724 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 725 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 726 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 727 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 728 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 729 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 730 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 731 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 732 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 733 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 734 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 735 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 736 AM_CONDITIONAL(TARGET_MAGEIA, test x"$with_distro" = xmageia)
 737
 738 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 739
 740 AC_ARG_WITH([dbuspolicydir],
 741         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 742         [],
 743         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 744
 745 AC_ARG_WITH([dbussessionservicedir],
 746         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 747         [],
 748         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 749
 750 AC_ARG_WITH([dbussystemservicedir],
 751         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 752         [],
 753         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 754
 755 AC_ARG_WITH([dbusinterfacedir],
 756         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 757         [],
 758         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 759
 760 AC_ARG_WITH([rootprefix],
 761         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 762         [], [with_rootprefix=${ac_default_prefix}])
 763
 764 AC_ARG_WITH([rootlibdir],
 765         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 766         [],
 767         [with_rootlibdir=${libdir}])
 768
 769 AC_ARG_WITH([pamlibdir],
 770         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 771         [],
 772         [with_pamlibdir=${with_rootlibdir}/security])
 773
 774 AC_ARG_ENABLE([split-usr],
 775         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 776         [],
 777         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 778                 enable_split_usr=yes
 779         ], [
 780                 enable_split_usr=no
 781         ])])
 782
 783 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 784         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 785 ])
 786
 787 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 788 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 789 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 790 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 791 AC_SUBST([pamlibdir], [$with_pamlibdir])
 792 AC_SUBST([rootprefix], [$with_rootprefix])
 793 AC_SUBST([rootlibdir], [$with_rootlibdir])
 794
 795 AC_CONFIG_FILES([
 796         Makefile po/Makefile.in
 797         docs/libudev/Makefile
 798         docs/libudev/version.xml
 799         docs/gudev/Makefile
 800         docs/gudev/version.xml
 801 ])
 802
 803 AC_OUTPUT
 804 AC_MSG_RESULT([
 805         $PACKAGE_NAME $VERSION
 806
 807         Distribution:            ${with_distro}
 808         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 809         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 810         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 811         libcryptsetup:           ${have_libcryptsetup}
 812         tcpwrap:                 ${have_tcpwrap}
 813         PAM:                     ${have_pam}
 814         AUDIT:                   ${have_audit}
 815         IMA:                     ${have_ima}
 816         SELinux:                 ${have_selinux}
 817         XZ:                      ${have_xz}
 818         ACL:                     ${have_acl}
 819         GCRYPT:                  ${have_gcrypt}
 820         QRENCODE:                ${have_qrencode}
 821         MICROHTTPD:              ${have_microhttpd}
 822         binfmt:                  ${have_binfmt}
 823         vconsole:                ${have_vconsole}
 824         readahead:               ${have_readahead}
 825         quotacheck:              ${have_quotacheck}
 826         randomseed:              ${have_randomseed}
 827         logind:                  ${have_logind}
 828         hostnamed:               ${have_hostnamed}
 829         timedated:               ${have_timedated}
 830         localed:                 ${have_localed}
 831         coredump:                ${have_coredump}
 832         firmware path:           ${FIRMWARE_PATH}
 833         usb.ids:                 ${USB_DATABASE}
 834         pci.ids:                 ${PCI_DATABASE}
 835         gudev:                   ${enable_gudev}
 836         gintrospection:          ${enable_introspection}
 837         keymap:                  ${enable_keymap}
 838         Python:                  ${have_python}
 839         Python Headers:          ${have_python_devel}
 840
 841         prefix:                  ${prefix}
 842         rootprefix:              ${with_rootprefix}
 843         sysconf dir:             ${sysconfdir}
 844         datarootdir:             ${datarootdir}
 845         includedir:              ${includedir}
 846         include_prefix:          ${INCLUDE_PREFIX}
 847         lib dir:                 ${libdir}
 848         rootlib dir:             ${with_rootlibdir}
 849         PAM modules dir:         ${with_pamlibdir}
 850         D-Bus policy dir:        ${with_dbuspolicydir}
 851         D-Bus session dir:       ${with_dbussessionservicedir}
 852         D-Bus system dir:        ${with_dbussystemservicedir}
 853         D-Bus interfaces dir:    ${with_dbusinterfacedir}
 854         Split /usr:              ${enable_split_usr}
 855         man pages:               ${have_manpages}
 856         gtk-doc:                 ${enable_gtk_doc}
 857
 858         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 859         CPPLAGS:                 ${OUR_CPPFLAGS} ${CPPFLAGS}
 860         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 861 ])