configure.ac

   1 AC_INIT([udev],
   2         [143],
   3         [linux-hotplug@vger.kernel.org])
   4 AC_PREREQ(2.60)
   5 AM_INIT_AUTOMAKE([check-news foreign 1.9 dist-bzip2])
   6 AC_DISABLE_STATIC
   7 AC_USE_SYSTEM_EXTENSIONS
   8 dnl AM_SILENT_RULES
   9 AC_SYS_LARGEFILE
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AC_PROG_LIBTOOL
  12 GTK_DOC_CHECK(1.10)
  13
  14 dnl /* prefix is /usr, exec_prefix is /, if overridden exec_prefix follows prefix */
  15 AC_PREFIX_DEFAULT([/usr])
  16 test "$prefix" = NONE && test "$exec_prefix" = NONE && exec_prefix=
  17
  18 dnl /* libudev version */
  19 LIBUDEV_LT_CURRENT=4
  20 LIBUDEV_LT_REVISION=0
  21 LIBUDEV_LT_AGE=4
  22 AC_SUBST(LIBUDEV_LT_CURRENT)
  23 AC_SUBST(LIBUDEV_LT_REVISION)
  24 AC_SUBST(LIBUDEV_LT_AGE)
  25
  26 AC_PATH_PROG([XSLTPROC], [xsltproc])
  27
  28 AC_ARG_WITH(udev-prefix,
  29         AS_HELP_STRING([--with-udev-prefix=DIR], [add prefix to internal udev path names]),
  30         [], [with_udev_prefix='${exec_prefix}'])
  31 udev_prefix=$with_udev_prefix
  32 AC_SUBST(udev_prefix)
  33
  34 AC_ARG_WITH(libdir-name,
  35         AS_HELP_STRING([--with-libdir-name=DIR], [name of the arch lib directory]),
  36         [], [with_libdir_name=lib])
  37 libdir_name=$with_libdir_name
  38 AC_SUBST(libdir_name)
  39
  40 AC_ARG_WITH(selinux,
  41         AS_HELP_STRING([--with-selinux], [enable SELinux support]),
  42         [], with_selinux=no)
  43 if test "x$with_selinux" = xyes; then
  44         LIBS_save=$LIBS
  45         AC_CHECK_LIB(selinux, getprevcon,
  46                 [],
  47                 AC_MSG_ERROR([SELinux selected but libselinux not found]))
  48         LIBS=$LIBS_save
  49         SELINUX_LIBS="-lselinux -lsepol"
  50         AC_DEFINE(WITH_SELINUX, [1] ,[SELinux support.])
  51 fi
  52 AC_SUBST([SELINUX_LIBS])
  53 AM_CONDITIONAL(WITH_SELINUX, [test "x$with_selinux" = xyes])
  54
  55 AC_ARG_ENABLE(debug,
  56         AS_HELP_STRING([--enable-debug], [enable debug messages]),
  57         [], enable_debug=no)
  58 if test "x$enable_debug" = "xyes"; then
  59         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  60 fi
  61
  62 AC_ARG_ENABLE(logging,
  63         AS_HELP_STRING([--disable-logging], [disable system logging]),
  64         [], enable_logging=yes)
  65 if test "x$enable_logging" = "xyes"; then
  66         AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
  67 fi
  68
  69 AC_CONFIG_HEADERS(config.h)
  70 AC_CONFIG_FILES([
  71         Makefile
  72         libudev/Makefile
  73         libudev/libudev.pc
  74         libudev/docs/Makefile
  75         libudev/docs/version.xml
  76         udev/Makefile
  77         rules/Makefile
  78         extras/Makefile
  79         extras/ata_id/Makefile
  80         extras/cdrom_id/Makefile
  81         extras/edd_id/Makefile
  82         extras/path_id/Makefile
  83         extras/firmware/Makefile
  84         extras/collect/Makefile
  85         extras/floppy/Makefile
  86         extras/fstab_import/Makefile
  87         extras/rule_generator/Makefile
  88         extras/scsi_id/Makefile
  89         extras/usb_id/Makefile
  90 ])
  91
  92 AC_OUTPUT
  93 AC_MSG_RESULT([
  94         udev $VERSION
  95         ========
  96
  97         prefix:                 ${prefix}
  98         exec_prefix:            ${exec_prefix}
  99         udev_prefix:            ${udev_prefix}
 100         libdir_name:            ${libdir_name}
 101         datarootdir:            ${datarootdir}
 102         mandir:                 ${mandir}
 103         includedir:             ${includedir}
 104
 105         logging:                ${enable_logging}
 106         debug:                  ${enable_debug}
 107         selinux:                ${with_selinux}
 108
 109         compiler:               ${CC}
 110         cflags:                 ${CFLAGS}
 111         ldflags:                ${LDFLAGS}
 112
 113         xsltproc:               ${XSLTPROC}
 114 ])