configure.ac

   1 AC_PREREQ(2.60)
   2 AC_INIT([udev],
   3         [174],
   4         [linux-hotplug@vger.kernel.org],
   5         [udev],
   6         [http://www.kernel.org/pub/linux/utils/kernel/hotplug/udev.html])
   7 AC_CONFIG_SRCDIR([udev/udevd.c])
   8 AC_CONFIG_AUX_DIR([build-aux])
   9 AM_INIT_AUTOMAKE([check-news foreign 1.11 -Wall -Wno-portability silent-rules tar-pax dist-bzip2 subdir-objects])
  10 AC_USE_SYSTEM_EXTENSIONS
  11 AC_SYS_LARGEFILE
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AM_SILENT_RULES([yes])
  14 LT_INIT([disable-static])
  15 AC_PROG_AWK
  16 GTK_DOC_CHECK(1.10)
  17 AC_PREFIX_DEFAULT([/usr])
  18 AC_PATH_PROG([XSLTPROC], [xsltproc])
  19
  20 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([POSIX RT library not found])])
  21
  22 AC_ARG_WITH([rootlibdir],
  23         AS_HELP_STRING([--with-rootlibdir=DIR], [rootfs directory to install shared libraries]),
  24         [], [with_rootlibdir=$libdir])
  25 AC_SUBST([rootlib_execdir], [$with_rootlibdir])
  26
  27 AC_ARG_WITH([selinux],
  28         AS_HELP_STRING([--with-selinux], [enable SELinux support]),
  29         [], [with_selinux=no])
  30 if test "x$with_selinux" = xyes; then
  31         LIBS_save=$LIBS
  32         AC_CHECK_LIB(selinux, getprevcon,
  33                 [],
  34                 AC_MSG_ERROR([SELinux selected but libselinux not found]))
  35         LIBS=$LIBS_save
  36         SELINUX_LIBS="-lselinux -lsepol"
  37         AC_DEFINE(WITH_SELINUX, [1] ,[SELinux support.])
  38 fi
  39 AC_SUBST([SELINUX_LIBS])
  40 AM_CONDITIONAL(WITH_SELINUX, [test "x$with_selinux" = xyes])
  41
  42 AC_ARG_ENABLE([debug],
  43         AS_HELP_STRING([--enable-debug], [enable debug messages]),
  44         [], [enable_debug=no])
  45 if test "x$enable_debug" = "xyes"; then
  46         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  47 fi
  48
  49 AC_ARG_ENABLE([logging],
  50         AS_HELP_STRING([--disable-logging], [disable system logging]),
  51         [], enable_logging=yes)
  52 if test "x$enable_logging" = "xyes"; then
  53         AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
  54 fi
  55
  56 AC_ARG_WITH(firmware-path,
  57         AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
  58            [Firmware search path (default=/lib/firmware/updates:/lib/firmware)]),
  59         [], [with_firmware_path="/lib/firmware/updates:/lib/firmware"])
  60 OLD_IFS=$IFS
  61 IFS=:
  62 for i in $with_firmware_path; do
  63         if test "x${FIRMWARE_PATH}" = "x"; then
  64                 FIRMWARE_PATH="\\\"${i}/\\\""
  65         else
  66                 FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
  67         fi
  68 done
  69 IFS=$OLD_IFS
  70 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
  71
  72 AC_ARG_WITH([systemdsystemunitdir],
  73         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
  74         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
  75 if test "x$with_systemdsystemunitdir" != xno; then
  76         AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
  77 fi
  78 AM_CONDITIONAL(WITH_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
  79
  80 # ------------------------------------------------------------------------------
  81 # GUdev - libudev gobject interface
  82 # ------------------------------------------------------------------------------
  83 AC_ARG_ENABLE([gudev],
  84         AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support]),
  85         [], [enable_gudev=yes])
  86 if test "x$enable_gudev" = xyes; then
  87         PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0])
  88 fi
  89
  90 AC_ARG_ENABLE([introspection],
  91         AS_HELP_STRING([--disable-introspection], [disable GObject introspection]),
  92         [], [enable_introspection=yes])
  93 if test "x$enable_introspection" = xyes; then
  94         PKG_CHECK_MODULES([INTROSPECTION], [gobject-introspection-1.0 >= 0.6.2])
  95         AC_DEFINE([ENABLE_INTROSPECTION], [1], [enable GObject introspection support])
  96         AC_SUBST([G_IR_SCANNER], [$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)])
  97         AC_SUBST([G_IR_COMPILER], [$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)])
  98         AC_SUBST([G_IR_GENERATE], [$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)])
  99         AC_SUBST([GIRDIR], [$($PKG_CONFIG --define-variable=datadir=${datadir} --variable=girdir gobject-introspection-1.0)])
 100         AC_SUBST([GIRTYPELIBDIR], [$($PKG_CONFIG --define-variable=libdir=${libdir} --variable=typelibdir gobject-introspection-1.0)])
 101 fi
 102 AM_CONDITIONAL([ENABLE_INTROSPECTION], [test "x$enable_introspection" = xyes])
 103
 104 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = xyes])
 105
 106 # ------------------------------------------------------------------------------
 107 # usb/pci-db - read vendor/device string database
 108 # ------------------------------------------------------------------------------
 109 AC_ARG_ENABLE([hwdb],
 110         AS_HELP_STRING([--disable-hwdb], [disable hardware database support]),
 111         [], [enable_hwdb=yes])
 112 if test "x$enable_hwdb" = xyes; then
 113         if test "x$cross_compiling" = "xno" ; then
 114                 AC_CHECK_FILES([/usr/share/pci.ids], [pciids=/usr/share/pci.ids])
 115                 AC_CHECK_FILES([/usr/share/hwdata/pci.ids], [pciids=/usr/share/hwdata/pci.ids])
 116                 AC_CHECK_FILES([/usr/share/misc/pci.ids], [pciids=/usr/share/misc/pci.ids])
 117         fi
 118
 119         AC_ARG_WITH(usb-ids-path,
 120                 [AS_HELP_STRING([--with-usb-ids-path=DIR], [Path to usb.ids file])],
 121                 [USB_DATABASE=${withval}],
 122                 [if test -n "$usbids" ; then
 123                         USB_DATABASE="$usbids"
 124                 else
 125                         PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
 126                         AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])
 127                 fi])
 128         AC_MSG_CHECKING([for USB database location])
 129         AC_MSG_RESULT([$USB_DATABASE])
 130         AC_SUBST(USB_DATABASE)
 131
 132         AC_ARG_WITH(pci-ids-path,
 133                 [AS_HELP_STRING([--with-pci-ids-path=DIR], [Path to pci.ids file])],
 134                 [PCI_DATABASE=${withval}],
 135                 [if test -n "$pciids" ; then
 136                         PCI_DATABASE="$pciids"
 137                 else
 138                         AC_MSG_ERROR([pci.ids not found, try --with-pci-ids-path=])
 139                 fi])
 140         AC_MSG_CHECKING([for PCI database location])
 141         AC_MSG_RESULT([$PCI_DATABASE])
 142         AC_SUBST(PCI_DATABASE)
 143 fi
 144 AM_CONDITIONAL([ENABLE_HWDB], [test "x$enable_hwdb" = xyes])
 145
 146 # ------------------------------------------------------------------------------
 147 # keymap - map custom hardware's multimedia keys
 148 # ------------------------------------------------------------------------------
 149 AC_ARG_ENABLE([keymap],
 150         AS_HELP_STRING([--disable-keymap], [disable keymap fixup support]),
 151         [], [enable_keymap=yes])
 152 if test "x$enable_keymap" = xyes; then
 153         AC_PATH_PROG([GPERF], [gperf])
 154         if test -z "$GPERF"; then
 155                 AC_MSG_ERROR([gperf is needed])
 156         fi
 157
 158         AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 159         AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 160 fi
 161 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = xyes])
 162
 163 # ------------------------------------------------------------------------------
 164 # mtd_probe - autoloads FTL module for mtd devices
 165 # ------------------------------------------------------------------------------
 166 AC_ARG_ENABLE([mtd_probe],
 167         AS_HELP_STRING([--disable-mtd_probe], [disable MTD support]),
 168         [], [enable_mtd_probe=yes])
 169 AM_CONDITIONAL([ENABLE_MTD_PROBE], [test "x$enable_mtd_probe" = xyes])
 170
 171 # ------------------------------------------------------------------------------
 172 # rule_generator - persistent network and optical device rule generator
 173 # ------------------------------------------------------------------------------
 174 AC_ARG_ENABLE([rule_generator],
 175         AS_HELP_STRING([--enable-rule_generator], [enable persistent network + cdrom links support]),
 176         [], [enable_rule_generator=no])
 177 AM_CONDITIONAL([ENABLE_RULE_GENERATOR], [test "x$enable_rule_generator" = xyes])
 178
 179 # ------------------------------------------------------------------------------
 180 # udev_acl - apply ACLs for users with local forground sessions
 181 # ------------------------------------------------------------------------------
 182 AC_ARG_ENABLE([udev_acl],
 183         AS_HELP_STRING([--enable-udev_acl], [enable local user acl permissions support]),
 184         [], [enable_udev_acl=no])
 185 if test "x$enable_udev_acl" = xyes; then
 186         AC_CHECK_LIB([acl], [acl_init], [:], AC_MSG_ERROR([libacl not found]))
 187         AC_CHECK_HEADER([acl/libacl.h], [:], AC_MSG_ERROR([libacl header not found]))
 188
 189         PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0])
 190 fi
 191 AM_CONDITIONAL([ENABLE_UDEV_ACL], [test "x$enable_udev_acl" = xyes])
 192
 193 # ------------------------------------------------------------------------------
 194 # create_floppy_devices - historical floppy kernel device nodes (/dev/fd0h1440, ...)
 195 # ------------------------------------------------------------------------------
 196 AC_ARG_ENABLE([floppy],
 197         AS_HELP_STRING([--enable-floppy], [enable legacy floppy support]),
 198         [], [enable_floppy=no])
 199 AM_CONDITIONAL([ENABLE_FLOPPY], [test "x$enable_floppy" = xyes])
 200
 201 # ------------------------------------------------------------------------------
 202 # edd_id - create /dev/disk/by-id/edd-* links for BIOS EDD data
 203 # ------------------------------------------------------------------------------
 204 AC_ARG_ENABLE([edd],
 205         AS_HELP_STRING([--enable-edd], [enable disk edd support]),
 206         [], [enable_edd=no])
 207 AM_CONDITIONAL([ENABLE_EDD], [test "x$enable_edd" = xyes])
 208
 209 AC_CONFIG_HEADERS(config.h)
 210 AC_CONFIG_FILES([
 211         Makefile
 212         udev/udev.pc
 213         init/udev.service
 214         init/udev-trigger.service
 215         init/udev-settle.service
 216         libudev/libudev.pc
 217         libudev/docs/Makefile
 218         libudev/docs/version.xml
 219         extras/gudev/gudev-1.0.pc
 220         extras/gudev/docs/Makefile
 221         extras/gudev/docs/version.xml
 222 ])
 223
 224 AC_OUTPUT
 225 AC_MSG_RESULT([
 226         udev $VERSION
 227         ========
 228
 229         prefix:                 ${prefix}
 230         sysconfdir:             ${sysconfdir}
 231         sbindir:                ${sbindir}
 232         libdir:                 ${libdir}
 233         rootlibdir:             ${rootlib_execdir}
 234         libexecdir:             ${libexecdir}
 235         datarootdir:            ${datarootdir}
 236         mandir:                 ${mandir}
 237         includedir:             ${includedir}
 238         include_prefix:         ${INCLUDE_PREFIX}
 239         systemdsystemunitdir:   ${systemdsystemunitdir}
 240         firmware path:          ${FIRMWARE_PATH}
 241
 242         compiler:               ${CC}
 243         cflags:                 ${CFLAGS}
 244         ldflags:                ${LDFLAGS}
 245         xsltproc:               ${XSLTPROC}
 246         gperf:                  ${GPERF}
 247
 248         logging:                ${enable_logging}
 249         debug:                  ${enable_debug}
 250         selinux:                ${with_selinux}
 251
 252         gudev:                  ${enable_gudev}
 253         gintrospection:         ${enable_introspection}
 254         keymap:                 ${enable_keymap}
 255         hwdb:                   ${enable_hwdb}
 256           usb.ids:              ${USB_DATABASE}
 257           pci.ids:              ${PCI_DATABASE}
 258         mtd_probe:              ${enable_mtd_probe}
 259         rule_generator:         ${enable_rule_generator}
 260         udev_acl:               ${enable_udev_acl}
 261         floppy:                 ${enable_floppy}
 262         edd:                    ${enable_edd}
 263 ])