configure.ac

   1 AC_INIT([udev],
   2         [143],
   3         [linux-hotplug@vger.kernel.org])
   4 AC_PREREQ(2.60)
   5 AM_INIT_AUTOMAKE([check-news foreign 1.9 dist-bzip2])
   6 AC_DISABLE_STATIC
   7 AC_USE_SYSTEM_EXTENSIONS
   8 dnl AM_SILENT_RULES
   9 AC_SYS_LARGEFILE
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AC_PROG_LIBTOOL
  12 GTK_DOC_CHECK(1.10)
  13
  14 dnl /* prefix is /usr, exec_prefix is /, if overridden exec_prefix follows prefix */
  15 AC_PREFIX_DEFAULT([/usr])
  16 test "$prefix" = NONE && test "$exec_prefix" = NONE && exec_prefix=
  17
  18 AC_PATH_PROG([XSLTPROC], [xsltproc])
  19
  20 AC_ARG_WITH(udev-prefix,
  21         AS_HELP_STRING([--with-udev-prefix=DIR], [add prefix to internal udev path names]),
  22         [], [with_udev_prefix='${exec_prefix}'])
  23 udev_prefix=$with_udev_prefix
  24 AC_SUBST(udev_prefix)
  25
  26 AC_ARG_WITH(libdir-name,
  27         AS_HELP_STRING([--with-libdir-name=DIR], [name of the arch lib directory]),
  28         [], [with_libdir_name=lib])
  29 libdir_name=$with_libdir_name
  30 AC_SUBST(libdir_name)
  31
  32 AC_ARG_WITH(selinux,
  33         AS_HELP_STRING([--with-selinux], [enable SELinux support]),
  34         [], with_selinux=no)
  35 if test "x$with_selinux" = xyes; then
  36         LIBS_save=$LIBS
  37         AC_CHECK_LIB(selinux, getprevcon,
  38                 [],
  39                 AC_MSG_ERROR([SELinux selected but libselinux not found]))
  40         LIBS=$LIBS_save
  41         SELINUX_LIBS="-lselinux -lsepol"
  42         AC_DEFINE(WITH_SELINUX, [1] ,[SELinux support.])
  43 fi
  44 AC_SUBST([SELINUX_LIBS])
  45 AM_CONDITIONAL(WITH_SELINUX, [test "x$with_selinux" = xyes])
  46
  47 AC_ARG_ENABLE(debug,
  48         AS_HELP_STRING([--enable-debug], [enable debug messages]),
  49         [], enable_debug=no)
  50 if test "x$enable_debug" = "xyes"; then
  51         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  52 fi
  53
  54 AC_ARG_ENABLE(logging,
  55         AS_HELP_STRING([--disable-logging], [disable system logging]),
  56         [], enable_logging=yes)
  57 if test "x$enable_logging" = "xyes"; then
  58         AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
  59 fi
  60
  61 AC_ARG_ENABLE([extras],
  62         AS_HELP_STRING([--enable-extras], [enable extras with external dependencies]),
  63         [], [enable_extras=no])
  64 if test "x$enable_extras" = xyes; then
  65         PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.7.0 gobject-2.0 >= 2.7.0])
  66         AC_SUBST([GLIB_CFLAGS])
  67         AC_SUBST([GLIB_LIBS])
  68 fi
  69 AM_CONDITIONAL([ENABLE_EXTRAS], [test "x$enable_extras" = xyes])
  70
  71 AC_CONFIG_HEADERS(config.h)
  72 AC_CONFIG_FILES([
  73         Makefile
  74         libudev/Makefile
  75         libudev/libudev.pc
  76         libudev/docs/Makefile
  77         libudev/docs/version.xml
  78         udev/Makefile
  79         rules/Makefile
  80         extras/Makefile
  81         extras/ata_id/Makefile
  82         extras/cdrom_id/Makefile
  83         extras/edd_id/Makefile
  84         extras/path_id/Makefile
  85         extras/firmware/Makefile
  86         extras/collect/Makefile
  87         extras/floppy/Makefile
  88         extras/fstab_import/Makefile
  89         extras/rule_generator/Makefile
  90         extras/scsi_id/Makefile
  91         extras/usb_id/Makefile
  92         extras/udev-acl/Makefile
  93 ])
  94
  95 AC_OUTPUT
  96 AC_MSG_RESULT([
  97         udev $VERSION
  98         ========
  99
 100         prefix:                 ${prefix}
 101         exec_prefix:            ${exec_prefix}
 102         udev_prefix:            ${udev_prefix}
 103         libdir_name:            ${libdir_name}
 104         datarootdir:            ${datarootdir}
 105         mandir:                 ${mandir}
 106         includedir:             ${includedir}
 107
 108         logging:                ${enable_logging}
 109         debug:                  ${enable_debug}
 110         selinux:                ${with_selinux}
 111
 112         compiler:               ${CC}
 113         cflags:                 ${CFLAGS}
 114         ldflags:                ${LDFLAGS}
 115
 116         extras:                 ${enable_extras}
 117
 118         xsltproc:               ${XSLTPROC}
 119 ])