configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [204],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT([disable-static])
  46
  47 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  48
  49 # i18n stuff for the PolicyKit policy files
  50 IT_PROG_INTLTOOL([0.40.0])
  51
  52 GETTEXT_PACKAGE=systemd
  53 AC_SUBST(GETTEXT_PACKAGE)
  54
  55 AC_PROG_MKDIR_P
  56 AC_PROG_LN_S
  57 AC_PROG_SED
  58 AC_PROG_GREP
  59 AC_PROG_AWK
  60
  61 AC_PROG_CC
  62 AC_PROG_CC_C99
  63 AM_PROG_CC_C_O
  64 AC_PROG_GCC_TRADITIONAL
  65
  66 AC_PATH_PROG([M4], [m4])
  67 AC_PATH_PROG([XSLTPROC], [xsltproc])
  68
  69 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  70 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  71
  72 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  73
  74 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  75
  76 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  77 m4_ifdef([GTK_DOC_CHECK], [
  78 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  79          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
  80           enable_gtk_doc=no])
  81
  82 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  83         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  84 ])
  85
  86 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  87 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  88 ], [
  89    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  90    enable_introspection=no])
  91
  92 AC_CHECK_TOOL(OBJCOPY, objcopy)
  93 AC_CHECK_TOOL(STRINGS, strings)
  94 AC_CHECK_TOOL(GPERF, gperf)
  95 if test -z "$GPERF" ; then
  96         AC_MSG_ERROR([*** gperf not found])
  97 fi
  98
  99 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 100         -pipe \
 101         -Wall \
 102         -Wextra \
 103         -Wno-inline \
 104         -Wundef \
 105         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 106         -Wlogical-op \
 107         -Wsign-compare \
 108         -Wmissing-include-dirs \
 109         -Wold-style-definition \
 110         -Wpointer-arith \
 111         -Winit-self \
 112         -Wdeclaration-after-statement \
 113         -Wfloat-equal \
 114         -Wmissing-prototypes \
 115         -Wstrict-prototypes \
 116         -Wredundant-decls \
 117         -Wmissing-declarations \
 118         -Wmissing-noreturn \
 119         -Wshadow \
 120         -Wendif-labels \
 121         -Wcast-align \
 122         -Wstrict-aliasing=2 \
 123         -Wwrite-strings \
 124         -Wno-long-long \
 125         -Wno-overlength-strings \
 126         -Wno-unused-parameter \
 127         -Wno-missing-field-initializers \
 128         -Wno-unused-result \
 129         -Werror=overflow \
 130         -ffast-math \
 131         -fno-common \
 132         -fdiagnostics-show-option \
 133         -fdiagnostics-color \
 134         -fno-strict-aliasing \
 135         -fvisibility=hidden \
 136         -ffunction-sections \
 137         -fdata-sections \
 138         -fstack-protector \
 139         --param=ssp-buffer-size=4])
 140 AC_SUBST([OUR_CFLAGS], $with_cflags)
 141
 142 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*], [
 143         CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 144                -Wp,-D_FORTIFY_SOURCE=2])], [
 145         python_extra_cflags=-Wp,-U_FORTIFY_SOURCE
 146         AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 147 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 148
 149 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 150         -Wl,--as-needed \
 151         -Wl,--no-undefined \
 152         -Wl,--gc-sections \
 153         -Wl,-z,relro \
 154         -Wl,-z,now])
 155 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 156
 157 # ------------------------------------------------------------------------------
 158 # we use python to build the man page index, and for systemd-python
 159 have_python=no
 160 have_python_devel=no
 161
 162 AC_ARG_WITH([python],
 163         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 164
 165 AS_IF([test "x$with_python" != "xno"], [
 166         AM_PATH_PYTHON(,, [:])
 167         AS_IF([test "$PYTHON" != :], [have_python=yes])
 168 ])
 169 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 170 AS_IF([test "x$PYTHON_BINARY" = "x"],
 171       [AS_IF([test "x$have_python" = "xyes"],
 172              [PYTHON_BINARY="$(which "$PYTHON")"],
 173              [PYTHON_BINARY=/usr/bin/python])])
 174 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 175
 176 AS_IF([test "x$with_python" != "xno"], [
 177         AC_PATH_PROG(PYTHON_CONFIG, python${PYTHON_VERSION}-config)
 178         AS_IF([test -n "$PYTHON_CONFIG"], [
 179               have_python_devel=yes
 180               PYTHON_CFLAGS="$($PYTHON_CONFIG --cflags) $python_extra_cflags"
 181               PYTHON_LIBS="$($PYTHON_CONFIG --ldflags)"
 182               AC_SUBST(PYTHON_CFLAGS)
 183               AC_SUBST(PYTHON_LIBS)
 184               AC_PATH_PROGS(SPHINX_BUILD, sphinx-build-${PYTHON_VERSION} sphinx-build)
 185         ])
 186 ])
 187 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 188
 189 # ------------------------------------------------------------------------------
 190
 191 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 192 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 193
 194 save_LIBS="$LIBS"
 195 LIBS=
 196 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 197 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 198 CAP_LIBS="$LIBS"
 199 LIBS="$save_LIBS"
 200 AC_SUBST(CAP_LIBS)
 201
 202 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 203 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 204 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 205 #include <unistd.h>
 206 #include <sys/mount.h>
 207 #include <fcntl.h>]])
 208
 209 # This makes sure pkg.m4 is available.
 210 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 211
 212 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 213
 214 # ------------------------------------------------------------------------------
 215 have_kmod=no
 216 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 217 if test "x$enable_kmod" != "xno"; then
 218         PKG_CHECK_MODULES(KMOD, [ libkmod >= 5 ],
 219                 [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available]) have_kmod=yes], have_kmod=no)
 220         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 221                 AC_MSG_ERROR([*** kmod support requested but libraries not found])
 222         fi
 223 fi
 224 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 225
 226 # ------------------------------------------------------------------------------
 227 have_blkid=no
 228 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 229 if test "x$enable_blkid" != "xno"; then
 230         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 231                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 232         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 233                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 234         fi
 235 fi
 236 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 237
 238 # ------------------------------------------------------------------------------
 239 have_ima=yes
 240 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 241                 [case "${enableval}" in
 242                         yes) have_ima=yes ;;
 243                         no) have_ima=no ;;
 244                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 245                 esac],
 246                 [have_ima=yes])
 247
 248 if test "x${have_ima}" != xno ; then
 249         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 250 fi
 251
 252 # ------------------------------------------------------------------------------
 253 have_chkconfig=yes
 254 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 255                 [case "${enableval}" in
 256                         yes) have_chkconfig=yes ;;
 257                         no) have_chkconfig=no ;;
 258                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 259                 esac],
 260                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 261                 if test -z "$CHKCONFIG"; then
 262                         have_chkconfig=no
 263                 else
 264                         have_chkconfig=yes
 265                 fi])
 266
 267 if test "x${have_chkconfig}" != xno ; then
 268         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 269 fi
 270
 271 # ------------------------------------------------------------------------------
 272 have_selinux=no
 273 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 274 if test "x$enable_selinux" != "xno"; then
 275         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 276                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 277         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 278                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 279         fi
 280 fi
 281 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 282
 283 AC_ARG_WITH(debug-shell,
 284         AS_HELP_STRING([--with-debug-shell=PATH],
 285                 [Path to debug shell binary]),
 286         [SUSHELL="$withval"],[
 287         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 288
 289 AC_SUBST(SUSHELL)
 290
 291 AC_ARG_WITH([debug-tty],
 292         AS_HELP_STRING([--with-debug-tty=PATH],
 293                 [Specify the tty device for debug shell]),
 294         [DEBUGTTY="$withval"],
 295         [DEBUGTTY=/dev/tty9])
 296
 297 AC_SUBST(DEBUGTTY)
 298
 299 # ------------------------------------------------------------------------------
 300 have_xz=no
 301 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 302 if test "x$enable_xz" != "xno"; then
 303         PKG_CHECK_MODULES(XZ, [ liblzma ],
 304                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 305         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 306                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 307         fi
 308 fi
 309 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 310
 311 # ------------------------------------------------------------------------------
 312 AC_ARG_ENABLE([tcpwrap],
 313         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 314                 [case "${enableval}" in
 315                         yes) have_tcpwrap=yes ;;
 316                         no) have_tcpwrap=no ;;
 317                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 318                 esac],
 319                 [have_tcpwrap=auto])
 320
 321 if test "x${have_tcpwrap}" != xno ; then
 322         ACX_LIBWRAP
 323         if test "x${LIBWRAP_LIBS}" = x ; then
 324                 if test "x$have_tcpwrap" = xyes ; then
 325                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 326                 fi
 327                 have_tcpwrap=no
 328         else
 329                 have_tcpwrap=yes
 330         fi
 331 else
 332         LIBWRAP_LIBS=
 333 fi
 334 AC_SUBST(LIBWRAP_LIBS)
 335
 336 # ------------------------------------------------------------------------------
 337 AC_ARG_ENABLE([pam],
 338         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 339                 [case "${enableval}" in
 340                         yes) have_pam=yes ;;
 341                         no) have_pam=no ;;
 342                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 343                 esac],
 344                 [have_pam=auto])
 345
 346 if test "x${have_pam}" != xno ; then
 347         AC_CHECK_HEADERS(
 348                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 349                 [have_pam=yes],
 350                 [if test "x$have_pam" = xyes ; then
 351                         AC_MSG_ERROR([*** PAM headers not found.])
 352                 fi])
 353
 354         AC_CHECK_LIB(
 355                 [pam],
 356                 [pam_syslog],
 357                 [have_pam=yes],
 358                 [if test "x$have_pam" = xyes ; then
 359                         AC_MSG_ERROR([*** libpam not found.])
 360                 fi])
 361
 362         if test "x$have_pam" = xyes ; then
 363                 PAM_LIBS="-lpam -lpam_misc"
 364                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 365         else
 366                 have_pam=no
 367         fi
 368 else
 369         PAM_LIBS=
 370 fi
 371 AC_SUBST(PAM_LIBS)
 372 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 373
 374 # ------------------------------------------------------------------------------
 375 AC_ARG_ENABLE([acl],
 376         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 377                 [case "${enableval}" in
 378                         yes) have_acl=yes ;;
 379                         no) have_acl=no ;;
 380                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 381                 esac],
 382                 [have_acl=auto])
 383
 384 if test "x${have_acl}" != xno ; then
 385         AC_CHECK_HEADERS(
 386                 [sys/acl.h acl/libacl.h],
 387                 [have_acl=yes],
 388                 [if test "x$have_acl" = xyes ; then
 389                         AC_MSG_ERROR([*** ACL headers not found.])
 390                 fi])
 391
 392         AC_CHECK_LIB(
 393                 [acl],
 394                 [acl_get_file],
 395                 [have_acl=yes],
 396                 [if test "x$have_acl" = xyes ; then
 397                         AC_MSG_ERROR([*** libacl not found.])
 398                 fi])
 399
 400         if test "x$have_acl" = xyes ; then
 401                 ACL_LIBS="-lacl"
 402                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 403         else
 404                 have_acl=no
 405         fi
 406 else
 407         ACL_LIBS=
 408 fi
 409 AC_SUBST(ACL_LIBS)
 410 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 411
 412 # ------------------------------------------------------------------------------
 413 AC_ARG_ENABLE([xattr],
 414         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 415                 [case "${enableval}" in
 416                         yes) have_xattr=yes ;;
 417                         no) have_xattr=no ;;
 418                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 419                 esac],
 420                 [have_xattr=auto])
 421
 422 if test "x${have_xattr}" != xno ; then
 423         AC_CHECK_HEADERS(
 424                 [attr/xattr.h],
 425                 [have_xattr=yes],
 426                 [if test "x$have_xattr" = xyes ; then
 427                         AC_MSG_ERROR([*** XATTR headers not found.])
 428                 fi])
 429
 430         AC_CHECK_LIB(
 431                 [attr],
 432                 [fsetxattr],
 433                 [have_xattr=yes],
 434                 [if test "x$have_xattr" = xyes ; then
 435                         AC_MSG_ERROR([*** libattr not found.])
 436                 fi])
 437
 438         if test "x$have_xattr" = xyes ; then
 439                 XATTR_LIBS="-lattr"
 440                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 441         else
 442                 have_xattr=no
 443         fi
 444 else
 445         XATTR_LIBS=
 446 fi
 447 AC_SUBST(XATTR_LIBS)
 448 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 449
 450 # ------------------------------------------------------------------------------
 451 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 452                 [case "${enableval}" in
 453                         yes) have_smack=yes ;;
 454                         no) have_smack=no ;;
 455                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 456                 esac],
 457                 [have_smack=auto])
 458
 459 if test "x${have_xattr}" = xno; then
 460         if test "x${have_smack}" = xyes; then
 461                 AC_MSG_ERROR(SMACK requires xattr support)
 462         else
 463                 have_smack=no
 464         fi
 465 else
 466         if test "x${have_smack}" = xauto; then
 467                 have_smack=yes
 468         fi
 469 fi
 470
 471 if test "x${have_smack}" = xyes ; then
 472         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 473 fi
 474
 475 # ------------------------------------------------------------------------------
 476 AC_ARG_ENABLE([gcrypt],
 477         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 478                 [case "${enableval}" in
 479                         yes) have_gcrypt=yes ;;
 480                         no) have_gcrypt=no ;;
 481                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 482                 esac],
 483                 [have_gcrypt=auto])
 484
 485 if test "x${have_gcrypt}" != xno ; then
 486         AM_PATH_LIBGCRYPT(
 487                 [1.4.5],
 488                 [have_gcrypt=yes],
 489                 [if test "x$have_gcrypt" = xyes ; then
 490                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 491                 fi])
 492
 493         if test "x$have_gcrypt" = xyes ; then
 494                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 495                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 496                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 497         else
 498                 have_gcrypt=no
 499         fi
 500 else
 501         GCRYPT_LIBS=
 502         GCRYPT_CFLAGS=
 503 fi
 504 AC_SUBST(GCRYPT_LIBS)
 505 AC_SUBST(GCRYPT_CFLAGS)
 506 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 507
 508 # ------------------------------------------------------------------------------
 509 AC_ARG_ENABLE([audit],
 510         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 511                 [case "${enableval}" in
 512                         yes) have_audit=yes ;;
 513                         no) have_audit=no ;;
 514                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 515                 esac],
 516                 [have_audit=auto])
 517
 518 if test "x${have_audit}" != xno ; then
 519         AC_CHECK_HEADERS(
 520                 [libaudit.h],
 521                 [have_audit=yes],
 522                 [if test "x$have_audit" = xyes ; then
 523                         AC_MSG_ERROR([*** AUDIT headers not found.])
 524                 fi])
 525
 526         AC_CHECK_LIB(
 527                 [audit],
 528                 [audit_open],
 529                 [have_audit=yes],
 530                 [if test "x$have_audit" = xyes ; then
 531                         AC_MSG_ERROR([*** libaudit not found.])
 532                 fi])
 533
 534         if test "x$have_audit" = xyes ; then
 535                 AUDIT_LIBS="-laudit"
 536                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 537         else
 538                 have_audit=no
 539         fi
 540 else
 541         AUDIT_LIBS=
 542 fi
 543 AC_SUBST(AUDIT_LIBS)
 544
 545 # ------------------------------------------------------------------------------
 546 have_libcryptsetup=no
 547 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 548 if test "x$enable_libcryptsetup" != "xno"; then
 549         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
 550                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 551         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 552                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 553         fi
 554 fi
 555 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 556
 557 # ------------------------------------------------------------------------------
 558 have_qrencode=no
 559 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 560 if test "x$enable_qrencode" != "xno"; then
 561         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 562                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 563         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 564                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 565         fi
 566 fi
 567 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 568
 569 # ------------------------------------------------------------------------------
 570 have_microhttpd=no
 571 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 572 if test "x$enable_microhttpd" != "xno"; then
 573         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 574                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 575         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 576                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 577         fi
 578 fi
 579 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 580
 581 # ------------------------------------------------------------------------------
 582 have_binfmt=no
 583 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 584 if test "x$enable_binfmt" != "xno"; then
 585         have_binfmt=yes
 586 fi
 587 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 588
 589 # ------------------------------------------------------------------------------
 590 have_vconsole=no
 591 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 592 if test "x$enable_vconsole" != "xno"; then
 593         have_vconsole=yes
 594 fi
 595 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 596
 597 # ------------------------------------------------------------------------------
 598 have_readahead=no
 599 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 600 if test "x$enable_readahead" != "xno"; then
 601         have_readahead=yes
 602 fi
 603 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 604
 605 # ------------------------------------------------------------------------------
 606 have_bootchart=no
 607 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 608 if test "x$enable_bootchart" != "xno"; then
 609         have_bootchart=yes
 610 fi
 611 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 612
 613 # ------------------------------------------------------------------------------
 614 have_quotacheck=no
 615 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 616 if test "x$enable_quotacheck" != "xno"; then
 617         have_quotacheck=yes
 618 fi
 619 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 620
 621 # ------------------------------------------------------------------------------
 622 have_tmpfiles=no
 623 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 624 if test "x$enable_tmpfiles" != "xno"; then
 625         have_tmpfiles=yes
 626 fi
 627 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 628
 629 # ------------------------------------------------------------------------------
 630 have_randomseed=no
 631 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 632 if test "x$enable_randomseed" != "xno"; then
 633         have_randomseed=yes
 634 fi
 635 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 636
 637 # ------------------------------------------------------------------------------
 638 have_logind=no
 639 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 640 if test "x$enable_logind" != "xno"; then
 641         have_logind=yes
 642 fi
 643 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 644 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 645
 646 # ------------------------------------------------------------------------------
 647 have_hostnamed=no
 648 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 649 if test "x$enable_hostnamed" != "xno"; then
 650         have_hostnamed=yes
 651 fi
 652 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 653
 654 # ------------------------------------------------------------------------------
 655 have_timedated=no
 656 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 657 if test "x$enable_timedated" != "xno"; then
 658         have_timedated=yes
 659 fi
 660 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 661
 662 # ------------------------------------------------------------------------------
 663 have_localed=no
 664 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 665 if test "x$enable_localed" != "xno"; then
 666         have_localed=yes
 667 fi
 668 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 669
 670 # ------------------------------------------------------------------------------
 671 have_coredump=no
 672 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 673 if test "x$enable_coredump" != "xno"; then
 674         have_coredump=yes
 675 fi
 676 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 677
 678 # ------------------------------------------------------------------------------
 679 have_polkit=no
 680 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 681 if test "x$enable_polkit" != "xno"; then
 682         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 683         have_polkit=yes
 684 fi
 685 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 686
 687 # ------------------------------------------------------------------------------
 688 have_efi=no
 689 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 690 if test "x$enable_efi" != "xno"; then
 691         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 692         have_efi=yes
 693 fi
 694 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 695
 696 # ------------------------------------------------------------------------------
 697 AC_ARG_WITH(rc-local-script-path-start,
 698         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 699                 [Path to /etc/rc.local]),
 700         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 701         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 702
 703 AC_ARG_WITH(rc-local-script-path-stop,
 704         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 705                 [Path to /usr/sbin/halt.local]),
 706         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 707         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 708
 709 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 710 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 711
 712 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 713 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 714
 715 # ------------------------------------------------------------------------------
 716 AC_ARG_WITH(kbd-loadkeys,
 717         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 718                 [Path to loadkeys]),
 719         [KBD_LOADKEYS="$withval"],
 720         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 721
 722 AC_ARG_WITH(kbd-setfont,
 723         AS_HELP_STRING([--with-kbd-setfont=PATH],
 724                 [Path to setfont]),
 725         [KBD_SETFONT="$withval"],
 726         [KBD_SETFONT="/usr/bin/setfont"])
 727
 728 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 729 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 730
 731 AC_SUBST(KBD_LOADKEYS)
 732 AC_SUBST(KBD_SETFONT)
 733
 734 AC_ARG_WITH(telinit,
 735         AS_HELP_STRING([--with-telinit=PATH],
 736                 [Path to telinit]),
 737         [TELINIT="$withval"],
 738         [TELINIT="/lib/upstart/telinit"])
 739
 740 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 741
 742 AC_SUBST(TELINIT)
 743
 744 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 745
 746 # ------------------------------------------------------------------------------
 747 have_myhostname=no
 748 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 749 if test "x$enable_myhostname" != "xno"; then
 750         AC_HEADER_STDC
 751         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h])
 752
 753         AC_C_CONST
 754         AC_TYPE_SIZE_T
 755         AC_HEADER_TIME
 756
 757         AC_FUNC_MALLOC
 758         AC_FUNC_SELECT_ARGTYPES
 759         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 760
 761         have_myhostname=yes
 762 fi
 763 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 764
 765 # ------------------------------------------------------------------------------
 766 AC_ARG_WITH(firmware-path,
 767        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 768           [Firmware search path (default="")]),
 769        [], [with_firmware_path=""])
 770 OLD_IFS=$IFS
 771 IFS=:
 772 for i in $with_firmware_path; do
 773        if test "x${FIRMWARE_PATH}" = "x"; then
 774               FIRMWARE_PATH="\\\"${i}/\\\""
 775        else
 776               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 777        fi
 778 done
 779 IFS=$OLD_IFS
 780 AC_SUBST(FIRMWARE_PATH)
 781 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
 782 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
 783
 784 # ------------------------------------------------------------------------------
 785 AC_ARG_ENABLE([gudev],
 786        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 787        [], [enable_gudev=yes])
 788 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 789 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 790 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 791
 792 # ------------------------------------------------------------------------------
 793 AC_ARG_ENABLE([keymap],
 794        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 795        [], [enable_keymap=yes])
 796 AS_IF([test "x$enable_keymap" = "xyes"], [
 797        AC_PATH_PROG([GPERF], [gperf])
 798        if test -z "$GPERF"; then
 799               AC_MSG_ERROR([gperf is needed])
 800        fi
 801
 802        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 803        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 804 ])
 805 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 806
 807 # ------------------------------------------------------------------------------
 808 have_manpages=no
 809 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 810 AS_IF([test "x$enable_manpages" != xno], [
 811         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 812                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 813         ])
 814         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 815 ])
 816 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 817
 818 # ------------------------------------------------------------------------------
 819
 820 # Location of the init scripts as mandated by LSB
 821 SYSTEM_SYSVINIT_PATH=/etc/init.d
 822 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 823 M4_DEFINES=
 824
 825 AC_ARG_WITH([sysvinit-path],
 826         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 827                 [Specify the path to where the SysV init scripts are located])],
 828         [SYSTEM_SYSVINIT_PATH="$withval"],
 829         [])
 830
 831 AC_ARG_WITH([sysvrcnd-path],
 832         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 833                 [Specify the path to the base directory for the SysV rcN.d directories])],
 834         [SYSTEM_SYSVRCND_PATH="$withval"],
 835         [])
 836
 837 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 838         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 839         SYSTEM_SYSV_COMPAT="yes"
 840         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 841 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 842         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 843 else
 844         SYSTEM_SYSV_COMPAT="no"
 845 fi
 846
 847 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 848 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 849 AC_SUBST(M4_DEFINES)
 850
 851 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 852
 853 AC_ARG_WITH([tty-gid],
 854         [AS_HELP_STRING([--with-tty-gid=GID],
 855                 [Specify the numeric GID of the 'tty' group])],
 856         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 857         [])
 858
 859 AC_ARG_WITH([dbuspolicydir],
 860         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 861         [],
 862         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
 863
 864 AC_ARG_WITH([dbussessionservicedir],
 865         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 866         [],
 867         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
 868
 869 AC_ARG_WITH([dbussystemservicedir],
 870         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 871         [],
 872         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
 873
 874 AC_ARG_WITH([dbusinterfacedir],
 875         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 876         [],
 877         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
 878
 879 AC_ARG_WITH([bashcompletiondir],
 880         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 881         [],
 882         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 883                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 884         ] , [
 885                 with_bashcompletiondir=${datadir}/bash-completion/completions
 886         ])])
 887
 888 AC_ARG_WITH([rootprefix],
 889         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 890         [], [with_rootprefix=${ac_default_prefix}])
 891
 892 AC_ARG_WITH([rootlibdir],
 893         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 894         [],
 895         [with_rootlibdir=${libdir}])
 896
 897 AC_ARG_WITH([pamlibdir],
 898         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 899         [],
 900         [with_pamlibdir=${with_rootlibdir}/security])
 901
 902 AC_ARG_ENABLE([split-usr],
 903         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 904         [],
 905         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 906                 enable_split_usr=yes
 907         ], [
 908                 enable_split_usr=no
 909         ])])
 910
 911 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 912         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 913 ])
 914
 915 # Work around intltoolize and gtk-doc problems in VPATH builds
 916 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 917                                        [Define to do gtk-doc tests])
 918 AS_IF([test "x$0" != "x./configure"], [
 919         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 920 ])
 921
 922 AC_ARG_ENABLE(tests,
 923        [AC_HELP_STRING([--disable-tests], [disable tests])],
 924        enable_tests=$enableval, enable_tests=yes)
 925 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 926
 927 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 928 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 929 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 930 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 931 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 932 AC_SUBST([pamlibdir], [$with_pamlibdir])
 933 AC_SUBST([rootprefix], [$with_rootprefix])
 934 AC_SUBST([rootlibdir], [$with_rootlibdir])
 935
 936 AC_CONFIG_FILES([
 937         Makefile po/Makefile.in
 938         docs/libudev/Makefile
 939         docs/libudev/version.xml
 940         docs/gudev/Makefile
 941         docs/gudev/version.xml
 942 ])
 943
 944 AC_OUTPUT
 945 AC_MSG_RESULT([
 946         $PACKAGE_NAME $VERSION
 947
 948         libcryptsetup:           ${have_libcryptsetup}
 949         tcpwrap:                 ${have_tcpwrap}
 950         PAM:                     ${have_pam}
 951         AUDIT:                   ${have_audit}
 952         IMA:                     ${have_ima}
 953         SELinux:                 ${have_selinux}
 954         SMACK:                   ${have_smack}
 955         XZ:                      ${have_xz}
 956         ACL:                     ${have_acl}
 957         XATTR:                   ${have_xattr}
 958         GCRYPT:                  ${have_gcrypt}
 959         QRENCODE:                ${have_qrencode}
 960         MICROHTTPD:              ${have_microhttpd}
 961         CHKCONFIG:               ${have_chkconfig}
 962         binfmt:                  ${have_binfmt}
 963         vconsole:                ${have_vconsole}
 964         readahead:               ${have_readahead}
 965         bootchart:               ${have_bootchart}
 966         quotacheck:              ${have_quotacheck}
 967         tmpfiles:                ${have_tmpfiles}
 968         randomseed:              ${have_randomseed}
 969         logind:                  ${have_logind}
 970         hostnamed:               ${have_hostnamed}
 971         timedated:               ${have_timedated}
 972         localed:                 ${have_localed}
 973         coredump:                ${have_coredump}
 974         polkit:                  ${have_polkit}
 975         efi:                     ${have_efi}
 976         kmod:                    ${have_kmod}
 977         blkid:                   ${have_blkid}
 978         nss-myhostname:          ${have_myhostname}
 979         gudev:                   ${enable_gudev}
 980         gintrospection:          ${enable_introspection}
 981         keymap:                  ${enable_keymap}
 982         Python:                  ${have_python}
 983         Python Headers:          ${have_python_devel}
 984         man pages:               ${have_manpages}
 985         gtk-doc:                 ${enable_gtk_doc}
 986         Split /usr:              ${enable_split_usr}
 987         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 988
 989         prefix:                  ${prefix}
 990         rootprefix:              ${with_rootprefix}
 991         sysconf dir:             ${sysconfdir}
 992         datarootdir:             ${datarootdir}
 993         includedir:              ${includedir}
 994         include_prefix:          ${INCLUDE_PREFIX}
 995         lib dir:                 ${libdir}
 996         rootlib dir:             ${with_rootlibdir}
 997         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 998         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 999         Build Python:            ${PYTHON}
1000         Installation Python:     ${PYTHON_BINARY}
1001         firmware path:           ${FIRMWARE_PATH}
1002         PAM modules dir:         ${with_pamlibdir}
1003         D-Bus policy dir:        ${with_dbuspolicydir}
1004         D-Bus session dir:       ${with_dbussessionservicedir}
1005         D-Bus system dir:        ${with_dbussystemservicedir}
1006         D-Bus interfaces dir:    ${with_dbusinterfacedir}
1007         Bash completions dir:    ${with_bashcompletiondir}
1008         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1009         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1010         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1011
1012         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1013         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1014         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1015         PYTHON_CFLAGS:           ${PYTHON_CFLAGS}
1016         PYTHON_LIBS:             ${PYTHON_LIBS}
1017 ])