configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010-2012 Lennart Poettering
   4 #  Copyright 2010-2012 Kay Sievers
   5 #
   6 #  systemd is free software; you can redistribute it and/or modify it
   7 #  under the terms of the GNU Lesser General Public License as published by
   8 #  the Free Software Foundation; either version 2.1 of the License, or
   9 #  (at your option) any later version.
  10 #
  11 #  systemd is distributed in the hope that it will be useful, but
  12 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  13 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  14 #  Lesser General Public License for more details.
  15 #
  16 #  You should have received a copy of the GNU Lesser General Public License
  17 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_PREREQ([2.64])
  20
  21 AC_INIT([systemd],
  22         [182],
  23         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  24         [systemd],
  25         [http://www.freedesktop.org/wiki/Software/systemd])
  26
  27 AC_CONFIG_SRCDIR([src/core/main.c])
  28 AC_CONFIG_MACRO_DIR([m4])
  29 AC_CONFIG_HEADERS([config.h])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 AC_SYS_LARGEFILE
  34 AC_PREFIX_DEFAULT([/usr])
  35 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  36 AM_SILENT_RULES([yes])
  37 AC_CANONICAL_HOST
  38 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  39 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  40        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  41       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  42
  43 LT_PREREQ(2.2)
  44 LT_INIT
  45
  46 # i18n stuff for the PolicyKit policy files
  47 IT_PROG_INTLTOOL([0.40.0])
  48
  49 GETTEXT_PACKAGE=systemd
  50 AC_SUBST(GETTEXT_PACKAGE)
  51
  52 AC_PROG_MKDIR_P
  53 AC_PROG_LN_S
  54 AC_PROG_SED
  55 AC_PROG_GREP
  56 AC_PROG_AWK
  57
  58 AC_PROG_CC
  59 AC_PROG_CC_C99
  60 AM_PROG_CC_C_O
  61 AC_PROG_GCC_TRADITIONAL
  62
  63 AC_PATH_PROG([M4], [m4])
  64
  65 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
  66 # it on it's own line.
  67 m4_ifdef([GTK_DOC_CHECK], [
  68 GTK_DOC_CHECK([1.18])
  69 ],[
  70 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
  71 ])
  72
  73
  74 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  75
  76 AC_CHECK_TOOL(OBJCOPY, objcopy)
  77 AC_CHECK_TOOL(STRINGS, strings)
  78 AC_CHECK_TOOL(GPERF, gperf)
  79 if test -z "$GPERF" ; then
  80         AC_MSG_ERROR([*** gperf not found])
  81 fi
  82
  83 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
  84         -pipe \
  85         -Wall \
  86         -W \
  87         -Wextra \
  88         -Wno-inline \
  89         -Wvla \
  90         -Wundef \
  91         -Wformat=2 \
  92         -Wlogical-op \
  93         -Wsign-compare \
  94         -Wformat-security \
  95         -Wmissing-include-dirs \
  96         -Wformat-nonliteral \
  97         -Wold-style-definition \
  98         -Wpointer-arith \
  99         -Winit-self \
 100         -Wdeclaration-after-statement \
 101         -Wfloat-equal \
 102         -Wmissing-prototypes \
 103         -Wstrict-prototypes \
 104         -Wredundant-decls \
 105         -Wmissing-declarations \
 106         -Wmissing-noreturn \
 107         -Wshadow \
 108         -Wendif-labels \
 109         -Wcast-align \
 110         -Wstrict-aliasing=2 \
 111         -Wwrite-strings \
 112         -Wno-long-long \
 113         -Wno-overlength-strings \
 114         -Wno-unused-parameter \
 115         -Wno-missing-field-initializers \
 116         -Wno-unused-result \
 117         -Werror=overflow \
 118         -Wp,-D_FORTIFY_SOURCE=2 \
 119         -ffast-math \
 120         -fno-common \
 121         -fdiagnostics-show-option \
 122         -fno-strict-aliasing \
 123         -fvisibility=hidden \
 124         -ffunction-sections \
 125         -fdata-sections])
 126 AC_SUBST([WARNINGFLAGS], $with_cflags)
 127
 128 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 129         -Wl,--as-needed \
 130         -Wl,--gc-sections])
 131 AC_SUBST([GCLDFLAGS], $with_ldflags)
 132
 133 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 134 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 135
 136 save_LIBS="$LIBS"
 137 LIBS=
 138 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 139 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 140 CAP_LIBS="$LIBS"
 141 LIBS="$save_LIBS"
 142 AC_SUBST(CAP_LIBS)
 143
 144 # This makes sure pkg.m4 is available.
 145 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 146
 147 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 148 PKG_CHECK_MODULES(KMOD, [libkmod >= 5])
 149 PKG_CHECK_MODULES(BLKID,[blkid >= 2.20])
 150
 151 # ------------------------------------------------------------------------------
 152 have_ima=yes
 153 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 154                 [case "${enableval}" in
 155                         yes) have_ima=yes ;;
 156                         no) have_ima=no ;;
 157                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 158                 esac],
 159                 [have_ima=yes])
 160
 161 if test "x${have_ima}" != xno ; then
 162         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 163 fi
 164
 165 # ------------------------------------------------------------------------------
 166 have_selinux=no
 167 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 168 if test "x$enable_selinux" != "xno"; then
 169         PKG_CHECK_MODULES(SELINUX, [ libselinux ],
 170                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 171         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 172                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 173         fi
 174 fi
 175 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 176
 177 # ------------------------------------------------------------------------------
 178 have_xz=no
 179 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 180 if test "x$enable_xz" != "xno"; then
 181         PKG_CHECK_MODULES(XZ, [ liblzma ],
 182                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 183         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 184                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 185         fi
 186 fi
 187 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 188
 189 # ------------------------------------------------------------------------------
 190 AC_ARG_ENABLE([tcpwrap],
 191         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 192                 [case "${enableval}" in
 193                         yes) have_tcpwrap=yes ;;
 194                         no) have_tcpwrap=no ;;
 195                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 196                 esac],
 197                 [have_tcpwrap=auto])
 198
 199 if test "x${have_tcpwrap}" != xno ; then
 200         ACX_LIBWRAP
 201         if test "x${LIBWRAP_LIBS}" = x ; then
 202                 if test "x$have_tcpwrap" = xyes ; then
 203                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 204                 fi
 205                 have_tcpwrap=no
 206         else
 207                 have_tcpwrap=yes
 208         fi
 209 else
 210         LIBWRAP_LIBS=
 211 fi
 212 AC_SUBST(LIBWRAP_LIBS)
 213
 214 # ------------------------------------------------------------------------------
 215 AC_ARG_ENABLE([pam],
 216         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 217                 [case "${enableval}" in
 218                         yes) have_pam=yes ;;
 219                         no) have_pam=no ;;
 220                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 221                 esac],
 222                 [have_pam=auto])
 223
 224 if test "x${have_pam}" != xno ; then
 225         AC_CHECK_HEADERS(
 226                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 227                 [have_pam=yes],
 228                 [if test "x$have_pam" = xyes ; then
 229                         AC_MSG_ERROR([*** PAM headers not found.])
 230                 fi])
 231
 232         AC_CHECK_LIB(
 233                 [pam],
 234                 [pam_syslog],
 235                 [have_pam=yes],
 236                 [if test "x$have_pam" = xyes ; then
 237                         AC_MSG_ERROR([*** libpam not found.])
 238                 fi])
 239
 240         if test "x$have_pam" = xyes ; then
 241                 PAM_LIBS="-lpam -lpam_misc"
 242                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 243         else
 244                 have_pam=no
 245         fi
 246 else
 247         PAM_LIBS=
 248 fi
 249 AC_SUBST(PAM_LIBS)
 250 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 251
 252 # ------------------------------------------------------------------------------
 253 AC_ARG_ENABLE([acl],
 254         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 255                 [case "${enableval}" in
 256                         yes) have_acl=yes ;;
 257                         no) have_acl=no ;;
 258                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 259                 esac],
 260                 [have_acl=auto])
 261
 262 if test "x${have_acl}" != xno ; then
 263         AC_CHECK_HEADERS(
 264                 [sys/acl.h acl/libacl.h],
 265                 [have_acl=yes],
 266                 [if test "x$have_acl" = xyes ; then
 267                         AC_MSG_ERROR([*** ACL headers not found.])
 268                 fi])
 269
 270         AC_CHECK_LIB(
 271                 [acl],
 272                 [acl_get_file],
 273                 [have_acl=yes],
 274                 [if test "x$have_acl" = xyes ; then
 275                         AC_MSG_ERROR([*** libacl not found.])
 276                 fi])
 277
 278         if test "x$have_acl" = xyes ; then
 279                 ACL_LIBS="-lacl"
 280                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 281         else
 282                 have_acl=no
 283         fi
 284 else
 285         ACL_LIBS=
 286 fi
 287 AC_SUBST(ACL_LIBS)
 288 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 289
 290 # ------------------------------------------------------------------------------
 291 AC_ARG_ENABLE([audit],
 292         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 293                 [case "${enableval}" in
 294                         yes) have_audit=yes ;;
 295                         no) have_audit=no ;;
 296                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 297                 esac],
 298                 [have_audit=auto])
 299
 300 if test "x${have_audit}" != xno ; then
 301         AC_CHECK_HEADERS(
 302                 [libaudit.h],
 303                 [have_audit=yes],
 304                 [if test "x$have_audit" = xyes ; then
 305                         AC_MSG_ERROR([*** AUDIT headers not found.])
 306                 fi])
 307
 308         AC_CHECK_LIB(
 309                 [audit],
 310                 [audit_open],
 311                 [have_audit=yes],
 312                 [if test "x$have_audit" = xyes ; then
 313                         AC_MSG_ERROR([*** libaudit not found.])
 314                 fi])
 315
 316         if test "x$have_audit" = xyes ; then
 317                 AUDIT_LIBS="-laudit"
 318                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 319         else
 320                 have_audit=no
 321         fi
 322 else
 323         AUDIT_LIBS=
 324 fi
 325 AC_SUBST(AUDIT_LIBS)
 326
 327 # ------------------------------------------------------------------------------
 328 have_libcryptsetup=no
 329 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 330 if test "x$enable_libcryptsetup" != "xno"; then
 331         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup ],
 332                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 333         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 334                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 335         fi
 336 fi
 337 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 338
 339 # ------------------------------------------------------------------------------
 340 have_binfmt=no
 341 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 342 if test "x$enable_binfmt" != "xno"; then
 343         have_binfmt=yes
 344 fi
 345 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 346
 347 # ------------------------------------------------------------------------------
 348 have_vconsole=no
 349 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 350 if test "x$enable_vconsole" != "xno"; then
 351         have_vconsole=yes
 352 fi
 353 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 354
 355 # ------------------------------------------------------------------------------
 356 have_readahead=no
 357 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 358 if test "x$enable_readahead" != "xno"; then
 359         have_readahead=yes
 360 fi
 361 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 362
 363 # ------------------------------------------------------------------------------
 364 have_quotacheck=no
 365 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 366 if test "x$enable_quotacheck" != "xno"; then
 367         have_quotacheck=yes
 368 fi
 369 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 370
 371 # ------------------------------------------------------------------------------
 372 have_randomseed=no
 373 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 374 if test "x$enable_randomseed" != "xno"; then
 375         have_randomseed=yes
 376 fi
 377 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 378
 379 # ------------------------------------------------------------------------------
 380 have_logind=no
 381 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 382 if test "x$enable_logind" != "xno"; then
 383         have_logind=yes
 384 fi
 385 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 386 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 387
 388 # ------------------------------------------------------------------------------
 389 have_hostnamed=no
 390 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 391 if test "x$enable_hostnamed" != "xno"; then
 392         have_hostnamed=yes
 393 fi
 394 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 395
 396 # ------------------------------------------------------------------------------
 397 have_timedated=no
 398 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 399 if test "x$enable_timedated" != "xno"; then
 400         have_timedated=yes
 401 fi
 402 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 403
 404 # ------------------------------------------------------------------------------
 405 have_localed=no
 406 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 407 if test "x$enable_localed" != "xno"; then
 408         have_localed=yes
 409 fi
 410 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 411
 412 # ------------------------------------------------------------------------------
 413 have_coredump=no
 414 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 415 if test "x$enable_coredump" != "xno"; then
 416         have_coredump=yes
 417 fi
 418 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 419
 420 # ------------------------------------------------------------------------------
 421 if test "x$cross_compiling" = "xno" ; then
 422        AC_CHECK_FILES([/usr/share/pci.ids], [pciids=/usr/share/pci.ids])
 423        AC_CHECK_FILES([/usr/share/hwdata/pci.ids], [pciids=/usr/share/hwdata/pci.ids])
 424        AC_CHECK_FILES([/usr/share/misc/pci.ids], [pciids=/usr/share/misc/pci.ids])
 425 fi
 426
 427 AC_ARG_WITH(usb-ids-path,
 428        [AS_HELP_STRING([--with-usb-ids-path=DIR], [Path to usb.ids file])],
 429        [USB_DATABASE=${withval}],
 430        [if test -n "$usbids" ; then
 431               USB_DATABASE="$usbids"
 432        else
 433               PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
 434               AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])
 435        fi])
 436 AC_MSG_CHECKING([for USB database location])
 437 AC_MSG_RESULT([$USB_DATABASE])
 438 AC_SUBST(USB_DATABASE)
 439
 440 AC_ARG_WITH(pci-ids-path,
 441        [AS_HELP_STRING([--with-pci-ids-path=DIR], [Path to pci.ids file])],
 442        [PCI_DATABASE=${withval}],
 443        [if test -n "$pciids" ; then
 444               PCI_DATABASE="$pciids"
 445        else
 446               AC_MSG_ERROR([pci.ids not found, try --with-pci-ids-path=])
 447        fi])
 448 AC_MSG_CHECKING([for PCI database location])
 449 AC_MSG_RESULT([$PCI_DATABASE])
 450 AC_SUBST(PCI_DATABASE)
 451
 452 # ------------------------------------------------------------------------------
 453 AC_ARG_WITH(firmware-path,
 454        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 455           [Firmware search path (default=ROOTPREFIX/lib/firmware/updates:ROOTPREFIX/lib/firmware)]),
 456        [], [with_firmware_path="$rootprefix/lib/firmware/updates:$rootprefix/lib/firmware"])
 457 OLD_IFS=$IFS
 458 IFS=:
 459 for i in $with_firmware_path; do
 460        if test "x${FIRMWARE_PATH}" = "x"; then
 461               FIRMWARE_PATH="\\\"${i}/\\\""
 462        else
 463               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 464        fi
 465 done
 466 IFS=$OLD_IFS
 467 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
 468
 469 # ------------------------------------------------------------------------------
 470 AC_ARG_ENABLE([gudev],
 471        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 472        [], [enable_gudev=yes])
 473 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0]) ])
 474 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 475
 476 # ------------------------------------------------------------------------------
 477 AC_ARG_ENABLE([keymap],
 478        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 479        [], [enable_keymap=yes])
 480 AS_IF([test "x$enable_keymap" = "xyes"], [
 481        AC_PATH_PROG([GPERF], [gperf])
 482        if test -z "$GPERF"; then
 483               AC_MSG_ERROR([gperf is needed])
 484        fi
 485
 486        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 487        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 488 ])
 489 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 490
 491 # ------------------------------------------------------------------------------
 492 have_manpages=no
 493 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 494 if test "x$enable_manpages" != "xno"; then
 495         have_manpages=yes
 496 fi
 497 AM_CONDITIONAL(ENABLE_MANPAGES, [test "$have_manpages" = "yes"])
 498
 499 # ------------------------------------------------------------------------------
 500 AC_PATH_PROG([XSLTPROC], [xsltproc])
 501 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 502
 503 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux, mandriva, meego, mageia, angstrom or other]))
 504 if test "z$with_distro" = "z"; then
 505         if test "$cross_compiling" = yes; then
 506                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 507         else
 508                 with_distro=$($GREP '^ID=' /etc/os-release | $SED 's/ID=//');
 509         fi
 510         if test "z$with_distro" = "z"; then
 511                 with_distro=other
 512         fi
 513 fi
 514 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 515 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 516
 517 # Location of the init scripts as mandated by LSB
 518 SYSTEM_SYSVINIT_PATH=/etc/init.d
 519 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 520
 521 M4_DEFINES=
 522 have_plymouth=no
 523
 524 case $with_distro in
 525         fedora)
 526                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 527                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 528                 M4_DEFINES=-DTARGET_FEDORA=1
 529                 have_plymouth=yes
 530                 ;;
 531         opensuse|suse)
 532                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 533                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 534                 M4_DEFINES=-DTARGET_SUSE=1
 535                 have_plymouth=yes
 536                 ;;
 537         debian)
 538                 SYSTEM_SYSVRCND_PATH=/etc
 539                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 540                 M4_DEFINES=-DTARGET_DEBIAN=1
 541                 ;;
 542         ubuntu)
 543                 SYSTEM_SYSVRCND_PATH=/etc
 544                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 545                 M4_DEFINES=-DTARGET_UBUNTU=1
 546                 ;;
 547         arch)
 548                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 549                 SYSTEM_SYSVRCND_PATH=/etc
 550                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 551                 M4_DEFINES=-DTARGET_ARCH=1
 552                 ;;
 553         gentoo)
 554                 SYSTEM_SYSVINIT_PATH=
 555                 SYSTEM_SYSVRCND_PATH=
 556                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 557                 M4_DEFINES=-DTARGET_GENTOO=1
 558                 ;;
 559         slackware)
 560                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 561                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 562                 M4_DEFINES=-DTARGET_SLACKWARE=1
 563                 ;;
 564         frugalware)
 565                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 566                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 567                 M4_DEFINES=-DTARGET_FRUGALWARE=1
 568                 have_plymouth=yes
 569                 ;;
 570         altlinux)
 571                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 572                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 573                 M4_DEFINES=-DTARGET_ALTLINUX=1
 574                 have_plymouth=yes
 575                 ;;
 576         mandriva)
 577                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 578                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 579                 M4_DEFINES=-DTARGET_MANDRIVA=1
 580                 have_plymouth=yes
 581                 ;;
 582         meego)
 583                 SYSTEM_SYSVINIT_PATH=
 584                 SYSTEM_SYSVRCND_PATH=
 585                 AC_DEFINE(TARGET_MEEGO, [], [Target is MeeGo])
 586                 M4_DEFINES=-DTARGET_MEEGO=1
 587                 ;;
 588         angstrom)
 589                 SYSTEM_SYSVRCND_PATH=/etc
 590                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 591                 M4_DEFINES=-DTARGET_ANGSTROM=1
 592                 ;;
 593         mageia)
 594                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 595                 AC_DEFINE(TARGET_MAGEIA, [], [Target is Mageia])
 596                 M4_DISTRO_FLAG=-DTARGET_MAGEIA=1
 597                 have_plymouth=yes
 598                 ;;
 599         other)
 600                 ;;
 601         *)
 602                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 603                 ;;
 604 esac
 605
 606 AC_ARG_WITH([sysvinit-path],
 607         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 608                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 609         [SYSTEM_SYSVINIT_PATH="$withval"],
 610         [])
 611
 612 AC_ARG_WITH([sysvrcd-path],
 613         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 614                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 615         [SYSTEM_SYSVRCND_PATH="$withval"],
 616         [])
 617
 618 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 619 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 620 AC_SUBST(M4_DEFINES)
 621
 622 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 623         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 624         SYSTEM_SYSV_COMPAT="yes"
 625         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 626 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 627         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 628 else
 629         SYSTEM_SYSV_COMPAT="no"
 630 fi
 631
 632 AC_ARG_WITH([tty-gid],
 633         [AS_HELP_STRING([--with-tty-gid=GID],
 634                 [Specify the numeric GID of the 'tty' group])],
 635         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 636         [])
 637
 638 AC_ARG_ENABLE(plymouth, AS_HELP_STRING([--enable-plymouth], [enable plymouth support]))
 639 if test -n "$enable_plymouth"; then
 640         have_plymouth="$enable_plymouth"
 641 fi
 642
 643 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 644 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 645 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 646 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 647 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 648 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 649 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 650 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 651 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 652 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 653 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 654 AM_CONDITIONAL(TARGET_MEEGO, test x"$with_distro" = xmeego)
 655 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 656 AM_CONDITIONAL(TARGET_MAGEIA, test x"$with_distro" = xmageia)
 657
 658 AM_CONDITIONAL(HAVE_PLYMOUTH, test "$have_plymouth" = "yes")
 659 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 660
 661 AC_ARG_WITH([dbuspolicydir],
 662         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 663         [],
 664         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 665
 666 AC_ARG_WITH([dbussessionservicedir],
 667         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 668         [],
 669         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 670
 671 AC_ARG_WITH([dbussystemservicedir],
 672         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 673         [],
 674         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 675
 676 AC_ARG_WITH([dbusinterfacedir],
 677         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 678         [],
 679         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 680
 681 AC_ARG_WITH([rootprefix],
 682         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 683         [], [with_rootprefix=${ac_default_prefix}])
 684
 685 AC_ARG_WITH([rootlibdir],
 686         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 687         [],
 688         [with_rootlibdir=${libdir}])
 689
 690 AC_ARG_WITH([pamlibdir],
 691         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 692         [],
 693         [with_pamlibdir=${with_rootlibdir}/security])
 694
 695 AC_ARG_ENABLE([split-usr],
 696         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 697         [],
 698         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 699                 enable_split_usr=yes
 700         ], [
 701                 enable_split_usr=no
 702         ])])
 703
 704 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 705         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 706 ])
 707
 708 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 709 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 710 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 711 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 712 AC_SUBST([pamlibdir], [$with_pamlibdir])
 713 AC_SUBST([rootprefix], [$with_rootprefix])
 714 AC_SUBST([rootlibdir], [$with_rootlibdir])
 715
 716 AC_CONFIG_FILES([
 717         Makefile po/Makefile.in
 718         docs/libudev/Makefile
 719         docs/libudev/version.xml
 720         docs/gudev/Makefile
 721         docs/gudev/version.xml
 722 ])
 723
 724 AC_OUTPUT
 725 AC_MSG_RESULT([
 726         $PACKAGE_NAME $VERSION
 727
 728         Distribution:            ${with_distro}
 729         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 730         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 731         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 732         libcryptsetup:           ${have_libcryptsetup}
 733         tcpwrap:                 ${have_tcpwrap}
 734         PAM:                     ${have_pam}
 735         AUDIT:                   ${have_audit}
 736         IMA:                     ${have_ima}
 737         SELinux:                 ${have_selinux}
 738         XZ:                      ${have_xz}
 739         ACL:                     ${have_acl}
 740         binfmt:                  ${have_binfmt}
 741         vconsole:                ${have_vconsole}
 742         readahead:               ${have_readahead}
 743         quotacheck:              ${have_quotacheck}
 744         randomseed:              ${have_randomseed}
 745         logind:                  ${have_logind}
 746         hostnamed:               ${have_hostnamed}
 747         timedated:               ${have_timedated}
 748         localed:                 ${have_localed}
 749         coredump:                ${have_coredump}
 750         plymouth:                ${have_plymouth}
 751         firmware path:           ${FIRMWARE_PATH}
 752         usb.ids:                 ${USB_DATABASE}
 753         pci.ids:                 ${PCI_DATABASE}
 754         gudev:                   ${enable_gudev}
 755         gintrospection:          ${enable_introspection}
 756         keymap:                  ${enable_keymap}
 757
 758         prefix:                  ${prefix}
 759         rootprefix:              ${with_rootprefix}
 760         sysconf dir:             ${sysconfdir}
 761         datarootdir:             ${datarootdir}
 762         includedir:              ${includedir}
 763         include_prefix:          ${INCLUDE_PREFIX}
 764         libexec dir:             ${libexecdir}
 765         lib dir:                 ${libdir}
 766         rootlib dir:             ${with_rootlibdir}
 767         PAM modules dir:         ${with_pamlibdir}
 768         D-Bus policy dir:        ${with_dbuspolicydir}
 769         D-Bus session dir:       ${with_dbussessionservicedir}
 770         D-Bus system dir:        ${with_dbussystemservicedir}
 771         D-Bus interfaces dir:    ${with_dbusinterfacedir}
 772         Split /usr:              ${enable_split_usr}
 773         man pages:               ${have_manpages}
 774 ])