configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [195],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT
  46
  47 # i18n stuff for the PolicyKit policy files
  48 IT_PROG_INTLTOOL([0.40.0])
  49
  50 GETTEXT_PACKAGE=systemd
  51 AC_SUBST(GETTEXT_PACKAGE)
  52
  53 AC_PROG_MKDIR_P
  54 AC_PROG_LN_S
  55 AC_PROG_SED
  56 AC_PROG_GREP
  57 AC_PROG_AWK
  58
  59 AC_PROG_CC
  60 AC_PROG_CC_C99
  61 AM_PROG_CC_C_O
  62 AC_PROG_GCC_TRADITIONAL
  63
  64 AC_PATH_PROG([M4], [m4])
  65 AC_PATH_PROG([XSLTPROC], [xsltproc])
  66
  67 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  68 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  69
  70 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  71
  72 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  73
  74 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  75 m4_ifdef([GTK_DOC_CHECK], [
  76 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])
  77 ], [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
  78
  79 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  80         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  81 ])
  82
  83 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  84 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  85 ], [AM_CONDITIONAL([HAVE_INTROSPECTION], [false])])
  86
  87 AC_PATH_TOOL(OBJCOPY, objcopy)
  88 AC_PATH_TOOL(STRINGS, strings)
  89 AC_PATH_TOOL(GPERF, gperf)
  90 if test -z "$GPERF" ; then
  91         AC_MSG_ERROR([*** gperf not found])
  92 fi
  93
  94 # we use python to build the man page index, and for systemd-python
  95 have_python=no
  96 have_python_devel=no
  97
  98 AC_ARG_WITH([python],
  99         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 100
 101 AS_IF([test "x$with_python" != "xno"], [
 102         AM_PATH_PYTHON(,, [:])
 103         AS_IF([test "$PYTHON" != :], [have_python=yes])
 104 ])
 105 AM_CONDITIONAL([HAVE_PYTHON], [test "$have_python" = "yes"])
 106
 107 AS_IF([test "x$with_python" != "xno"], [
 108         AC_PATH_PROG(PYTHON_CONFIG, python${PYTHON_VERSION}-config)
 109         AS_IF([test -n "$PYTHON_CONFIG"], [
 110               have_python_devel=yes
 111               PYTHON_CFLAGS="`$PYTHON_CONFIG --cflags`"
 112               PYTHON_LIBS="`$PYTHON_CONFIG --ldflags`"
 113               AC_SUBST(PYTHON_CFLAGS)
 114               AC_SUBST(PYTHON_LIBS)
 115         ])
 116 ])
 117 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 118
 119 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 120         -pipe \
 121         -Wall \
 122         -Wextra \
 123         -Wno-inline \
 124         -Wundef \
 125         -Wformat=2 \
 126         -Wlogical-op \
 127         -Wsign-compare \
 128         -Wformat-security \
 129         -Wmissing-include-dirs \
 130         -Wformat-nonliteral \
 131         -Wold-style-definition \
 132         -Wpointer-arith \
 133         -Winit-self \
 134         -Wdeclaration-after-statement \
 135         -Wfloat-equal \
 136         -Wmissing-prototypes \
 137         -Wstrict-prototypes \
 138         -Wredundant-decls \
 139         -Wmissing-declarations \
 140         -Wmissing-noreturn \
 141         -Wshadow \
 142         -Wendif-labels \
 143         -Wcast-align \
 144         -Wstrict-aliasing=2 \
 145         -Wwrite-strings \
 146         -Wno-long-long \
 147         -Wno-overlength-strings \
 148         -Wno-unused-parameter \
 149         -Wno-missing-field-initializers \
 150         -Wno-unused-result \
 151         -Werror=overflow \
 152         -ffast-math \
 153         -fno-common \
 154         -fdiagnostics-show-option \
 155         -fno-strict-aliasing \
 156         -fvisibility=hidden \
 157         -ffunction-sections \
 158         -fdata-sections \
 159         -fstack-protector \
 160         --param=ssp-buffer-size=4])
 161 AC_SUBST([OUR_CFLAGS], $with_cflags)
 162
 163 CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 164         -Wp,-D_FORTIFY_SOURCE=2])
 165 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 166
 167 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 168         -Wl,--as-needed \
 169         -Wl,--gc-sections \
 170         -Wl,-z,relro \
 171         -Wl,-z,now])
 172 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 173
 174 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 175 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 176
 177 save_LIBS="$LIBS"
 178 LIBS=
 179 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 180 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 181 CAP_LIBS="$LIBS"
 182 LIBS="$save_LIBS"
 183 AC_SUBST(CAP_LIBS)
 184
 185 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 186 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 187 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 188 #include <unistd.h>
 189 #include <sys/mount.h>
 190 #include <fcntl.h>]])
 191
 192 # This makes sure pkg.m4 is available.
 193 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 194
 195 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 196 PKG_CHECK_MODULES(KMOD, [libkmod >= 5])
 197 PKG_CHECK_MODULES(BLKID,[blkid >= 2.20])
 198
 199 # ------------------------------------------------------------------------------
 200 have_ima=yes
 201 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 202                 [case "${enableval}" in
 203                         yes) have_ima=yes ;;
 204                         no) have_ima=no ;;
 205                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 206                 esac],
 207                 [have_ima=yes])
 208
 209 if test "x${have_ima}" != xno ; then
 210         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 211 fi
 212
 213 # ------------------------------------------------------------------------------
 214 have_selinux=no
 215 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 216 if test "x$enable_selinux" != "xno"; then
 217         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 218                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 219         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 220                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 221         fi
 222 fi
 223 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 224 if test "x${have_selinux}" != xno ; then
 225         sushell=/sbin/sushell
 226 else
 227         sushell=/bin/bash
 228 fi
 229 AC_SUBST(sushell)
 230
 231 # ------------------------------------------------------------------------------
 232 have_xz=no
 233 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 234 if test "x$enable_xz" != "xno"; then
 235         PKG_CHECK_MODULES(XZ, [ liblzma ],
 236                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 237         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 238                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 239         fi
 240 fi
 241 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 242
 243 # ------------------------------------------------------------------------------
 244 AC_ARG_ENABLE([tcpwrap],
 245         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 246                 [case "${enableval}" in
 247                         yes) have_tcpwrap=yes ;;
 248                         no) have_tcpwrap=no ;;
 249                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 250                 esac],
 251                 [have_tcpwrap=auto])
 252
 253 if test "x${have_tcpwrap}" != xno ; then
 254         ACX_LIBWRAP
 255         if test "x${LIBWRAP_LIBS}" = x ; then
 256                 if test "x$have_tcpwrap" = xyes ; then
 257                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 258                 fi
 259                 have_tcpwrap=no
 260         else
 261                 have_tcpwrap=yes
 262         fi
 263 else
 264         LIBWRAP_LIBS=
 265 fi
 266 AC_SUBST(LIBWRAP_LIBS)
 267
 268 # ------------------------------------------------------------------------------
 269 AC_ARG_ENABLE([pam],
 270         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 271                 [case "${enableval}" in
 272                         yes) have_pam=yes ;;
 273                         no) have_pam=no ;;
 274                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 275                 esac],
 276                 [have_pam=auto])
 277
 278 if test "x${have_pam}" != xno ; then
 279         AC_CHECK_HEADERS(
 280                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 281                 [have_pam=yes],
 282                 [if test "x$have_pam" = xyes ; then
 283                         AC_MSG_ERROR([*** PAM headers not found.])
 284                 fi])
 285
 286         AC_CHECK_LIB(
 287                 [pam],
 288                 [pam_syslog],
 289                 [have_pam=yes],
 290                 [if test "x$have_pam" = xyes ; then
 291                         AC_MSG_ERROR([*** libpam not found.])
 292                 fi])
 293
 294         if test "x$have_pam" = xyes ; then
 295                 PAM_LIBS="-lpam -lpam_misc"
 296                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 297         else
 298                 have_pam=no
 299         fi
 300 else
 301         PAM_LIBS=
 302 fi
 303 AC_SUBST(PAM_LIBS)
 304 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 305
 306 # ------------------------------------------------------------------------------
 307 AC_ARG_ENABLE([acl],
 308         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 309                 [case "${enableval}" in
 310                         yes) have_acl=yes ;;
 311                         no) have_acl=no ;;
 312                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 313                 esac],
 314                 [have_acl=auto])
 315
 316 if test "x${have_acl}" != xno ; then
 317         AC_CHECK_HEADERS(
 318                 [sys/acl.h acl/libacl.h],
 319                 [have_acl=yes],
 320                 [if test "x$have_acl" = xyes ; then
 321                         AC_MSG_ERROR([*** ACL headers not found.])
 322                 fi])
 323
 324         AC_CHECK_LIB(
 325                 [acl],
 326                 [acl_get_file],
 327                 [have_acl=yes],
 328                 [if test "x$have_acl" = xyes ; then
 329                         AC_MSG_ERROR([*** libacl not found.])
 330                 fi])
 331
 332         if test "x$have_acl" = xyes ; then
 333                 ACL_LIBS="-lacl"
 334                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 335         else
 336                 have_acl=no
 337         fi
 338 else
 339         ACL_LIBS=
 340 fi
 341 AC_SUBST(ACL_LIBS)
 342 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 343
 344 # ------------------------------------------------------------------------------
 345 AC_ARG_ENABLE([xattr],
 346         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 347                 [case "${enableval}" in
 348                         yes) have_xattr=yes ;;
 349                         no) have_xattr=no ;;
 350                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 351                 esac],
 352                 [have_xattr=auto])
 353
 354 if test "x${have_xattr}" != xno ; then
 355         AC_CHECK_HEADERS(
 356                 [attr/xattr.h],
 357                 [have_xattr=yes],
 358                 [if test "x$have_xattr" = xyes ; then
 359                         AC_MSG_ERROR([*** XATTR headers not found.])
 360                 fi])
 361
 362         AC_CHECK_LIB(
 363                 [attr],
 364                 [fsetxattr],
 365                 [have_xattr=yes],
 366                 [if test "x$have_xattr" = xyes ; then
 367                         AC_MSG_ERROR([*** libattr not found.])
 368                 fi])
 369
 370         if test "x$have_xattr" = xyes ; then
 371                 XATTR_LIBS="-lattr"
 372                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 373         else
 374                 have_xattr=no
 375         fi
 376 else
 377         XATTR_LIBS=
 378 fi
 379 AC_SUBST(XATTR_LIBS)
 380 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 381
 382 # ------------------------------------------------------------------------------
 383 AC_ARG_ENABLE([gcrypt],
 384         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 385                 [case "${enableval}" in
 386                         yes) have_gcrypt=yes ;;
 387                         no) have_gcrypt=no ;;
 388                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 389                 esac],
 390                 [have_gcrypt=auto])
 391
 392 if test "x${have_gcrypt}" != xno ; then
 393         AM_PATH_LIBGCRYPT(
 394                 [1.4.5],
 395                 [have_gcrypt=yes],
 396                 [if test "x$have_gcrypt" = xyes ; then
 397                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 398                 fi])
 399
 400         if test "x$have_gcrypt" = xyes ; then
 401                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 402                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 403                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 404         else
 405                 have_gcrypt=no
 406         fi
 407 else
 408         GCRYPT_LIBS=
 409         GCRYPT_CFLAGS=
 410 fi
 411 AC_SUBST(GCRYPT_LIBS)
 412 AC_SUBST(GCRYPT_CFLAGS)
 413 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 414
 415 # ------------------------------------------------------------------------------
 416 AC_ARG_ENABLE([audit],
 417         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 418                 [case "${enableval}" in
 419                         yes) have_audit=yes ;;
 420                         no) have_audit=no ;;
 421                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 422                 esac],
 423                 [have_audit=auto])
 424
 425 if test "x${have_audit}" != xno ; then
 426         AC_CHECK_HEADERS(
 427                 [libaudit.h],
 428                 [have_audit=yes],
 429                 [if test "x$have_audit" = xyes ; then
 430                         AC_MSG_ERROR([*** AUDIT headers not found.])
 431                 fi])
 432
 433         AC_CHECK_LIB(
 434                 [audit],
 435                 [audit_open],
 436                 [have_audit=yes],
 437                 [if test "x$have_audit" = xyes ; then
 438                         AC_MSG_ERROR([*** libaudit not found.])
 439                 fi])
 440
 441         if test "x$have_audit" = xyes ; then
 442                 AUDIT_LIBS="-laudit"
 443                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 444         else
 445                 have_audit=no
 446         fi
 447 else
 448         AUDIT_LIBS=
 449 fi
 450 AC_SUBST(AUDIT_LIBS)
 451
 452 # ------------------------------------------------------------------------------
 453 have_libcryptsetup=no
 454 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 455 if test "x$enable_libcryptsetup" != "xno"; then
 456         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
 457                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 458         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 459                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 460         fi
 461 fi
 462 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 463
 464 # ------------------------------------------------------------------------------
 465 have_qrencode=no
 466 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 467 if test "x$enable_qrencode" != "xno"; then
 468         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 469                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 470         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 471                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 472         fi
 473 fi
 474 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 475
 476 # ------------------------------------------------------------------------------
 477 have_microhttpd=no
 478 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 479 if test "x$enable_microhttpd" != "xno"; then
 480         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 481                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 482         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 483                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 484         fi
 485 fi
 486 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 487
 488 # ------------------------------------------------------------------------------
 489 have_binfmt=no
 490 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 491 if test "x$enable_binfmt" != "xno"; then
 492         have_binfmt=yes
 493 fi
 494 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 495
 496 # ------------------------------------------------------------------------------
 497 have_vconsole=no
 498 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 499 if test "x$enable_vconsole" != "xno"; then
 500         have_vconsole=yes
 501 fi
 502 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 503
 504 # ------------------------------------------------------------------------------
 505 have_readahead=no
 506 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 507 if test "x$enable_readahead" != "xno"; then
 508         have_readahead=yes
 509 fi
 510 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 511
 512 # ------------------------------------------------------------------------------
 513 have_quotacheck=no
 514 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 515 if test "x$enable_quotacheck" != "xno"; then
 516         have_quotacheck=yes
 517 fi
 518 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 519
 520 # ------------------------------------------------------------------------------
 521 have_randomseed=no
 522 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 523 if test "x$enable_randomseed" != "xno"; then
 524         have_randomseed=yes
 525 fi
 526 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 527
 528 # ------------------------------------------------------------------------------
 529 have_logind=no
 530 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 531 if test "x$enable_logind" != "xno"; then
 532         have_logind=yes
 533 fi
 534 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 535 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 536
 537 # ------------------------------------------------------------------------------
 538 have_hostnamed=no
 539 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 540 if test "x$enable_hostnamed" != "xno"; then
 541         have_hostnamed=yes
 542 fi
 543 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 544
 545 # ------------------------------------------------------------------------------
 546 have_timedated=no
 547 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 548 if test "x$enable_timedated" != "xno"; then
 549         have_timedated=yes
 550 fi
 551 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 552
 553 # ------------------------------------------------------------------------------
 554 have_localed=no
 555 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 556 if test "x$enable_localed" != "xno"; then
 557         have_localed=yes
 558 fi
 559 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 560
 561 # ------------------------------------------------------------------------------
 562 have_coredump=no
 563 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 564 if test "x$enable_coredump" != "xno"; then
 565         have_coredump=yes
 566 fi
 567 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 568
 569 # ------------------------------------------------------------------------------
 570 AC_ARG_WITH(firmware-path,
 571        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 572           [Firmware search path (default=ROOTPREFIX/lib/firmware/updates:ROOTPREFIX/lib/firmware)]),
 573        [], [with_firmware_path="$rootprefix/lib/firmware/updates:$rootprefix/lib/firmware"])
 574 OLD_IFS=$IFS
 575 IFS=:
 576 for i in $with_firmware_path; do
 577        if test "x${FIRMWARE_PATH}" = "x"; then
 578               FIRMWARE_PATH="\\\"${i}/\\\""
 579        else
 580               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 581        fi
 582 done
 583 IFS=$OLD_IFS
 584 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
 585
 586 # ------------------------------------------------------------------------------
 587 AC_ARG_ENABLE([gudev],
 588        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 589        [], [enable_gudev=yes])
 590 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0]) ])
 591 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 592
 593 # ------------------------------------------------------------------------------
 594 AC_ARG_ENABLE([keymap],
 595        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 596        [], [enable_keymap=yes])
 597 AS_IF([test "x$enable_keymap" = "xyes"], [
 598        AC_PATH_PROG([GPERF], [gperf])
 599        if test -z "$GPERF"; then
 600               AC_MSG_ERROR([gperf is needed])
 601        fi
 602
 603        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 604        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 605 ])
 606 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 607
 608 # ------------------------------------------------------------------------------
 609 have_manpages=no
 610 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 611 AS_IF([test "x$enable_manpages" != xno], [
 612         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 613                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 614         ])
 615         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 616 ])
 617 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 618
 619 # ------------------------------------------------------------------------------
 620
 621 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux, mandriva, mageia, angstrom or other]))
 622 if test "z$with_distro" = "z"; then
 623         if test "$cross_compiling" = yes; then
 624                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 625         else
 626                 with_distro=$($GREP '^ID=' /etc/os-release 2>/dev/null | $SED 's/ID=//');
 627         fi
 628         if test "z$with_distro" = "z"; then
 629                 with_distro=other
 630         fi
 631 fi
 632 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 633 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 634
 635 # Location of the init scripts as mandated by LSB
 636 SYSTEM_SYSVINIT_PATH=/etc/init.d
 637 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 638
 639 M4_DEFINES=
 640
 641 case $with_distro in
 642         fedora)
 643                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 644                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 645                 M4_DEFINES=-DTARGET_FEDORA=1
 646                 ;;
 647         opensuse|suse)
 648                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 649                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 650                 M4_DEFINES=-DTARGET_SUSE=1
 651                 ;;
 652         debian)
 653                 SYSTEM_SYSVRCND_PATH=/etc
 654                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 655                 M4_DEFINES=-DTARGET_DEBIAN=1
 656                 ;;
 657         ubuntu)
 658                 SYSTEM_SYSVRCND_PATH=/etc
 659                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 660                 M4_DEFINES=-DTARGET_UBUNTU=1
 661                 ;;
 662         arch)
 663                 SYSTEM_SYSVINIT_PATH=
 664                 SYSTEM_SYSVRCND_PATH=
 665                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 666                 M4_DEFINES=-DTARGET_ARCH=1
 667                 ;;
 668         gentoo)
 669                 SYSTEM_SYSVINIT_PATH=
 670                 SYSTEM_SYSVRCND_PATH=
 671                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 672                 M4_DEFINES=-DTARGET_GENTOO=1
 673                 ;;
 674         slackware)
 675                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 676                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 677                 M4_DEFINES=-DTARGET_SLACKWARE=1
 678                 ;;
 679         frugalware)
 680                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 681                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 682                 M4_DEFINES=-DTARGET_FRUGALWARE=1
 683                 ;;
 684         altlinux)
 685                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 686                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 687                 M4_DEFINES=-DTARGET_ALTLINUX=1
 688                 ;;
 689         mandriva)
 690                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 691                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 692                 M4_DEFINES=-DTARGET_MANDRIVA=1
 693                 ;;
 694         angstrom)
 695                 SYSTEM_SYSVRCND_PATH=/etc
 696                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 697                 M4_DEFINES=-DTARGET_ANGSTROM=1
 698                 ;;
 699         mageia)
 700                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 701                 AC_DEFINE(TARGET_MAGEIA, [], [Target is Mageia])
 702                 M4_DEFINES=-DTARGET_MAGEIA=1
 703                 ;;
 704         other)
 705                 ;;
 706         *)
 707                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 708                 ;;
 709 esac
 710
 711 AC_ARG_WITH([sysvinit-path],
 712         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 713                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 714         [SYSTEM_SYSVINIT_PATH="$withval"],
 715         [])
 716
 717 AC_ARG_WITH([sysvrcd-path],
 718         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 719                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 720         [SYSTEM_SYSVRCND_PATH="$withval"],
 721         [])
 722
 723 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 724 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 725 AC_SUBST(M4_DEFINES)
 726
 727 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 728         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 729         SYSTEM_SYSV_COMPAT="yes"
 730         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 731 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 732         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 733 else
 734         SYSTEM_SYSV_COMPAT="no"
 735 fi
 736
 737 AC_ARG_WITH([tty-gid],
 738         [AS_HELP_STRING([--with-tty-gid=GID],
 739                 [Specify the numeric GID of the 'tty' group])],
 740         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 741         [])
 742
 743 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 744 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 745 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 746 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 747 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 748 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 749 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 750 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 751 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 752 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 753 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 754 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 755 AM_CONDITIONAL(TARGET_MAGEIA, test x"$with_distro" = xmageia)
 756
 757 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 758
 759 AC_ARG_WITH([dbuspolicydir],
 760         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 761         [],
 762         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 763
 764 AC_ARG_WITH([dbussessionservicedir],
 765         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 766         [],
 767         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 768
 769 AC_ARG_WITH([dbussystemservicedir],
 770         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 771         [],
 772         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 773
 774 AC_ARG_WITH([dbusinterfacedir],
 775         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 776         [],
 777         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 778
 779 AC_ARG_WITH([rootprefix],
 780         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 781         [], [with_rootprefix=${ac_default_prefix}])
 782
 783 AC_ARG_WITH([rootlibdir],
 784         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 785         [],
 786         [with_rootlibdir=${libdir}])
 787
 788 AC_ARG_WITH([pamlibdir],
 789         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 790         [],
 791         [with_pamlibdir=${with_rootlibdir}/security])
 792
 793 AC_ARG_ENABLE([split-usr],
 794         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 795         [],
 796         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 797                 enable_split_usr=yes
 798         ], [
 799                 enable_split_usr=no
 800         ])])
 801
 802 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 803         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 804 ])
 805
 806 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 807 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 808 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 809 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 810 AC_SUBST([pamlibdir], [$with_pamlibdir])
 811 AC_SUBST([rootprefix], [$with_rootprefix])
 812 AC_SUBST([rootlibdir], [$with_rootlibdir])
 813
 814 AC_CONFIG_FILES([
 815         Makefile po/Makefile.in
 816         docs/libudev/Makefile
 817         docs/libudev/version.xml
 818         docs/gudev/Makefile
 819         docs/gudev/version.xml
 820 ])
 821
 822 AC_OUTPUT
 823 AC_MSG_RESULT([
 824         $PACKAGE_NAME $VERSION
 825
 826         Distribution:            ${with_distro}
 827         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 828         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 829         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 830         libcryptsetup:           ${have_libcryptsetup}
 831         tcpwrap:                 ${have_tcpwrap}
 832         PAM:                     ${have_pam}
 833         AUDIT:                   ${have_audit}
 834         IMA:                     ${have_ima}
 835         SELinux:                 ${have_selinux}
 836         XZ:                      ${have_xz}
 837         ACL:                     ${have_acl}
 838         XATTR:                   ${have_xattr}
 839         GCRYPT:                  ${have_gcrypt}
 840         QRENCODE:                ${have_qrencode}
 841         MICROHTTPD:              ${have_microhttpd}
 842         binfmt:                  ${have_binfmt}
 843         vconsole:                ${have_vconsole}
 844         readahead:               ${have_readahead}
 845         quotacheck:              ${have_quotacheck}
 846         randomseed:              ${have_randomseed}
 847         logind:                  ${have_logind}
 848         hostnamed:               ${have_hostnamed}
 849         timedated:               ${have_timedated}
 850         localed:                 ${have_localed}
 851         coredump:                ${have_coredump}
 852         firmware path:           ${FIRMWARE_PATH}
 853         gudev:                   ${enable_gudev}
 854         gintrospection:          ${enable_introspection}
 855         keymap:                  ${enable_keymap}
 856         Python:                  ${have_python}
 857         Python Headers:          ${have_python_devel}
 858
 859         prefix:                  ${prefix}
 860         rootprefix:              ${with_rootprefix}
 861         sysconf dir:             ${sysconfdir}
 862         datarootdir:             ${datarootdir}
 863         includedir:              ${includedir}
 864         include_prefix:          ${INCLUDE_PREFIX}
 865         lib dir:                 ${libdir}
 866         rootlib dir:             ${with_rootlibdir}
 867         PAM modules dir:         ${with_pamlibdir}
 868         D-Bus policy dir:        ${with_dbuspolicydir}
 869         D-Bus session dir:       ${with_dbussessionservicedir}
 870         D-Bus system dir:        ${with_dbussystemservicedir}
 871         D-Bus interfaces dir:    ${with_dbusinterfacedir}
 872         Split /usr:              ${enable_split_usr}
 873         man pages:               ${have_manpages}
 874         gtk-doc:                 ${enable_gtk_doc}
 875
 876         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 877         CPPLAGS:                 ${OUR_CPPFLAGS} ${CPPFLAGS}
 878         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 879         PYTHON_CFLAGS:           ${PYTHON_CFLAGS}
 880         PYTHON_LIBS:             ${PYTHON_LIBS}
 881 ])