configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010 Lennart Poettering
   4 #
   5 #  systemd is free software; you can redistribute it and/or modify it
   6 #  under the terms of the GNU General Public License as published by
   7 #  the Free Software Foundation; either version 2 of the License, or
   8 #  (at your option) any later version.
   9 #
  10 #  systemd is distributed in the hope that it will be useful, but
  11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 #  General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU General Public License
  16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ(2.63)
  19
  20 AC_INIT([systemd],[0],[systemd-devel@lists.freedesktop.org])
  21 AC_CONFIG_SRCDIR([src/main.c])
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
  26
  27 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
  28
  29 AC_CANONICAL_HOST
  30
  31 AM_SILENT_RULES([yes])
  32
  33 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  34
  35 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  36         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  37         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  38 ])
  39
  40 AC_PROG_MKDIR_P
  41 AC_PROG_LN_S
  42 AC_PROG_SED
  43
  44 AC_PROG_CC
  45 AC_PROG_CC_C99
  46 AM_PROG_CC_C_O
  47 AC_PROG_GCC_TRADITIONAL
  48 AC_USE_SYSTEM_EXTENSIONS
  49
  50 CC_CHECK_CFLAGS_APPEND([ \
  51         -Wall \
  52         -W \
  53         -Wextra \
  54         -pipe \
  55         -Wno-long-long \
  56         -Winline \
  57         -Wvla \
  58         -Wno-overlength-strings \
  59         -Wundef \
  60         -Wformat=2 \
  61         -Wlogical-op \
  62         -Wsign-compare \
  63         -Wformat-security \
  64         -Wmissing-include-dirs \
  65         -Wformat-nonliteral \
  66         -Wold-style-definition \
  67         -Wpointer-arith \
  68         -Winit-self \
  69         -Wdeclaration-after-statement \
  70         -Wfloat-equal \
  71         -Wmissing-prototypes \
  72         -Wstrict-prototypes \
  73         -Wredundant-decls \
  74         -Wmissing-declarations \
  75         -Wmissing-noreturn \
  76         -Wshadow \
  77         -Wendif-labels \
  78         -Wcast-align \
  79         -Wstrict-aliasing=2 \
  80         -Wwrite-strings \
  81         -Wno-unused-parameter \
  82         -ffast-math \
  83         -Wp,-D_FORTIFY_SOURCE=2 \
  84         -fno-common \
  85         -fdiagnostics-show-option \
  86         -Wno-missing-field-initializers])
  87
  88 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
  89 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
  90 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
  91
  92 # This makes sure pkg.m4 is available.
  93 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
  94
  95 PKG_CHECK_MODULES(UDEV, [ libudev >= 154 ])
  96 AC_SUBST(UDEV_CFLAGS)
  97 AC_SUBST(UDEV_LIBS)
  98
  99 PKG_CHECK_MODULES(DBUS, [ dbus-1 ])
 100 AC_SUBST(DBUS_CFLAGS)
 101 AC_SUBST(DBUS_LIBS)
 102
 103 PKG_CHECK_MODULES(DBUSGLIB, [ dbus-glib-1 ])
 104 AC_SUBST(DBUSGLIB_CFLAGS)
 105 AC_SUBST(DBUSGLIB_LIBS)
 106
 107 PKG_CHECK_MODULES(CGROUP, [ libcgroup >= 0.36 ])
 108 AC_SUBST(CGROUP_CFLAGS)
 109 AC_SUBST(CGROUP_LIBS)
 110
 111 AC_ARG_ENABLE([tcpwrap],
 112         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 113                 [case "${enableval}" in
 114                         yes) have_tcpwrap=yes ;;
 115                         no) have_tcpwrap=no ;;
 116                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 117                 esac],
 118                 [have_tcpwrap=auto])
 119
 120 if test "x${have_tcpwrap}" != xno ; then
 121         ACX_LIBWRAP
 122         if test "x${LIBWRAP_LIBS}" = x ; then
 123                 if test "x$have_tcpwrap" = xyes ; then
 124                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 125                 fi
 126         else
 127                 have_tcpwrap=yes
 128         fi
 129 else
 130         LIBWRAP_LIBS=
 131 fi
 132 AC_SUBST(LIBWRAP_LIBS)
 133
 134 AC_ARG_ENABLE([pam],
 135         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 136                 [case "${enableval}" in
 137                         yes) have_pam=yes ;;
 138                         no) have_pam=no ;;
 139                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 140                 esac],
 141                 [have_pam=auto])
 142
 143 if test "x${have_pam}" != xno ; then
 144         AC_CHECK_HEADERS(
 145                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 146                 [have_pam=yes],
 147                 [if test "x$have_pam" = xyes ; then
 148                         AC_MSG_ERROR([*** PAM headers not found.])
 149                 fi])
 150
 151         AC_CHECK_LIB(
 152                 [pam],
 153                 [pam_syslog],
 154                 [have_pam=yes],
 155                 [if test "x$have_pam" = xyes ; then
 156                         AC_MSG_ERROR([*** libpam not found.])
 157                 fi])
 158
 159         if test "x$have_pam" = xyes ; then
 160                 PAM_LIBS="-lpam -lpam_misc"
 161                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 162         fi
 163 else
 164         PAM_LIBS=
 165 fi
 166 AC_SUBST(PAM_LIBS)
 167 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 168
 169 have_gtk=no
 170 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
 171 if test "x$enable_gtk" != "xno"; then
 172         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 ],
 173                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
 174         AC_SUBST(GTK_CFLAGS)
 175         AC_SUBST(GTK_LIBS)
 176         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
 177              AC_MSG_ERROR([*** gtk support requested but libraries not found])
 178         fi
 179 fi
 180 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
 181
 182 AM_PROG_VALAC([0.8])
 183 AC_SUBST(VAPIDIR)
 184 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
 185
 186 AC_PATH_PROG([XSLTPROC], [xsltproc])
 187 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 188
 189 AC_PATH_PROG([M4], [m4])
 190
 191 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, arch, gentoo, slackware or other]))
 192 if test "z$with_distro" = "z"; then
 193         if test "$cross_compiling" = yes; then
 194                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 195         else
 196                 AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 197                 AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 198                 AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 199                 AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
 200                 AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 201                 AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 202         fi
 203         if test "z$with_distro" = "z"; then
 204                 with_distro=`uname -s`
 205         fi
 206 fi
 207 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 208
 209 # Default generic names
 210 SPECIAL_DBUS_SERVICE=dbus.service
 211 SPECIAL_SYSLOG_SERVICE=syslog.service
 212
 213 # Location of the init scripts as mandated by LSB
 214 SYSTEM_SYSVINIT_PATH=/etc/init.d
 215
 216 M4_DISTRO_FLAG=
 217
 218 case $with_distro in
 219         fedora)
 220                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 221                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 222
 223                 # A little background why we define these special unit
 224                 # names here in configure.ac: SysV services currently
 225                 # cannot have aliases. As long as syslog is started
 226                 # via a SysV init script we hence define these names
 227                 # to the actual SysV name here. Later on when SysV
 228                 # init scripts are not used anymore it is advisable to
 229                 # use the generic names instead and use symlinks in
 230                 # the unit directories to point to the right native
 231                 # unit file.
 232
 233                 SPECIAL_DBUS_SERVICE=messagebus.service
 234                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 235                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 236                 M4_DISTRO_FLAG=-DTARGET_FEDORA=1
 237                 ;;
 238         suse)
 239                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 240                 AC_DEFINE(TARGET_SUSE, [], [Target is OpenSUSE/SLE])
 241                 M4_DISTRO_FLAG=-DTARGET_SUSE=1
 242                 ;;
 243         debian)
 244                 SYSTEM_SYSVRCND_PATH=/etc
 245                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 246                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian/Ubuntu])
 247                 M4_DISTRO_FLAG=-DTARGET_DEBIAN=1
 248                 ;;
 249         arch)
 250                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 251                 SYSTEM_SYSVRCND_PATH=/etc
 252                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 253                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 254                 M4_DISTRO_FLAG=-DTARGET_ARCH=1
 255                 ;;
 256         gentoo)
 257                 SYSTEM_SYSVRCND_PATH=/etc
 258                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 259                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 260                 M4_DISTRO_FLAG=-DTARGET_GENTOO=1
 261                 ;;
 262         slackware)
 263                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 264                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 265                 SPECIAL_DBUS_SERVICE=messagebus.service
 266                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 267                 M4_DISTRO_FLAG=-DTARGET_SLACKWARE=1
 268                 ;;
 269         other)
 270                 AS_IF([test "x$with_sysvinit_path" = "x"],
 271                         [AC_MSG_ERROR([With --distro=other, you must pass --with-sysvinit-path= to configure])])
 272                 AS_IF([test "x$with_sysvrcd_path" = "x"],
 273                         [AC_MSG_ERROR([With --distro=other, you must pass --with-sysvrcd-path= to configure])])
 274                 AS_IF([test "x$with_dbus_service" = "x"],
 275                         [AC_MSG_ERROR([With --distro=other, you must pass --with-dbus-service= to configure])])
 276                 AS_IF([test "x$with_syslog_service" = "x"],
 277                         [AC_MSG_ERROR([With --distro=other, you must pass --with-syslog-service= to configure])])
 278                 ;;
 279         *)
 280                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 281                 ;;
 282 esac
 283
 284 AC_ARG_WITH([sysvinit-path],
 285         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 286                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 287         [SYSTEM_SYSVINIT_PATH="$withval"],
 288         [])
 289
 290 AC_ARG_WITH([sysvrcd-path],
 291         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 292                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 293         [SYSTEM_SYSVRCND_PATH="$withval"],
 294         [])
 295
 296 AC_ARG_WITH([dbus-service],
 297         [AS_HELP_STRING([--with-dbus-service=UNIT],
 298                 [Specify the name of the special DBus service @<:@default=based on distro@:>@])],
 299         [SPECIAL_DBUS_SERVICE="$withval"],
 300         [])
 301
 302 AC_ARG_WITH([syslog-service],
 303         [AS_HELP_STRING([--with-syslog-service=UNIT],
 304                 [Specify the name of the special syslog service @<:@default=based on distro@:>@])],
 305         [SPECIAL_SYSLOG_SERVICE="$withval"],
 306         [])
 307
 308 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 309 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 310 AC_SUBST(SPECIAL_DBUS_SERVICE)
 311 AC_SUBST(SPECIAL_SYSLOG_SERVICE)
 312 AC_SUBST(M4_DISTRO_FLAG)
 313
 314 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 315 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 316 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 317 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 318 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 319 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 320
 321 AC_DEFINE_UNQUOTED(SPECIAL_DBUS_SERVICE, ["$SPECIAL_DBUS_SERVICE"], [D-Bus service name])
 322 AC_DEFINE_UNQUOTED(SPECIAL_SYSLOG_SERVICE, ["$SPECIAL_SYSLOG_SERVICE"], [Syslog service name])
 323
 324 AC_ARG_WITH([dbuspolicydir],
 325         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 326         [],
 327         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 328
 329 AC_ARG_WITH([dbussessionservicedir],
 330         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 331         [],
 332         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 333
 334 AC_ARG_WITH([dbussystemservicedir],
 335         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 336         [],
 337         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 338
 339 AC_ARG_WITH([dbusinterfacedir],
 340         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 341         [],
 342         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 343
 344 AC_ARG_WITH([udevrulesdir],
 345         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
 346         [],
 347         [with_udevrulesdir=/lib/udev/rules.d])
 348
 349 AC_ARG_WITH([rootdir],
 350         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
 351         [],
 352         [with_rootdir=${ac_default_prefix}])
 353
 354 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 355 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 356 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 357 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 358 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 359 AC_SUBST([rootdir], [$with_rootdir])
 360
 361 AC_CONFIG_FILES([Makefile])
 362 AC_OUTPUT
 363
 364 echo "
 365         $PACKAGE_NAME $VERSION
 366
 367         Distribution:            ${with_distro}
 368         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 369         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 370         Syslog service:          ${SPECIAL_SYSLOG_SERVICE}
 371         D-Bus service:           ${SPECIAL_DBUS_SERVICE}
 372         Gtk:                     ${have_gtk}
 373         tcpwrap:                 ${have_tcpwrap}
 374         PAM:                     ${have_pam}
 375         prefix:                  ${prefix}
 376         root dir:                ${with_rootdir}
 377         udev rules dir:          ${with_udevrulesdir}
 378         dbus policy dir:         ${with_dbuspolicydir}
 379         dbus session dir:        ${with_dbussessionservicedir}
 380         dbus system dir:         ${with_dbussystemservicedir}
 381         dbus interfaces dir:     ${with_dbusinterfacedir}
 382 "