configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 # FIXME: Update to proper web page
  23 AC_INIT([elogind],
  24         [219.5],
  25         [http://bugs.freedesktop.org/enter_bug.cgi?product=elogind],
  26         [elogind],
  27         [http://www.freedesktop.org/wiki/Software/elogind])
  28
  29 AC_CONFIG_SRCDIR([src/login/logind.c])
  30 AC_CONFIG_MACRO_DIR([m4])
  31 AC_CONFIG_HEADERS([config.h])
  32 AC_CONFIG_AUX_DIR([build-aux])
  33
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_SYS_LARGEFILE
  36 AC_PREFIX_DEFAULT([/usr])
  37 AM_MAINTAINER_MODE([enable])
  38 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  39 AM_SILENT_RULES([yes])
  40 AC_CANONICAL_HOST
  41 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  42 LT_PREREQ(2.2)
  43 LT_INIT([disable-static])
  44
  45 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by elogind])])
  46 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by elogind])])
  47
  48 SET_ARCH(X86_64, x86_64*)
  49 SET_ARCH(IA32, i*86*)
  50 SET_ARCH(MIPS, mips*)
  51
  52 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  53 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  54 AS_IF([test x"$intltool_found" != xyes],
  55       [AS_IF([test x"$enable_nls" = xyes],
  56              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  57              [AS_IF([test x"$enable_nls" != xno],
  58                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  59                      enable_nls=no])
  60              ])
  61       ])
  62
  63 AM_NLS
  64 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  65     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  66 IT_PROG_INTLTOOL([0.40.0])
  67 ])
  68
  69 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  70     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  71     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  72     AC_SUBST(INTLTOOL_POLICY_RULE)
  73 ])
  74
  75 GETTEXT_PACKAGE=elogind
  76 AC_SUBST(GETTEXT_PACKAGE)
  77 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [elogind])
  78
  79 AC_PROG_MKDIR_P
  80 AC_PROG_LN_S
  81 AC_PROG_SED
  82 AC_PROG_GREP
  83 AC_PROG_AWK
  84
  85 AC_PROG_CC_C99
  86
  87 AC_PATH_PROG([M4], [m4])
  88 AC_PATH_PROG([XSLTPROC], [xsltproc])
  89
  90 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
  91
  92 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
  93
  94 M4_DEFINES=
  95
  96 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  97 m4_ifdef([GTK_DOC_CHECK], [
  98 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  99          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
 100           enable_gtk_doc=no])
 101
 102 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
 103         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
 104 ])
 105
 106 AC_CHECK_TOOL(GPERF, gperf)
 107 if test -z "$GPERF" ; then
 108         AC_MSG_ERROR([*** gperf not found])
 109 fi
 110
 111 # ------------------------------------------------------------------------------
 112 address_sanitizer_cflags=
 113 address_sanitizer_cppflags=
 114 address_sanitizer_ldflags=
 115 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 116 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 117             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 118             AS_IF([test -z "$with_as_cflags"],
 119                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 120             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 121             address_sanitizer_cppflags="-DVALGRIND=1"
 122             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 123       ])
 124
 125 undefined_sanitizer_cflags=
 126 undefined_sanitizer_cppflags=
 127 undefined_sanitizer_ldflags=
 128 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 129 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 130             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 131             AS_IF([test -z "$with_us_cflags"],
 132                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 133             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 134             undefined_sanitizer_cppflags="-DVALGRIND=1"
 135             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 136       ])
 137
 138 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 139 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 140 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 141
 142 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 143         -pipe \
 144         -Wall \
 145         -Wextra \
 146         -Wno-inline \
 147         -Wundef \
 148         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 149         -Wlogical-op \
 150         -Wsign-compare \
 151         -Wmissing-include-dirs \
 152         -Wold-style-definition \
 153         -Wpointer-arith \
 154         -Winit-self \
 155         -Wdeclaration-after-statement \
 156         -Wfloat-equal \
 157         -Wsuggest-attribute=noreturn \
 158         -Wmissing-prototypes \
 159         -Wstrict-prototypes \
 160         -Wredundant-decls \
 161         -Wmissing-declarations \
 162         -Wmissing-noreturn \
 163         -Wshadow \
 164         -Wendif-labels \
 165         -Wstrict-aliasing=2 \
 166         -Wwrite-strings \
 167         -Wno-long-long \
 168         -Wno-overlength-strings \
 169         -Wno-unused-parameter \
 170         -Wno-missing-field-initializers \
 171         -Wno-unused-result \
 172         -Wno-format-signedness \
 173         -Werror=overflow \
 174         -Wdate-time \
 175         -Wnested-externs \
 176         -ffast-math \
 177         -fno-common \
 178         -fdiagnostics-show-option \
 179         -fno-strict-aliasing \
 180         -fvisibility=hidden \
 181         -ffunction-sections \
 182         -fdata-sections \
 183         -fstack-protector \
 184         -fstack-protector-strong \
 185         -fPIE \
 186         --param=ssp-buffer-size=4])
 187
 188 AS_CASE([$CC], [*clang*],
 189         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 190                -Wno-typedef-redefinition \
 191                -Wno-gnu-variable-sized-type-not-at-end \
 192         ])])
 193
 194 dnl AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 195 dnl         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 196 dnl                -flto -ffat-lto-objects])],
 197 dnl         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 198 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 199
 200 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 201         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 202                -Wp,-D_FORTIFY_SOURCE=2])],
 203         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 204 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 205
 206 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 207         -Wl,--as-needed \
 208         -Wl,--no-undefined \
 209         -Wl,--gc-sections \
 210         -Wl,-z,relro \
 211         -Wl,-z,now \
 212         -pie \
 213         -Wl,-fuse-ld=gold])
 214 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 215
 216 AC_CHECK_SIZEOF(pid_t)
 217 AC_CHECK_SIZEOF(uid_t)
 218 AC_CHECK_SIZEOF(gid_t)
 219 AC_CHECK_SIZEOF(time_t)
 220 AC_CHECK_SIZEOF(dev_t)
 221 AC_CHECK_SIZEOF(rlim_t,,[
 222        #include <sys/time.h>
 223        #include <sys/resource.h>
 224 ])
 225
 226 # ------------------------------------------------------------------------------
 227
 228 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 229 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 230 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 231
 232 # unconditionally pull-in librt with old glibc versions
 233 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 234
 235 save_LIBS="$LIBS"
 236 LIBS=
 237 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 238 CAP_LIBS="$LIBS"
 239 AC_SUBST(CAP_LIBS)
 240
 241 AC_CHECK_FUNCS([memfd_create])
 242 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 243 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2, kcmp, LO_FLAGS_PARTSCAN],
 244                [], [], [[
 245 #include <sys/types.h>
 246 #include <unistd.h>
 247 #include <sys/mount.h>
 248 #include <fcntl.h>
 249 #include <sched.h>
 250 #include <linux/loop.h>
 251 #include <linux/random.h>
 252 ]])
 253
 254 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 255                 IFLA_MACVLAN_FLAGS,
 256                 IFLA_IPVLAN_MODE,
 257                 IFLA_VTI_REMOTE,
 258                 IFLA_PHYS_PORT_ID,
 259                 IFLA_BOND_AD_INFO,
 260                 IFLA_VLAN_PROTOCOL,
 261                 IFLA_VXLAN_LOCAL6,
 262                 IFLA_IPTUN_6RD_RELAY_PREFIXLEN,
 263                 IFLA_BRIDGE_VLAN_INFO,
 264                 IFLA_BRPORT_UNICAST_FLOOD,
 265                 NDA_IFINDEX],
 266 [], [], [[
 267 #include <inttypes.h>
 268 #include <netinet/in.h>
 269 #include <netinet/ether.h>
 270 #include <linux/rtnetlink.h>
 271 #include <net/if.h>
 272 #include <linux/ip.h>
 273 #include <linux/if_tunnel.h>
 274 #include <linux/if_link.h>
 275 #include <linux/if_bridge.h>
 276 #include <linux/neighbour.h>
 277 ]])
 278
 279 # This makes sure pkg.m4 is available.
 280 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 281
 282 # ------------------------------------------------------------------------------
 283 have_dbus=no
 284 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 285 AS_IF([test "x$enable_dbus" != "xno"], [
 286         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 287                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 288                 [have_dbus=no])
 289         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 290                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 291 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 292
 293 # ------------------------------------------------------------------------------
 294 PKG_CHECK_MODULES(UDEV, [libudev])
 295
 296 AC_ARG_WITH([udevrulesdir],
 297             AS_HELP_STRING([--with-udevrulesdir=DIR], [Directory for udev rules files]),
 298             [],
 299             [with_udevrulesdir=$($PKG_CONFIG --variable=udevdir udev)/rules.d])
 300 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 301 AC_SUBST([udevbindir], [$($PKG_CONFIG --variable=udevdir udev)/../bin])
 302
 303 # ------------------------------------------------------------------------------
 304 have_coverage=no
 305 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 306 if test "x$enable_coverage" = "xyes" ; then
 307         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 308         if test "x$lcov_found" = xno ; then
 309                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 310         else
 311                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 312                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 313                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 314                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 315                 else
 316                         have_coverage=yes
 317                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 318                         -fprofile-arcs \
 319                         -ftest-coverage])
 320                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 321                 fi
 322         fi
 323 fi
 324 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 325
 326 # ------------------------------------------------------------------------------
 327 have_blkid=no
 328 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 329 if test "x$enable_blkid" != "xno"; then
 330         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 331                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 332         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 333                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 334         fi
 335 fi
 336 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 337
 338 # ------------------------------------------------------------------------------
 339 have_seccomp=no
 340 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 341 if test "x$enable_seccomp" != "xno"; then
 342         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 343                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 344                 have_seccomp=yes
 345                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 346                [have_seccomp=no])
 347         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 348                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 349         fi
 350 fi
 351 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 352
 353 # ------------------------------------------------------------------------------
 354 have_selinux=no
 355 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 356 if test "x$enable_selinux" != "xno"; then
 357         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 358                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 359                  have_selinux=yes
 360                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 361                 [have_selinux=no])
 362         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 363                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 364         fi
 365 fi
 366 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 367
 368 have_apparmor=no
 369 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 370 if test "x$enable_apparmor" != "xno"; then
 371         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 372                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 373                  have_apparmor=yes
 374                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 375                 [have_apparmor=no])
 376         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 377                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 378         fi
 379 fi
 380 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 381
 382 # ------------------------------------------------------------------------------
 383 AC_ARG_ENABLE([pam],
 384         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 385                 [case "${enableval}" in
 386                         yes) have_pam=yes ;;
 387                         no) have_pam=no ;;
 388                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 389                 esac],
 390                 [have_pam=auto])
 391
 392 if test "x${have_pam}" != xno ; then
 393         AC_CHECK_HEADERS(
 394                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 395                 [have_pam=yes],
 396                 [if test "x$have_pam" = xyes ; then
 397                         AC_MSG_ERROR([*** PAM headers not found.])
 398                 fi])
 399
 400         AC_CHECK_LIB(
 401                 [pam],
 402                 [pam_syslog],
 403                 [have_pam=yes],
 404                 [if test "x$have_pam" = xyes ; then
 405                         AC_MSG_ERROR([*** libpam not found.])
 406                 fi])
 407
 408         if test "x$have_pam" = xyes ; then
 409                 PAM_LIBS="-lpam -lpam_misc"
 410                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 411                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 412         else
 413                 have_pam=no
 414         fi
 415 else
 416         PAM_LIBS=
 417 fi
 418 AC_SUBST(PAM_LIBS)
 419 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 420
 421 # ------------------------------------------------------------------------------
 422 AC_ARG_ENABLE([acl],
 423         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 424                 [case "${enableval}" in
 425                         yes) have_acl=yes ;;
 426                         no) have_acl=no ;;
 427                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 428                 esac],
 429                 [have_acl=auto])
 430
 431 if test "x${have_acl}" != xno ; then
 432         AC_CHECK_HEADERS(
 433                 [sys/acl.h acl/libacl.h],
 434                 [have_acl=yes],
 435                 [if test "x$have_acl" = xyes ; then
 436                         AC_MSG_ERROR([*** ACL headers not found.])
 437                 fi])
 438
 439         AC_CHECK_LIB(
 440                 [acl],
 441                 [acl_get_file],
 442                 [have_acl=yes],
 443                 [if test "x$have_acl" = xyes ; then
 444                         AC_MSG_ERROR([*** libacl not found.])
 445                 fi])
 446
 447         if test "x$have_acl" = xyes ; then
 448                 ACL_LIBS="-lacl"
 449                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 450                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 451         else
 452                 have_acl=no
 453         fi
 454 else
 455         ACL_LIBS=
 456 fi
 457 AC_SUBST(ACL_LIBS)
 458 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 459
 460 # ------------------------------------------------------------------------------
 461 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 462                 [case "${enableval}" in
 463                         yes) have_smack=yes ;;
 464                         no) have_smack=no ;;
 465                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 466                 esac],
 467                 [have_smack=auto])
 468
 469 if test "x${have_smack}" = xauto; then
 470         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 471         have_smack=yes
 472 fi
 473
 474 AC_ARG_WITH(smack-run-label,
 475 AS_HELP_STRING([--with-smack-run-label=STRING],
 476         [run systemd --system with a specific SMACK label]),
 477         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run with a smack label])],
 478         [])
 479
 480 if test "x${have_smack}" = xyes ; then
 481         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 482 fi
 483
 484 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 485
 486 # ------------------------------------------------------------------------------
 487 AC_ARG_WITH(system-uid-max,
 488         AS_HELP_STRING([--with-system-uid-max=UID]
 489                 [Maximum UID for system users]),
 490         [SYSTEM_UID_MAX="$withval"],
 491         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
 492
 493 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
 494 AC_SUBST(SYSTEM_UID_MAX)
 495
 496 # ------------------------------------------------------------------------------
 497 AC_ARG_WITH(system-gid-max,
 498         AS_HELP_STRING([--with-system-gid-max=GID]
 499                 [Maximum GID for system groups]),
 500         [SYSTEM_GID_MAX="$withval"],
 501         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
 502
 503 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
 504 AC_SUBST(SYSTEM_GID_MAX)
 505
 506 # ------------------------------------------------------------------------------
 507 have_polkit=no
 508 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 509 if test "x$enable_polkit" != "xno"; then
 510         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 511         have_polkit=yes
 512 fi
 513 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 514
 515 # ------------------------------------------------------------------------------
 516 have_kdbus=no
 517 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--enable-kdbus], [do connect to kdbus by default]))
 518 if test "x$enable_kdbus" = "xyes"; then
 519         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus support is to be enabled])
 520         have_kdbus=yes
 521         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
 522 fi
 523 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
 524
 525 # ------------------------------------------------------------------------------
 526 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
 527
 528 # ------------------------------------------------------------------------------
 529 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0],
 530                   [have_glib=yes], [have_glib=no])
 531 AS_IF([test "x$have_glib" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 532
 533 # ------------------------------------------------------------------------------
 534 have_manpages=no
 535 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 536 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
 537 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 538
 539 # ------------------------------------------------------------------------------
 540 AC_SUBST(M4_DEFINES)
 541
 542 AC_ARG_WITH([dbuspolicydir],
 543         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 544         [],
 545         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
 546
 547 AC_ARG_WITH([dbussessionservicedir],
 548         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 549         [],
 550         [with_dbussessionservicedir=${datadir}/dbus-1/services])
 551
 552 AC_ARG_WITH([dbussystemservicedir],
 553         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 554         [],
 555         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
 556
 557 AC_ARG_WITH([bashcompletiondir],
 558         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 559         [],
 560         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 561                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 562         ] , [
 563                 with_bashcompletiondir=${datadir}/bash-completion/completions
 564         ])])
 565
 566 AC_ARG_WITH([zshcompletiondir],
 567         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
 568         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
 569
 570 AC_ARG_WITH([rootlibdir],
 571         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 572         [],
 573         [with_rootlibdir=${libdir}])
 574
 575 AC_ARG_WITH([pamlibdir],
 576         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 577         [],
 578         [with_pamlibdir=${with_rootlibdir}/security])
 579
 580 AC_ARG_WITH([pamconfdir],
 581         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
 582         [],
 583         [with_pamconfdir=${sysconfdir}/pam.d])
 584
 585 AC_ARG_ENABLE([split-usr],
 586         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 587         [],
 588         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 589                 enable_split_usr=yes
 590         ], [
 591                 enable_split_usr=no
 592         ])])
 593
 594 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 595         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 596 ])
 597
 598 # Work around intltoolize and gtk-doc problems in VPATH builds
 599 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 600                                        [Define to do gtk-doc tests])
 601 AS_IF([test "x$0" != "x./configure"], [
 602         AC_SUBST([INTLTOOL_UPDATE], [/usr/bin/env true])
 603 ])
 604
 605 AC_ARG_ENABLE(tests,
 606         [AC_HELP_STRING([--disable-tests], [disable tests])],
 607         enable_tests=$enableval, enable_tests=yes)
 608 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 609
 610 AC_ARG_ENABLE(debug,
 611         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
 612         [if test "x$enableval" = "xyes"; then
 613                 enableval="hashmap,mmap-cache"
 614         fi
 615         saved_ifs="$IFS"
 616         IFS="$IFS$PATH_SEPARATOR,"
 617         for name in $enableval; do
 618                 case $name in
 619                 hashmap)
 620                         enable_debug_hashmap=yes
 621                         ;;
 622                 mmap-cache)
 623                         enable_debug_mmap_cache=yes
 624                         ;;
 625                 esac
 626         done
 627         IFS="$saved_ifs"],[])
 628
 629 enable_debug=""
 630 AS_IF([test x$enable_debug_hashmap = xyes], [
 631         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
 632         enable_debug="hashmap $enable_debug"
 633 ])
 634 AS_IF([test x$enable_debug_mmap_cache = xyes], [
 635         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
 636         enable_debug="mmap-cache $enable_debug"
 637 ])
 638 test -z "$enable_debug" && enable_debug="none"
 639
 640 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 641 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 642 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 643 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 644 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
 645 AC_SUBST([pamlibdir], [$with_pamlibdir])
 646 AC_SUBST([pamconfdir], [$with_pamconfdir])
 647 AC_SUBST([rootlibdir], [$with_rootlibdir])
 648
 649 AC_CONFIG_FILES([
 650         Makefile po/Makefile.in
 651 ])
 652
 653 AC_OUTPUT
 654 AC_MSG_RESULT([
 655         $PACKAGE_NAME $VERSION
 656
 657         PAM:                     ${have_pam}
 658         AppArmor:                ${have_apparmor}
 659         SELinux:                 ${have_selinux}
 660         SECCOMP:                 ${have_seccomp}
 661         SMACK:                   ${have_smack}
 662         ACL:                     ${have_acl}
 663         polkit:                  ${have_polkit}
 664         blkid:                   ${have_blkid}
 665         dbus:                    ${have_dbus}
 666         kdbus:                   ${have_kdbus}
 667         man pages:               ${have_manpages}
 668         gtk-doc:                 ${enable_gtk_doc}
 669         test coverage:           ${have_coverage}
 670         Split /usr:              ${enable_split_usr}
 671         extra debugging:         ${enable_debug}
 672
 673         prefix:                  ${prefix}
 674         sysconf dir:             ${sysconfdir}
 675         datarootdir:             ${datarootdir}
 676         includedir:              ${includedir}
 677         lib dir:                 ${libdir}
 678         rootlib dir:             ${with_rootlibdir}
 679         PAM modules dir:         ${with_pamlibdir}
 680         PAM configuration dir:   ${with_pamconfdir}
 681         D-Bus policy dir:        ${with_dbuspolicydir}
 682         D-Bus session dir:       ${with_dbussessionservicedir}
 683         D-Bus system dir:        ${with_dbussystemservicedir}
 684         Bash completions dir:    ${with_bashcompletiondir}
 685         Zsh completions dir:     ${with_zshcompletiondir}
 686         Maximum System UID:      ${SYSTEM_UID_MAX}
 687         Maximum System GID:      ${SYSTEM_GID_MAX}
 688
 689         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 690         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
 691         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 692 ])