configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([elogind],
  23         [219.12],
  24         [https://github.com/andywingo/elogind/issues],
  25         [elogind],
  26         [https://github.com/andywingo/elogind])
  27
  28 AC_CONFIG_SRCDIR([src/login/logind.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41 LT_PREREQ(2.2)
  42 LT_INIT([disable-static])
  43
  44 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by elogind])])
  45 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by elogind])])
  46
  47 SET_ARCH(X86_64, x86_64*)
  48 SET_ARCH(IA32, i*86*)
  49 SET_ARCH(MIPS, mips*)
  50
  51 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  52 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  53 AS_IF([test x"$intltool_found" != xyes],
  54       [AS_IF([test x"$enable_nls" = xyes],
  55              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  56              [AS_IF([test x"$enable_nls" != xno],
  57                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  58                      enable_nls=no])
  59              ])
  60       ])
  61
  62 AM_NLS
  63 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  64     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  65 IT_PROG_INTLTOOL([0.40.0])
  66 ])
  67
  68 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  69     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  70     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  71     AC_SUBST(INTLTOOL_POLICY_RULE)
  72 ])
  73
  74 GETTEXT_PACKAGE=elogind
  75 AC_SUBST(GETTEXT_PACKAGE)
  76 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [elogind])
  77
  78 AC_PROG_MKDIR_P
  79 AC_PROG_LN_S
  80 AC_PROG_SED
  81 AC_PROG_GREP
  82 AC_PROG_AWK
  83
  84 AC_PROG_CC_C99
  85
  86 AC_PATH_PROG([M4], [m4])
  87 AC_PATH_PROG([XSLTPROC], [xsltproc])
  88
  89 AC_PATH_PROG([HALT], [halt], [halt])
  90 AC_PATH_PROG([REBOOT], [reboot], [reboot])
  91 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
  92
  93 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
  94
  95 M4_DEFINES=
  96
  97 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  98 m4_ifdef([GTK_DOC_CHECK], [
  99 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
 100          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
 101           enable_gtk_doc=no])
 102
 103 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
 104         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
 105 ])
 106
 107 AC_CHECK_TOOL(GPERF, gperf)
 108 if test -z "$GPERF" ; then
 109         AC_MSG_ERROR([*** gperf not found])
 110 fi
 111
 112 # ------------------------------------------------------------------------------
 113 address_sanitizer_cflags=
 114 address_sanitizer_cppflags=
 115 address_sanitizer_ldflags=
 116 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 117 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 118             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 119             AS_IF([test -z "$with_as_cflags"],
 120                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 121             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 122             address_sanitizer_cppflags="-DVALGRIND=1"
 123             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 124       ])
 125
 126 undefined_sanitizer_cflags=
 127 undefined_sanitizer_cppflags=
 128 undefined_sanitizer_ldflags=
 129 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 130 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 131             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 132             AS_IF([test -z "$with_us_cflags"],
 133                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 134             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 135             undefined_sanitizer_cppflags="-DVALGRIND=1"
 136             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 137       ])
 138
 139 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 140 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 141 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 142
 143 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 144         -pipe \
 145         -Wall \
 146         -Wextra \
 147         -Wno-inline \
 148         -Wundef \
 149         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 150         -Wlogical-op \
 151         -Wsign-compare \
 152         -Wmissing-include-dirs \
 153         -Wold-style-definition \
 154         -Wpointer-arith \
 155         -Winit-self \
 156         -Wdeclaration-after-statement \
 157         -Wfloat-equal \
 158         -Wsuggest-attribute=noreturn \
 159         -Wmissing-prototypes \
 160         -Wstrict-prototypes \
 161         -Wredundant-decls \
 162         -Wmissing-declarations \
 163         -Wmissing-noreturn \
 164         -Wshadow \
 165         -Wendif-labels \
 166         -Wstrict-aliasing=2 \
 167         -Wwrite-strings \
 168         -Wno-long-long \
 169         -Wno-overlength-strings \
 170         -Wno-unused-parameter \
 171         -Wno-missing-field-initializers \
 172         -Wno-unused-result \
 173         -Wno-format-signedness \
 174         -Werror=overflow \
 175         -Wdate-time \
 176         -Wnested-externs \
 177         -ffast-math \
 178         -fno-common \
 179         -fdiagnostics-show-option \
 180         -fno-strict-aliasing \
 181         -fvisibility=hidden \
 182         -ffunction-sections \
 183         -fdata-sections \
 184         -fstack-protector \
 185         -fstack-protector-strong \
 186         -fPIE \
 187         --param=ssp-buffer-size=4])
 188
 189 AS_CASE([$CC], [*clang*],
 190         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 191                -Wno-typedef-redefinition \
 192                -Wno-gnu-variable-sized-type-not-at-end \
 193         ])])
 194
 195 dnl AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 196 dnl         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 197 dnl                -flto -ffat-lto-objects])],
 198 dnl         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 199 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 200
 201 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 202         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 203                -Wp,-D_FORTIFY_SOURCE=2])],
 204         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 205 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 206
 207 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 208         -Wl,--as-needed \
 209         -Wl,--no-undefined \
 210         -Wl,--gc-sections \
 211         -Wl,-z,relro \
 212         -Wl,-z,now \
 213         -pie \
 214         -Wl,-fuse-ld=gold])
 215 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 216
 217 AC_CHECK_SIZEOF(pid_t)
 218 AC_CHECK_SIZEOF(uid_t)
 219 AC_CHECK_SIZEOF(gid_t)
 220 AC_CHECK_SIZEOF(time_t)
 221 AC_CHECK_SIZEOF(dev_t)
 222 AC_CHECK_SIZEOF(rlim_t,,[
 223        #include <sys/time.h>
 224        #include <sys/resource.h>
 225 ])
 226
 227 # ------------------------------------------------------------------------------
 228
 229 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 230 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 231 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 232
 233 # unconditionally pull-in librt with old glibc versions
 234 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 235
 236 AC_ARG_WITH([libcap],
 237             AS_HELP_STRING([--with-libcap=DIR], [Prefix for libcap]),
 238             [CAP_LDFLAGS="-L$with_libcap/lib"],
 239             [CAP_LDFLAGS=""])
 240 save_LIBS="$LIBS"
 241 LIBS=
 242 LDFLAGS="$LDFLAGS $CAP_LDFLAGS"
 243 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 244 CAP_LIBS="$LIBS"
 245 AC_SUBST(CAP_LIBS)
 246 AC_SUBST(CAP_LDFLAGS)
 247 LDFLAGS="$save_LDFLAGS"
 248
 249 AC_CHECK_FUNCS([memfd_create])
 250 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 251 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2, kcmp, LO_FLAGS_PARTSCAN],
 252                [], [], [[
 253 #include <sys/types.h>
 254 #include <unistd.h>
 255 #include <sys/mount.h>
 256 #include <fcntl.h>
 257 #include <sched.h>
 258 #include <linux/loop.h>
 259 #include <linux/random.h>
 260 ]])
 261
 262 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 263                 IFLA_MACVLAN_FLAGS,
 264                 IFLA_IPVLAN_MODE,
 265                 IFLA_VTI_REMOTE,
 266                 IFLA_PHYS_PORT_ID,
 267                 IFLA_BOND_AD_INFO,
 268                 IFLA_VLAN_PROTOCOL,
 269                 IFLA_VXLAN_LOCAL6,
 270                 IFLA_IPTUN_6RD_RELAY_PREFIXLEN,
 271                 IFLA_BRIDGE_VLAN_INFO,
 272                 IFLA_BRPORT_UNICAST_FLOOD,
 273                 NDA_IFINDEX],
 274 [], [], [[
 275 #include <inttypes.h>
 276 #include <netinet/in.h>
 277 #include <netinet/ether.h>
 278 #include <linux/rtnetlink.h>
 279 #include <net/if.h>
 280 #include <linux/ip.h>
 281 #include <linux/if_tunnel.h>
 282 #include <linux/if_link.h>
 283 #include <linux/if_bridge.h>
 284 #include <linux/neighbour.h>
 285 ]])
 286
 287 # This makes sure pkg.m4 is available.
 288 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 289
 290 # ------------------------------------------------------------------------------
 291 have_dbus=no
 292 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 293 AS_IF([test "x$enable_dbus" != "xno"], [
 294         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 295                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 296                 [have_dbus=no])
 297         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 298                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 299 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 300
 301 # ------------------------------------------------------------------------------
 302 PKG_CHECK_MODULES(UDEV, [libudev])
 303
 304 AC_ARG_WITH([udevrulesdir],
 305             AS_HELP_STRING([--with-udevrulesdir=DIR], [Directory for udev rules files]),
 306             [],
 307             [with_udevrulesdir=$($PKG_CONFIG --variable=udevdir udev)/rules.d])
 308 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 309 AC_SUBST([udevbindir], [$($PKG_CONFIG --variable=udevdir udev)/../bin])
 310
 311 # ------------------------------------------------------------------------------
 312 have_coverage=no
 313 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 314 if test "x$enable_coverage" = "xyes" ; then
 315         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 316         if test "x$lcov_found" = xno ; then
 317                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 318         else
 319                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 320                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 321                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 322                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 323                 else
 324                         have_coverage=yes
 325                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 326                         -fprofile-arcs \
 327                         -ftest-coverage])
 328                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 329                 fi
 330         fi
 331 fi
 332 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 333
 334 # ------------------------------------------------------------------------------
 335 have_blkid=no
 336 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 337 if test "x$enable_blkid" != "xno"; then
 338         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 339                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 340         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 341                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 342         fi
 343 fi
 344 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 345
 346 # ------------------------------------------------------------------------------
 347 have_seccomp=no
 348 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 349 if test "x$enable_seccomp" != "xno"; then
 350         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 351                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 352                 have_seccomp=yes
 353                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 354                [have_seccomp=no])
 355         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 356                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 357         fi
 358 fi
 359 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 360
 361 # ------------------------------------------------------------------------------
 362 have_selinux=no
 363 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 364 if test "x$enable_selinux" != "xno"; then
 365         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 366                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 367                  have_selinux=yes
 368                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 369                 [have_selinux=no])
 370         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 371                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 372         fi
 373 fi
 374 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 375
 376 have_apparmor=no
 377 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 378 if test "x$enable_apparmor" != "xno"; then
 379         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 380                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 381                  have_apparmor=yes
 382                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 383                 [have_apparmor=no])
 384         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 385                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 386         fi
 387 fi
 388 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 389
 390 # ------------------------------------------------------------------------------
 391 AC_ARG_ENABLE([pam],
 392         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 393                 [case "${enableval}" in
 394                         yes) have_pam=yes ;;
 395                         no) have_pam=no ;;
 396                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 397                 esac],
 398                 [have_pam=auto])
 399
 400 if test "x${have_pam}" != xno ; then
 401         AC_CHECK_HEADERS(
 402                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 403                 [have_pam=yes],
 404                 [if test "x$have_pam" = xyes ; then
 405                         AC_MSG_ERROR([*** PAM headers not found.])
 406                 fi])
 407
 408         AC_CHECK_LIB(
 409                 [pam],
 410                 [pam_syslog],
 411                 [have_pam=yes],
 412                 [if test "x$have_pam" = xyes ; then
 413                         AC_MSG_ERROR([*** libpam not found.])
 414                 fi])
 415
 416         if test "x$have_pam" = xyes ; then
 417                 PAM_LIBS="-lpam -lpam_misc"
 418                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 419                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 420         else
 421                 have_pam=no
 422         fi
 423 else
 424         PAM_LIBS=
 425 fi
 426 AC_SUBST(PAM_LIBS)
 427 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 428
 429 # ------------------------------------------------------------------------------
 430 AC_ARG_ENABLE([acl],
 431         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 432                 [case "${enableval}" in
 433                         yes) have_acl=yes ;;
 434                         no) have_acl=no ;;
 435                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 436                 esac],
 437                 [have_acl=auto])
 438
 439 if test "x${have_acl}" != xno ; then
 440         AC_CHECK_HEADERS(
 441                 [sys/acl.h acl/libacl.h],
 442                 [have_acl=yes],
 443                 [if test "x$have_acl" = xyes ; then
 444                         AC_MSG_ERROR([*** ACL headers not found.])
 445                 fi])
 446
 447         AC_CHECK_LIB(
 448                 [acl],
 449                 [acl_get_file],
 450                 [have_acl=yes],
 451                 [if test "x$have_acl" = xyes ; then
 452                         AC_MSG_ERROR([*** libacl not found.])
 453                 fi])
 454
 455         if test "x$have_acl" = xyes ; then
 456                 ACL_LIBS="-lacl"
 457                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 458                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 459         else
 460                 have_acl=no
 461         fi
 462 else
 463         ACL_LIBS=
 464 fi
 465 AC_SUBST(ACL_LIBS)
 466 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 467
 468 # ------------------------------------------------------------------------------
 469 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 470                 [case "${enableval}" in
 471                         yes) have_smack=yes ;;
 472                         no) have_smack=no ;;
 473                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 474                 esac],
 475                 [have_smack=auto])
 476
 477 if test "x${have_smack}" = xauto; then
 478         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 479         have_smack=yes
 480 fi
 481
 482 AC_ARG_WITH(smack-run-label,
 483 AS_HELP_STRING([--with-smack-run-label=STRING],
 484         [run systemd --system with a specific SMACK label]),
 485         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run with a smack label])],
 486         [])
 487
 488 if test "x${have_smack}" = xyes ; then
 489         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 490 fi
 491
 492 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 493
 494 # ------------------------------------------------------------------------------
 495 AC_ARG_WITH(system-uid-max,
 496         AS_HELP_STRING([--with-system-uid-max=UID]
 497                 [Maximum UID for system users]),
 498         [SYSTEM_UID_MAX="$withval"],
 499         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
 500
 501 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
 502 AC_SUBST(SYSTEM_UID_MAX)
 503
 504 # ------------------------------------------------------------------------------
 505 AC_ARG_WITH(system-gid-max,
 506         AS_HELP_STRING([--with-system-gid-max=GID]
 507                 [Maximum GID for system groups]),
 508         [SYSTEM_GID_MAX="$withval"],
 509         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
 510
 511 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
 512 AC_SUBST(SYSTEM_GID_MAX)
 513
 514 # ------------------------------------------------------------------------------
 515 have_polkit=no
 516 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 517 if test "x$enable_polkit" != "xno"; then
 518         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 519         have_polkit=yes
 520 fi
 521 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 522
 523 # ------------------------------------------------------------------------------
 524 have_kdbus=no
 525 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--enable-kdbus], [do connect to kdbus by default]))
 526 if test "x$enable_kdbus" = "xyes"; then
 527         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus support is to be enabled])
 528         have_kdbus=yes
 529         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
 530 fi
 531 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
 532
 533 # ------------------------------------------------------------------------------
 534 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
 535
 536 # ------------------------------------------------------------------------------
 537 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0],
 538                   [have_glib=yes], [have_glib=no])
 539 AS_IF([test "x$have_glib" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 540
 541 # ------------------------------------------------------------------------------
 542 have_manpages=no
 543 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 544 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
 545 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 546
 547 # ------------------------------------------------------------------------------
 548 AC_SUBST(M4_DEFINES)
 549
 550 AC_ARG_WITH([dbuspolicydir],
 551         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 552         [],
 553         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
 554
 555 AC_ARG_WITH([dbussessionservicedir],
 556         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 557         [],
 558         [with_dbussessionservicedir=${datadir}/dbus-1/services])
 559
 560 AC_ARG_WITH([dbussystemservicedir],
 561         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 562         [],
 563         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
 564
 565 AC_ARG_WITH([bashcompletiondir],
 566         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 567         [],
 568         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 569                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 570         ] , [
 571                 with_bashcompletiondir=${datadir}/bash-completion/completions
 572         ])])
 573
 574 AC_ARG_WITH([zshcompletiondir],
 575         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
 576         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
 577
 578 AC_ARG_WITH([rootlibdir],
 579         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 580         [],
 581         [with_rootlibdir=${libdir}])
 582
 583 AC_ARG_WITH([pamlibdir],
 584         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 585         [],
 586         [with_pamlibdir=${with_rootlibdir}/security])
 587
 588 AC_ARG_WITH([pamconfdir],
 589         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
 590         [],
 591         [with_pamconfdir=${sysconfdir}/pam.d])
 592
 593 AC_ARG_ENABLE([split-usr],
 594         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 595         [],
 596         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 597                 enable_split_usr=yes
 598         ], [
 599                 enable_split_usr=no
 600         ])])
 601
 602 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 603         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 604 ])
 605
 606 # Work around intltoolize and gtk-doc problems in VPATH builds
 607 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 608                                        [Define to do gtk-doc tests])
 609 AS_IF([test "x$0" != "x./configure"], [
 610         AC_SUBST([INTLTOOL_UPDATE], [/usr/bin/env true])
 611 ])
 612
 613 AC_ARG_ENABLE(tests,
 614         [AC_HELP_STRING([--disable-tests], [disable tests])],
 615         enable_tests=$enableval, enable_tests=yes)
 616 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 617
 618 AC_ARG_ENABLE(debug,
 619         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
 620         [if test "x$enableval" = "xyes"; then
 621                 enableval="hashmap,mmap-cache"
 622         fi
 623         saved_ifs="$IFS"
 624         IFS="$IFS$PATH_SEPARATOR,"
 625         for name in $enableval; do
 626                 case $name in
 627                 hashmap)
 628                         enable_debug_hashmap=yes
 629                         ;;
 630                 mmap-cache)
 631                         enable_debug_mmap_cache=yes
 632                         ;;
 633                 esac
 634         done
 635         IFS="$saved_ifs"],[])
 636
 637 enable_debug=""
 638 AS_IF([test x$enable_debug_hashmap = xyes], [
 639         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
 640         enable_debug="hashmap $enable_debug"
 641 ])
 642 AS_IF([test x$enable_debug_mmap_cache = xyes], [
 643         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
 644         enable_debug="mmap-cache $enable_debug"
 645 ])
 646 test -z "$enable_debug" && enable_debug="none"
 647
 648 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 649 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 650 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 651 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 652 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
 653 AC_SUBST([pamlibdir], [$with_pamlibdir])
 654 AC_SUBST([pamconfdir], [$with_pamconfdir])
 655 AC_SUBST([rootlibdir], [$with_rootlibdir])
 656
 657 AC_CONFIG_FILES([
 658         Makefile po/Makefile.in
 659 ])
 660
 661 AC_OUTPUT
 662 AC_MSG_RESULT([
 663         $PACKAGE_NAME $VERSION
 664
 665         PAM:                     ${have_pam}
 666         AppArmor:                ${have_apparmor}
 667         SELinux:                 ${have_selinux}
 668         SECCOMP:                 ${have_seccomp}
 669         SMACK:                   ${have_smack}
 670         ACL:                     ${have_acl}
 671         polkit:                  ${have_polkit}
 672         blkid:                   ${have_blkid}
 673         dbus:                    ${have_dbus}
 674         kdbus:                   ${have_kdbus}
 675         man pages:               ${have_manpages}
 676         gtk-doc:                 ${enable_gtk_doc}
 677         test coverage:           ${have_coverage}
 678         Split /usr:              ${enable_split_usr}
 679         extra debugging:         ${enable_debug}
 680
 681         prefix:                  ${prefix}
 682         sysconf dir:             ${sysconfdir}
 683         datarootdir:             ${datarootdir}
 684         includedir:              ${includedir}
 685         lib dir:                 ${libdir}
 686         rootlib dir:             ${with_rootlibdir}
 687         PAM modules dir:         ${with_pamlibdir}
 688         PAM configuration dir:   ${with_pamconfdir}
 689         D-Bus policy dir:        ${with_dbuspolicydir}
 690         D-Bus session dir:       ${with_dbussessionservicedir}
 691         D-Bus system dir:        ${with_dbussystemservicedir}
 692         Bash completions dir:    ${with_bashcompletiondir}
 693         Zsh completions dir:     ${with_zshcompletiondir}
 694         Maximum System UID:      ${SYSTEM_UID_MAX}
 695         Maximum System GID:      ${SYSTEM_GID_MAX}
 696
 697         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 698         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
 699         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 700 ])